data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore)\r
  39                         {\r
  40                                 play2(self, "misc/unavailable.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore)\r
  50                         {\r
  51                                 play2(self, "misc/unavailable.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore)\r
  62                         {\r
  63                                 play2(self, "misc/unavailable.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Vore_CanLeave()\r
  76 {\r
  77         if(self.predator.classname == "player")\r
  78         {\r
  79                 if(teams_matter && self.team == self.predator.team)\r
  80                         return TRUE;\r
  81                 if(g_rpg && cvar("g_rpg_canleave"))\r
  82                         return TRUE;\r
  83         }\r
  84         return FALSE;\r
  85 }\r
  86 \r
  87 // make the camera smoothly lower itself when we get swallowed\r
  88 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  89 .float cameraeffect_current, cameraeffect_target;\r
  90 void Vore_CameraEffect_Set(entity e)\r
  91 {\r
  92         e.cameraeffect_current = 1;\r
  93         e.cameraeffect_target = 2;\r
  94 }\r
  95 void Vore_CameraEffect_Apply()\r
  96 {\r
  97         if(self.predator.classname != "player")\r
  98                 return;\r
  99 \r
 100         if(self.cvar_cl_vore_cameraspeed)\r
 101         {\r
 102                 local float step;\r
 103                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 104 \r
 105                 // not sure if these maths are good, as the effect should be smoother\r
 106                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 107                         self.cameraeffect_current -= step;\r
 108                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 109                         self.cameraeffect_current += step;\r
 110         }\r
 111         else\r
 112                 self.cameraeffect_current = self.cameraeffect_target;\r
 113 \r
 114         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 115 }\r
 116 \r
 117 .float gurgle_oldstomachload;\r
 118 void Vore_Gurglesound()\r
 119 {\r
 120         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 121         {\r
 122                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 123 \r
 124                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 125                 self.gurgle_oldstomachload = self.stomach_load;\r
 126         }\r
 127 }\r
 128 \r
 129 void Vore_Weight_apply(entity e)\r
 130 {\r
 131         // apply stomach weight that makes you heavier the more you eat\r
 132         // slowing the player is done in cl_physics.qc\r
 133 \r
 134         if(e.stomach_load != e.vore_oldstomachload)\r
 135                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 136         if(e.gravity == 0)\r
 137                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 138         e.vore_oldstomachload = e.stomach_load;\r
 139 }\r
 140 \r
 141 .entity pusher;\r
 142 .float pushltime;\r
 143 void Vore_Swallow(entity e)\r
 144 {\r
 145         // this player is being swallowed by another player, apply the proper changes\r
 146 \r
 147         e.vore_oldmovetype = e.movetype;\r
 148         e.vore_oldsolid = e.solid;\r
 149 \r
 150         e.predator = self;\r
 151         setorigin(e, e.predator.origin);\r
 152         e.velocity = '0 0 0';\r
 153         e.movetype = MOVETYPE_FOLLOW;\r
 154         e.solid = SOLID_NOT;\r
 155         e.alpha = -1; // best way of hiding the eaten player\r
 156         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 157 \r
 158         // drop keys (KH) and flags (CTF) when we get swallowed\r
 159         kh_Key_DropAll(e, FALSE);\r
 160         if(e.flagcarried)\r
 161                 DropFlag(e.flagcarried, world, e.predator);\r
 162 \r
 163         Vore_CameraEffect_Set(e);\r
 164 \r
 165         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 166                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 167 \r
 168         if(teams_matter && e.team == e.predator.team)\r
 169         {\r
 170                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 171                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 172         }\r
 173 \r
 174         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 175         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 176         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 177         e.predator.stomach_load += 1;\r
 178         e.predator.regurgitate_prepare = 0;\r
 179         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 180         Vore_Weight_apply(e.predator);\r
 181 \r
 182         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 183         e.predator.weapon_delay = time + button_delay_time;\r
 184         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 185         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 186 }\r
 187 \r
 188 void Vore_Regurgitate(entity e)\r
 189 {\r
 190         // this player is being regurgitated by their predator, apply the proper changes\r
 191 \r
 192         e.movetype = e.vore_oldmovetype;\r
 193         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 194                 e.solid = e.vore_oldsolid;\r
 195         e.view_ofs_z = PL_VIEW_OFS_z;\r
 196         e.alpha = default_player_alpha;\r
 197 \r
 198         // apply velocities\r
 199         local vector oldforward, oldright, oldup;\r
 200         oldforward = v_forward;\r
 201         oldright = v_right;\r
 202         oldup = v_up;\r
 203         makevectors(e.predator.v_angle);\r
 204         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 205         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 206         v_forward = oldforward;\r
 207         v_right = oldright;\r
 208         v_up = oldup;\r
 209 \r
 210         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 211         e.pushltime = time + cvar("g_maxpushtime");\r
 212 \r
 213         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 214         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 215         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 216         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 217         e.predator.stomach_load -= 1;\r
 218         e.predator.regurgitate_prepare = 0;\r
 219         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 220         Vore_Weight_apply(e.predator);\r
 221 \r
 222         // block firing for a small amount of time, or we'll be firing the next frame\r
 223         e.weapon_delay = time + button_delay_time;\r
 224         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 225         e.predator = world;\r
 226 }\r
 227 \r
 228 void Vore_Disconnect()\r
 229 {\r
 230         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 231 \r
 232         // prey disconnects or goes spectating while inside someone's belly\r
 233         if(self.predator.classname == "player")\r
 234                 Vore_Regurgitate(self);\r
 235 \r
 236         // pred disconnects or goes spectating with players in their belly\r
 237         else if(self.stomach_load > 0)\r
 238         {\r
 239                 entity head;\r
 240                 FOR_EACH_PLAYER(head)\r
 241                 {\r
 242                         if(head.predator == self)\r
 243                                 Vore_Regurgitate(head);\r
 244                 }\r
 245                 Vore_Gurglesound(); // stop the gurgling sound\r
 246         }\r
 247 \r
 248         self.stomach_load = self.gravity = 0; // prevents a bug\r
 249 }\r
 250 \r
 251 .float digestion_step;\r
 252 void Vore_Digest()\r
 253 {\r
 254         // apply digestion to prey\r
 255 \r
 256         if(time > self.predator.digestion_step)\r
 257         {\r
 258                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 259                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 260                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 261 \r
 262                 if (self.predator.digestsound_finished < time)\r
 263                 {\r
 264                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 265                         self.predator.digestsound_finished = time + 0.5;\r
 266                 }\r
 267                 self.predator.digestion_step = time + steptime;\r
 268         }\r
 269 \r
 270         if(self.health <= 0)\r
 271         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 272                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 273 }\r
 274 \r
 275 .float teamheal_step;\r
 276 void Vore_Teamheal()\r
 277 {\r
 278         // apply teamheal\r
 279 \r
 280         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 281         if(time > self.teamheal_step)\r
 282         {\r
 283                 self.health += cvar("g_balance_vore_teamheal");\r
 284                 self.teamheal_step = time + steptime;\r
 285         }\r
 286 }\r
 287 \r
 288 .float stomachkick_delay;\r
 289 void Vore_StomachKick()\r
 290 {\r
 291         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 292 \r
 293         if(time > self.stomachkick_delay)\r
 294         {\r
 295                 float damage;\r
 296                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 297                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 298                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 299 \r
 300                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 301                         Vore_Regurgitate(self);\r
 302 \r
 303                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 304         }\r
 305 }\r
 306 \r
 307 void Vore_StomachLeave()\r
 308 {\r
 309         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 310 \r
 311         if(Vore_CanLeave())\r
 312                 Vore_Regurgitate(self);\r
 313         else if(time > self.complain_vore)\r
 314         {\r
 315                 play2(self, "misc/unavailable.wav");\r
 316                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 317                 self.complain_vore = time + complain_delay_time;\r
 318         }\r
 319 }\r
 320 \r
 321 void Vore()\r
 322 {\r
 323         // main vore code, this is where it all happens\r
 324 \r
 325         if(!cvar("g_vore")) // the vore system is disabled\r
 326         {\r
 327                 Vore_Disconnect();\r
 328                 return;\r
 329         }\r
 330 \r
 331         // set all vore related stats\r
 332         if(self.predator.classname == "player")\r
 333         {\r
 334                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 335                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 336                 self.stat_eaten = num_for_edict(self.predator);\r
 337         }\r
 338         else\r
 339         {\r
 340                 self.stat_stomachload = self.stomach_load;\r
 341                 self.stat_digesting = self.digesting;\r
 342                 self.stat_eaten = 0;\r
 343         }\r
 344         self.stat_canleave = Vore_CanLeave();\r
 345 \r
 346         // don't allow a player inside a player inside another player :)\r
 347         // prevent this by checking if such has happened, and taking the proper measures\r
 348         // this code has a high priority and must not be stopped by any delay, so run it here\r
 349         if(self.predator.predator.classname == "player")\r
 350         {\r
 351                 entity target_predator, target_predator_predator, oldself;\r
 352                 target_predator = self.predator;\r
 353                 target_predator_predator = self.predator.predator;\r
 354 \r
 355                 Vore_Regurgitate(self);\r
 356 \r
 357                 // now steal our prey's prey if this probability applies\r
 358                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 359                 {\r
 360                         oldself = self;\r
 361                         self = target_predator_predator;\r
 362                         if(Swallow_condition_check(oldself))\r
 363                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 364                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 365                                 Vore_Swallow(oldself);\r
 366                         self = oldself;\r
 367                 }\r
 368         }\r
 369 \r
 370         // apply delays and skip the vore system under some circumstances\r
 371         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 372         {\r
 373                 Vore_Disconnect();\r
 374                 return;\r
 375         }\r
 376         if(self.spectatee_status)\r
 377                 return;\r
 378         if(time < self.system_delay)\r
 379                 return;\r
 380 \r
 381 // --------------------------------\r
 382 // Code that addresses predators:\r
 383 // --------------------------------\r
 384 \r
 385         entity prey;\r
 386         prey = Swallow_player_check();\r
 387 \r
 388         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 389         if(self.BUTTON_ATCK)\r
 390         if(Swallow_condition_check(prey))\r
 391                 Vore_Swallow(prey);\r
 392 \r
 393         // toggle digestion, if the player has someone in their stomach\r
 394         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 395         {\r
 396                 if(self.stomach_load)\r
 397                 {\r
 398                         if(time > self.digest_button_delay_time)\r
 399                         {\r
 400                                 self.digesting = !self.digesting;\r
 401                                 self.digest_button_delay_time = time + button_delay_time;\r
 402                         }\r
 403                 }\r
 404                 else if(time > self.complain_vore)\r
 405                 {\r
 406                         play2(self, "misc/unavailable.wav");\r
 407                         sprint(self, "There is nothing to digest\n");\r
 408                         self.complain_vore = time + complain_delay_time;\r
 409                 }\r
 410         }\r
 411         if(!self.stomach_load)\r
 412                 self.digesting = FALSE;\r
 413 \r
 414         // predator wishes to regurgitate his prey\r
 415         if(self.BUTTON_REGURGITATE)\r
 416         {\r
 417                 if(self.stomach_load)\r
 418                 {\r
 419                         if(time > self.regurgitate_button_delay_time)\r
 420                         {\r
 421                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 422                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 423                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 424                         }\r
 425                 }\r
 426                 else if(time > self.complain_vore)\r
 427                 {\r
 428                         play2(self, "misc/unavailable.wav");\r
 429                         sprint(self, "There is nothing to regurgitate\n");\r
 430                         self.complain_vore = time + complain_delay_time;\r
 431                 }\r
 432         }\r
 433 \r
 434         if(cvar("g_vore_gurglesound"))\r
 435                 Vore_Gurglesound();\r
 436 \r
 437 // --------------------------------\r
 438 // Code that addresses the prey:\r
 439 // --------------------------------\r
 440 \r
 441         if(self.predator.classname != "player")\r
 442                 return;\r
 443 \r
 444         if(self.deadflag || self.predator.deadflag)\r
 445                 Vore_Regurgitate(self);\r
 446         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 447                 Vore_Regurgitate(self);\r
 448 \r
 449         // apply delayed regurgitating if it was scheduled\r
 450         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 451         {\r
 452                 self.predator.regurgitate_prepare = 0;\r
 453                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 454                 Vore_Regurgitate(self);\r
 455         }\r
 456 \r
 457         // execute digesting and team healing\r
 458         if(self.predator.digesting == TRUE)\r
 459                 Vore_Digest();\r
 460         if(teams_matter && self.team == self.predator.team)\r
 461         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 462                 Vore_Teamheal();\r
 463 \r
 464         // execute prey commands\r
 465         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 466                 Vore_StomachKick();\r
 467         if(self.BUTTON_JUMP)\r
 468                 Vore_StomachLeave();\r
 469 \r
 470         Vore_CameraEffect_Apply();\r
 471 }