data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 void Vore_SwallowModel_Think()\r
 203 {\r
 204         //update the necessary angles to match our view\r
 205         self.angles_x = self.owner.angles_x;\r
 206         self.view_ofs = self.owner.view_ofs;\r
 207         self.alpha = self.owner.cvar_cl_vore_stomachmodel;\r
 208 \r
 209         // if our swallow progress is gone, the swallow model must also go\r
 210         if(!self.owner.swallow_progress_prey)\r
 211         {\r
 212                 self.nextthink = 0;\r
 213                 remove(self);\r
 214                 self = world;\r
 215                 return;\r
 216         }\r
 217 \r
 218         self.nextthink = time;\r
 219 }\r
 220 \r
 221 .entity swallow_model;\r
 222 void Vore_SwallowModel_Update(entity prey)\r
 223 {\r
 224         // if we don't have a swallow model already, spawn one\r
 225         if(!prey.swallow_model)\r
 226         {\r
 227                 prey.swallow_model = spawn();\r
 228                 \r
 229                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 230                 prey.swallow_model.solid = SOLID_NOT;\r
 231 \r
 232                 prey.swallow_model.skin = self.skin;\r
 233                 prey.swallow_model.scale = self.scale;\r
 234 \r
 235                 // apply the properties of the prey\r
 236                 prey.swallow_model.aiment = prey;\r
 237 \r
 238                 prey.swallow_model.owner = prey; // owned by the prey\r
 239                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 240                 prey.swallow_model.nextthink = time;\r
 241         }\r
 242 \r
 243         // if predator has changed, update the swallow model\r
 244         if(prey.swallow_model.enemy != self)\r
 245         {\r
 246                 setmodel(prey.swallow_model, strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3")); // 4 is the extension length\r
 247                 prey.swallow_model.skin = self.skin;\r
 248                 prey.swallow_model.enemy = self; // enemy is the predator\r
 249         }\r
 250 }\r
 251 \r
 252 .entity pusher;\r
 253 .float pushltime;\r
 254 void Vore_Swallow(entity e)\r
 255 {\r
 256         // this player is being swallowed by another player, apply the proper changes\r
 257 \r
 258         e.vore_oldmovetype = e.movetype;\r
 259         e.vore_oldsolid = e.solid;\r
 260 \r
 261         e.predator = self;\r
 262         setorigin(e, e.predator.origin);\r
 263         e.velocity = '0 0 0';\r
 264         e.movetype = MOVETYPE_FOLLOW;\r
 265         e.solid = SOLID_NOT;\r
 266         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 267 \r
 268         // drop keys (KH) and flags (CTF) when we get swallowed\r
 269         kh_Key_DropAll(e, FALSE);\r
 270         if(e.flagcarried)\r
 271                 DropFlag(e.flagcarried, world, e.predator);\r
 272 \r
 273         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 274                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 275 \r
 276         if(teams_matter && e.team == e.predator.team)\r
 277         {\r
 278                 if(cvar("g_vore_kick"))\r
 279                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 280                 if(cvar("g_vore_digestion"))\r
 281                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 282         }\r
 283 \r
 284         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 285         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 286         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 287         e.predator.stomach_load += 1;\r
 288         e.predator.regurgitate_prepare = 0;\r
 289         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 290         Vore_WeightApply(e.predator);\r
 291         Vore_AutoDigest(e.predator);\r
 292 \r
 293         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 294         e.predator.weapon_delay = time + button_delay_time;\r
 295         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 296         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 297         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 298 }\r
 299 \r
 300 void Vore_SwallowStep(entity e)\r
 301 {\r
 302         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 303         {\r
 304                 Vore_Swallow(e);\r
 305                 return;\r
 306         }\r
 307 \r
 308         Vore_SwallowModel_Update(e);\r
 309 \r
 310         // increase the progress value until it reaches 1, then swallow the player\r
 311         if(e.swallow_progress_prey < 1)\r
 312         {\r
 313                 float fill;\r
 314                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 315                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 316                         fill *= (self.scale / e.scale);\r
 317                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 318                         fill /= e.stomach_load;\r
 319 \r
 320                 e.swallow_progress_prey += fill;\r
 321         }\r
 322         else\r
 323         {\r
 324                 Vore_Swallow(e);\r
 325                 e.swallow_progress_prey = 0;\r
 326         }\r
 327 \r
 328         // the predator's progress is how much the prey got swallowed\r
 329         self.swallow_progress_pred = e.swallow_progress_prey;\r
 330 }\r
 331 \r
 332 void Vore_Regurgitate(entity e)\r
 333 {\r
 334         // this player is being regurgitated by their predator, apply the proper changes\r
 335 \r
 336         e.movetype = e.vore_oldmovetype;\r
 337         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 338                 e.solid = e.vore_oldsolid;\r
 339         e.view_ofs_z = PL_VIEW_OFS_z;\r
 340 \r
 341         // apply velocities\r
 342         local vector oldforward, oldright, oldup;\r
 343         oldforward = v_forward;\r
 344         oldright = v_right;\r
 345         oldup = v_up;\r
 346         makevectors(e.predator.v_angle);\r
 347         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 348         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 349         v_forward = oldforward;\r
 350         v_right = oldright;\r
 351         v_up = oldup;\r
 352 \r
 353         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 354         e.pushltime = time + cvar("g_maxpushtime");\r
 355 \r
 356         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 357         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 358                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 359 \r
 360         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 361         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 362         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 363         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 364         e.predator.stomach_load -= 1;\r
 365         e.predator.regurgitate_prepare = 0;\r
 366         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 367         Vore_WeightApply(e.predator);\r
 368 \r
 369         // block firing for a small amount of time, or we'll be firing the next frame\r
 370         e.weapon_delay = time + button_delay_time;\r
 371         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 372         e.predator = world;\r
 373 }\r
 374 \r
 375 void Vore_DeadPrey_Configure(entity e)\r
 376 {\r
 377         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 378 \r
 379         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 380                 return;\r
 381 \r
 382         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 383         e.fakepredator = e.predator;\r
 384         e.fakeprey = TRUE;\r
 385 \r
 386         // first release the prey from the predator, as dead prey needs to be attached differently\r
 387         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 388         e.predator.stomach_load -= 1;\r
 389         Vore_WeightApply(e.predator);\r
 390         e.predator = world;\r
 391 \r
 392         // now put our dead prey inside the predator's stomach, but only as an effect\r
 393         e.movetype = MOVETYPE_FOLLOW;\r
 394         e.takedamage = DAMAGE_NO;\r
 395         e.solid = SOLID_NOT;\r
 396         e.aiment = e.fakepredator;\r
 397 }\r
 398 \r
 399 void Vore_DeadPrey_Detach(entity e)\r
 400 {\r
 401         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 402         // should only execute after Vore_DeadPrey_Configure has ran first\r
 403 \r
 404         if not(cvar("g_vore_keepdeadprey"))\r
 405                 return;\r
 406 \r
 407         e.fakepredator = world;\r
 408         e.fakeprey = TRUE; // keep fakeprey status\r
 409         e.stat_eaten = 0;\r
 410         e.aiment = world;\r
 411         e.movetype = MOVETYPE_TOSS;\r
 412 }\r
 413 \r
 414 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 415 {\r
 416         if(pred_disconnect)\r
 417         {\r
 418                 if(e.fakeprey)\r
 419                         Vore_DeadPrey_Detach(e);\r
 420                 else\r
 421                         Vore_Regurgitate(e);\r
 422         }\r
 423         else if(self.stat_eaten && !self.fakeprey)\r
 424         {\r
 425                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 426                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 427                         Vore_DeadPrey_Configure(e);\r
 428                 else\r
 429                         Vore_Regurgitate(e);\r
 430         }\r
 431 }\r
 432 \r
 433 void Vore_Disconnect()\r
 434 {\r
 435         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 436 \r
 437         // prey disconnects or goes spectating while inside someone's belly\r
 438         if(self.stat_eaten)\r
 439                 Vore_PreyRelease(self, TRUE);\r
 440 \r
 441         // pred disconnects or goes spectating with players in their belly\r
 442         entity head;\r
 443         FOR_EACH_PLAYER(head)\r
 444         {\r
 445                 if(head.predator == self || head.fakepredator == self)\r
 446                         Vore_PreyRelease(head, TRUE);\r
 447         }\r
 448         Vore_GurgleSound(); // stop the gurgling sound\r
 449 \r
 450         self.stomach_load = self.gravity = 0; // prevents a bug\r
 451 }\r
 452 \r
 453 .float digestion_step;\r
 454 void Vore_Digest()\r
 455 {\r
 456         // apply digestion to prey\r
 457 \r
 458         if(time > self.digestion_step)\r
 459         {\r
 460                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 461                 float reduce;\r
 462                 if(cvar("g_balance_vore_digestion_distribute"))\r
 463                         reduce = self.predator.stomach_load;\r
 464                 else\r
 465                         reduce = 1;\r
 466 \r
 467                 float damage;\r
 468                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 469 \r
 470                 // apply player scale to digestion damage\r
 471                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 472                         damage *= (self.predator.scale / self.scale);\r
 473 \r
 474                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 475                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 476                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 477 \r
 478                 if (self.predator.digestsound_finished < time)\r
 479                 {\r
 480                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 481                         self.predator.digestsound_finished = time + 0.5;\r
 482                 }\r
 483                 self.digestion_step = time + steptime;\r
 484         }\r
 485 \r
 486         if(self.deadflag != DEAD_NO)\r
 487         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 488                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 489 }\r
 490 \r
 491 .float teamheal_step;\r
 492 void Vore_Teamheal()\r
 493 {\r
 494         // apply teamheal\r
 495 \r
 496         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 497         if(time > self.teamheal_step)\r
 498         {\r
 499                 self.health += cvar("g_balance_vore_teamheal");\r
 500                 self.teamheal_step = time + steptime;\r
 501 \r
 502                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 503                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 504                 {\r
 505                         play2(self, "misc/beep.wav");\r
 506                         play2(self.predator, "misc/beep.wav");\r
 507                 }\r
 508         }\r
 509 }\r
 510 \r
 511 void Vore_StomachKick()\r
 512 {\r
 513         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 514 \r
 515         if(time > self.stomachkick_delay)\r
 516         {\r
 517                 float damage;\r
 518                 vector force;\r
 519                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 520                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 521 \r
 522                 // apply player scale to the damage / force of the kick\r
 523                 if(cvar("g_balance_vore_kick_scalediff"))\r
 524                 {\r
 525                         damage *= (self.scale / self.predator.scale);\r
 526                         force *= (self.scale / self.predator.scale);\r
 527                 }\r
 528 \r
 529                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 530                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 531                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 532                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 533 \r
 534                 // abort the predator's scheduled regurgitation\r
 535                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 536                         self.predator.regurgitate_prepare = 0;\r
 537 \r
 538                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 539         }\r
 540 }\r
 541 \r
 542 void Vore_StomachLeave()\r
 543 {\r
 544         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 545 \r
 546         if(Vore_CanLeave())\r
 547                 Vore_Regurgitate(self);\r
 548         else if(time > self.complain_vore)\r
 549         {\r
 550                 play2(self, "misc/forbidden.wav");\r
 551                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 552                 self.complain_vore = time + complain_delay_time;\r
 553         }\r
 554 }\r
 555 \r
 556 void Vore_AutoTaunt()\r
 557 {\r
 558         // triggers ambient vore taunts, for both pred and prey\r
 559 \r
 560         float taunt_time;\r
 561 \r
 562         // predator taunts\r
 563         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 564         {\r
 565                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 566                 {\r
 567                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 568                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 569                 }\r
 570         }\r
 571         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 572         {\r
 573                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 574                 SetAutoTaunt(self, 0, 0);\r
 575         }\r
 576 \r
 577         // prey taunts\r
 578         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 579         {\r
 580                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 581                 {\r
 582                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 583                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 584                 }\r
 585         }\r
 586         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 587         {\r
 588                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 589                 SetAutoTaunt(self, 0, 0);\r
 590         }\r
 591 }\r
 592 \r
 593 void Vore_SetSbarRings()\r
 594 {\r
 595         // first clear the ring stats, then configure them if needed\r
 596         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 597         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 598 \r
 599         if(self.stat_eaten)\r
 600         {\r
 601                 if(time <= self.stomachkick_delay)\r
 602                 {\r
 603                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 604                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 605                 }\r
 606         }\r
 607         else\r
 608         {\r
 609                 if(self.swallow_progress_pred)\r
 610                 {\r
 611                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 612                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 613                 }\r
 614                 else if(time <= self.action_delay)\r
 615                 {\r
 616                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 617                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 618                 }\r
 619 \r
 620                 if(self.swallow_progress_prey)\r
 621                 {\r
 622                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 623                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 624                 }\r
 625                 else if(time <= self.regurgitate_prepare)\r
 626                 {\r
 627                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 628                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 629                 }\r
 630         }\r
 631 }\r
 632 \r
 633 void Vore()\r
 634 {\r
 635         // main vore code, this is where it all happens\r
 636 \r
 637         if(!cvar("g_vore")) // the vore system is disabled\r
 638         {\r
 639                 Vore_Disconnect();\r
 640                 return;\r
 641         }\r
 642 \r
 643         Vore_AutoTaunt();\r
 644 \r
 645         // wash the goo away from players once they leave the stomach\r
 646         if(!self.stat_eaten)\r
 647         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 648         if(self.colormod)\r
 649         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 650         {\r
 651                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 652                 if(self.colormod_x > 1)\r
 653                         self.colormod_x = 1;\r
 654                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 655                 if(self.colormod_y > 1)\r
 656                         self.colormod_y = 1;\r
 657                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 658                 if(self.colormod_z > 1)\r
 659                         self.colormod_z = 1;\r
 660         }\r
 661 \r
 662         // set all vore stats\r
 663         Vore_SetSbarRings();\r
 664         if(self.fakepredator.classname == "player")\r
 665                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 666         else if(self.predator.classname == "player")\r
 667         {\r
 668                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 669                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 670                 self.stat_eaten = num_for_edict(self.predator);\r
 671         }\r
 672         else\r
 673         {\r
 674                 self.stat_stomachload = self.stomach_load;\r
 675                 self.stat_digesting = self.digesting;\r
 676                 self.stat_eaten = 0;\r
 677         }\r
 678         self.stat_canleave = Vore_CanLeave();\r
 679 \r
 680         // don't allow a player inside a player inside another player :)\r
 681         // prevent this by checking if such has happened, and taking the proper measures\r
 682         // this code has a high priority and must not be stopped by any delay, so run it here\r
 683         if(self.predator.stat_eaten)\r
 684         {\r
 685                 entity target_predator, target_predator_predator, oldself;\r
 686                 target_predator = self.predator;\r
 687                 target_predator_predator = self.predator.predator;\r
 688 \r
 689                 Vore_Regurgitate(self);\r
 690 \r
 691                 // now steal our prey's prey if this probability applies\r
 692                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 693                 {\r
 694                         oldself = self;\r
 695                         self = target_predator_predator;\r
 696                         if(Swallow_condition_check(oldself))\r
 697                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 698                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 699                                 Vore_Swallow(oldself);\r
 700                         self = oldself;\r
 701                 }\r
 702         }\r
 703 \r
 704         // the swallow progress of prey and preds idly decrease by this amount\r
 705         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 706         {\r
 707                 if(self.swallow_progress_pred)\r
 708                 {\r
 709                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 710                         if(self.swallow_progress_pred < 0)\r
 711                                 self.swallow_progress_pred = 0;\r
 712                 }\r
 713                 if(self.swallow_progress_prey)\r
 714                 {\r
 715                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 716                         if(self.swallow_progress_prey < 0)\r
 717                                 self.swallow_progress_prey = 0;\r
 718                 }\r
 719         }\r
 720 \r
 721         // apply delays and skip the vore system under some circumstances\r
 722         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 723         {\r
 724                 Vore_Disconnect();\r
 725                 return;\r
 726         }\r
 727         if(self.spectatee_status)\r
 728                 return;\r
 729         if(time < self.system_delay)\r
 730                 return;\r
 731 \r
 732 // --------------------------------\r
 733 // Code that addresses predators:\r
 734 // --------------------------------\r
 735 \r
 736         entity prey;\r
 737         prey = Swallow_player_check();\r
 738 \r
 739         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 740         self.stat_canswallow = 0;\r
 741         if(Swallow_condition_check(prey))\r
 742         {\r
 743                 // canswallow stat, used by the HUD\r
 744                 if(teams_matter && prey.team == self.team)\r
 745                         self.stat_canswallow = 2;\r
 746                 else\r
 747                         self.stat_canswallow = 1;\r
 748 \r
 749                 if(self.BUTTON_ATCK)\r
 750                         Vore_SwallowStep(prey);\r
 751         }\r
 752         else if(prey != world)\r
 753                 self.stat_canswallow = -1;\r
 754 \r
 755         // toggle digestion, if the player has someone in their stomach\r
 756         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 757         {\r
 758                 if(self.stomach_load)\r
 759                 {\r
 760                         if(time > self.digest_button_delay_time)\r
 761                         {\r
 762                                 self.digesting = !self.digesting;\r
 763                                 self.digest_button_delay_time = time + button_delay_time;\r
 764                         }\r
 765                 }\r
 766                 else if(time > self.complain_vore)\r
 767                 {\r
 768                         play2(self, "misc/forbidden.wav");\r
 769                         sprint(self, "There is nothing to digest\n");\r
 770                         self.complain_vore = time + complain_delay_time;\r
 771                 }\r
 772         }\r
 773         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 774                 self.digesting = FALSE;\r
 775 \r
 776         // predator wishes to regurgitate his prey\r
 777         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 778         {\r
 779                 if(self.stomach_load)\r
 780                 {\r
 781                         if(time > self.regurgitate_button_delay_time)\r
 782                         {\r
 783                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 784                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 785                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 786                         }\r
 787                 }\r
 788                 else if(time > self.complain_vore)\r
 789                 {\r
 790                         play2(self, "misc/forbidden.wav");\r
 791                         sprint(self, "There is nothing to regurgitate\n");\r
 792                         self.complain_vore = time + complain_delay_time;\r
 793                 }\r
 794         }\r
 795 \r
 796         if(cvar("g_vore_gurglesound"))\r
 797                 Vore_GurgleSound();\r
 798 \r
 799 // --------------------------------\r
 800 // Code that addresses the prey:\r
 801 // --------------------------------\r
 802 \r
 803         Vore_SetPreyPositions();\r
 804 \r
 805         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 806         if(self.fakeprey)\r
 807         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 808                 Vore_DeadPrey_Detach(self);\r
 809 \r
 810         if(!self.stat_eaten)\r
 811                 return;\r
 812 \r
 813         if(self.deadflag != DEAD_NO)\r
 814         {\r
 815                 Vore_PreyRelease(self, FALSE);\r
 816                 return;\r
 817         }\r
 818 \r
 819         if(self.predator.deadflag != DEAD_NO)\r
 820                 Vore_Regurgitate(self);\r
 821         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 822                 Vore_Regurgitate(self);\r
 823 \r
 824         // apply delayed regurgitating if it was scheduled\r
 825         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 826         {\r
 827                 self.predator.regurgitate_prepare = 0;\r
 828                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 829                 Vore_Regurgitate(self);\r
 830         }\r
 831 \r
 832         // execute digesting and team healing\r
 833         if(self.predator.digesting == TRUE)\r
 834                 Vore_Digest();\r
 835         if(teams_matter && self.team == self.predator.team)\r
 836         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 837                 Vore_Teamheal();\r
 838 \r
 839         // execute prey commands\r
 840         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 841                 Vore_StomachKick();\r
 842         if(self.BUTTON_JUMP)\r
 843                 Vore_StomachLeave();\r
 844 \r
 845         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 846         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 847         kh_Key_DropAll(self, FALSE);\r
 848 }