data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity pusher;\r
 203 .float pushltime;\r
 204 void Vore_Swallow(entity e)\r
 205 {\r
 206         // this player is being swallowed by another player, apply the proper changes\r
 207 \r
 208         e.vore_oldmovetype = e.movetype;\r
 209         e.vore_oldsolid = e.solid;\r
 210 \r
 211         e.predator = self;\r
 212         setorigin(e, e.predator.origin);\r
 213         e.velocity = '0 0 0';\r
 214         e.movetype = MOVETYPE_FOLLOW;\r
 215         e.solid = SOLID_NOT;\r
 216         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 217 \r
 218         // drop keys (KH) and flags (CTF) when we get swallowed\r
 219         kh_Key_DropAll(e, FALSE);\r
 220         if(e.flagcarried)\r
 221                 DropFlag(e.flagcarried, world, e.predator);\r
 222 \r
 223         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 224                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 225 \r
 226         if(teams_matter && e.team == e.predator.team)\r
 227         {\r
 228                 if(cvar("g_vore_kick"))\r
 229                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 230                 if(cvar("g_vore_digestion"))\r
 231                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 232         }\r
 233 \r
 234         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 235         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 236         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 237         e.predator.stomach_load += 1;\r
 238         e.predator.regurgitate_prepare = 0;\r
 239         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 240         Vore_WeightApply(e.predator);\r
 241         Vore_AutoDigest(e.predator);\r
 242 \r
 243         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 244         e.predator.weapon_delay = time + button_delay_time;\r
 245         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 246         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 247         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 248 }\r
 249 \r
 250 void Vore_Regurgitate(entity e)\r
 251 {\r
 252         // this player is being regurgitated by their predator, apply the proper changes\r
 253 \r
 254         e.movetype = e.vore_oldmovetype;\r
 255         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 256                 e.solid = e.vore_oldsolid;\r
 257         e.view_ofs_z = PL_VIEW_OFS_z;\r
 258 \r
 259         // apply velocities\r
 260         local vector oldforward, oldright, oldup;\r
 261         oldforward = v_forward;\r
 262         oldright = v_right;\r
 263         oldup = v_up;\r
 264         makevectors(e.predator.v_angle);\r
 265         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 266         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 267         v_forward = oldforward;\r
 268         v_right = oldright;\r
 269         v_up = oldup;\r
 270 \r
 271         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 272         e.pushltime = time + cvar("g_maxpushtime");\r
 273 \r
 274         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 275         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 276         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 277         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 278         e.predator.stomach_load -= 1;\r
 279         e.predator.regurgitate_prepare = 0;\r
 280         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 281         Vore_WeightApply(e.predator);\r
 282 \r
 283         // block firing for a small amount of time, or we'll be firing the next frame\r
 284         e.weapon_delay = time + button_delay_time;\r
 285         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 286         e.predator = world;\r
 287 }\r
 288 \r
 289 void Vore_DeadPrey_Configure(entity e)\r
 290 {\r
 291         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 292 \r
 293         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 294                 return;\r
 295 \r
 296         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 297         e.fakepredator = e.predator;\r
 298         e.fakeprey = TRUE;\r
 299 \r
 300         // first release the prey from the predator, as dead prey needs to be attached differently\r
 301         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 302         e.predator.stomach_load -= 1;\r
 303         Vore_WeightApply(e.predator);\r
 304         e.predator = world;\r
 305 \r
 306         // now put our dead prey inside the predator's stomach, but only as an effect\r
 307         e.movetype = MOVETYPE_FOLLOW;\r
 308         e.takedamage = DAMAGE_NO;\r
 309         e.solid = SOLID_NOT;\r
 310         e.aiment = e.fakepredator;\r
 311 }\r
 312 \r
 313 void Vore_DeadPrey_Detach(entity e)\r
 314 {\r
 315         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 316         // should only execute after Vore_DeadPrey_Configure has ran first\r
 317 \r
 318         if not(cvar("g_vore_keepdeadprey"))\r
 319                 return;\r
 320 \r
 321         e.fakepredator = world;\r
 322         e.fakeprey = TRUE; // keep fakeprey status\r
 323         e.stat_eaten = 0;\r
 324         e.aiment = world;\r
 325         e.movetype = MOVETYPE_TOSS;\r
 326 }\r
 327 \r
 328 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 329 {\r
 330         if(pred_disconnect)\r
 331         {\r
 332                 if(e.fakeprey)\r
 333                         Vore_DeadPrey_Detach(e);\r
 334                 else\r
 335                         Vore_Regurgitate(e);\r
 336         }\r
 337         else if(self.stat_eaten && !self.fakeprey)\r
 338         {\r
 339                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 340                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 341                         Vore_DeadPrey_Configure(e);\r
 342                 else\r
 343                         Vore_Regurgitate(e);\r
 344         }\r
 345 }\r
 346 \r
 347 void Vore_Disconnect()\r
 348 {\r
 349         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 350 \r
 351         // prey disconnects or goes spectating while inside someone's belly\r
 352         if(self.stat_eaten)\r
 353                 Vore_PreyRelease(self, TRUE);\r
 354 \r
 355         // pred disconnects or goes spectating with players in their belly\r
 356         entity head;\r
 357         FOR_EACH_PLAYER(head)\r
 358         {\r
 359                 if(head.predator == self || head.fakepredator == self)\r
 360                         Vore_PreyRelease(head, TRUE);\r
 361         }\r
 362         Vore_GurgleSound(); // stop the gurgling sound\r
 363 \r
 364         self.stomach_load = self.gravity = 0; // prevents a bug\r
 365 }\r
 366 \r
 367 .float digestion_step;\r
 368 void Vore_Digest()\r
 369 {\r
 370         // apply digestion to prey\r
 371 \r
 372         if(time > self.digestion_step)\r
 373         {\r
 374                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 375                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 376                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 377 \r
 378                 if (self.predator.digestsound_finished < time)\r
 379                 {\r
 380                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 381                         self.predator.digestsound_finished = time + 0.5;\r
 382                 }\r
 383                 self.digestion_step = time + steptime;\r
 384         }\r
 385 \r
 386         if(self.deadflag != DEAD_NO)\r
 387         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 388                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 389 }\r
 390 \r
 391 .float teamheal_step;\r
 392 void Vore_Teamheal()\r
 393 {\r
 394         // apply teamheal\r
 395 \r
 396         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 397         if(time > self.teamheal_step)\r
 398         {\r
 399                 self.health += cvar("g_balance_vore_teamheal");\r
 400                 self.teamheal_step = time + steptime;\r
 401 \r
 402                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 403                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 404                 {\r
 405                         play2(self, "misc/beep.wav");\r
 406                         play2(self.predator, "misc/beep.wav");\r
 407                 }\r
 408         }\r
 409 }\r
 410 \r
 411 void Vore_StomachKick()\r
 412 {\r
 413         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 414 \r
 415         if(time > self.stomachkick_delay)\r
 416         {\r
 417                 float damage;\r
 418                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 419 \r
 420                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 421                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 422                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 423                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 424 \r
 425                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 426         }\r
 427 }\r
 428 \r
 429 void Vore_StomachLeave()\r
 430 {\r
 431         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 432 \r
 433         if(Vore_CanLeave())\r
 434                 Vore_Regurgitate(self);\r
 435         else if(time > self.complain_vore)\r
 436         {\r
 437                 play2(self, "misc/forbidden.wav");\r
 438                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 439                 self.complain_vore = time + complain_delay_time;\r
 440         }\r
 441 }\r
 442 \r
 443 void Vore_AutoTaunt()\r
 444 {\r
 445         // triggers ambient vore taunts, for both pred and prey\r
 446 \r
 447         float taunt_time;\r
 448 \r
 449         // predator taunts\r
 450         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 451         {\r
 452                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 453                 {\r
 454                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 455                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 456                 }\r
 457         }\r
 458         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 459         {\r
 460                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 461                 SetAutoTaunt(self, 0, 0);\r
 462         }\r
 463 \r
 464         // prey taunts\r
 465         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 466         {\r
 467                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 468                 {\r
 469                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 470                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 471                 }\r
 472         }\r
 473         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 474         {\r
 475                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 476                 SetAutoTaunt(self, 0, 0);\r
 477         }\r
 478 }\r
 479 \r
 480 void Vore_SetSbarRings()\r
 481 {\r
 482         // first clear the ring stats, then configure them if needed\r
 483         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 484         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 485 \r
 486         if(self.stat_eaten)\r
 487         {\r
 488                 if(time <= self.stomachkick_delay)\r
 489                 {\r
 490                         self.stat_sbring1_type = 2; // ring shows stomach kick delay, empties with progress\r
 491                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 492                 }\r
 493         }\r
 494         else\r
 495         {\r
 496                 if(time <= self.action_delay)\r
 497                 {\r
 498                         self.stat_sbring1_type = 1; // ring shows vore action delay, empties with progress\r
 499                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 500                 }\r
 501                 if(time <= self.regurgitate_prepare)\r
 502                 {\r
 503                         self.stat_sbring2_type = 1; // ring shows regurgitation preparing, fills with progress\r
 504                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 505                 }\r
 506         }\r
 507 }\r
 508 \r
 509 void Vore()\r
 510 {\r
 511         // main vore code, this is where it all happens\r
 512 \r
 513         if(!cvar("g_vore")) // the vore system is disabled\r
 514         {\r
 515                 Vore_Disconnect();\r
 516                 return;\r
 517         }\r
 518 \r
 519         Vore_AutoTaunt();\r
 520 \r
 521         // wash the goo away from players once they leave the stomach\r
 522         if(!self.stat_eaten)\r
 523         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 524         if(self.colormod)\r
 525         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 526         {\r
 527                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 528                 if(self.colormod_x > 1)\r
 529                         self.colormod_x = 1;\r
 530                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 531                 if(self.colormod_y > 1)\r
 532                         self.colormod_y = 1;\r
 533                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 534                 if(self.colormod_z > 1)\r
 535                         self.colormod_z = 1;\r
 536         }\r
 537 \r
 538         // set all vore stats\r
 539         Vore_SetSbarRings();\r
 540         if(self.fakepredator.classname == "player")\r
 541                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 542         else if(self.predator.classname == "player")\r
 543         {\r
 544                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 545                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 546                 self.stat_eaten = num_for_edict(self.predator);\r
 547         }\r
 548         else\r
 549         {\r
 550                 self.stat_stomachload = self.stomach_load;\r
 551                 self.stat_digesting = self.digesting;\r
 552                 self.stat_eaten = 0;\r
 553         }\r
 554         self.stat_canleave = Vore_CanLeave();\r
 555 \r
 556         // don't allow a player inside a player inside another player :)\r
 557         // prevent this by checking if such has happened, and taking the proper measures\r
 558         // this code has a high priority and must not be stopped by any delay, so run it here\r
 559         if(self.predator.stat_eaten)\r
 560         {\r
 561                 entity target_predator, target_predator_predator, oldself;\r
 562                 target_predator = self.predator;\r
 563                 target_predator_predator = self.predator.predator;\r
 564 \r
 565                 Vore_Regurgitate(self);\r
 566 \r
 567                 // now steal our prey's prey if this probability applies\r
 568                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 569                 {\r
 570                         oldself = self;\r
 571                         self = target_predator_predator;\r
 572                         if(Swallow_condition_check(oldself))\r
 573                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 574                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 575                                 Vore_Swallow(oldself);\r
 576                         self = oldself;\r
 577                 }\r
 578         }\r
 579 \r
 580         // apply delays and skip the vore system under some circumstances\r
 581         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 582         {\r
 583                 Vore_Disconnect();\r
 584                 return;\r
 585         }\r
 586         if(self.spectatee_status)\r
 587                 return;\r
 588         if(time < self.system_delay)\r
 589                 return;\r
 590 \r
 591 // --------------------------------\r
 592 // Code that addresses predators:\r
 593 // --------------------------------\r
 594 \r
 595         entity prey;\r
 596         prey = Swallow_player_check();\r
 597 \r
 598         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 599         self.stat_canswallow = 0;\r
 600         if(Swallow_condition_check(prey))\r
 601         {\r
 602                 // canswallow stat, used by the HUD\r
 603                 if(teams_matter && prey.team == self.team)\r
 604                         self.stat_canswallow = 2;\r
 605                 else\r
 606                         self.stat_canswallow = 1;\r
 607 \r
 608                 if(self.BUTTON_ATCK)\r
 609                         Vore_Swallow(prey);\r
 610         }\r
 611         else if(prey != world)\r
 612                 self.stat_canswallow = -1;\r
 613 \r
 614         // toggle digestion, if the player has someone in their stomach\r
 615         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 616         {\r
 617                 if(self.stomach_load)\r
 618                 {\r
 619                         if(time > self.digest_button_delay_time)\r
 620                         {\r
 621                                 self.digesting = !self.digesting;\r
 622                                 self.digest_button_delay_time = time + button_delay_time;\r
 623                         }\r
 624                 }\r
 625                 else if(time > self.complain_vore)\r
 626                 {\r
 627                         play2(self, "misc/forbidden.wav");\r
 628                         sprint(self, "There is nothing to digest\n");\r
 629                         self.complain_vore = time + complain_delay_time;\r
 630                 }\r
 631         }\r
 632         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 633                 self.digesting = FALSE;\r
 634 \r
 635         // predator wishes to regurgitate his prey\r
 636         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 637         {\r
 638                 if(self.stomach_load)\r
 639                 {\r
 640                         if(time > self.regurgitate_button_delay_time)\r
 641                         {\r
 642                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 643                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 644                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 645                         }\r
 646                 }\r
 647                 else if(time > self.complain_vore)\r
 648                 {\r
 649                         play2(self, "misc/forbidden.wav");\r
 650                         sprint(self, "There is nothing to regurgitate\n");\r
 651                         self.complain_vore = time + complain_delay_time;\r
 652                 }\r
 653         }\r
 654 \r
 655         if(cvar("g_vore_gurglesound"))\r
 656                 Vore_GurgleSound();\r
 657 \r
 658 // --------------------------------\r
 659 // Code that addresses the prey:\r
 660 // --------------------------------\r
 661 \r
 662         Vore_SetPreyPositions();\r
 663 \r
 664         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 665         if(self.fakeprey)\r
 666         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 667                 Vore_DeadPrey_Detach(self);\r
 668 \r
 669         if(!self.stat_eaten)\r
 670                 return;\r
 671 \r
 672         if(self.deadflag != DEAD_NO)\r
 673         {\r
 674                 Vore_PreyRelease(self, FALSE);\r
 675                 return;\r
 676         }\r
 677 \r
 678         if(self.predator.deadflag != DEAD_NO)\r
 679                 Vore_Regurgitate(self);\r
 680         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 681                 Vore_Regurgitate(self);\r
 682 \r
 683         // apply delayed regurgitating if it was scheduled\r
 684         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 685         {\r
 686                 self.predator.regurgitate_prepare = 0;\r
 687                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 688                 Vore_Regurgitate(self);\r
 689         }\r
 690 \r
 691         // execute digesting and team healing\r
 692         if(self.predator.digesting == TRUE)\r
 693                 Vore_Digest();\r
 694         if(teams_matter && self.team == self.predator.team)\r
 695         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 696                 Vore_Teamheal();\r
 697 \r
 698         // execute prey commands\r
 699         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 700                 Vore_StomachKick();\r
 701         if(self.BUTTON_JUMP)\r
 702                 Vore_StomachLeave();\r
 703 \r
 704         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 705         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 706         kh_Key_DropAll(self, FALSE);\r
 707 }