#ifdef INTERFACE
CLASS(VoretCvarsDialog) EXTENDS(VoretDialog)
	METHOD(VoretCvarsDialog, toString, string(entity))
	METHOD(VoretCvarsDialog, fill, void(entity))
	METHOD(VoretCvarsDialog, showNotify, void(entity))
	ATTRIB(VoretCvarsDialog, title, string, "Advanced settings")
	ATTRIB(VoretCvarsDialog, color, vector, SKINCOLOR_DIALOG_CVARS)
	ATTRIB(VoretCvarsDialog, intendedWidth, float, 0.8)
	ATTRIB(VoretCvarsDialog, rows, float, 25)
	ATTRIB(VoretCvarsDialog, columns, float, 6)
ENDCLASS(VoretCvarsDialog)
#endif

#ifdef IMPLEMENTATION
void showNotifyVoretCvarsDialog(entity me)
{
	loadAllCvars(me);
}
string toStringVoretCvarsDialog(entity me)
{
	return "XXX";
}
void fillVoretCvarsDialog(entity me)
{
	entity e, cvarlist, btn;
	cvarlist = makeVoretCvarList();
	me.TR(me);
		me.TD(me, 1, 1, e = makeVoretTextLabel(0, "Cvar filter:"));
		me.TD(me, 1, 0.5, btn = makeVoretButton("Clear", '0 0 0'));
		me.TD(me, 1, me.columns - 1.5, e = makeVoretInputBox(0, string_null));
			e.onChange = CvarList_Filter_Change;
			e.onChangeEntity = cvarlist;
			btn.onClick = InputBox_Clear_Click;
			btn.onClickEntity = e;
			cvarlist.controlledTextbox = e; // this COULD also be the Value box, but this leads to accidentally editing stuff
	me.TR(me);
		me.TD(me, me.rows - me.currentRow - 7, me.columns, cvarlist);
	me.gotoRC(me, me.rows - 7, 0);
		me.TD(me, 1, 1, e = makeVoretTextLabel(0, "Setting:"));
		me.TD(me, 1, me.columns - 1, e = makeVoretTextLabel(0, string_null));
			cvarlist.cvarNameBox = e;
	me.TR(me);
		me.TD(me, 1, 1, e = makeVoretTextLabel(0, "Type:"));
		me.TD(me, 1, me.columns - 1, e = makeVoretTextLabel(0, string_null));
			cvarlist.cvarTypeBox = e;
	me.TR(me);
		me.TD(me, 1, 1, e = makeVoretTextLabel(0, "Value:"));
		me.TD(me, 1, me.columns - 2, e = makeVoretInputBox(0, string_null));
			cvarlist.cvarValueBox = e;
			e.onChange = CvarList_Value_Change;
			e.onChangeEntity = cvarlist;
		me.TD(me, 1, 1, e = makeVoretButton(string_null, SKINCOLOR_CVARLIST_REVERTBUTTON));
			cvarlist.cvarDefaultBox = e;
			e.onClick = CvarList_Revert_Click;
			e.onClickEntity = cvarlist;
			e.allowCut = 1;
			e.marginLeft = e.marginRight = 0.5;
	me.TR(me);
		me.TD(me, 1, 1, e = makeVoretTextLabel(0, "Description:"));
		me.TD(me, 1, me.columns - 1, e = makeVoretTextLabel(0, string_null));
			cvarlist.cvarDescriptionBox = e;
			e.allowWrap = 1;
	me.gotoRC(me, me.rows - 1, 0);
		me.TD(me, 1, me.columns, e = makeVoretButton("OK", '0 0 0'));
			e.onClick = Dialog_Close;
			e.onClickEntity = me;
}

#endif