data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload, vore_oldview_ofs_z;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  34         {\r
  35                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  36                 {\r
  37                         if(time > self.complain_vore)\r
  38                         {\r
  39                                 play2(self, "misc/unavailable.wav");\r
  40                                 sprint(self, "You cannot swallow your team mates\n");\r
  41                                 self.complain_vore = time + complain_delay_time;\r
  42                         }\r
  43                         return FALSE;\r
  44                 }\r
  45 \r
  46                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                 {\r
  48                         if(time > self.complain_vore)\r
  49                         {\r
  50                                 play2(self, "misc/unavailable.wav");\r
  51                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  52                                 self.complain_vore = time + complain_delay_time;\r
  53                         }\r
  54                         return FALSE;\r
  55                 }\r
  56 \r
  57                 if(cvar("g_vore_biggergut"))\r
  58                 if(prey.stomach_load > self.stomach_load)\r
  59                 {\r
  60                         if(time > self.complain_vore)\r
  61                         {\r
  62                                 play2(self, "misc/unavailable.wav");\r
  63                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  64                                 self.complain_vore = time + complain_delay_time;\r
  65                         }\r
  66                         return FALSE;\r
  67                 }\r
  68 \r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Vore_CanLeave()\r
  75 {\r
  76         if(self.predator.classname == "player")\r
  77         {\r
  78                 if(teams_matter && self.team == self.predator.team)\r
  79                         return TRUE;\r
  80                 if(g_rpg && cvar("g_rpg_canleave"))\r
  81                         return TRUE;\r
  82         }\r
  83         return FALSE;\r
  84 }\r
  85 \r
  86 // make the camera smoothly lower itself when we get swallowed\r
  87 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  88 .float cameraeffect_current, cameraeffect_target;\r
  89 void Vore_CameraEffect_Set(entity e)\r
  90 {\r
  91         e.cameraeffect_current = 1;\r
  92         e.cameraeffect_target = 2;\r
  93 }\r
  94 void Vore_CameraEffect_Apply()\r
  95 {\r
  96         if(self.predator.classname != "player")\r
  97                 return;\r
  98 \r
  99         if(self.cvar_cl_vore_cameraspeed)\r
 100         {\r
 101                 local float step;\r
 102                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 103 \r
 104                 // not sure if these maths are good, as the effect should be smoother\r
 105                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 106                         self.cameraeffect_current -= step;\r
 107                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 108                         self.cameraeffect_current += step;\r
 109         }\r
 110         else\r
 111                 self.cameraeffect_current = self.cameraeffect_target;\r
 112 \r
 113         self.view_ofs_z = self.vore_oldview_ofs_z / self.cameraeffect_current;\r
 114 }\r
 115 \r
 116 .float gurgle_oldstomachload;\r
 117 void Vore_Gurglesound()\r
 118 {\r
 119         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 120         {\r
 121                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 122 \r
 123                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 124                 self.gurgle_oldstomachload = self.stomach_load;\r
 125         }\r
 126 }\r
 127 \r
 128 void Vore_Weight_apply(entity e)\r
 129 {\r
 130         // apply stomach weight that makes you heavier the more you eat\r
 131         // slowing the player is done in cl_physics.qc\r
 132 \r
 133         if(e.stomach_load != e.vore_oldstomachload)\r
 134                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 135         if(e.gravity == 0)\r
 136                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 137         e.vore_oldstomachload = e.stomach_load;\r
 138 }\r
 139 \r
 140 .entity pusher;\r
 141 .float pushltime;\r
 142 void Vore_Swallow(entity e)\r
 143 {\r
 144         // this player is being swallowed by another player, apply the proper changes\r
 145 \r
 146         e.vore_oldmovetype = e.movetype;\r
 147         e.vore_oldsolid = e.solid;\r
 148         e.vore_oldview_ofs_z = e.view_ofs_z;\r
 149 \r
 150         e.predator = self;\r
 151         setorigin(e, e.predator.origin);\r
 152         e.velocity = '0 0 0';\r
 153         e.movetype = MOVETYPE_FOLLOW;\r
 154         e.solid = SOLID_NOT;\r
 155         e.alpha = -1; // best way of hiding the eaten player\r
 156         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 157 \r
 158         // drop keys (KH) and flags (CTF) when we get swallowed\r
 159         kh_Key_DropAll(e, FALSE);\r
 160         if(e.flagcarried)\r
 161                 DropFlag(e.flagcarried, world, e.predator);\r
 162 \r
 163         Vore_CameraEffect_Set(e);\r
 164 \r
 165         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 166                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 167 \r
 168         if(teams_matter && e.team == e.predator.team)\r
 169         {\r
 170                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 171                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 172         }\r
 173 \r
 174         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 175         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 176         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 177         e.predator.stomach_load += 1;\r
 178         e.predator.regurgitate_prepare = 0;\r
 179         Vore_Weight_apply(e.predator);\r
 180 \r
 181         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 182         e.predator.weapon_delay = time + button_delay_time;\r
 183         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 184         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 185 }\r
 186 \r
 187 void Vore_Regurgitate(entity e)\r
 188 {\r
 189         // this player is being regurgitated by their predator, apply the proper changes\r
 190 \r
 191         e.movetype = e.vore_oldmovetype;\r
 192         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 193                 e.solid = e.vore_oldsolid;\r
 194         e.view_ofs_z = e.vore_oldview_ofs_z;\r
 195         e.alpha = default_player_alpha;\r
 196 \r
 197         // apply velocities\r
 198         local vector oldforward, oldright, oldup;\r
 199         oldforward = v_forward;\r
 200         oldright = v_right;\r
 201         oldup = v_up;\r
 202         makevectors(e.predator.v_angle);\r
 203         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 204         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 205         v_forward = oldforward;\r
 206         v_right = oldright;\r
 207         v_up = oldup;\r
 208 \r
 209         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 210         e.pushltime = time + cvar("g_maxpushtime");\r
 211 \r
 212         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 213         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 214         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 215         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 216         e.predator.stomach_load -= 1;\r
 217         e.predator.regurgitate_prepare = 0;\r
 218         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 219         Vore_Weight_apply(e.predator);\r
 220 \r
 221         // block firing for a small amount of time, or we'll be firing the next frame\r
 222         e.weapon_delay = time + button_delay_time;\r
 223         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 224         e.predator = world;\r
 225 }\r
 226 \r
 227 void Vore_Disconnect()\r
 228 {\r
 229         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 230 \r
 231         // prey disconnects or goes spectating while inside someone's belly\r
 232         if(self.predator.classname == "player")\r
 233                 Vore_Regurgitate(self);\r
 234 \r
 235         // pred disconnects or goes spectating with players in their belly\r
 236         else if(self.stomach_load > 0)\r
 237         {\r
 238                 entity head;\r
 239                 FOR_EACH_PLAYER(head)\r
 240                 {\r
 241                         if(head.predator == self)\r
 242                                 Vore_Regurgitate(head);\r
 243                 }\r
 244                 Vore_Gurglesound(); // stop the gurgling sound\r
 245         }\r
 246 }\r
 247 \r
 248 .float digestion_step;\r
 249 void Vore_Digest()\r
 250 {\r
 251         // apply digestion to prey\r
 252 \r
 253         if(time > self.predator.digestion_step)\r
 254         {\r
 255                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 256                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 257                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 258 \r
 259                 if (self.predator.digestsound_finished < time)\r
 260                 {\r
 261                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 262                         self.predator.digestsound_finished = time + 0.5;\r
 263                 }\r
 264                 self.predator.digestion_step = time + steptime;\r
 265         }\r
 266 \r
 267         if(self.health <= 0)\r
 268         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 269                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 270 }\r
 271 \r
 272 .float teamheal_step;\r
 273 void Vore_Teamheal()\r
 274 {\r
 275         // apply teamheal\r
 276 \r
 277         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 278         if(time > self.teamheal_step)\r
 279         {\r
 280                 self.health += cvar("g_balance_vore_teamheal");\r
 281                 self.teamheal_step = time + steptime;\r
 282         }\r
 283 }\r
 284 \r
 285 .float stomachkick_delay;\r
 286 void Vore_StomachKick()\r
 287 {\r
 288         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 289 \r
 290         if(time > self.stomachkick_delay)\r
 291         {\r
 292                 float damage;\r
 293                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 294                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, '0 0 0');\r
 295                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 296 \r
 297                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 298                         Vore_Regurgitate(self);\r
 299 \r
 300                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 301         }\r
 302 }\r
 303 \r
 304 void Vore_StomachLeave()\r
 305 {\r
 306         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 307 \r
 308         if(Vore_CanLeave())\r
 309                 Vore_Regurgitate(self);\r
 310         else if(time > self.complain_vore)\r
 311         {\r
 312                 play2(self, "misc/unavailable.wav");\r
 313                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 314                 self.complain_vore = time + complain_delay_time;\r
 315         }\r
 316 }\r
 317 \r
 318 void Vore()\r
 319 {\r
 320         // main vore code, this is where it all happens\r
 321 \r
 322         // set all vore related stats\r
 323         if(self.predator.classname == "player")\r
 324         {\r
 325                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 326                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 327                 self.stat_eaten = num_for_edict(self.predator);\r
 328         }\r
 329         else\r
 330         {\r
 331                 self.stat_stomachload = self.stomach_load;\r
 332                 self.stat_digesting = self.digesting;\r
 333                 self.stat_eaten = 0;\r
 334         }\r
 335         self.stat_canleave = Vore_CanLeave();\r
 336 \r
 337         // don't allow a player inside a player inside another player :)\r
 338         // prevent this by checking if such has happened, and taking the proper measures\r
 339         // this code has a high priority and must not be stopped by any delay, so run it here\r
 340         if(self.predator.predator.classname == "player")\r
 341         {\r
 342                 entity target_predator, target_predator_predator, oldself;\r
 343                 target_predator = self.predator;\r
 344                 target_predator_predator = self.predator.predator;\r
 345 \r
 346                 Vore_Regurgitate(self);\r
 347 \r
 348                 // now steal our prey's prey if this probability applies\r
 349                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 350                 {\r
 351                         oldself = self;\r
 352                         self = target_predator_predator;\r
 353                         if(Swallow_condition_check(oldself))\r
 354                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 355                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 356                                 Vore_Swallow(oldself);\r
 357                         self = oldself;\r
 358                 }\r
 359         }\r
 360 \r
 361         // apply delays and skip the vore system under some circumstances\r
 362         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 363         {\r
 364                 Vore_Disconnect();\r
 365                 return;\r
 366         }\r
 367         if(self.spectatee_status)\r
 368                 return;\r
 369         if(time < self.system_delay)\r
 370                 return;\r
 371 \r
 372 // --------------------------------\r
 373 // Code that addresses predators:\r
 374 // --------------------------------\r
 375 \r
 376         entity prey;\r
 377         prey = Swallow_player_check();\r
 378 \r
 379         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 380         if(self.BUTTON_ATCK && !self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
 381         if(Swallow_condition_check(prey))\r
 382                 Vore_Swallow(prey);\r
 383 \r
 384         // toggle digestion, if the player has someone in their stomach\r
 385         if(self.BUTTON_DIGEST)\r
 386         {\r
 387                 if(self.stomach_load)\r
 388                 {\r
 389                         if(time > self.digest_button_delay_time)\r
 390                         {\r
 391                                 self.digesting = !self.digesting;\r
 392                                 self.digest_button_delay_time = time + button_delay_time;\r
 393                         }\r
 394                 }\r
 395                 else if(time > self.complain_vore)\r
 396                 {\r
 397                         play2(self, "misc/unavailable.wav");\r
 398                         sprint(self, "There is nothing to digest\n");\r
 399                         self.complain_vore = time + complain_delay_time;\r
 400                 }\r
 401         }\r
 402         if(!self.stomach_load)\r
 403                 self.digesting = FALSE;\r
 404 \r
 405         // predator wishes to regurgitate his prey\r
 406         if(self.BUTTON_REGURGITATE)\r
 407         {\r
 408                 if(self.stomach_load)\r
 409                 {\r
 410                         if(time > self.regurgitate_button_delay_time)\r
 411                         {\r
 412                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 413                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 414                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 415                         }\r
 416                 }\r
 417                 else if(time > self.complain_vore)\r
 418                 {\r
 419                         play2(self, "misc/unavailable.wav");\r
 420                         sprint(self, "There is nothing to regurgitate\n");\r
 421                         self.complain_vore = time + complain_delay_time;\r
 422                 }\r
 423         }\r
 424 \r
 425         if(cvar("g_vore_gurglesound"))\r
 426                 Vore_Gurglesound();\r
 427 \r
 428 // --------------------------------\r
 429 // Code that addresses the prey:\r
 430 // --------------------------------\r
 431 \r
 432         if(self.predator.classname != "player")\r
 433                 return;\r
 434 \r
 435         if(self.deadflag || self.predator.deadflag)\r
 436                 Vore_Regurgitate(self);\r
 437         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 438                 Vore_Regurgitate(self);\r
 439 \r
 440         // apply delayed regurgitating if it was scheduled\r
 441         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 442         {\r
 443                 self.predator.regurgitate_prepare = 0;\r
 444                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 445                 Vore_Regurgitate(self);\r
 446         }\r
 447 \r
 448         // execute digesting and team healing\r
 449         if(self.predator.digesting == TRUE)\r
 450                 Vore_Digest();\r
 451         if(teams_matter && self.team == self.predator.team)\r
 452         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 453                 Vore_Teamheal();\r
 454 \r
 455         // execute prey commands\r
 456         if(self.BUTTON_ATCK)\r
 457                 Vore_StomachKick();\r
 458         if(self.BUTTON_JUMP)\r
 459                 Vore_StomachLeave();\r
 460 \r
 461         Vore_CameraEffect_Apply();\r
 462 }