data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetCamera()\r
 100 {\r
 101         local entity head;\r
 102         local vector oldforward, oldright, oldup;\r
 103         local float position_counter;\r
 104         local vector origin_apply;\r
 105         oldforward = v_forward;\r
 106         oldright = v_right;\r
 107         oldup = v_up;\r
 108 \r
 109         makevectors(self.v_angle);\r
 110         v_forward_z = 0;\r
 111 \r
 112         // In order to allow prey to see each other in the same stomach, we must position each occupant differently,\r
 113         // else all players would overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 114         // For each player, the origin is updated, then a new origin is used for the next player and so on.\r
 115         // This requires that no more than 9 players can be in a stomach at a time!\r
 116         FOR_EACH_PLAYER(head)\r
 117         {\r
 118                 if(head.predator == self)\r
 119                 {\r
 120                         switch(position_counter)\r
 121                         {\r
 122                                 case 0:\r
 123                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 124                                         break;\r
 125                                 case 1:\r
 126                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 127                                         break;\r
 128                                 case 2:\r
 129                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 130                                         break;\r
 131                                 case 3:\r
 132                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 133                                         break;\r
 134                                 case 4:\r
 135                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 136                                         break;\r
 137                                 case 5:\r
 138                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 139                                         break;\r
 140                                 case 6:\r
 141                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 142                                         break;\r
 143                                 case 7:\r
 144                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 145                                         break;\r
 146                                 case 8:\r
 147                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 148                                         break;\r
 149                                 default:\r
 150                                         break;\r
 151                         }\r
 152                         head.view_ofs = PL_PREY_VIEW_OFS + (v_forward + origin_apply * 16);\r
 153                         position_counter += 1;\r
 154                 }\r
 155         }\r
 156 \r
 157         v_forward = oldforward;\r
 158         v_right = oldright;\r
 159         v_up = oldup;\r
 160 \r
 161         /*float prey_height;\r
 162         if(self.fakeprey)\r
 163                 prey_height = (self.scale - self.fakepredator.scale) * cvar("g_healthsize_vore_pos");\r
 164         else\r
 165                 prey_height = (self.scale - self.predator.scale) * cvar("g_healthsize_vore_pos");\r
 166         self.view_ofs_z += prey_height;*/\r
 167 }\r
 168 \r
 169 .float gurgle_oldstomachload;\r
 170 void Vore_GurgleSound()\r
 171 {\r
 172         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 173         {\r
 174                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 175 \r
 176                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 177                 self.gurgle_oldstomachload = self.stomach_load;\r
 178         }\r
 179 }\r
 180 \r
 181 void Vore_WeightApply(entity e)\r
 182 {\r
 183         // apply stomach weight that makes you heavier the more you eat\r
 184         // slowing the player is done in cl_physics.qc\r
 185 \r
 186         if(e.stomach_load != e.vore_oldstomachload)\r
 187                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 188         if(e.gravity == 0)\r
 189                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 190         e.vore_oldstomachload = e.stomach_load;\r
 191 }\r
 192 \r
 193 void Vore_AutoDigest(entity e)\r
 194 {\r
 195         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 196 \r
 197         if(!cvar("g_vore_digestion") || e.digesting)\r
 198                 return;\r
 199         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 200                 return; // this feature is only for players, not bots\r
 201         if(e.stomach_load > 1)\r
 202                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 203         if(Stomach_TeamMates_check(e))\r
 204                 return; // never begin automatic digestion if we've swallowed a team mate\r
 205 \r
 206         e.digesting = TRUE;\r
 207 }\r
 208 \r
 209 .entity pusher;\r
 210 .float pushltime;\r
 211 void Vore_Swallow(entity e)\r
 212 {\r
 213         // this player is being swallowed by another player, apply the proper changes\r
 214 \r
 215         e.vore_oldmovetype = e.movetype;\r
 216         e.vore_oldsolid = e.solid;\r
 217 \r
 218         e.predator = self;\r
 219         setorigin(e, e.predator.origin);\r
 220         e.velocity = '0 0 0';\r
 221         e.movetype = MOVETYPE_FOLLOW;\r
 222         e.solid = SOLID_NOT;\r
 223         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 224 \r
 225         // drop keys (KH) and flags (CTF) when we get swallowed\r
 226         kh_Key_DropAll(e, FALSE);\r
 227         if(e.flagcarried)\r
 228                 DropFlag(e.flagcarried, world, e.predator);\r
 229 \r
 230         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 231                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 232 \r
 233         if(teams_matter && e.team == e.predator.team)\r
 234         {\r
 235                 if(cvar("g_vore_kick"))\r
 236                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 237                 if(cvar("g_vore_digestion"))\r
 238                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 239         }\r
 240 \r
 241         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 242         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 243         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 244         e.predator.stomach_load += 1;\r
 245         e.predator.regurgitate_prepare = 0;\r
 246         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 247         Vore_WeightApply(e.predator);\r
 248         Vore_AutoDigest(e.predator);\r
 249 \r
 250         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 251         e.predator.weapon_delay = time + button_delay_time;\r
 252         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 253         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 254         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 255 }\r
 256 \r
 257 void Vore_Regurgitate(entity e)\r
 258 {\r
 259         // this player is being regurgitated by their predator, apply the proper changes\r
 260 \r
 261         e.movetype = e.vore_oldmovetype;\r
 262         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 263                 e.solid = e.vore_oldsolid;\r
 264         e.view_ofs_z = PL_VIEW_OFS_z;\r
 265 \r
 266         // apply velocities\r
 267         local vector oldforward, oldright, oldup;\r
 268         oldforward = v_forward;\r
 269         oldright = v_right;\r
 270         oldup = v_up;\r
 271         makevectors(e.predator.v_angle);\r
 272         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 273         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 274         v_forward = oldforward;\r
 275         v_right = oldright;\r
 276         v_up = oldup;\r
 277 \r
 278         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 279         e.pushltime = time + cvar("g_maxpushtime");\r
 280 \r
 281         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 282         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 283         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 284         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 285         e.predator.stomach_load -= 1;\r
 286         e.predator.regurgitate_prepare = 0;\r
 287         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 288         Vore_WeightApply(e.predator);\r
 289 \r
 290         // block firing for a small amount of time, or we'll be firing the next frame\r
 291         e.weapon_delay = time + button_delay_time;\r
 292         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 293         e.predator = world;\r
 294 }\r
 295 \r
 296 void Vore_DeadPrey_Configure(entity e)\r
 297 {\r
 298         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 299 \r
 300         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 301                 return;\r
 302 \r
 303         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 304         e.fakepredator = e.predator;\r
 305         e.fakeprey = TRUE;\r
 306 \r
 307         // first release the prey from the predator, as dead prey needs to be attached differently\r
 308         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 309         e.predator.stomach_load -= 1;\r
 310         Vore_WeightApply(e.predator);\r
 311         e.predator = world;\r
 312 \r
 313         // now put our dead prey inside the predator's stomach, but only as an effect\r
 314         e.movetype = MOVETYPE_FOLLOW;\r
 315         e.takedamage = DAMAGE_NO;\r
 316         e.solid = SOLID_NOT;\r
 317         e.aiment = e.fakepredator;\r
 318 }\r
 319 \r
 320 void Vore_DeadPrey_Detach(entity e)\r
 321 {\r
 322         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 323         // should only execute after Vore_DeadPrey_Configure has ran first\r
 324 \r
 325         if not(cvar("g_vore_keepdeadprey"))\r
 326                 return;\r
 327 \r
 328         e.fakepredator = world;\r
 329         e.fakeprey = TRUE; // keep fakeprey status\r
 330         e.stat_eaten = 0;\r
 331         e.aiment = world;\r
 332         e.movetype = MOVETYPE_TOSS;\r
 333 }\r
 334 \r
 335 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 336 {\r
 337         if(pred_disconnect)\r
 338         {\r
 339                 if(e.fakeprey)\r
 340                         Vore_DeadPrey_Detach(e);\r
 341                 else\r
 342                         Vore_Regurgitate(e);\r
 343         }\r
 344         else if(self.stat_eaten && !self.fakeprey)\r
 345         {\r
 346                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 347                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 348                         Vore_DeadPrey_Configure(e);\r
 349                 else\r
 350                         Vore_Regurgitate(e);\r
 351         }\r
 352 }\r
 353 \r
 354 void Vore_Disconnect()\r
 355 {\r
 356         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 357 \r
 358         // prey disconnects or goes spectating while inside someone's belly\r
 359         if(self.stat_eaten)\r
 360                 Vore_PreyRelease(self, TRUE);\r
 361 \r
 362         // pred disconnects or goes spectating with players in their belly\r
 363         entity head;\r
 364         FOR_EACH_PLAYER(head)\r
 365         {\r
 366                 if(head.predator == self || head.fakepredator == self)\r
 367                         Vore_PreyRelease(head, TRUE);\r
 368         }\r
 369         Vore_GurgleSound(); // stop the gurgling sound\r
 370 \r
 371         self.stomach_load = self.gravity = 0; // prevents a bug\r
 372 }\r
 373 \r
 374 .float digestion_step;\r
 375 void Vore_Digest()\r
 376 {\r
 377         // apply digestion to prey\r
 378 \r
 379         if(time > self.predator.digestion_step)\r
 380         {\r
 381                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 382                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 383                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 384 \r
 385                 if (self.predator.digestsound_finished < time)\r
 386                 {\r
 387                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 388                         self.predator.digestsound_finished = time + 0.5;\r
 389                 }\r
 390                 self.predator.digestion_step = time + steptime;\r
 391         }\r
 392 \r
 393         if(self.deadflag != DEAD_NO)\r
 394         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 395                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 396 }\r
 397 \r
 398 .float teamheal_step;\r
 399 void Vore_Teamheal()\r
 400 {\r
 401         // apply teamheal\r
 402 \r
 403         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 404         if(time > self.teamheal_step)\r
 405         {\r
 406                 self.health += cvar("g_balance_vore_teamheal");\r
 407                 self.teamheal_step = time + steptime;\r
 408 \r
 409                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 410                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 411                 {\r
 412                         play2(self, "misc/beep.wav");\r
 413                         play2(self.predator, "misc/beep.wav");\r
 414                 }\r
 415         }\r
 416 }\r
 417 \r
 418 void Vore_StomachKick()\r
 419 {\r
 420         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 421 \r
 422         if(time > self.stomachkick_delay)\r
 423         {\r
 424                 float damage;\r
 425                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 426 \r
 427                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 428                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 429                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 430                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 431 \r
 432                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 433                         Vore_Regurgitate(self);\r
 434 \r
 435                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 436         }\r
 437 }\r
 438 \r
 439 void Vore_StomachLeave()\r
 440 {\r
 441         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 442 \r
 443         if(Vore_CanLeave())\r
 444                 Vore_Regurgitate(self);\r
 445         else if(time > self.complain_vore)\r
 446         {\r
 447                 play2(self, "misc/forbidden.wav");\r
 448                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 449                 self.complain_vore = time + complain_delay_time;\r
 450         }\r
 451 }\r
 452 \r
 453 void Vore_AutoTaunt()\r
 454 {\r
 455         // triggers ambient vore taunts, for both pred and prey\r
 456 \r
 457         float taunt_time;\r
 458 \r
 459         // predator taunts\r
 460         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 461         {\r
 462                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 463                 {\r
 464                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 465                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 466                 }\r
 467         }\r
 468         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 469         {\r
 470                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 471                 SetAutoTaunt(self, 0, 0);\r
 472         }\r
 473 \r
 474         // prey taunts\r
 475         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 476         {\r
 477                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 478                 {\r
 479                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 480                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 481                 }\r
 482         }\r
 483         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 484         {\r
 485                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 486                 SetAutoTaunt(self, 0, 0);\r
 487         }\r
 488 }\r
 489 \r
 490 void Vore_SetSbarRings()\r
 491 {\r
 492         // first clear the ring stats, then configure them if needed\r
 493         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 494         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 495 \r
 496         if(self.stat_eaten)\r
 497         {\r
 498                 if(time <= self.stomachkick_delay)\r
 499                 {\r
 500                         self.stat_sbring1_type = 2; // ring shows stomach kick delay, empties with progress\r
 501                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 502                 }\r
 503         }\r
 504         else\r
 505         {\r
 506                 if(time <= self.action_delay)\r
 507                 {\r
 508                         self.stat_sbring1_type = 1; // ring shows vore action delay, empties with progress\r
 509                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 510                 }\r
 511                 if(time <= self.regurgitate_prepare)\r
 512                 {\r
 513                         self.stat_sbring2_type = 1; // ring shows regurgitation preparing, fills with progress\r
 514                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 515                 }\r
 516         }\r
 517 }\r
 518 \r
 519 void Vore()\r
 520 {\r
 521         // main vore code, this is where it all happens\r
 522 \r
 523         if(!cvar("g_vore")) // the vore system is disabled\r
 524         {\r
 525                 Vore_Disconnect();\r
 526                 return;\r
 527         }\r
 528 \r
 529         Vore_AutoTaunt();\r
 530 \r
 531         // wash the goo away from players once they leave the stomach\r
 532         if(!self.stat_eaten)\r
 533         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 534         if(self.colormod)\r
 535         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 536         {\r
 537                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 538                 if(self.colormod_x > 1)\r
 539                         self.colormod_x = 1;\r
 540                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 541                 if(self.colormod_y > 1)\r
 542                         self.colormod_y = 1;\r
 543                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 544                 if(self.colormod_z > 1)\r
 545                         self.colormod_z = 1;\r
 546         }\r
 547 \r
 548         // set all vore stats\r
 549         Vore_SetSbarRings();\r
 550         if(self.fakepredator.classname == "player")\r
 551                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 552         else if(self.predator.classname == "player")\r
 553         {\r
 554                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 555                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 556                 self.stat_eaten = num_for_edict(self.predator);\r
 557         }\r
 558         else\r
 559         {\r
 560                 self.stat_stomachload = self.stomach_load;\r
 561                 self.stat_digesting = self.digesting;\r
 562                 self.stat_eaten = 0;\r
 563         }\r
 564         self.stat_canleave = Vore_CanLeave();\r
 565 \r
 566         // don't allow a player inside a player inside another player :)\r
 567         // prevent this by checking if such has happened, and taking the proper measures\r
 568         // this code has a high priority and must not be stopped by any delay, so run it here\r
 569         if(self.predator.stat_eaten)\r
 570         {\r
 571                 entity target_predator, target_predator_predator, oldself;\r
 572                 target_predator = self.predator;\r
 573                 target_predator_predator = self.predator.predator;\r
 574 \r
 575                 Vore_Regurgitate(self);\r
 576 \r
 577                 // now steal our prey's prey if this probability applies\r
 578                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 579                 {\r
 580                         oldself = self;\r
 581                         self = target_predator_predator;\r
 582                         if(Swallow_condition_check(oldself))\r
 583                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 584                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 585                                 Vore_Swallow(oldself);\r
 586                         self = oldself;\r
 587                 }\r
 588         }\r
 589 \r
 590         // apply delays and skip the vore system under some circumstances\r
 591         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 592         {\r
 593                 Vore_Disconnect();\r
 594                 return;\r
 595         }\r
 596         if(self.spectatee_status)\r
 597                 return;\r
 598         if(time < self.system_delay)\r
 599                 return;\r
 600 \r
 601 // --------------------------------\r
 602 // Code that addresses predators:\r
 603 // --------------------------------\r
 604 \r
 605         entity prey;\r
 606         prey = Swallow_player_check();\r
 607 \r
 608         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 609         self.stat_canswallow = 0;\r
 610         if(Swallow_condition_check(prey))\r
 611         {\r
 612                 // canswallow stat, used by the HUD\r
 613                 if(teams_matter && prey.team == self.team)\r
 614                         self.stat_canswallow = 2;\r
 615                 else\r
 616                         self.stat_canswallow = 1;\r
 617 \r
 618                 if(self.BUTTON_ATCK)\r
 619                         Vore_Swallow(prey);\r
 620         }\r
 621         else if(prey != world)\r
 622                 self.stat_canswallow = -1;\r
 623 \r
 624         // toggle digestion, if the player has someone in their stomach\r
 625         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 626         {\r
 627                 if(self.stomach_load)\r
 628                 {\r
 629                         if(time > self.digest_button_delay_time)\r
 630                         {\r
 631                                 self.digesting = !self.digesting;\r
 632                                 self.digest_button_delay_time = time + button_delay_time;\r
 633                         }\r
 634                 }\r
 635                 else if(time > self.complain_vore)\r
 636                 {\r
 637                         play2(self, "misc/forbidden.wav");\r
 638                         sprint(self, "There is nothing to digest\n");\r
 639                         self.complain_vore = time + complain_delay_time;\r
 640                 }\r
 641         }\r
 642         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 643                 self.digesting = FALSE;\r
 644 \r
 645         // predator wishes to regurgitate his prey\r
 646         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 647         {\r
 648                 if(self.stomach_load)\r
 649                 {\r
 650                         if(time > self.regurgitate_button_delay_time)\r
 651                         {\r
 652                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 653                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 654                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 655                         }\r
 656                 }\r
 657                 else if(time > self.complain_vore)\r
 658                 {\r
 659                         play2(self, "misc/forbidden.wav");\r
 660                         sprint(self, "There is nothing to regurgitate\n");\r
 661                         self.complain_vore = time + complain_delay_time;\r
 662                 }\r
 663         }\r
 664 \r
 665         if(cvar("g_vore_gurglesound"))\r
 666                 Vore_GurgleSound();\r
 667 \r
 668 // --------------------------------\r
 669 // Code that addresses the prey:\r
 670 // --------------------------------\r
 671 \r
 672         Vore_SetCamera();\r
 673 \r
 674         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 675         if(self.fakeprey)\r
 676         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 677                 Vore_DeadPrey_Detach(self);\r
 678 \r
 679         if(!self.stat_eaten)\r
 680                 return;\r
 681 \r
 682         if(self.deadflag != DEAD_NO)\r
 683         {\r
 684                 Vore_PreyRelease(self, FALSE);\r
 685                 return;\r
 686         }\r
 687 \r
 688         if(self.predator.deadflag != DEAD_NO)\r
 689                 Vore_Regurgitate(self);\r
 690         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 691                 Vore_Regurgitate(self);\r
 692 \r
 693         // apply delayed regurgitating if it was scheduled\r
 694         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 695         {\r
 696                 self.predator.regurgitate_prepare = 0;\r
 697                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 698                 Vore_Regurgitate(self);\r
 699         }\r
 700 \r
 701         // execute digesting and team healing\r
 702         if(self.predator.digesting == TRUE)\r
 703                 Vore_Digest();\r
 704         if(teams_matter && self.team == self.predator.team)\r
 705         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 706                 Vore_Teamheal();\r
 707 \r
 708         // execute prey commands\r
 709         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 710                 Vore_StomachKick();\r
 711         if(self.BUTTON_JUMP)\r
 712                 Vore_StomachLeave();\r
 713 \r
 714         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 715         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 716         kh_Key_DropAll(self, FALSE);\r
 717 }