data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  42                 {\r
  43                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  44                         {\r
  45                                 play2(self, "misc/forbidden.wav");\r
  46                                 sprint(self, "You cannot swallow your team mates\n");\r
  47                                 self.complain_vore = time + complain_delay_time;\r
  48                         }\r
  49                         return FALSE;\r
  50                 }\r
  51 \r
  52                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  53                 {\r
  54                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  55                         {\r
  56                                 play2(self, "misc/forbidden.wav");\r
  57                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  58                                 self.complain_vore = time + complain_delay_time;\r
  59                         }\r
  60                         return FALSE;\r
  61                 }\r
  62 \r
  63                 if(cvar("g_vore_biggergut"))\r
  64                 if(prey.stomach_load > self.stomach_load)\r
  65                 {\r
  66                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  67                         {\r
  68                                 play2(self, "misc/forbidden.wav");\r
  69                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  70                                 self.complain_vore = time + complain_delay_time;\r
  71                         }\r
  72                         return FALSE;\r
  73                 }\r
  74 \r
  75                 if(!cvar("g_vore_spawnshield"))\r
  76                 if(prey.spawnshieldtime > time)\r
  77                 {\r
  78                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  79                         {\r
  80                                 play2(self, "misc/forbidden.wav");\r
  81                                 sprint(self, "You cannot swallow someone protected by the spawn shield\n");\r
  82                                 self.complain_vore = time + complain_delay_time;\r
  83                         }\r
  84                         return FALSE;\r
  85                 }\r
  86 \r
  87                 return TRUE;\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_TeamMates_check(entity pred)\r
  93 {\r
  94         // checks if a player's stomach contains any team mates\r
  95 \r
  96         entity head;\r
  97         if(teams_matter)\r
  98         {\r
  99                 FOR_EACH_PLAYER(head)\r
 100                 {\r
 101                         if(head.predator == pred && head.team == pred.team)\r
 102                                 return TRUE;\r
 103                 }\r
 104         }\r
 105         return FALSE;\r
 106 }\r
 107 \r
 108 float Vore_CanLeave()\r
 109 {\r
 110         if(self.predator.classname == "player")\r
 111         {\r
 112                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 113                         return TRUE;\r
 114                 if(teams_matter && self.team == self.predator.team)\r
 115                         return TRUE;\r
 116                 if(g_rpg && cvar("g_rpg_canleave"))\r
 117                         return TRUE;\r
 118         }\r
 119         return FALSE;\r
 120 }\r
 121 \r
 122 // position the camera properly for prey\r
 123 void Vore_SetCamera()\r
 124 {\r
 125         if not(self.predator.classname == "player" || self.fakeprey > 1)\r
 126                 return;\r
 127 \r
 128         self.view_ofs = PL_PREY_VIEW_OFS;\r
 129 \r
 130         float prey_height;\r
 131         if(self.fakeprey > 1)\r
 132                 prey_height = (self.scale - self.fakepredator.scale) * cvar("g_healthsize_vore_pos");\r
 133         else\r
 134                 prey_height = (self.scale - self.predator.scale) * cvar("g_healthsize_vore_pos");\r
 135         self.view_ofs_z += prey_height;\r
 136 }\r
 137 \r
 138 .float gurgle_oldstomachload;\r
 139 void Vore_GurgleSound()\r
 140 {\r
 141         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 142         {\r
 143                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 144 \r
 145                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 146                 self.gurgle_oldstomachload = self.stomach_load;\r
 147         }\r
 148 }\r
 149 \r
 150 void Vore_WeightApply(entity e)\r
 151 {\r
 152         // apply stomach weight that makes you heavier the more you eat\r
 153         // slowing the player is done in cl_physics.qc\r
 154 \r
 155         if(e.stomach_load != e.vore_oldstomachload)\r
 156                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 157         if(e.gravity == 0)\r
 158                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 159         e.vore_oldstomachload = e.stomach_load;\r
 160 }\r
 161 \r
 162 void Vore_AutoDigest(entity e)\r
 163 {\r
 164         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 165 \r
 166         if(!cvar("g_vore_digestion") || e.digesting)\r
 167                 return;\r
 168         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 169                 return; // this feature is only for players, not bots\r
 170         if(e.stomach_load > 1)\r
 171                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 172         if(Stomach_TeamMates_check(e))\r
 173                 return; // never begin automatic digestion if we've swallowed a team mate\r
 174 \r
 175         e.digesting = TRUE;\r
 176 }\r
 177 \r
 178 .entity pusher;\r
 179 .float pushltime;\r
 180 void Vore_Swallow(entity e)\r
 181 {\r
 182         // this player is being swallowed by another player, apply the proper changes\r
 183 \r
 184         e.vore_oldmovetype = e.movetype;\r
 185         e.vore_oldsolid = e.solid;\r
 186 \r
 187         e.predator = self;\r
 188         setorigin(e, e.predator.origin);\r
 189         e.velocity = '0 0 0';\r
 190         e.movetype = MOVETYPE_FOLLOW;\r
 191         e.solid = SOLID_NOT;\r
 192         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 193 \r
 194         // drop keys (KH) and flags (CTF) when we get swallowed\r
 195         kh_Key_DropAll(e, FALSE);\r
 196         if(e.flagcarried)\r
 197                 DropFlag(e.flagcarried, world, e.predator);\r
 198 \r
 199         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 200                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 201 \r
 202         if(teams_matter && e.team == e.predator.team)\r
 203         {\r
 204                 if(cvar("g_vore_kick"))\r
 205                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 206                 if(cvar("g_vore_digestion"))\r
 207                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 208         }\r
 209 \r
 210         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 211         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 212         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 213         e.predator.stomach_load += 1;\r
 214         e.predator.regurgitate_prepare = 0;\r
 215         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 216         Vore_WeightApply(e.predator);\r
 217         Vore_AutoDigest(e.predator);\r
 218 \r
 219         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 220         e.predator.weapon_delay = time + button_delay_time;\r
 221         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 222         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 223 }\r
 224 \r
 225 void Vore_Regurgitate(entity e)\r
 226 {\r
 227         // this player is being regurgitated by their predator, apply the proper changes\r
 228 \r
 229         e.movetype = e.vore_oldmovetype;\r
 230         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 231                 e.solid = e.vore_oldsolid;\r
 232         e.view_ofs_z = PL_VIEW_OFS_z;\r
 233 \r
 234         // apply velocities\r
 235         local vector oldforward, oldright, oldup;\r
 236         oldforward = v_forward;\r
 237         oldright = v_right;\r
 238         oldup = v_up;\r
 239         makevectors(e.predator.v_angle);\r
 240         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 241         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 242         v_forward = oldforward;\r
 243         v_right = oldright;\r
 244         v_up = oldup;\r
 245 \r
 246         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 247         e.pushltime = time + cvar("g_maxpushtime");\r
 248 \r
 249         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 250         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 251         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 252         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 253         e.predator.stomach_load -= 1;\r
 254         e.predator.regurgitate_prepare = 0;\r
 255         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 256         Vore_WeightApply(e.predator);\r
 257 \r
 258         // block firing for a small amount of time, or we'll be firing the next frame\r
 259         e.weapon_delay = time + button_delay_time;\r
 260         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 261         e.predator = world;\r
 262 }\r
 263 \r
 264 void Vore_DeadPrey_Configure(entity e)\r
 265 {\r
 266         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 267 \r
 268         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 269                 return;\r
 270 \r
 271         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 272         e.fakepredator = e.predator;\r
 273         e.fakeprey = 2; // is fakeprey in a stomach\r
 274 \r
 275         // first release the prey from the predator, as dead prey needs to be attached differently\r
 276         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 277         e.predator.stomach_load -= 1;\r
 278         Vore_WeightApply(e.predator);\r
 279         e.predator = world;\r
 280 \r
 281         // now put our dead prey inside the predator's stomach, but only as an effect\r
 282         e.movetype = MOVETYPE_FOLLOW;\r
 283         e.takedamage = DAMAGE_NO;\r
 284         e.solid = SOLID_NOT;\r
 285         e.aiment = e.fakepredator;\r
 286 }\r
 287 \r
 288 void Vore_DeadPrey_Detach(entity e)\r
 289 {\r
 290         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 291         // should only execute after Vore_DeadPrey_Configure has ran first\r
 292 \r
 293         if not(cvar("g_vore_keepdeadprey"))\r
 294                 return;\r
 295 \r
 296         e.fakepredator = world;\r
 297         e.fakeprey = 1; // was fakeprey but is now detached\r
 298         e.aiment = world;\r
 299         e.movetype = MOVETYPE_TOSS;\r
 300 }\r
 301 \r
 302 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 303 {\r
 304         if(pred_disconnect)\r
 305         {\r
 306                 if(e.fakeprey > 1)\r
 307                         Vore_DeadPrey_Detach(e);\r
 308                 else\r
 309                         Vore_Regurgitate(e);\r
 310         }\r
 311         else\r
 312         {\r
 313                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 314                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 315                         Vore_DeadPrey_Configure(e);\r
 316                 else\r
 317                         Vore_Regurgitate(e);\r
 318         }\r
 319 }\r
 320 \r
 321 void Vore_Disconnect()\r
 322 {\r
 323         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 324 \r
 325         // prey disconnects or goes spectating while inside someone's belly\r
 326         if(self.predator.classname == "player")\r
 327                 Vore_PreyRelease(self, TRUE);\r
 328 \r
 329         // pred disconnects or goes spectating with players in their belly\r
 330         entity head;\r
 331         FOR_EACH_PLAYER(head)\r
 332         {\r
 333                 if(head.predator == self || head.fakepredator == self)\r
 334                         Vore_PreyRelease(head, TRUE);\r
 335         }\r
 336         Vore_GurgleSound(); // stop the gurgling sound\r
 337 \r
 338         self.stomach_load = self.gravity = 0; // prevents a bug\r
 339 }\r
 340 \r
 341 .float digestion_step;\r
 342 void Vore_Digest()\r
 343 {\r
 344         // apply digestion to prey\r
 345 \r
 346         if(time > self.predator.digestion_step)\r
 347         {\r
 348                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 349                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 350                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 351 \r
 352                 if (self.predator.digestsound_finished < time)\r
 353                 {\r
 354                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 355                         self.predator.digestsound_finished = time + 0.5;\r
 356                 }\r
 357                 self.predator.digestion_step = time + steptime;\r
 358         }\r
 359 \r
 360         if(self.deadflag != DEAD_NO)\r
 361         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 362                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 363 }\r
 364 \r
 365 .float teamheal_step;\r
 366 void Vore_Teamheal()\r
 367 {\r
 368         // apply teamheal\r
 369 \r
 370         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 371         if(time > self.teamheal_step)\r
 372         {\r
 373                 self.health += cvar("g_balance_vore_teamheal");\r
 374                 self.teamheal_step = time + steptime;\r
 375 \r
 376                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 377                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 378                 {\r
 379                         play2(self, "misc/beep.wav");\r
 380                         play2(self.predator, "misc/beep.wav");\r
 381                 }\r
 382         }\r
 383 }\r
 384 \r
 385 .float stomachkick_delay;\r
 386 void Vore_StomachKick()\r
 387 {\r
 388         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 389 \r
 390         if(time > self.stomachkick_delay)\r
 391         {\r
 392                 float damage;\r
 393                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 394 \r
 395                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 396                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 397                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 398                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 399 \r
 400                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 401                         Vore_Regurgitate(self);\r
 402 \r
 403                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 404         }\r
 405 }\r
 406 \r
 407 void Vore_StomachLeave()\r
 408 {\r
 409         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 410 \r
 411         if(Vore_CanLeave())\r
 412                 Vore_Regurgitate(self);\r
 413         else if(time > self.complain_vore)\r
 414         {\r
 415                 play2(self, "misc/forbidden.wav");\r
 416                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 417                 self.complain_vore = time + complain_delay_time;\r
 418         }\r
 419 }\r
 420 \r
 421 void Vore_AutoTaunt()\r
 422 {\r
 423         // triggers ambient vore taunts, for both pred and prey\r
 424 \r
 425         float taunt_time;\r
 426 \r
 427         // predator taunts\r
 428         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 429         {\r
 430                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 431                 {\r
 432                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 433                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 434                 }\r
 435         }\r
 436         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 437         {\r
 438                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 439                 SetAutoTaunt(self, 0, 0);\r
 440         }\r
 441 \r
 442         // prey taunts\r
 443         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 444         {\r
 445                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 446                 {\r
 447                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 448                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 449                 }\r
 450         }\r
 451         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 452         {\r
 453                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 454                 SetAutoTaunt(self, 0, 0);\r
 455         }\r
 456 }\r
 457 \r
 458 void Vore()\r
 459 {\r
 460         // main vore code, this is where it all happens\r
 461 \r
 462         if(!cvar("g_vore")) // the vore system is disabled\r
 463         {\r
 464                 Vore_Disconnect();\r
 465                 return;\r
 466         }\r
 467 \r
 468         Vore_AutoTaunt();\r
 469 \r
 470         // wash the goo away from players once they leave the stomach\r
 471         if(self.predator.classname != "player")\r
 472         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 473         if(self.colormod)\r
 474         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 475         {\r
 476                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 477                 if(self.colormod_x > 1)\r
 478                         self.colormod_x = 1;\r
 479                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 480                 if(self.colormod_y > 1)\r
 481                         self.colormod_y = 1;\r
 482                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 483                 if(self.colormod_z > 1)\r
 484                         self.colormod_z = 1;\r
 485         }\r
 486 \r
 487         // set all vore stats\r
 488         if(self.fakeprey > 1)\r
 489                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 490         else if(self.predator.classname == "player")\r
 491         {\r
 492                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 493                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 494                 self.stat_eaten = num_for_edict(self.predator);\r
 495         }\r
 496         else\r
 497         {\r
 498                 self.stat_stomachload = self.stomach_load;\r
 499                 self.stat_digesting = self.digesting;\r
 500                 self.stat_eaten = 0;\r
 501         }\r
 502         self.stat_canleave = Vore_CanLeave();\r
 503 \r
 504         // don't allow a player inside a player inside another player :)\r
 505         // prevent this by checking if such has happened, and taking the proper measures\r
 506         // this code has a high priority and must not be stopped by any delay, so run it here\r
 507         if(self.predator.predator.classname == "player")\r
 508         {\r
 509                 entity target_predator, target_predator_predator, oldself;\r
 510                 target_predator = self.predator;\r
 511                 target_predator_predator = self.predator.predator;\r
 512 \r
 513                 Vore_Regurgitate(self);\r
 514 \r
 515                 // now steal our prey's prey if this probability applies\r
 516                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 517                 {\r
 518                         oldself = self;\r
 519                         self = target_predator_predator;\r
 520                         if(Swallow_condition_check(oldself))\r
 521                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 522                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 523                                 Vore_Swallow(oldself);\r
 524                         self = oldself;\r
 525                 }\r
 526         }\r
 527 \r
 528         // apply delays and skip the vore system under some circumstances\r
 529         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 530         {\r
 531                 Vore_Disconnect();\r
 532                 return;\r
 533         }\r
 534         if(self.spectatee_status)\r
 535                 return;\r
 536         if(time < self.system_delay)\r
 537                 return;\r
 538 \r
 539 // --------------------------------\r
 540 // Code that addresses predators:\r
 541 // --------------------------------\r
 542 \r
 543         entity prey;\r
 544         prey = Swallow_player_check();\r
 545 \r
 546         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 547         self.stat_canswallow = 0;\r
 548         if(Swallow_condition_check(prey))\r
 549         {\r
 550                 // canswallow stat, used by the HUD\r
 551                 if(teams_matter && prey.team == self.team)\r
 552                         self.stat_canswallow = 2;\r
 553                 else\r
 554                         self.stat_canswallow = 1;\r
 555 \r
 556                 if(self.BUTTON_ATCK)\r
 557                         Vore_Swallow(prey);\r
 558         }\r
 559         else if(prey != world)\r
 560                 self.stat_canswallow = -1;\r
 561 \r
 562         // toggle digestion, if the player has someone in their stomach\r
 563         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 564         {\r
 565                 if(self.stomach_load)\r
 566                 {\r
 567                         if(time > self.digest_button_delay_time)\r
 568                         {\r
 569                                 self.digesting = !self.digesting;\r
 570                                 self.digest_button_delay_time = time + button_delay_time;\r
 571                         }\r
 572                 }\r
 573                 else if(time > self.complain_vore)\r
 574                 {\r
 575                         play2(self, "misc/forbidden.wav");\r
 576                         sprint(self, "There is nothing to digest\n");\r
 577                         self.complain_vore = time + complain_delay_time;\r
 578                 }\r
 579         }\r
 580         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 581                 self.digesting = FALSE;\r
 582 \r
 583         // predator wishes to regurgitate his prey\r
 584         if(self.BUTTON_REGURGITATE)\r
 585         {\r
 586                 if(self.stomach_load)\r
 587                 {\r
 588                         if(time > self.regurgitate_button_delay_time)\r
 589                         {\r
 590                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 591                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 592                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 593                         }\r
 594                 }\r
 595                 else if(time > self.complain_vore)\r
 596                 {\r
 597                         play2(self, "misc/forbidden.wav");\r
 598                         sprint(self, "There is nothing to regurgitate\n");\r
 599                         self.complain_vore = time + complain_delay_time;\r
 600                 }\r
 601         }\r
 602 \r
 603         if(cvar("g_vore_gurglesound"))\r
 604                 Vore_GurgleSound();\r
 605 \r
 606 // --------------------------------\r
 607 // Code that addresses the prey:\r
 608 // --------------------------------\r
 609 \r
 610         Vore_SetCamera();\r
 611 \r
 612         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 613         if(self.fakepredator.classname == "player")\r
 614         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 615                 Vore_DeadPrey_Detach(self);\r
 616 \r
 617         if(self.predator.classname != "player")\r
 618                 return;\r
 619 \r
 620         if(self.deadflag != DEAD_NO)\r
 621         {\r
 622                 Vore_PreyRelease(self, FALSE);\r
 623                 return;\r
 624         }\r
 625 \r
 626         if(self.predator.deadflag != DEAD_NO)\r
 627                 Vore_Regurgitate(self);\r
 628         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 629                 Vore_Regurgitate(self);\r
 630 \r
 631         // apply delayed regurgitating if it was scheduled\r
 632         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 633         {\r
 634                 self.predator.regurgitate_prepare = 0;\r
 635                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 636                 Vore_Regurgitate(self);\r
 637         }\r
 638 \r
 639         // execute digesting and team healing\r
 640         if(self.predator.digesting == TRUE)\r
 641                 Vore_Digest();\r
 642         if(teams_matter && self.team == self.predator.team)\r
 643         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 644                 Vore_Teamheal();\r
 645 \r
 646         // execute prey commands\r
 647         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 648                 Vore_StomachKick();\r
 649         if(self.BUTTON_JUMP)\r
 650                 Vore_StomachLeave();\r
 651 \r
 652         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 653         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 654         kh_Key_DropAll(self, FALSE);\r
 655 }