data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  34         {\r
  35                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  36                 {\r
  37                         if(time > self.complain_vore)\r
  38                         {\r
  39                                 play2(self, "misc/unavailable.wav");\r
  40                                 sprint(self, "You cannot swallow your team mates\n");\r
  41                                 self.complain_vore = time + complain_delay_time;\r
  42                         }\r
  43                         return FALSE;\r
  44                 }\r
  45 \r
  46                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                 {\r
  48                         if(time > self.complain_vore)\r
  49                         {\r
  50                                 play2(self, "misc/unavailable.wav");\r
  51                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  52                                 self.complain_vore = time + complain_delay_time;\r
  53                         }\r
  54                         return FALSE;\r
  55                 }\r
  56 \r
  57                 if(cvar("g_vore_biggergut"))\r
  58                 if(prey.stomach_load > self.stomach_load)\r
  59                 {\r
  60                         if(time > self.complain_vore)\r
  61                         {\r
  62                                 play2(self, "misc/unavailable.wav");\r
  63                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  64                                 self.complain_vore = time + complain_delay_time;\r
  65                         }\r
  66                         return FALSE;\r
  67                 }\r
  68 \r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Vore_CanLeave()\r
  75 {\r
  76         if(self.predator.classname == "player")\r
  77         {\r
  78                 if(teams_matter && self.team == self.predator.team)\r
  79                         return TRUE;\r
  80                 if(g_rpg && cvar("g_rpg_canleave"))\r
  81                         return TRUE;\r
  82         }\r
  83         return FALSE;\r
  84 }\r
  85 \r
  86 // make the camera smoothly lower itself when we get swallowed\r
  87 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  88 .float cameraeffect_current, cameraeffect_target;\r
  89 void Vore_CameraEffect_Set(entity e)\r
  90 {\r
  91         e.cameraeffect_current = 1;\r
  92         e.cameraeffect_target = 2;\r
  93 }\r
  94 void Vore_CameraEffect_Apply()\r
  95 {\r
  96         if(self.predator.classname != "player")\r
  97                 return;\r
  98 \r
  99         if(self.cvar_cl_vore_cameraspeed)\r
 100         {\r
 101                 local float step;\r
 102                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 103 \r
 104                 // not sure if these maths are good, as the effect should be smoother\r
 105                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 106                         self.cameraeffect_current -= step;\r
 107                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 108                         self.cameraeffect_current += step;\r
 109         }\r
 110         else\r
 111                 self.cameraeffect_current = self.cameraeffect_target;\r
 112 \r
 113         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 114 }\r
 115 \r
 116 .float gurgle_oldstomachload;\r
 117 void Vore_Gurglesound()\r
 118 {\r
 119         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 120         {\r
 121                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 122 \r
 123                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 124                 self.gurgle_oldstomachload = self.stomach_load;\r
 125         }\r
 126 }\r
 127 \r
 128 void Vore_Weight_apply(entity e)\r
 129 {\r
 130         // apply stomach weight that makes you heavier the more you eat\r
 131         // slowing the player is done in cl_physics.qc\r
 132 \r
 133         if(e.stomach_load != e.vore_oldstomachload)\r
 134                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 135         if(e.gravity == 0)\r
 136                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 137         e.vore_oldstomachload = e.stomach_load;\r
 138 }\r
 139 \r
 140 .entity pusher;\r
 141 .float pushltime;\r
 142 void Vore_Swallow(entity e)\r
 143 {\r
 144         // this player is being swallowed by another player, apply the proper changes\r
 145 \r
 146         e.vore_oldmovetype = e.movetype;\r
 147         e.vore_oldsolid = e.solid;\r
 148 \r
 149         e.predator = self;\r
 150         setorigin(e, e.predator.origin);\r
 151         e.velocity = '0 0 0';\r
 152         e.movetype = MOVETYPE_FOLLOW;\r
 153         e.solid = SOLID_NOT;\r
 154         e.alpha = -1; // best way of hiding the eaten player\r
 155         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 156 \r
 157         // drop keys (KH) and flags (CTF) when we get swallowed\r
 158         kh_Key_DropAll(e, FALSE);\r
 159         if(e.flagcarried)\r
 160                 DropFlag(e.flagcarried, world, e.predator);\r
 161 \r
 162         Vore_CameraEffect_Set(e);\r
 163 \r
 164         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 165                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 166 \r
 167         if(teams_matter && e.team == e.predator.team)\r
 168         {\r
 169                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 170                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 171         }\r
 172 \r
 173         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 174         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 175         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 176         e.predator.stomach_load += 1;\r
 177         e.predator.regurgitate_prepare = 0;\r
 178         Vore_Weight_apply(e.predator);\r
 179 \r
 180         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 181         e.predator.weapon_delay = time + button_delay_time;\r
 182         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 183         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 184 }\r
 185 \r
 186 void Vore_Regurgitate(entity e)\r
 187 {\r
 188         // this player is being regurgitated by their predator, apply the proper changes\r
 189 \r
 190         e.movetype = e.vore_oldmovetype;\r
 191         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 192                 e.solid = e.vore_oldsolid;\r
 193         e.view_ofs_z = PL_VIEW_OFS_z;\r
 194         e.alpha = default_player_alpha;\r
 195 \r
 196         // apply velocities\r
 197         local vector oldforward, oldright, oldup;\r
 198         oldforward = v_forward;\r
 199         oldright = v_right;\r
 200         oldup = v_up;\r
 201         makevectors(e.predator.v_angle);\r
 202         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 203         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 204         v_forward = oldforward;\r
 205         v_right = oldright;\r
 206         v_up = oldup;\r
 207 \r
 208         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 209         e.pushltime = time + cvar("g_maxpushtime");\r
 210 \r
 211         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 212         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 213         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 214         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 215         e.predator.stomach_load -= 1;\r
 216         e.predator.regurgitate_prepare = 0;\r
 217         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 218         Vore_Weight_apply(e.predator);\r
 219 \r
 220         // block firing for a small amount of time, or we'll be firing the next frame\r
 221         e.weapon_delay = time + button_delay_time;\r
 222         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 223         e.predator = world;\r
 224 }\r
 225 \r
 226 void Vore_Disconnect()\r
 227 {\r
 228         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 229 \r
 230         // prey disconnects or goes spectating while inside someone's belly\r
 231         if(self.predator.classname == "player")\r
 232                 Vore_Regurgitate(self);\r
 233 \r
 234         // pred disconnects or goes spectating with players in their belly\r
 235         else if(self.stomach_load > 0)\r
 236         {\r
 237                 entity head;\r
 238                 FOR_EACH_PLAYER(head)\r
 239                 {\r
 240                         if(head.predator == self)\r
 241                                 Vore_Regurgitate(head);\r
 242                 }\r
 243                 Vore_Gurglesound(); // stop the gurgling sound\r
 244         }\r
 245 }\r
 246 \r
 247 .float digestion_step;\r
 248 void Vore_Digest()\r
 249 {\r
 250         // apply digestion to prey\r
 251 \r
 252         if(time > self.predator.digestion_step)\r
 253         {\r
 254                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 255                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 256                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 257 \r
 258                 if (self.predator.digestsound_finished < time)\r
 259                 {\r
 260                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 261                         self.predator.digestsound_finished = time + 0.5;\r
 262                 }\r
 263                 self.predator.digestion_step = time + steptime;\r
 264         }\r
 265 \r
 266         if(self.health <= 0)\r
 267         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 268                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 269 }\r
 270 \r
 271 .float teamheal_step;\r
 272 void Vore_Teamheal()\r
 273 {\r
 274         // apply teamheal\r
 275 \r
 276         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 277         if(time > self.teamheal_step)\r
 278         {\r
 279                 self.health += cvar("g_balance_vore_teamheal");\r
 280                 self.teamheal_step = time + steptime;\r
 281         }\r
 282 }\r
 283 \r
 284 .float stomachkick_delay;\r
 285 void Vore_StomachKick()\r
 286 {\r
 287         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 288 \r
 289         if(time > self.stomachkick_delay)\r
 290         {\r
 291                 float damage;\r
 292                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 293                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, '0 0 0');\r
 294                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 295 \r
 296                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 297                         Vore_Regurgitate(self);\r
 298 \r
 299                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 300         }\r
 301 }\r
 302 \r
 303 void Vore_StomachLeave()\r
 304 {\r
 305         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 306 \r
 307         if(Vore_CanLeave())\r
 308                 Vore_Regurgitate(self);\r
 309         else if(time > self.complain_vore)\r
 310         {\r
 311                 play2(self, "misc/unavailable.wav");\r
 312                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 313                 self.complain_vore = time + complain_delay_time;\r
 314         }\r
 315 }\r
 316 \r
 317 void Vore()\r
 318 {\r
 319         // main vore code, this is where it all happens\r
 320 \r
 321         if(!cvar("g_vore")) // the vore system is disabled\r
 322         {\r
 323                 Vore_Disconnect();\r
 324                 return;\r
 325         }\r
 326 \r
 327         // set all vore related stats\r
 328         if(self.predator.classname == "player")\r
 329         {\r
 330                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 331                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 332                 self.stat_eaten = num_for_edict(self.predator);\r
 333         }\r
 334         else\r
 335         {\r
 336                 self.stat_stomachload = self.stomach_load;\r
 337                 self.stat_digesting = self.digesting;\r
 338                 self.stat_eaten = 0;\r
 339         }\r
 340         self.stat_canleave = Vore_CanLeave();\r
 341 \r
 342         // don't allow a player inside a player inside another player :)\r
 343         // prevent this by checking if such has happened, and taking the proper measures\r
 344         // this code has a high priority and must not be stopped by any delay, so run it here\r
 345         if(self.predator.predator.classname == "player")\r
 346         {\r
 347                 entity target_predator, target_predator_predator, oldself;\r
 348                 target_predator = self.predator;\r
 349                 target_predator_predator = self.predator.predator;\r
 350 \r
 351                 Vore_Regurgitate(self);\r
 352 \r
 353                 // now steal our prey's prey if this probability applies\r
 354                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 355                 {\r
 356                         oldself = self;\r
 357                         self = target_predator_predator;\r
 358                         if(Swallow_condition_check(oldself))\r
 359                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 360                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 361                                 Vore_Swallow(oldself);\r
 362                         self = oldself;\r
 363                 }\r
 364         }\r
 365 \r
 366         // apply delays and skip the vore system under some circumstances\r
 367         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 368         {\r
 369                 Vore_Disconnect();\r
 370                 return;\r
 371         }\r
 372         if(self.spectatee_status)\r
 373                 return;\r
 374         if(time < self.system_delay)\r
 375                 return;\r
 376 \r
 377 // --------------------------------\r
 378 // Code that addresses predators:\r
 379 // --------------------------------\r
 380 \r
 381         entity prey;\r
 382         prey = Swallow_player_check();\r
 383 \r
 384         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 385         if(self.BUTTON_ATCK && !self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
 386         if(Swallow_condition_check(prey))\r
 387                 Vore_Swallow(prey);\r
 388 \r
 389         // toggle digestion, if the player has someone in their stomach\r
 390         if(self.BUTTON_DIGEST)\r
 391         {\r
 392                 if(self.stomach_load)\r
 393                 {\r
 394                         if(time > self.digest_button_delay_time)\r
 395                         {\r
 396                                 self.digesting = !self.digesting;\r
 397                                 self.digest_button_delay_time = time + button_delay_time;\r
 398                         }\r
 399                 }\r
 400                 else if(time > self.complain_vore)\r
 401                 {\r
 402                         play2(self, "misc/unavailable.wav");\r
 403                         sprint(self, "There is nothing to digest\n");\r
 404                         self.complain_vore = time + complain_delay_time;\r
 405                 }\r
 406         }\r
 407         if(!self.stomach_load)\r
 408                 self.digesting = FALSE;\r
 409 \r
 410         // predator wishes to regurgitate his prey\r
 411         if(self.BUTTON_REGURGITATE)\r
 412         {\r
 413                 if(self.stomach_load)\r
 414                 {\r
 415                         if(time > self.regurgitate_button_delay_time)\r
 416                         {\r
 417                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 418                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 419                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 420                         }\r
 421                 }\r
 422                 else if(time > self.complain_vore)\r
 423                 {\r
 424                         play2(self, "misc/unavailable.wav");\r
 425                         sprint(self, "There is nothing to regurgitate\n");\r
 426                         self.complain_vore = time + complain_delay_time;\r
 427                 }\r
 428         }\r
 429 \r
 430         if(cvar("g_vore_gurglesound"))\r
 431                 Vore_Gurglesound();\r
 432 \r
 433 // --------------------------------\r
 434 // Code that addresses the prey:\r
 435 // --------------------------------\r
 436 \r
 437         if(self.predator.classname != "player")\r
 438                 return;\r
 439 \r
 440         if(self.deadflag || self.predator.deadflag)\r
 441                 Vore_Regurgitate(self);\r
 442         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 443                 Vore_Regurgitate(self);\r
 444 \r
 445         // apply delayed regurgitating if it was scheduled\r
 446         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 447         {\r
 448                 self.predator.regurgitate_prepare = 0;\r
 449                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 450                 Vore_Regurgitate(self);\r
 451         }\r
 452 \r
 453         // execute digesting and team healing\r
 454         if(self.predator.digesting == TRUE)\r
 455                 Vore_Digest();\r
 456         if(teams_matter && self.team == self.predator.team)\r
 457         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 458                 Vore_Teamheal();\r
 459 \r
 460         // execute prey commands\r
 461         if(self.BUTTON_ATCK)\r
 462                 Vore_StomachKick();\r
 463         if(self.BUTTON_JUMP)\r
 464                 Vore_StomachLeave();\r
 465 \r
 466         Vore_CameraEffect_Apply();\r
 467 }