data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 void Vore_SwallowModel_Think()\r
 203 {\r
 204         //update the necessary angles to match our view\r
 205         //self.angles_x = self.owner.angles_x;\r
 206         //self.view_ofs = self.owner.view_ofs;\r
 207 \r
 208         // if our swallow progress is gone, the swallow model must also go\r
 209         if(!self.owner.swallow_progress_prey)\r
 210         {\r
 211                 self.nextthink = 0;\r
 212                 remove(self);\r
 213                 self = world;\r
 214                 return;\r
 215         }\r
 216 \r
 217         self.nextthink = time;\r
 218 }\r
 219 \r
 220 .entity swallow_model;\r
 221 void Vore_SwallowModel_Update(entity prey)\r
 222 {\r
 223         // if we don't have a swallow model already, spawn one\r
 224         if(!prey.swallow_model)\r
 225         {\r
 226                 prey.swallow_model = spawn();\r
 227                 \r
 228                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 229                 prey.swallow_model.solid = SOLID_NOT;\r
 230 \r
 231                 prey.swallow_model.skin = self.skin;\r
 232                 prey.swallow_model.scale = self.scale;\r
 233 \r
 234                 // apply the properties of the prey\r
 235                 prey.swallow_model.viewmodelforclient = prey;\r
 236                 prey.swallow_model.effects |= EF_NOGUNBOB;\r
 237                 prey.swallow_model.alpha = prey.cvar_cl_vore_stomachmodel;\r
 238                 prey.swallow_model.colormap = prey.colormap;\r
 239                 prey.swallow_model.glowmod = prey.glowmod;\r
 240 \r
 241                 prey.swallow_model.owner = prey; // owned by the prey\r
 242                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 243                 prey.swallow_model.nextthink = time;\r
 244         }\r
 245 \r
 246         // if predator has changed, update the swallow model\r
 247         if(prey.swallow_model.enemy != self)\r
 248         {\r
 249                 setmodel(prey.swallow_model, strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3")); // 4 is the extension length\r
 250                 prey.swallow_model.skin = self.skin;\r
 251                 prey.swallow_model.enemy = self; // enemy is the predator\r
 252         }\r
 253 }\r
 254 \r
 255 .entity pusher;\r
 256 .float pushltime;\r
 257 void Vore_Swallow(entity e)\r
 258 {\r
 259         // this player is being swallowed by another player, apply the proper changes\r
 260 \r
 261         e.vore_oldmovetype = e.movetype;\r
 262         e.vore_oldsolid = e.solid;\r
 263 \r
 264         e.predator = self;\r
 265         setorigin(e, e.predator.origin);\r
 266         e.velocity = '0 0 0';\r
 267         e.movetype = MOVETYPE_FOLLOW;\r
 268         e.solid = SOLID_NOT;\r
 269         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 270 \r
 271         // drop keys (KH) and flags (CTF) when we get swallowed\r
 272         kh_Key_DropAll(e, FALSE);\r
 273         if(e.flagcarried)\r
 274                 DropFlag(e.flagcarried, world, e.predator);\r
 275 \r
 276         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 277                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 278 \r
 279         if(teams_matter && e.team == e.predator.team)\r
 280         {\r
 281                 if(cvar("g_vore_kick"))\r
 282                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 283                 if(cvar("g_vore_digestion"))\r
 284                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 285         }\r
 286 \r
 287         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 288         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 289         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 290         e.predator.stomach_load += 1;\r
 291         e.predator.regurgitate_prepare = 0;\r
 292         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 293         Vore_WeightApply(e.predator);\r
 294         Vore_AutoDigest(e.predator);\r
 295 \r
 296         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 297         e.predator.weapon_delay = time + button_delay_time;\r
 298         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 299         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 300         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 301 }\r
 302 \r
 303 void Vore_SwallowStep(entity e)\r
 304 {\r
 305         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 306         {\r
 307                 Vore_Swallow(e);\r
 308                 return;\r
 309         }\r
 310 \r
 311         Vore_SwallowModel_Update(e);\r
 312 \r
 313         // increase the progress value until it reaches 1, then swallow the player\r
 314         if(e.swallow_progress_prey < 1)\r
 315         {\r
 316                 float fill;\r
 317                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 318                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 319                         fill *= (self.scale / e.scale);\r
 320                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 321                         fill /= e.stomach_load;\r
 322 \r
 323                 e.swallow_progress_prey += fill;\r
 324         }\r
 325         else\r
 326         {\r
 327                 Vore_Swallow(e);\r
 328                 e.swallow_progress_prey = 0;\r
 329         }\r
 330 \r
 331         // the predator's progress is how much the prey got swallowed\r
 332         self.swallow_progress_pred = e.swallow_progress_prey;\r
 333 }\r
 334 \r
 335 void Vore_Regurgitate(entity e)\r
 336 {\r
 337         // this player is being regurgitated by their predator, apply the proper changes\r
 338 \r
 339         e.movetype = e.vore_oldmovetype;\r
 340         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 341                 e.solid = e.vore_oldsolid;\r
 342         e.view_ofs_z = PL_VIEW_OFS_z;\r
 343 \r
 344         // apply velocities\r
 345         local vector oldforward, oldright, oldup;\r
 346         oldforward = v_forward;\r
 347         oldright = v_right;\r
 348         oldup = v_up;\r
 349         makevectors(e.predator.v_angle);\r
 350         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 351         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 352         v_forward = oldforward;\r
 353         v_right = oldright;\r
 354         v_up = oldup;\r
 355 \r
 356         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 357         e.pushltime = time + cvar("g_maxpushtime");\r
 358 \r
 359         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 360         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 361                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 362 \r
 363         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 364         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 365         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 366         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 367         e.predator.stomach_load -= 1;\r
 368         e.predator.regurgitate_prepare = 0;\r
 369         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 370         Vore_WeightApply(e.predator);\r
 371 \r
 372         // block firing for a small amount of time, or we'll be firing the next frame\r
 373         e.weapon_delay = time + button_delay_time;\r
 374         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 375         e.predator = world;\r
 376 }\r
 377 \r
 378 void Vore_DeadPrey_Configure(entity e)\r
 379 {\r
 380         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 381 \r
 382         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 383                 return;\r
 384 \r
 385         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 386         e.fakepredator = e.predator;\r
 387         e.fakeprey = TRUE;\r
 388 \r
 389         // first release the prey from the predator, as dead prey needs to be attached differently\r
 390         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 391         e.predator.stomach_load -= 1;\r
 392         Vore_WeightApply(e.predator);\r
 393         e.predator = world;\r
 394 \r
 395         // now put our dead prey inside the predator's stomach, but only as an effect\r
 396         e.movetype = MOVETYPE_FOLLOW;\r
 397         e.takedamage = DAMAGE_NO;\r
 398         e.solid = SOLID_NOT;\r
 399         e.aiment = e.fakepredator;\r
 400 }\r
 401 \r
 402 void Vore_DeadPrey_Detach(entity e)\r
 403 {\r
 404         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 405         // should only execute after Vore_DeadPrey_Configure has ran first\r
 406 \r
 407         if not(cvar("g_vore_keepdeadprey"))\r
 408                 return;\r
 409 \r
 410         e.fakepredator = world;\r
 411         e.fakeprey = TRUE; // keep fakeprey status\r
 412         e.stat_eaten = 0;\r
 413         e.aiment = world;\r
 414         e.movetype = MOVETYPE_TOSS;\r
 415 }\r
 416 \r
 417 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 418 {\r
 419         if(pred_disconnect)\r
 420         {\r
 421                 if(e.fakeprey)\r
 422                         Vore_DeadPrey_Detach(e);\r
 423                 else\r
 424                         Vore_Regurgitate(e);\r
 425         }\r
 426         else if(self.stat_eaten && !self.fakeprey)\r
 427         {\r
 428                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 429                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 430                         Vore_DeadPrey_Configure(e);\r
 431                 else\r
 432                         Vore_Regurgitate(e);\r
 433         }\r
 434 }\r
 435 \r
 436 void Vore_Disconnect()\r
 437 {\r
 438         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 439 \r
 440         // prey disconnects or goes spectating while inside someone's belly\r
 441         if(self.stat_eaten)\r
 442                 Vore_PreyRelease(self, TRUE);\r
 443 \r
 444         // pred disconnects or goes spectating with players in their belly\r
 445         entity head;\r
 446         FOR_EACH_PLAYER(head)\r
 447         {\r
 448                 if(head.predator == self || head.fakepredator == self)\r
 449                         Vore_PreyRelease(head, TRUE);\r
 450         }\r
 451         Vore_GurgleSound(); // stop the gurgling sound\r
 452 \r
 453         self.stomach_load = self.gravity = 0; // prevents a bug\r
 454 }\r
 455 \r
 456 .float digestion_step;\r
 457 void Vore_Digest()\r
 458 {\r
 459         // apply digestion to prey\r
 460 \r
 461         if(time > self.digestion_step)\r
 462         {\r
 463                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 464                 float reduce;\r
 465                 if(cvar("g_balance_vore_digestion_distribute"))\r
 466                         reduce = self.predator.stomach_load;\r
 467                 else\r
 468                         reduce = 1;\r
 469 \r
 470                 float damage;\r
 471                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 472 \r
 473                 // apply player scale to digestion damage\r
 474                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 475                         damage *= (self.predator.scale / self.scale);\r
 476 \r
 477                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 478                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 479                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 480 \r
 481                 if (self.predator.digestsound_finished < time)\r
 482                 {\r
 483                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 484                         self.predator.digestsound_finished = time + 0.5;\r
 485                 }\r
 486                 self.digestion_step = time + steptime;\r
 487         }\r
 488 \r
 489         if(self.deadflag != DEAD_NO)\r
 490         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 491                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 492 }\r
 493 \r
 494 .float teamheal_step;\r
 495 void Vore_Teamheal()\r
 496 {\r
 497         // apply teamheal\r
 498 \r
 499         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 500         if(time > self.teamheal_step)\r
 501         {\r
 502                 self.health += cvar("g_balance_vore_teamheal");\r
 503                 self.teamheal_step = time + steptime;\r
 504 \r
 505                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 506                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 507                 {\r
 508                         play2(self, "misc/beep.wav");\r
 509                         play2(self.predator, "misc/beep.wav");\r
 510                 }\r
 511         }\r
 512 }\r
 513 \r
 514 void Vore_StomachKick()\r
 515 {\r
 516         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 517 \r
 518         if(time > self.stomachkick_delay)\r
 519         {\r
 520                 float damage;\r
 521                 vector force;\r
 522                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 523                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 524 \r
 525                 // apply player scale to the damage / force of the kick\r
 526                 if(cvar("g_balance_vore_kick_scalediff"))\r
 527                 {\r
 528                         damage *= (self.scale / self.predator.scale);\r
 529                         force *= (self.scale / self.predator.scale);\r
 530                 }\r
 531 \r
 532                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 533                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 534                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 535                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 536 \r
 537                 // abort the predator's scheduled regurgitation\r
 538                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 539                         self.predator.regurgitate_prepare = 0;\r
 540 \r
 541                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 542         }\r
 543 }\r
 544 \r
 545 void Vore_StomachLeave()\r
 546 {\r
 547         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 548 \r
 549         if(Vore_CanLeave())\r
 550                 Vore_Regurgitate(self);\r
 551         else if(time > self.complain_vore)\r
 552         {\r
 553                 play2(self, "misc/forbidden.wav");\r
 554                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 555                 self.complain_vore = time + complain_delay_time;\r
 556         }\r
 557 }\r
 558 \r
 559 void Vore_AutoTaunt()\r
 560 {\r
 561         // triggers ambient vore taunts, for both pred and prey\r
 562 \r
 563         float taunt_time;\r
 564 \r
 565         // predator taunts\r
 566         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 567         {\r
 568                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 569                 {\r
 570                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 571                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 572                 }\r
 573         }\r
 574         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 575         {\r
 576                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 577                 SetAutoTaunt(self, 0, 0);\r
 578         }\r
 579 \r
 580         // prey taunts\r
 581         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 582         {\r
 583                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 584                 {\r
 585                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 586                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 587                 }\r
 588         }\r
 589         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 590         {\r
 591                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 592                 SetAutoTaunt(self, 0, 0);\r
 593         }\r
 594 }\r
 595 \r
 596 void Vore_SetSbarRings()\r
 597 {\r
 598         // first clear the ring stats, then configure them if needed\r
 599         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 600         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 601 \r
 602         if(self.stat_eaten)\r
 603         {\r
 604                 if(time <= self.stomachkick_delay)\r
 605                 {\r
 606                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 607                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 608                 }\r
 609         }\r
 610         else\r
 611         {\r
 612                 if(self.swallow_progress_pred)\r
 613                 {\r
 614                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 615                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 616                 }\r
 617                 else if(time <= self.action_delay)\r
 618                 {\r
 619                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 620                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 621                 }\r
 622 \r
 623                 if(self.swallow_progress_prey)\r
 624                 {\r
 625                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 626                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 627                 }\r
 628                 else if(time <= self.regurgitate_prepare)\r
 629                 {\r
 630                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 631                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 632                 }\r
 633         }\r
 634 }\r
 635 \r
 636 void Vore()\r
 637 {\r
 638         // main vore code, this is where it all happens\r
 639 \r
 640         if(!cvar("g_vore")) // the vore system is disabled\r
 641         {\r
 642                 Vore_Disconnect();\r
 643                 return;\r
 644         }\r
 645 \r
 646         Vore_AutoTaunt();\r
 647 \r
 648         // wash the goo away from players once they leave the stomach\r
 649         if(!self.stat_eaten)\r
 650         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 651         if(self.colormod)\r
 652         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 653         {\r
 654                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 655                 if(self.colormod_x > 1)\r
 656                         self.colormod_x = 1;\r
 657                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 658                 if(self.colormod_y > 1)\r
 659                         self.colormod_y = 1;\r
 660                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 661                 if(self.colormod_z > 1)\r
 662                         self.colormod_z = 1;\r
 663         }\r
 664 \r
 665         // set all vore stats\r
 666         Vore_SetSbarRings();\r
 667         if(self.fakepredator.classname == "player")\r
 668                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 669         else if(self.predator.classname == "player")\r
 670         {\r
 671                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 672                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 673                 self.stat_eaten = num_for_edict(self.predator);\r
 674         }\r
 675         else\r
 676         {\r
 677                 self.stat_stomachload = self.stomach_load;\r
 678                 self.stat_digesting = self.digesting;\r
 679                 self.stat_eaten = 0;\r
 680         }\r
 681         self.stat_canleave = Vore_CanLeave();\r
 682 \r
 683         // don't allow a player inside a player inside another player :)\r
 684         // prevent this by checking if such has happened, and taking the proper measures\r
 685         // this code has a high priority and must not be stopped by any delay, so run it here\r
 686         if(self.predator.stat_eaten)\r
 687         {\r
 688                 entity target_predator, target_predator_predator, oldself;\r
 689                 target_predator = self.predator;\r
 690                 target_predator_predator = self.predator.predator;\r
 691 \r
 692                 Vore_Regurgitate(self);\r
 693 \r
 694                 // now steal our prey's prey if this probability applies\r
 695                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 696                 {\r
 697                         oldself = self;\r
 698                         self = target_predator_predator;\r
 699                         if(Swallow_condition_check(oldself))\r
 700                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 701                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 702                                 Vore_Swallow(oldself);\r
 703                         self = oldself;\r
 704                 }\r
 705         }\r
 706 \r
 707         // the swallow progress of prey and preds idly decrease by this amount\r
 708         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 709         {\r
 710                 if(self.swallow_progress_pred)\r
 711                 {\r
 712                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 713                         if(self.swallow_progress_pred < 0)\r
 714                                 self.swallow_progress_pred = 0;\r
 715                 }\r
 716                 if(self.swallow_progress_prey)\r
 717                 {\r
 718                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 719                         if(self.swallow_progress_prey < 0)\r
 720                                 self.swallow_progress_prey = 0;\r
 721                 }\r
 722         }\r
 723 \r
 724         // apply delays and skip the vore system under some circumstances\r
 725         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 726         {\r
 727                 Vore_Disconnect();\r
 728                 return;\r
 729         }\r
 730         if(self.spectatee_status)\r
 731                 return;\r
 732         if(time < self.system_delay)\r
 733                 return;\r
 734 \r
 735 // --------------------------------\r
 736 // Code that addresses predators:\r
 737 // --------------------------------\r
 738 \r
 739         entity prey;\r
 740         prey = Swallow_player_check();\r
 741 \r
 742         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 743         self.stat_canswallow = 0;\r
 744         if(Swallow_condition_check(prey))\r
 745         {\r
 746                 // canswallow stat, used by the HUD\r
 747                 if(teams_matter && prey.team == self.team)\r
 748                         self.stat_canswallow = 2;\r
 749                 else\r
 750                         self.stat_canswallow = 1;\r
 751 \r
 752                 if(self.BUTTON_ATCK)\r
 753                         Vore_SwallowStep(prey);\r
 754         }\r
 755         else if(prey != world)\r
 756                 self.stat_canswallow = -1;\r
 757 \r
 758         // toggle digestion, if the player has someone in their stomach\r
 759         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 760         {\r
 761                 if(self.stomach_load)\r
 762                 {\r
 763                         if(time > self.digest_button_delay_time)\r
 764                         {\r
 765                                 self.digesting = !self.digesting;\r
 766                                 self.digest_button_delay_time = time + button_delay_time;\r
 767                         }\r
 768                 }\r
 769                 else if(time > self.complain_vore)\r
 770                 {\r
 771                         play2(self, "misc/forbidden.wav");\r
 772                         sprint(self, "There is nothing to digest\n");\r
 773                         self.complain_vore = time + complain_delay_time;\r
 774                 }\r
 775         }\r
 776         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 777                 self.digesting = FALSE;\r
 778 \r
 779         // predator wishes to regurgitate his prey\r
 780         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 781         {\r
 782                 if(self.stomach_load)\r
 783                 {\r
 784                         if(time > self.regurgitate_button_delay_time)\r
 785                         {\r
 786                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 787                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 788                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 789                         }\r
 790                 }\r
 791                 else if(time > self.complain_vore)\r
 792                 {\r
 793                         play2(self, "misc/forbidden.wav");\r
 794                         sprint(self, "There is nothing to regurgitate\n");\r
 795                         self.complain_vore = time + complain_delay_time;\r
 796                 }\r
 797         }\r
 798 \r
 799         if(cvar("g_vore_gurglesound"))\r
 800                 Vore_GurgleSound();\r
 801 \r
 802 // --------------------------------\r
 803 // Code that addresses the prey:\r
 804 // --------------------------------\r
 805 \r
 806         Vore_SetPreyPositions();\r
 807 \r
 808         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 809         if(self.fakeprey)\r
 810         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 811                 Vore_DeadPrey_Detach(self);\r
 812 \r
 813         if(!self.stat_eaten)\r
 814                 return;\r
 815 \r
 816         if(self.deadflag != DEAD_NO)\r
 817         {\r
 818                 Vore_PreyRelease(self, FALSE);\r
 819                 return;\r
 820         }\r
 821 \r
 822         if(self.predator.deadflag != DEAD_NO)\r
 823                 Vore_Regurgitate(self);\r
 824         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 825                 Vore_Regurgitate(self);\r
 826 \r
 827         // apply delayed regurgitating if it was scheduled\r
 828         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 829         {\r
 830                 self.predator.regurgitate_prepare = 0;\r
 831                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 832                 Vore_Regurgitate(self);\r
 833         }\r
 834 \r
 835         // execute digesting and team healing\r
 836         if(self.predator.digesting == TRUE)\r
 837                 Vore_Digest();\r
 838         if(teams_matter && self.team == self.predator.team)\r
 839         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 840                 Vore_Teamheal();\r
 841 \r
 842         // execute prey commands\r
 843         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 844                 Vore_StomachKick();\r
 845         if(self.BUTTON_JUMP)\r
 846                 Vore_StomachLeave();\r
 847 \r
 848         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 849         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 850         kh_Key_DropAll(self, FALSE);\r
 851 }