data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50 \r
  51                 if(swallow_complain != "")\r
  52                 {\r
  53                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  54                         {\r
  55                                 play2(self, "misc/forbidden.wav");\r
  56                                 sprint(self, swallow_complain);\r
  57                                 self.complain_vore = time + complain_delay_time;\r
  58                         }\r
  59                         return FALSE;\r
  60                 }\r
  61                 return TRUE;\r
  62         }\r
  63         return FALSE;\r
  64 }\r
  65 \r
  66 float Stomach_TeamMates_check(entity pred)\r
  67 {\r
  68         // checks if a player's stomach contains any team mates\r
  69 \r
  70         entity head;\r
  71         if(teams_matter)\r
  72         {\r
  73                 FOR_EACH_PLAYER(head)\r
  74                 {\r
  75                         if(head.predator == pred && head.team == pred.team)\r
  76                                 return TRUE;\r
  77                 }\r
  78         }\r
  79         return FALSE;\r
  80 }\r
  81 \r
  82 float Vore_CanLeave()\r
  83 {\r
  84         if(self.predator.classname == "player")\r
  85         {\r
  86                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  87                         return TRUE;\r
  88                 if(teams_matter && self.team == self.predator.team)\r
  89                         return TRUE;\r
  90                 if(g_rpg && cvar("g_rpg_canleave"))\r
  91                         return TRUE;\r
  92         }\r
  93         return FALSE;\r
  94 }\r
  95 \r
  96 // position the camera properly for prey\r
  97 void Vore_SetCamera()\r
  98 {\r
  99         if not(self.predator.classname == "player" || self.fakeprey > 1)\r
 100                 return;\r
 101 \r
 102         self.view_ofs = PL_PREY_VIEW_OFS;\r
 103 \r
 104         float prey_height;\r
 105         if(self.fakeprey > 1)\r
 106                 prey_height = (self.scale - self.fakepredator.scale) * cvar("g_healthsize_vore_pos");\r
 107         else\r
 108                 prey_height = (self.scale - self.predator.scale) * cvar("g_healthsize_vore_pos");\r
 109         self.view_ofs_z += prey_height;\r
 110 }\r
 111 \r
 112 .float gurgle_oldstomachload;\r
 113 void Vore_GurgleSound()\r
 114 {\r
 115         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 116         {\r
 117                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 118 \r
 119                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 120                 self.gurgle_oldstomachload = self.stomach_load;\r
 121         }\r
 122 }\r
 123 \r
 124 void Vore_WeightApply(entity e)\r
 125 {\r
 126         // apply stomach weight that makes you heavier the more you eat\r
 127         // slowing the player is done in cl_physics.qc\r
 128 \r
 129         if(e.stomach_load != e.vore_oldstomachload)\r
 130                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 131         if(e.gravity == 0)\r
 132                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 133         e.vore_oldstomachload = e.stomach_load;\r
 134 }\r
 135 \r
 136 void Vore_AutoDigest(entity e)\r
 137 {\r
 138         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 139 \r
 140         if(!cvar("g_vore_digestion") || e.digesting)\r
 141                 return;\r
 142         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 143                 return; // this feature is only for players, not bots\r
 144         if(e.stomach_load > 1)\r
 145                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 146         if(Stomach_TeamMates_check(e))\r
 147                 return; // never begin automatic digestion if we've swallowed a team mate\r
 148 \r
 149         e.digesting = TRUE;\r
 150 }\r
 151 \r
 152 .entity pusher;\r
 153 .float pushltime;\r
 154 void Vore_Swallow(entity e)\r
 155 {\r
 156         // this player is being swallowed by another player, apply the proper changes\r
 157 \r
 158         e.vore_oldmovetype = e.movetype;\r
 159         e.vore_oldsolid = e.solid;\r
 160 \r
 161         e.predator = self;\r
 162         setorigin(e, e.predator.origin);\r
 163         e.velocity = '0 0 0';\r
 164         e.movetype = MOVETYPE_FOLLOW;\r
 165         e.solid = SOLID_NOT;\r
 166         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 167 \r
 168         // drop keys (KH) and flags (CTF) when we get swallowed\r
 169         kh_Key_DropAll(e, FALSE);\r
 170         if(e.flagcarried)\r
 171                 DropFlag(e.flagcarried, world, e.predator);\r
 172 \r
 173         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 174                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 175 \r
 176         if(teams_matter && e.team == e.predator.team)\r
 177         {\r
 178                 if(cvar("g_vore_kick"))\r
 179                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 180                 if(cvar("g_vore_digestion"))\r
 181                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 182         }\r
 183 \r
 184         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 185         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 186         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 187         e.predator.stomach_load += 1;\r
 188         e.predator.regurgitate_prepare = 0;\r
 189         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 190         Vore_WeightApply(e.predator);\r
 191         Vore_AutoDigest(e.predator);\r
 192 \r
 193         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 194         e.predator.weapon_delay = time + button_delay_time;\r
 195         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 196         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 197 }\r
 198 \r
 199 void Vore_Regurgitate(entity e)\r
 200 {\r
 201         // this player is being regurgitated by their predator, apply the proper changes\r
 202 \r
 203         e.movetype = e.vore_oldmovetype;\r
 204         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 205                 e.solid = e.vore_oldsolid;\r
 206         e.view_ofs_z = PL_VIEW_OFS_z;\r
 207 \r
 208         // apply velocities\r
 209         local vector oldforward, oldright, oldup;\r
 210         oldforward = v_forward;\r
 211         oldright = v_right;\r
 212         oldup = v_up;\r
 213         makevectors(e.predator.v_angle);\r
 214         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 215         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 216         v_forward = oldforward;\r
 217         v_right = oldright;\r
 218         v_up = oldup;\r
 219 \r
 220         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 221         e.pushltime = time + cvar("g_maxpushtime");\r
 222 \r
 223         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 224         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 225         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 226         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 227         e.predator.stomach_load -= 1;\r
 228         e.predator.regurgitate_prepare = 0;\r
 229         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 230         Vore_WeightApply(e.predator);\r
 231 \r
 232         // block firing for a small amount of time, or we'll be firing the next frame\r
 233         e.weapon_delay = time + button_delay_time;\r
 234         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 235         e.predator = world;\r
 236 }\r
 237 \r
 238 void Vore_DeadPrey_Configure(entity e)\r
 239 {\r
 240         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 241 \r
 242         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 243                 return;\r
 244 \r
 245         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 246         e.fakepredator = e.predator;\r
 247         e.fakeprey = 2; // is fakeprey in a stomach\r
 248 \r
 249         // first release the prey from the predator, as dead prey needs to be attached differently\r
 250         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 251         e.predator.stomach_load -= 1;\r
 252         Vore_WeightApply(e.predator);\r
 253         e.predator = world;\r
 254 \r
 255         // now put our dead prey inside the predator's stomach, but only as an effect\r
 256         e.movetype = MOVETYPE_FOLLOW;\r
 257         e.takedamage = DAMAGE_NO;\r
 258         e.solid = SOLID_NOT;\r
 259         e.aiment = e.fakepredator;\r
 260 }\r
 261 \r
 262 void Vore_DeadPrey_Detach(entity e)\r
 263 {\r
 264         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 265         // should only execute after Vore_DeadPrey_Configure has ran first\r
 266 \r
 267         if not(cvar("g_vore_keepdeadprey"))\r
 268                 return;\r
 269 \r
 270         e.fakepredator = world;\r
 271         e.fakeprey = 1; // was fakeprey but is now detached\r
 272         e.aiment = world;\r
 273         e.movetype = MOVETYPE_TOSS;\r
 274 }\r
 275 \r
 276 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 277 {\r
 278         if(pred_disconnect)\r
 279         {\r
 280                 if(e.fakeprey > 1)\r
 281                         Vore_DeadPrey_Detach(e);\r
 282                 else\r
 283                         Vore_Regurgitate(e);\r
 284         }\r
 285         else\r
 286         {\r
 287                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 288                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 289                         Vore_DeadPrey_Configure(e);\r
 290                 else\r
 291                         Vore_Regurgitate(e);\r
 292         }\r
 293 }\r
 294 \r
 295 void Vore_Disconnect()\r
 296 {\r
 297         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 298 \r
 299         // prey disconnects or goes spectating while inside someone's belly\r
 300         if(self.predator.classname == "player")\r
 301                 Vore_PreyRelease(self, TRUE);\r
 302 \r
 303         // pred disconnects or goes spectating with players in their belly\r
 304         entity head;\r
 305         FOR_EACH_PLAYER(head)\r
 306         {\r
 307                 if(head.predator == self || head.fakepredator == self)\r
 308                         Vore_PreyRelease(head, TRUE);\r
 309         }\r
 310         Vore_GurgleSound(); // stop the gurgling sound\r
 311 \r
 312         self.stomach_load = self.gravity = 0; // prevents a bug\r
 313 }\r
 314 \r
 315 .float digestion_step;\r
 316 void Vore_Digest()\r
 317 {\r
 318         // apply digestion to prey\r
 319 \r
 320         if(time > self.predator.digestion_step)\r
 321         {\r
 322                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 323                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 324                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 325 \r
 326                 if (self.predator.digestsound_finished < time)\r
 327                 {\r
 328                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 329                         self.predator.digestsound_finished = time + 0.5;\r
 330                 }\r
 331                 self.predator.digestion_step = time + steptime;\r
 332         }\r
 333 \r
 334         if(self.deadflag != DEAD_NO)\r
 335         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 336                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 337 }\r
 338 \r
 339 .float teamheal_step;\r
 340 void Vore_Teamheal()\r
 341 {\r
 342         // apply teamheal\r
 343 \r
 344         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 345         if(time > self.teamheal_step)\r
 346         {\r
 347                 self.health += cvar("g_balance_vore_teamheal");\r
 348                 self.teamheal_step = time + steptime;\r
 349 \r
 350                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 351                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 352                 {\r
 353                         play2(self, "misc/beep.wav");\r
 354                         play2(self.predator, "misc/beep.wav");\r
 355                 }\r
 356         }\r
 357 }\r
 358 \r
 359 .float stomachkick_delay;\r
 360 void Vore_StomachKick()\r
 361 {\r
 362         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 363 \r
 364         if(time > self.stomachkick_delay)\r
 365         {\r
 366                 float damage;\r
 367                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 368 \r
 369                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 370                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 371                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 372                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 373 \r
 374                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 375                         Vore_Regurgitate(self);\r
 376 \r
 377                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 378         }\r
 379 }\r
 380 \r
 381 void Vore_StomachLeave()\r
 382 {\r
 383         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 384 \r
 385         if(Vore_CanLeave())\r
 386                 Vore_Regurgitate(self);\r
 387         else if(time > self.complain_vore)\r
 388         {\r
 389                 play2(self, "misc/forbidden.wav");\r
 390                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 391                 self.complain_vore = time + complain_delay_time;\r
 392         }\r
 393 }\r
 394 \r
 395 void Vore_AutoTaunt()\r
 396 {\r
 397         // triggers ambient vore taunts, for both pred and prey\r
 398 \r
 399         float taunt_time;\r
 400 \r
 401         // predator taunts\r
 402         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 403         {\r
 404                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 405                 {\r
 406                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 407                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 408                 }\r
 409         }\r
 410         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 411         {\r
 412                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 413                 SetAutoTaunt(self, 0, 0);\r
 414         }\r
 415 \r
 416         // prey taunts\r
 417         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 418         {\r
 419                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 420                 {\r
 421                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 422                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 423                 }\r
 424         }\r
 425         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 426         {\r
 427                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 428                 SetAutoTaunt(self, 0, 0);\r
 429         }\r
 430 }\r
 431 \r
 432 void Vore()\r
 433 {\r
 434         // main vore code, this is where it all happens\r
 435 \r
 436         if(!cvar("g_vore")) // the vore system is disabled\r
 437         {\r
 438                 Vore_Disconnect();\r
 439                 return;\r
 440         }\r
 441 \r
 442         Vore_AutoTaunt();\r
 443 \r
 444         // wash the goo away from players once they leave the stomach\r
 445         if(self.predator.classname != "player")\r
 446         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 447         if(self.colormod)\r
 448         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 449         {\r
 450                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 451                 if(self.colormod_x > 1)\r
 452                         self.colormod_x = 1;\r
 453                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 454                 if(self.colormod_y > 1)\r
 455                         self.colormod_y = 1;\r
 456                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 457                 if(self.colormod_z > 1)\r
 458                         self.colormod_z = 1;\r
 459         }\r
 460 \r
 461         // set all vore stats\r
 462         if(self.fakeprey > 1)\r
 463                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 464         else if(self.predator.classname == "player")\r
 465         {\r
 466                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 467                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 468                 self.stat_eaten = num_for_edict(self.predator);\r
 469         }\r
 470         else\r
 471         {\r
 472                 self.stat_stomachload = self.stomach_load;\r
 473                 self.stat_digesting = self.digesting;\r
 474                 self.stat_eaten = 0;\r
 475         }\r
 476         self.stat_canleave = Vore_CanLeave();\r
 477 \r
 478         // don't allow a player inside a player inside another player :)\r
 479         // prevent this by checking if such has happened, and taking the proper measures\r
 480         // this code has a high priority and must not be stopped by any delay, so run it here\r
 481         if(self.predator.predator.classname == "player")\r
 482         {\r
 483                 entity target_predator, target_predator_predator, oldself;\r
 484                 target_predator = self.predator;\r
 485                 target_predator_predator = self.predator.predator;\r
 486 \r
 487                 Vore_Regurgitate(self);\r
 488 \r
 489                 // now steal our prey's prey if this probability applies\r
 490                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 491                 {\r
 492                         oldself = self;\r
 493                         self = target_predator_predator;\r
 494                         if(Swallow_condition_check(oldself))\r
 495                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 496                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 497                                 Vore_Swallow(oldself);\r
 498                         self = oldself;\r
 499                 }\r
 500         }\r
 501 \r
 502         // apply delays and skip the vore system under some circumstances\r
 503         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 504         {\r
 505                 Vore_Disconnect();\r
 506                 return;\r
 507         }\r
 508         if(self.spectatee_status)\r
 509                 return;\r
 510         if(time < self.system_delay)\r
 511                 return;\r
 512 \r
 513 // --------------------------------\r
 514 // Code that addresses predators:\r
 515 // --------------------------------\r
 516 \r
 517         entity prey;\r
 518         prey = Swallow_player_check();\r
 519 \r
 520         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 521         self.stat_canswallow = 0;\r
 522         if(Swallow_condition_check(prey))\r
 523         {\r
 524                 // canswallow stat, used by the HUD\r
 525                 if(teams_matter && prey.team == self.team)\r
 526                         self.stat_canswallow = 2;\r
 527                 else\r
 528                         self.stat_canswallow = 1;\r
 529 \r
 530                 if(self.BUTTON_ATCK)\r
 531                         Vore_Swallow(prey);\r
 532         }\r
 533         else if(prey != world)\r
 534                 self.stat_canswallow = -1;\r
 535 \r
 536         // toggle digestion, if the player has someone in their stomach\r
 537         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 538         {\r
 539                 if(self.stomach_load)\r
 540                 {\r
 541                         if(time > self.digest_button_delay_time)\r
 542                         {\r
 543                                 self.digesting = !self.digesting;\r
 544                                 self.digest_button_delay_time = time + button_delay_time;\r
 545                         }\r
 546                 }\r
 547                 else if(time > self.complain_vore)\r
 548                 {\r
 549                         play2(self, "misc/forbidden.wav");\r
 550                         sprint(self, "There is nothing to digest\n");\r
 551                         self.complain_vore = time + complain_delay_time;\r
 552                 }\r
 553         }\r
 554         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 555                 self.digesting = FALSE;\r
 556 \r
 557         // predator wishes to regurgitate his prey\r
 558         if(self.BUTTON_REGURGITATE)\r
 559         {\r
 560                 if(self.stomach_load)\r
 561                 {\r
 562                         if(time > self.regurgitate_button_delay_time)\r
 563                         {\r
 564                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 565                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 566                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 567                         }\r
 568                 }\r
 569                 else if(time > self.complain_vore)\r
 570                 {\r
 571                         play2(self, "misc/forbidden.wav");\r
 572                         sprint(self, "There is nothing to regurgitate\n");\r
 573                         self.complain_vore = time + complain_delay_time;\r
 574                 }\r
 575         }\r
 576 \r
 577         if(cvar("g_vore_gurglesound"))\r
 578                 Vore_GurgleSound();\r
 579 \r
 580 // --------------------------------\r
 581 // Code that addresses the prey:\r
 582 // --------------------------------\r
 583 \r
 584         Vore_SetCamera();\r
 585 \r
 586         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 587         if(self.fakepredator.classname == "player")\r
 588         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 589                 Vore_DeadPrey_Detach(self);\r
 590 \r
 591         if(self.predator.classname != "player")\r
 592                 return;\r
 593 \r
 594         if(self.deadflag != DEAD_NO)\r
 595         {\r
 596                 Vore_PreyRelease(self, FALSE);\r
 597                 return;\r
 598         }\r
 599 \r
 600         if(self.predator.deadflag != DEAD_NO)\r
 601                 Vore_Regurgitate(self);\r
 602         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 603                 Vore_Regurgitate(self);\r
 604 \r
 605         // apply delayed regurgitating if it was scheduled\r
 606         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 607         {\r
 608                 self.predator.regurgitate_prepare = 0;\r
 609                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 610                 Vore_Regurgitate(self);\r
 611         }\r
 612 \r
 613         // execute digesting and team healing\r
 614         if(self.predator.digesting == TRUE)\r
 615                 Vore_Digest();\r
 616         if(teams_matter && self.team == self.predator.team)\r
 617         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 618                 Vore_Teamheal();\r
 619 \r
 620         // execute prey commands\r
 621         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 622                 Vore_StomachKick();\r
 623         if(self.BUTTON_JUMP)\r
 624                 Vore_StomachLeave();\r
 625 \r
 626         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 627         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 628         kh_Key_DropAll(self, FALSE);\r
 629 }