#ifdef INTERFACE
CLASS(VoretSliderCheckBox) EXTENDS(CheckBox)
	METHOD(VoretSliderCheckBox, configureVoretSliderCheckBox, void(entity, float, float, entity, string))
	METHOD(VoretSliderCheckBox, setChecked, void(entity, float))
	METHOD(VoretSliderCheckBox, draw, void(entity))
	ATTRIB(VoretSliderCheckBox, fontSize, float, SKINFONTSIZE_NORMAL)
	ATTRIB(VoretSliderCheckBox, image, string, SKINGFX_CHECKBOX)

	ATTRIB(VoretSliderCheckBox, color, vector, SKINCOLOR_CHECKBOX_N)
	ATTRIB(VoretSliderCheckBox, colorC, vector, SKINCOLOR_CHECKBOX_C)
	ATTRIB(VoretSliderCheckBox, colorF, vector, SKINCOLOR_CHECKBOX_F)
	ATTRIB(VoretSliderCheckBox, colorD, vector, SKINCOLOR_CHECKBOX_D)

	ATTRIB(VoretSliderCheckBox, alpha, float, SKINALPHA_TEXT)
	ATTRIB(VoretSliderCheckBox, disabledAlpha, float, SKINALPHA_DISABLED)

	ATTRIB(VoretSliderCheckBox, controlledSlider, entity, NULL)
	ATTRIB(VoretSliderCheckBox, offValue, float, -1)
	ATTRIB(VoretSliderCheckBox, inverted, float, 0)
	ATTRIB(VoretSliderCheckBox, savedValue, float, -1)
ENDCLASS(VoretSliderCheckBox)
entity makeVoretSliderCheckBox(float, float, entity, string);
#endif

#ifdef IMPLEMENTATION
entity makeVoretSliderCheckBox(float theOffValue, float isInverted, entity theControlledSlider, string theText)
{
	entity me;
	me = spawnVoretSliderCheckBox();
	me.configureVoretSliderCheckBox(me, theOffValue, isInverted, theControlledSlider, theText);
	return me;
}
void configureVoretSliderCheckBoxVoretSliderCheckBox(entity me, float theOffValue, float isInverted, entity theControlledSlider, string theText)
{
	me.offValue = theOffValue;
	me.inverted = isInverted;
	me.checked = (theControlledSlider.value == theOffValue);
	if(theControlledSlider.value == median(theControlledSlider.valueMin, theControlledSlider.value, theControlledSlider.valueMax))
		me.savedValue = theControlledSlider.value;
	else
		me.savedValue = theControlledSlider.valueMin; 
	me.controlledSlider = theControlledSlider;
	me.configureCheckBox(me, theText, me.fontSize, me.image);
	me.tooltip = theControlledSlider.tooltip;
}
void drawVoretSliderCheckBox(entity me)
{
	me.checked = ((me.controlledSlider.value == me.offValue) != me.inverted);
	if(me.controlledSlider.value == median(me.controlledSlider.valueMin, me.controlledSlider.value, me.controlledSlider.valueMax))
		me.savedValue = me.controlledSlider.value;
	drawCheckBox(me);
}
void setCheckedVoretSliderCheckBox(entity me, float val)
{
	if(me.checked == val)
		return;
	me.checked = val;
	if(val == me.inverted)
		me.controlledSlider.setValue(me.controlledSlider, median(me.controlledSlider.valueMin, me.savedValue, me.controlledSlider.valueMax));
	else
		me.controlledSlider.setValue(me.controlledSlider, me.offValue);
}

#endif