data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity swallow_model;\r
 203 void Vore_SwallowModel_Think()\r
 204 {\r
 205         //update the position of the swallow model to match our swallow progress\r
 206         float dist;\r
 207         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 208         if(cvar("g_healthsize"))\r
 209                 dist *= self.scale;\r
 210         self.view_ofs = '1 0 0' * dist;\r
 211 \r
 212         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 213         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 214         {\r
 215                 remove(self.owner.swallow_model);\r
 216                 self.owner.swallow_model = world;\r
 217                 return;\r
 218         }\r
 219 \r
 220         // properties that should update whenever possible, but when the predator is not available\r
 221         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 222         self.nextthink = time;\r
 223 }\r
 224 \r
 225 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 226 {\r
 227         // if we don't have a swallow model already, spawn one\r
 228         if(!prey.swallow_model)\r
 229         {\r
 230                 prey.swallow_model = spawn();\r
 231 \r
 232                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 233                 prey.swallow_model.solid = SOLID_NOT;\r
 234 \r
 235                 // apply the properties of the prey\r
 236                 prey.swallow_model.viewmodelforclient = prey; // use the same system as the weapon model\r
 237                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 238                 prey.swallow_model.colormap = prey.colormap; // pants and shirt color\r
 239                 prey.swallow_model.glowmod = prey.glowmod; // glow color\r
 240 \r
 241                 prey.swallow_model.owner = prey; // owned by the prey\r
 242                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 243                 prey.swallow_model.nextthink = time;\r
 244         }\r
 245 \r
 246         // properties that should update whenever possible, but when the predator is available\r
 247         string player_swallowmodel;\r
 248         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 249         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 250                 setmodel(prey.swallow_model, player_swallowmodel);\r
 251         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 252                 prey.swallow_model.skin = pred.skin;\r
 253         if(cvar("g_healthsize"))\r
 254                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 255         if(prey.swallow_model.enemy != pred)\r
 256                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 257 }\r
 258 \r
 259 .entity pusher;\r
 260 .float pushltime;\r
 261 void Vore_Swallow(entity e)\r
 262 {\r
 263         // this player is being swallowed by another player, apply the proper changes\r
 264 \r
 265         e.vore_oldmovetype = e.movetype;\r
 266         e.vore_oldsolid = e.solid;\r
 267 \r
 268         e.predator = self;\r
 269         setorigin(e, e.predator.origin);\r
 270         e.velocity = '0 0 0';\r
 271         e.movetype = MOVETYPE_FOLLOW;\r
 272         e.solid = SOLID_NOT;\r
 273         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 274 \r
 275         // drop keys (KH) and flags (CTF) when we get swallowed\r
 276         kh_Key_DropAll(e, FALSE);\r
 277         if(e.flagcarried)\r
 278                 DropFlag(e.flagcarried, world, e.predator);\r
 279 \r
 280         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 281                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 282 \r
 283         if(teams_matter && e.team == e.predator.team)\r
 284         {\r
 285                 if(cvar("g_vore_kick"))\r
 286                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 287                 if(cvar("g_vore_digestion"))\r
 288                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 289         }\r
 290 \r
 291         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 292         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 293         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 294         e.predator.stomach_load += 1;\r
 295         e.predator.regurgitate_prepare = 0;\r
 296         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 297         Vore_WeightApply(e.predator);\r
 298         Vore_AutoDigest(e.predator);\r
 299 \r
 300         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 301         e.predator.weapon_delay = time + button_delay_time;\r
 302         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 303         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 304         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 305 }\r
 306 \r
 307 void Vore_SwallowStep(entity e)\r
 308 {\r
 309         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 310         {\r
 311                 Vore_Swallow(e);\r
 312                 return;\r
 313         }\r
 314 \r
 315         Vore_SwallowModel_Update(e, self);\r
 316 \r
 317         // increase the progress value until it reaches 1, then swallow the player\r
 318         if(e.swallow_progress_prey < 1)\r
 319         {\r
 320                 float fill;\r
 321                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 322                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 323                         fill *= (self.scale / e.scale);\r
 324                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 325                         fill /= e.stomach_load;\r
 326 \r
 327                 e.swallow_progress_prey += fill;\r
 328         }\r
 329         else\r
 330         {\r
 331                 Vore_Swallow(e);\r
 332                 e.swallow_progress_prey = 0;\r
 333         }\r
 334 \r
 335         // the predator's progress is how much the prey got swallowed\r
 336         self.swallow_progress_pred = e.swallow_progress_prey;\r
 337 }\r
 338 \r
 339 void Vore_Regurgitate(entity e)\r
 340 {\r
 341         // this player is being regurgitated by their predator, apply the proper changes\r
 342 \r
 343         e.movetype = e.vore_oldmovetype;\r
 344         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 345                 e.solid = e.vore_oldsolid;\r
 346         e.view_ofs_z = PL_VIEW_OFS_z;\r
 347 \r
 348         // apply velocities\r
 349         local vector oldforward, oldright, oldup;\r
 350         oldforward = v_forward;\r
 351         oldright = v_right;\r
 352         oldup = v_up;\r
 353         makevectors(e.predator.v_angle);\r
 354         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 355         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 356         v_forward = oldforward;\r
 357         v_right = oldright;\r
 358         v_up = oldup;\r
 359 \r
 360         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 361         e.pushltime = time + cvar("g_maxpushtime");\r
 362 \r
 363         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 364         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 365         {\r
 366                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 367                 Vore_SwallowModel_Update(e, e.predator);\r
 368         }\r
 369 \r
 370         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 371         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 372         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 373         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 374         e.predator.stomach_load -= 1;\r
 375         e.predator.regurgitate_prepare = 0;\r
 376         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 377         Vore_WeightApply(e.predator);\r
 378 \r
 379         // block firing for a small amount of time, or we'll be firing the next frame\r
 380         e.weapon_delay = time + button_delay_time;\r
 381         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 382         e.predator = world;\r
 383 }\r
 384 \r
 385 void Vore_DeadPrey_Configure(entity e)\r
 386 {\r
 387         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 388 \r
 389         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 390                 return;\r
 391 \r
 392         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 393         e.fakepredator = e.predator;\r
 394         e.fakeprey = TRUE;\r
 395 \r
 396         // first release the prey from the predator, as dead prey needs to be attached differently\r
 397         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 398         e.predator.stomach_load -= 1;\r
 399         Vore_WeightApply(e.predator);\r
 400         e.predator = world;\r
 401 \r
 402         // now put our dead prey inside the predator's stomach, but only as an effect\r
 403         e.movetype = MOVETYPE_FOLLOW;\r
 404         e.takedamage = DAMAGE_NO;\r
 405         e.solid = SOLID_NOT;\r
 406         e.aiment = e.fakepredator;\r
 407 }\r
 408 \r
 409 void Vore_DeadPrey_Detach(entity e)\r
 410 {\r
 411         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 412         // should only execute after Vore_DeadPrey_Configure has ran first\r
 413 \r
 414         if not(cvar("g_vore_keepdeadprey"))\r
 415                 return;\r
 416 \r
 417         e.fakepredator = world;\r
 418         e.fakeprey = TRUE; // keep fakeprey status\r
 419         e.stat_eaten = 0;\r
 420         e.aiment = world;\r
 421         e.movetype = MOVETYPE_TOSS;\r
 422 }\r
 423 \r
 424 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 425 {\r
 426         if(pred_disconnect)\r
 427         {\r
 428                 if(e.fakeprey)\r
 429                         Vore_DeadPrey_Detach(e);\r
 430                 else\r
 431                         Vore_Regurgitate(e);\r
 432         }\r
 433         else if(self.stat_eaten && !self.fakeprey)\r
 434         {\r
 435                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 436                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 437                         Vore_DeadPrey_Configure(e);\r
 438                 else\r
 439                         Vore_Regurgitate(e);\r
 440         }\r
 441 }\r
 442 \r
 443 void Vore_Disconnect()\r
 444 {\r
 445         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 446 \r
 447         // prey disconnects or goes spectating while inside someone's belly\r
 448         if(self.stat_eaten)\r
 449                 Vore_PreyRelease(self, TRUE);\r
 450 \r
 451         // pred disconnects or goes spectating with players in their belly\r
 452         entity head;\r
 453         FOR_EACH_PLAYER(head)\r
 454         {\r
 455                 if(head.predator == self || head.fakepredator == self)\r
 456                         Vore_PreyRelease(head, TRUE);\r
 457         }\r
 458         Vore_GurgleSound(); // stop the gurgling sound\r
 459 \r
 460         self.stomach_load = self.gravity = 0; // prevents a bug\r
 461 }\r
 462 \r
 463 .float digestion_step;\r
 464 void Vore_Digest()\r
 465 {\r
 466         // apply digestion to prey\r
 467 \r
 468         if(time > self.digestion_step)\r
 469         {\r
 470                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 471                 float reduce;\r
 472                 if(cvar("g_balance_vore_digestion_distribute"))\r
 473                         reduce = self.predator.stomach_load;\r
 474                 else\r
 475                         reduce = 1;\r
 476 \r
 477                 float damage;\r
 478                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 479 \r
 480                 // apply player scale to digestion damage\r
 481                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 482                         damage *= (self.predator.scale / self.scale);\r
 483 \r
 484                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 485                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 486                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 487 \r
 488                 if (self.predator.digestsound_finished < time)\r
 489                 {\r
 490                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 491                         self.predator.digestsound_finished = time + 0.5;\r
 492                 }\r
 493                 self.digestion_step = time + steptime;\r
 494         }\r
 495 \r
 496         if(self.deadflag != DEAD_NO)\r
 497         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 498                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 499 }\r
 500 \r
 501 .float teamheal_step;\r
 502 void Vore_Teamheal()\r
 503 {\r
 504         // apply teamheal\r
 505 \r
 506         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 507         if(time > self.teamheal_step)\r
 508         {\r
 509                 self.health += cvar("g_balance_vore_teamheal");\r
 510                 self.teamheal_step = time + steptime;\r
 511 \r
 512                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 513                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 514                 {\r
 515                         play2(self, "misc/beep.wav");\r
 516                         play2(self.predator, "misc/beep.wav");\r
 517                 }\r
 518         }\r
 519 }\r
 520 \r
 521 void Vore_StomachKick()\r
 522 {\r
 523         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 524 \r
 525         if(time > self.stomachkick_delay)\r
 526         {\r
 527                 float damage;\r
 528                 vector force;\r
 529                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 530                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 531 \r
 532                 // apply player scale to the damage / force of the kick\r
 533                 if(cvar("g_balance_vore_kick_scalediff"))\r
 534                 {\r
 535                         damage *= (self.scale / self.predator.scale);\r
 536                         force *= (self.scale / self.predator.scale);\r
 537                 }\r
 538 \r
 539                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 540                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 541                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 542                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 543 \r
 544                 // abort the predator's scheduled regurgitation\r
 545                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 546                         self.predator.regurgitate_prepare = 0;\r
 547 \r
 548                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 549         }\r
 550 }\r
 551 \r
 552 void Vore_StomachLeave()\r
 553 {\r
 554         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 555 \r
 556         if(Vore_CanLeave())\r
 557                 Vore_Regurgitate(self);\r
 558         else if(time > self.complain_vore)\r
 559         {\r
 560                 play2(self, "misc/forbidden.wav");\r
 561                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 562                 self.complain_vore = time + complain_delay_time;\r
 563         }\r
 564 }\r
 565 \r
 566 void Vore_AutoTaunt()\r
 567 {\r
 568         // triggers ambient vore taunts, for both pred and prey\r
 569 \r
 570         float taunt_time;\r
 571 \r
 572         // predator taunts\r
 573         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 574         {\r
 575                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 576                 {\r
 577                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 578                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 579                 }\r
 580         }\r
 581         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 582         {\r
 583                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 584                 SetAutoTaunt(self, 0, 0);\r
 585         }\r
 586 \r
 587         // prey taunts\r
 588         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 589         {\r
 590                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 591                 {\r
 592                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 593                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 594                 }\r
 595         }\r
 596         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 597         {\r
 598                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 599                 SetAutoTaunt(self, 0, 0);\r
 600         }\r
 601 }\r
 602 \r
 603 void Vore_SetSbarRings()\r
 604 {\r
 605         // first clear the ring stats, then configure them if needed\r
 606         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 607         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 608 \r
 609         if(self.stat_eaten)\r
 610         {\r
 611                 if(time <= self.stomachkick_delay)\r
 612                 {\r
 613                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 614                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 615                 }\r
 616         }\r
 617         else\r
 618         {\r
 619                 if(self.swallow_progress_pred)\r
 620                 {\r
 621                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 622                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 623                 }\r
 624                 else if(time <= self.action_delay)\r
 625                 {\r
 626                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 627                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 628                 }\r
 629 \r
 630                 if(self.swallow_progress_prey)\r
 631                 {\r
 632                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 633                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 634                 }\r
 635                 else if(time <= self.regurgitate_prepare)\r
 636                 {\r
 637                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 638                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 639                 }\r
 640         }\r
 641 }\r
 642 \r
 643 void Vore()\r
 644 {\r
 645         // main vore code, this is where it all happens\r
 646 \r
 647         if(!cvar("g_vore")) // the vore system is disabled\r
 648         {\r
 649                 Vore_Disconnect();\r
 650                 return;\r
 651         }\r
 652 \r
 653         Vore_AutoTaunt();\r
 654 \r
 655         // wash the goo away from players once they leave the stomach\r
 656         if(!self.stat_eaten)\r
 657         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 658         if(self.colormod)\r
 659         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 660         {\r
 661                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 662                 if(self.colormod_x > 1)\r
 663                         self.colormod_x = 1;\r
 664                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 665                 if(self.colormod_y > 1)\r
 666                         self.colormod_y = 1;\r
 667                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 668                 if(self.colormod_z > 1)\r
 669                         self.colormod_z = 1;\r
 670         }\r
 671 \r
 672         // set all vore stats\r
 673         Vore_SetSbarRings();\r
 674         if(self.fakepredator.classname == "player")\r
 675                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 676         else if(self.predator.classname == "player")\r
 677         {\r
 678                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 679                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 680                 self.stat_eaten = num_for_edict(self.predator);\r
 681         }\r
 682         else\r
 683         {\r
 684                 self.stat_stomachload = self.stomach_load;\r
 685                 self.stat_digesting = self.digesting;\r
 686                 self.stat_eaten = 0;\r
 687         }\r
 688         self.stat_canleave = Vore_CanLeave();\r
 689 \r
 690         // don't allow a player inside a player inside another player :)\r
 691         // prevent this by checking if such has happened, and taking the proper measures\r
 692         // this code has a high priority and must not be stopped by any delay, so run it here\r
 693         if(self.predator.stat_eaten)\r
 694         {\r
 695                 entity target_predator, target_predator_predator, oldself;\r
 696                 target_predator = self.predator;\r
 697                 target_predator_predator = self.predator.predator;\r
 698 \r
 699                 Vore_Regurgitate(self);\r
 700 \r
 701                 // now steal our prey's prey if this probability applies\r
 702                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 703                 {\r
 704                         oldself = self;\r
 705                         self = target_predator_predator;\r
 706                         if(Swallow_condition_check(oldself))\r
 707                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 708                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 709                                 Vore_Swallow(oldself);\r
 710                         self = oldself;\r
 711                 }\r
 712         }\r
 713 \r
 714         // the swallow progress of prey and preds idly decrease by this amount\r
 715         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 716         {\r
 717                 if(self.swallow_progress_pred)\r
 718                 {\r
 719                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 720                         if(self.swallow_progress_pred < 0)\r
 721                                 self.swallow_progress_pred = 0;\r
 722                 }\r
 723                 if(self.swallow_progress_prey)\r
 724                 {\r
 725                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 726                         if(self.swallow_progress_prey < 0)\r
 727                                 self.swallow_progress_prey = 0;\r
 728                 }\r
 729         }\r
 730 \r
 731         // apply delays and skip the vore system under some circumstances\r
 732         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 733         {\r
 734                 Vore_Disconnect();\r
 735                 return;\r
 736         }\r
 737         if(self.spectatee_status)\r
 738                 return;\r
 739         if(time < self.system_delay)\r
 740                 return;\r
 741 \r
 742 // --------------------------------\r
 743 // Code that addresses predators:\r
 744 // --------------------------------\r
 745 \r
 746         entity prey;\r
 747         prey = Swallow_player_check();\r
 748 \r
 749         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 750         self.stat_canswallow = 0;\r
 751         if(Swallow_condition_check(prey))\r
 752         {\r
 753                 // canswallow stat, used by the HUD\r
 754                 if(teams_matter && prey.team == self.team)\r
 755                         self.stat_canswallow = 2;\r
 756                 else\r
 757                         self.stat_canswallow = 1;\r
 758 \r
 759                 if(self.BUTTON_ATCK)\r
 760                         Vore_SwallowStep(prey);\r
 761         }\r
 762         else if(prey != world)\r
 763                 self.stat_canswallow = -1;\r
 764 \r
 765         // toggle digestion, if the player has someone in their stomach\r
 766         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 767         {\r
 768                 if(self.stomach_load)\r
 769                 {\r
 770                         if(time > self.digest_button_delay_time)\r
 771                         {\r
 772                                 self.digesting = !self.digesting;\r
 773                                 self.digest_button_delay_time = time + button_delay_time;\r
 774                         }\r
 775                 }\r
 776                 else if(time > self.complain_vore)\r
 777                 {\r
 778                         play2(self, "misc/forbidden.wav");\r
 779                         sprint(self, "There is nothing to digest\n");\r
 780                         self.complain_vore = time + complain_delay_time;\r
 781                 }\r
 782         }\r
 783         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 784                 self.digesting = FALSE;\r
 785 \r
 786         // predator wishes to regurgitate his prey\r
 787         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 788         {\r
 789                 if(self.stomach_load)\r
 790                 {\r
 791                         if(time > self.regurgitate_button_delay_time)\r
 792                         {\r
 793                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 794                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 795                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 796                         }\r
 797                 }\r
 798                 else if(time > self.complain_vore)\r
 799                 {\r
 800                         play2(self, "misc/forbidden.wav");\r
 801                         sprint(self, "There is nothing to regurgitate\n");\r
 802                         self.complain_vore = time + complain_delay_time;\r
 803                 }\r
 804         }\r
 805 \r
 806         if(cvar("g_vore_gurglesound"))\r
 807                 Vore_GurgleSound();\r
 808 \r
 809 // --------------------------------\r
 810 // Code that addresses the prey:\r
 811 // --------------------------------\r
 812 \r
 813         Vore_SetPreyPositions();\r
 814 \r
 815         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 816         if(self.fakeprey)\r
 817         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 818                 Vore_DeadPrey_Detach(self);\r
 819 \r
 820         if(!self.stat_eaten)\r
 821                 return;\r
 822 \r
 823         if(self.deadflag != DEAD_NO)\r
 824         {\r
 825                 Vore_PreyRelease(self, FALSE);\r
 826                 return;\r
 827         }\r
 828 \r
 829         if(self.predator.deadflag != DEAD_NO)\r
 830                 Vore_Regurgitate(self);\r
 831         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 832                 Vore_Regurgitate(self);\r
 833 \r
 834         // apply delayed regurgitating if it was scheduled\r
 835         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 836         {\r
 837                 self.predator.regurgitate_prepare = 0;\r
 838                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 839                 Vore_Regurgitate(self);\r
 840         }\r
 841 \r
 842         // execute digesting and team healing\r
 843         if(self.predator.digesting == TRUE)\r
 844                 Vore_Digest();\r
 845         if(teams_matter && self.team == self.predator.team)\r
 846         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 847                 Vore_Teamheal();\r
 848 \r
 849         // execute prey commands\r
 850         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 851                 Vore_StomachKick();\r
 852         if(self.BUTTON_JUMP)\r
 853                 Vore_StomachLeave();\r
 854 \r
 855         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 856         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 857         kh_Key_DropAll(self, FALSE);\r
 858 }