CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15
  16 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  17 if (EXISTS "${BUILTINS_INSTALL_DIR}/lib/pkgconfig/gtkglext-1.0.pc")
  18     set(BUILTIN_GTKGLEXT_BUILT ON)
  19 endif ()
  20
  21 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  22     include_directories("${BUILTINS_INCLUDE_DIR}")
  23 endif ()
  24
  25 if (EXISTS "${BUILTINS_LIB_DIR}")
  26     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  27     link_directories("${BUILTINS_LIB_DIR}")
  28 endif ()
  29
  30 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  31     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  32 endif ()
  33
  34 #-----------------------------------------------------------------------
  35 # CMake modules
  36 #-----------------------------------------------------------------------
  37
  38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  39
  40 #-----------------------------------------------------------------------
  41 # Submodules
  42 #-----------------------------------------------------------------------
  43
  44 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  45     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  46 else ()
  47     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  48 endif ()
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  51     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 #-----------------------------------------------------------------------
  57 # Build options
  58 #-----------------------------------------------------------------------
  59
  60 option(BUILD_RADIANT "Build the GUI" ON)
  61 option(BUILD_TOOLS "Build the tools" ON)
  62 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  63 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  64 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  65 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  66 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  67
  68 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  69 if (BUILD_RADIANT OR BUILD_TOOLS)
  70     set(BUILD_BINARIES ON)
  71 endif ()
  72
  73 if (BUILD_BINARIES)
  74     if (WIN32 OR APPLE OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  75         set(BUNDLING_SUPPORTED ON)
  76     endif()
  77
  78     if (BUNDLING_SUPPORTED)
  79         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  80             set(BUNDLE_LIBRARIES_DEFAULT ON)
  81         else ()
  82             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  83         endif ()
  84
  85         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  86     endif ()
  87
  88     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  89         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
  90     endif ()
  91 endif ()
  92
  93 #-----------------------------------------------------------------------
  94 # Paths
  95 #-----------------------------------------------------------------------
  96
  97 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  98     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  99 endif ()
 100
 101 if (APPLE)
 102         set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 103         set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 104 else ()
 105         set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 106 endif ()
 107
 108 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 109 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 110 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 111 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 112
 113 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 114 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 115 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 116 set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc CACHE INTERNAL "...")
 117 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 118 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 119
 120 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
 121     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 122     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib)
 123     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 124     set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc)
 125     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 126     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 127 endif ()
 128
 129 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 130
 131 #-----------------------------------------------------------------------
 132 # Version
 133 #-----------------------------------------------------------------------
 134
 135 # CMake 3.0+ would allow this in project()
 136 set(RADIANT_VERSION_MAJOR 1)
 137 set(RADIANT_VERSION_MINOR 5)
 138 set(RADIANT_VERSION_PATCH 0)
 139 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 140
 141 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 142
 143 find_package(Git REQUIRED)
 144
 145 execute_process(
 146      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 147      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 148      OUTPUT_VARIABLE GIT_VERSION
 149      OUTPUT_STRIP_TRAILING_WHITESPACE
 150 )
 151
 152 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 153
 154 if (GIT_VERSION)
 155     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 156 endif ()
 157
 158 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 159
 160 #-----------------------------------------------------------------------
 161 # Language standard
 162 #-----------------------------------------------------------------------
 163
 164 if (BUILD_BINARIES)
 165     set(CMAKE_CXX_STANDARD 11)
 166     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 167     set(CMAKE_CXX_EXTENSIONS OFF)
 168
 169     if (CMAKE_VERSION VERSION_LESS "3.1")
 170         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 171             include(CheckCXXCompilerFlag)
 172             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 173             if (STD_CXX)
 174                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 175             else ()
 176                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 177             endif ()
 178         else ()
 179             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 180         endif ()
 181     endif ()
 182 endif ()
 183
 184 #-----------------------------------------------------------------------
 185 # Flags
 186 #-----------------------------------------------------------------------
 187
 188 if (BUILD_BINARIES)
 189     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 190
 191     macro (addflags_c args)
 192         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 193     endmacro ()
 194
 195     macro (addflags_cxx args)
 196         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 197     endmacro ()
 198
 199     macro (addflags args)
 200         addflags_c("${args}")
 201         addflags_cxx("${args}")
 202     endmacro ()
 203
 204     addflags("-fno-strict-aliasing")
 205     if (NOT WIN32)
 206         addflags("-fvisibility=hidden")
 207     endif ()
 208
 209     if (USE_WERROR)
 210         addflags("-Werror")
 211         addflags("-pedantic-errors")
 212     endif ()
 213
 214     addflags("-Wall")
 215     addflags("-Wextra")
 216     addflags("-pedantic")
 217
 218     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 219
 220     addflags("-Wno-unused-function")
 221     addflags("-Wno-unused-variable")
 222     addflags("-Wno-unused-parameter")
 223
 224     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 225 endif ()
 226
 227 if (BUILD_RADIANT)
 228     set(GTK_TARGET 2 CACHE STRING "GTK target")
 229     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 230
 231     if (WIN32)
 232         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 233
 234         if (GTK_TARGET EQUAL 2)
 235             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 236         endif ()
 237     endif ()
 238
 239     if (APPLE)
 240         if (GTK_TARGET EQUAL 2)
 241             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 242         endif ()
 243     endif ()
 244 endif ()
 245
 246 #-----------------------------------------------------------------------
 247 # Defs
 248 #-----------------------------------------------------------------------
 249
 250 if (BUILD_BINARIES)
 251     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 252     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 253
 254     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 255         add_definitions(-D_DEBUG=1)
 256     endif ()
 257 endif ()
 258
 259 if (BUILD_RADIANT)
 260     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 261
 262     macro (disable_deprecated name gtk2only)
 263         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 264         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 265             add_definitions(-D${name}_DISABLE_DEPRECATED)
 266         endif ()
 267     endmacro ()
 268
 269     disable_deprecated(ATK 0)
 270     disable_deprecated(G 0)
 271     disable_deprecated(GDK 0)
 272     disable_deprecated(GDK_PIXBUF 0)
 273     disable_deprecated(GTK 1)
 274     disable_deprecated(PANGO 0)
 275 endif ()
 276
 277 if (BUILD_BINARIES)
 278     add_custom_target(binaries ALL)
 279
 280     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 281         link_directories(
 282             /usr/local/lib
 283         )
 284     endif ()
 285
 286     if (WIN32)
 287         add_definitions(
 288             -DWIN32=1
 289             -D_WIN32=1
 290         )
 291     else ()
 292         add_definitions(
 293             -DPOSIX=1
 294         )
 295     endif ()
 296 endif ()
 297
 298 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 299     set(XWINDOWS ON)
 300     find_package(X11 REQUIRED)
 301     include_directories(${X11_INCLUDE_DIR})
 302     add_definitions(-DXWINDOWS=1)
 303 endif ()
 304
 305 if (BUILD_BINARIES)
 306     include_directories("${PROJECT_SOURCE_DIR}/include")
 307     include_directories("${PROJECT_SOURCE_DIR}/libs")
 308
 309     macro (copy_dlls target)
 310         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 311             add_custom_command(TARGET ${target} POST_BUILD
 312                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 313                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 314                 VERBATIM
 315             )
 316             add_dependencies(bundle ${target})
 317         endif ()
 318     endmacro ()
 319 endif ()
 320
 321 #-----------------------------------------------------------------------
 322 # Bundle
 323 #-----------------------------------------------------------------------
 324
 325 if (BUILD_BINARIES)
 326     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 327         add_subdirectory(bundle)
 328     endif ()
 329 endif ()
 330
 331 #-----------------------------------------------------------------------
 332 # Builtins: targets
 333 #-----------------------------------------------------------------------
 334
 335 add_custom_target(builtins)
 336
 337 if (BUILTIN_GTKGLEXT)
 338     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 339
 340     execute_process(COMMAND pkg-config --libs gdk-2.0 gtk+-2.0 glib-2.0 gl
 341         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 342         OUTPUT_STRIP_TRAILING_WHITESPACE
 343     )
 344     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 345
 346     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 347                 set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} -g")
 348         else ()
 349                 set(GTKGLEXT_CFLAGS "$ENV{CFLAGS}")
 350         endif()
 351
 352     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf)
 353
 354     if (APPLE)
 355         set(GTKGLEXT_GIT_TAG macos)
 356     else ()
 357         set(GTKGLEXT_GIT_TAG fixes)
 358     endif ()
 359
 360     ExternalProject_Add(gtkglext
 361         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 362         GIT_TAG ${GTKGLEXT_GIT_TAG}
 363         BUILD_IN_SOURCE ON
 364         CONFIGURE_COMMAND export LDFLAGS=${GTKGLEXT_LDFLAGS}
 365         CONFIGURE_COMMAND && NOCONFIGURE=1 ./autogen.sh
 366         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 367         BUILD_COMMAND $(MAKE) CFLAGS=${GTKGLEXT_CFLAGS} LDFLAGS=${GTKGLEXT_LDFLAGS}
 368         INSTALL_COMMAND $(MAKE) install
 369     )
 370
 371     include_directories("${BUILTINS_INSTALL_DIR}/lib/gtkglext-1.0/include")
 372     include_directories("${BUILTINS_INSTALL_DIR}/include/gtkglext-1.0")
 373
 374     add_dependencies(builtins gtkglext)
 375     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 376 endif ()
 377
 378 if (BUNDLE_LIBRARIES AND EXISTS ${BUILTINS_LIB_DIR})
 379     set(CMAKE_SKIP_BUILD_RPATH ON)
 380 endif()
 381
 382 #-----------------------------------------------------------------------
 383 # Libraries
 384 #-----------------------------------------------------------------------
 385
 386 if (BUILD_BINARIES)
 387     add_subdirectory(libs)
 388 endif ()
 389
 390 if (BUILD_RADIANT)
 391     add_subdirectory(include)
 392 endif ()
 393
 394 #-----------------------------------------------------------------------
 395 # Plugins
 396 #-----------------------------------------------------------------------
 397
 398 if (BUILD_RADIANT)
 399     add_subdirectory(contrib)
 400 endif ()
 401
 402 #-----------------------------------------------------------------------
 403 # Modules
 404 #-----------------------------------------------------------------------
 405
 406 if (BUILD_RADIANT)
 407     add_subdirectory(plugins)
 408 endif ()
 409
 410 #-----------------------------------------------------------------------
 411 # Radiant
 412 #-----------------------------------------------------------------------
 413
 414 if (BUILD_BINARIES)
 415     macro (radiant_tool name)
 416         add_dependencies(binaries ${name})
 417
 418         if (WIN32)
 419             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 420         else ()
 421             add_executable(${name} ${ARGN})
 422         endif()
 423
 424         copy_dlls(${name})
 425
 426         install(
 427             TARGETS ${name}
 428             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 429         )
 430     endmacro ()
 431
 432     if (BUILD_RADIANT)
 433         add_subdirectory(radiant)
 434     endif ()
 435 endif ()
 436
 437 #-----------------------------------------------------------------------
 438 # Tools
 439 #-----------------------------------------------------------------------
 440
 441 if (BUILD_TOOLS)
 442     add_subdirectory(tools)
 443
 444     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 445
 446     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 447         # Copy data files from sources to the build directory
 448         message(STATUS "Copying data files")
 449         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 450     endif ()
 451 endif ()
 452
 453 #-----------------------------------------------------------------------
 454 # Game packs
 455 #-----------------------------------------------------------------------
 456
 457 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 458 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 459
 460 if (DOWNLOAD_GAMEPACKS)
 461     add_custom_target(gamepacks ALL
 462        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 463        COMMENT "Downloading game packs"
 464     )
 465 endif ()
 466
 467 #-----------------------------------------------------------------------
 468 # Install
 469 #-----------------------------------------------------------------------
 470
 471 if (BUILD_BINARIES)
 472     install(DIRECTORY
 473         setup/data/tools/base
 474         setup/data/tools/bitmaps
 475         setup/data/tools/gl
 476         setup/data/tools/plugins
 477         docs
 478         DESTINATION ${RADIANT_DATA_DIR}
 479     )
 480
 481     install(FILES
 482         setup/data/tools/global.xlink
 483         DESTINATION ${RADIANT_DATA_DIR}
 484     )
 485 endif ()
 486
 487 if (DOWNLOAD_GAMEPACKS)
 488     install(DIRECTORY
 489         ${PROJECT_BINARY_DIR}/gamepacks
 490         DESTINATION ${RADIANT_DATA_DIR}
 491     )
 492 endif ()
 493
 494 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 495     install(FILES
 496         icons/netradiant.png
 497         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 498     )
 499     install(FILES
 500         icons/netradiant.desktop
 501         DESTINATION ${RADIANT_SHARE_DIR}/applications
 502     )
 503     install(FILES
 504         icons/mime/map.xml
 505         DESTINATION ${RADIANT_SHARE_DIR}/mime/model
 506     )
 507 endif ()
 508
 509 if (APPLE)
 510     install(DIRECTORY
 511         setup/apple/Contents
 512         DESTINATION ${APPLE_INSTALL_PREFIX}
 513     )
 514     install(PROGRAMS
 515         setup/apple/netradiant
 516         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 517     )
 518 endif ()
 519
 520 include(cmake/scripts/package.cmake)