CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_INSTALL_DIR}/lib/pkgconfig/gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  57     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  58 else ()
  59     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  60 endif ()
  61
  62 #-----------------------------------------------------------------------
  63 # Build options
  64 #-----------------------------------------------------------------------
  65
  66 option(BUILD_RADIANT "Build the GUI" ON)
  67 option(BUILD_TOOLS "Build the tools" ON)
  68 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  69 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  70 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  71 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  72 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  73
  74 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  75 if (BUILD_RADIANT OR BUILD_TOOLS)
  76     set(BUILD_BINARIES ON)
  77 endif ()
  78
  79 if (BUILD_BINARIES)
  80     if (WIN32 OR APPLE
  81         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  82         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  83         set(BUNDLING_SUPPORTED ON)
  84     endif()
  85
  86     if (BUNDLING_SUPPORTED)
  87         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  88             set(BUNDLE_LIBRARIES_DEFAULT ON)
  89         else ()
  90             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  91         endif ()
  92
  93         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  94     endif ()
  95
  96     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  97         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
  98     endif ()
  99 endif ()
 100
 101 #-----------------------------------------------------------------------
 102 # Paths
 103 #-----------------------------------------------------------------------
 104
 105 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 106     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 107 endif ()
 108
 109 if (APPLE)
 110     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 111     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 112 else ()
 113     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 114 endif ()
 115
 116 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 117 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 118 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 119 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 120
 121 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 122 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 123 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 124 set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc CACHE INTERNAL "...")
 125 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 126 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 127
 128 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
 129     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 130     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib)
 131     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 132     set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc)
 133     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 134     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 135 endif ()
 136
 137 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 138
 139 #-----------------------------------------------------------------------
 140 # Version
 141 #-----------------------------------------------------------------------
 142
 143 # CMake 3.0+ would allow this in project()
 144 set(RADIANT_VERSION_MAJOR 1)
 145 set(RADIANT_VERSION_MINOR 5)
 146 set(RADIANT_VERSION_PATCH 0)
 147 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 148
 149 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 150
 151 find_package(Git REQUIRED)
 152
 153 execute_process(
 154      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 155      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 156      OUTPUT_VARIABLE GIT_VERSION
 157      OUTPUT_STRIP_TRAILING_WHITESPACE
 158 )
 159
 160 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 161
 162 if (GIT_VERSION)
 163     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 164 endif ()
 165
 166 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 167
 168 #-----------------------------------------------------------------------
 169 # Language standard
 170 #-----------------------------------------------------------------------
 171
 172 if (BUILD_BINARIES)
 173     set(CMAKE_CXX_STANDARD 11)
 174     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 175     set(CMAKE_CXX_EXTENSIONS OFF)
 176
 177     if (CMAKE_VERSION VERSION_LESS "3.1")
 178         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 179             include(CheckCXXCompilerFlag)
 180             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 181             if (STD_CXX)
 182                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 183             else ()
 184                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 185             endif ()
 186         else ()
 187             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 188         endif ()
 189     endif ()
 190 endif ()
 191
 192 #-----------------------------------------------------------------------
 193 # Flags
 194 #-----------------------------------------------------------------------
 195
 196 if (BUILD_BINARIES)
 197     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 198
 199     macro (addflags_c args)
 200         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 201     endmacro ()
 202
 203     macro (addflags_cxx args)
 204         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 205     endmacro ()
 206
 207     macro (addflags args)
 208         addflags_c("${args}")
 209         addflags_cxx("${args}")
 210     endmacro ()
 211
 212     addflags("-fno-strict-aliasing")
 213     if (NOT WIN32)
 214         addflags("-fvisibility=hidden")
 215     endif ()
 216
 217     if (USE_WERROR)
 218         addflags("-Werror")
 219         addflags("-pedantic-errors")
 220     endif ()
 221
 222     addflags("-Wall")
 223     addflags("-Wextra")
 224     addflags("-pedantic")
 225
 226     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 227
 228     addflags("-Wno-unused-function")
 229     addflags("-Wno-unused-variable")
 230     addflags("-Wno-unused-parameter")
 231
 232     if (APPLE)
 233         add_definitions(-DGL_SILENCE_DEPRECATION=1)
 234     endif()
 235
 236     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 237 endif ()
 238
 239 if (BUILD_RADIANT)
 240     set(GTK_TARGET 2 CACHE STRING "GTK target")
 241     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 242
 243     if (WIN32)
 244         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 245
 246         if (GTK_TARGET EQUAL 2)
 247             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 248         endif ()
 249     endif ()
 250
 251     if (APPLE)
 252         if (GTK_TARGET EQUAL 2)
 253             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 254             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 255         endif ()
 256     endif ()
 257 endif ()
 258
 259 #-----------------------------------------------------------------------
 260 # Defs
 261 #-----------------------------------------------------------------------
 262
 263 if (BUILD_BINARIES)
 264     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 265     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 266
 267     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 268         add_definitions(-D_DEBUG=1)
 269     endif ()
 270 endif ()
 271
 272 if (BUILD_RADIANT)
 273     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 274
 275     macro (disable_deprecated name gtk2only)
 276         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 277         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 278             add_definitions(-D${name}_DISABLE_DEPRECATED)
 279         endif ()
 280     endmacro ()
 281
 282     disable_deprecated(ATK 0)
 283     disable_deprecated(G 0)
 284     disable_deprecated(GDK 0)
 285     disable_deprecated(GDK_PIXBUF 0)
 286     disable_deprecated(GTK 1)
 287     disable_deprecated(PANGO 0)
 288 endif ()
 289
 290 if (BUILD_BINARIES)
 291     add_custom_target(binaries ALL)
 292
 293     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 294         link_directories(
 295             /usr/local/lib
 296         )
 297     endif ()
 298
 299     if (WIN32)
 300         add_definitions(
 301             -DWIN32=1
 302             -D_WIN32=1
 303         )
 304     else ()
 305         add_definitions(
 306             -DPOSIX=1
 307         )
 308     endif ()
 309 endif ()
 310
 311 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 312     set(XWINDOWS ON)
 313     find_package(X11 REQUIRED)
 314     include_directories(${X11_INCLUDE_DIR})
 315     add_definitions(-DXWINDOWS=1)
 316 endif ()
 317
 318 if (BUILD_BINARIES)
 319     include_directories("${PROJECT_SOURCE_DIR}/include")
 320     include_directories("${PROJECT_SOURCE_DIR}/libs")
 321
 322     macro (copy_dlls target)
 323         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 324             add_custom_command(TARGET ${target} POST_BUILD
 325                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 326                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 327                 VERBATIM
 328             )
 329             add_dependencies(bundle ${target})
 330         endif ()
 331     endmacro ()
 332 endif ()
 333
 334 #-----------------------------------------------------------------------
 335 # Bundle
 336 #-----------------------------------------------------------------------
 337
 338 if (BUILD_BINARIES)
 339     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 340         add_subdirectory(bundle)
 341     endif ()
 342 endif ()
 343
 344 #-----------------------------------------------------------------------
 345 # Builtins: targets
 346 #-----------------------------------------------------------------------
 347
 348 add_custom_target(builtins)
 349
 350 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 351     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 352 endif ()
 353
 354 if (BUILTIN_GTKGLEXT)
 355     execute_process(COMMAND pkg-config --libs gdk-2.0 gtk+-2.0 glib-2.0 gl
 356         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 357         OUTPUT_STRIP_TRAILING_WHITESPACE
 358     )
 359     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 360
 361     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 362         set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} -g")
 363     else ()
 364         set(GTKGLEXT_CFLAGS "$ENV{CFLAGS}")
 365     endif()
 366
 367     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf)
 368
 369     if (APPLE)
 370         set(GTKGLEXT_GIT_TAG macos)
 371         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -DGL_SILENCE_DEPRECATION=1")
 372     else ()
 373         set(GTKGLEXT_GIT_TAG fixes)
 374     endif ()
 375
 376     ExternalProject_Add(gtkglext
 377         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 378         GIT_TAG ${GTKGLEXT_GIT_TAG}
 379         BUILD_IN_SOURCE ON
 380         CONFIGURE_COMMAND export LDFLAGS=${GTKGLEXT_LDFLAGS}
 381         CONFIGURE_COMMAND && NOCONFIGURE=1 ./autogen.sh
 382         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 383         BUILD_COMMAND $(MAKE) CFLAGS=${GTKGLEXT_CFLAGS} LDFLAGS=${GTKGLEXT_LDFLAGS}
 384         INSTALL_COMMAND $(MAKE) install
 385     )
 386
 387     include_directories("${BUILTINS_INSTALL_DIR}/lib/gtkglext-1.0/include")
 388     include_directories("${BUILTINS_INSTALL_DIR}/include/gtkglext-1.0")
 389
 390     add_dependencies(builtins gtkglext)
 391     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 392 endif ()
 393
 394 if (BUNDLE_LIBRARIES)
 395     # It was required to tell cmake to not patch rpath on macos builtins.
 396     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 397     # Patching rpath is done in library_bundler instead so we can skip this
 398     # step entirely when bundling.
 399     set(CMAKE_SKIP_RPATH ON)
 400 endif()
 401
 402 if (BUILTIN_GTKTHEME_MOJAVE)
 403     ExternalProject_Add(gtktheme-mojave
 404         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 405         GIT_TAG master
 406         BUILD_IN_SOURCE ON
 407         CONFIGURE_COMMAND echo
 408         BUILD_COMMAND echo
 409         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 410     )
 411     add_dependencies(builtins gtktheme-mojave)
 412     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 413 endif ()
 414
 415 #-----------------------------------------------------------------------
 416 # Libraries
 417 #-----------------------------------------------------------------------
 418
 419 if (BUILD_BINARIES)
 420     add_subdirectory(libs)
 421 endif ()
 422
 423 if (BUILD_RADIANT)
 424     add_subdirectory(include)
 425 endif ()
 426
 427 #-----------------------------------------------------------------------
 428 # Plugins
 429 #-----------------------------------------------------------------------
 430
 431 if (BUILD_RADIANT)
 432     add_subdirectory(contrib)
 433 endif ()
 434
 435 #-----------------------------------------------------------------------
 436 # Modules
 437 #-----------------------------------------------------------------------
 438
 439 if (BUILD_RADIANT)
 440     add_subdirectory(plugins)
 441 endif ()
 442
 443 #-----------------------------------------------------------------------
 444 # Radiant
 445 #-----------------------------------------------------------------------
 446
 447 if (BUILD_BINARIES)
 448     macro (radiant_tool name)
 449         add_dependencies(binaries ${name})
 450
 451         if (WIN32)
 452             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 453         else ()
 454             add_executable(${name} ${ARGN})
 455         endif()
 456
 457         copy_dlls(${name})
 458
 459         install(
 460             TARGETS ${name}
 461             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 462         )
 463     endmacro ()
 464
 465     if (BUILD_RADIANT)
 466         add_subdirectory(radiant)
 467     endif ()
 468 endif ()
 469
 470 #-----------------------------------------------------------------------
 471 # Tools
 472 #-----------------------------------------------------------------------
 473
 474 if (BUILD_TOOLS)
 475     add_subdirectory(tools)
 476
 477     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 478
 479     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 480         # Copy data files from sources to the build directory
 481         message(STATUS "Copying data files")
 482         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 483     endif ()
 484 endif ()
 485
 486 #-----------------------------------------------------------------------
 487 # Game packs
 488 #-----------------------------------------------------------------------
 489
 490 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 491 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 492
 493 if (DOWNLOAD_GAMEPACKS)
 494     add_custom_target(gamepacks ALL
 495        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 496        COMMENT "Downloading game packs"
 497     )
 498 endif ()
 499
 500 #-----------------------------------------------------------------------
 501 # Install
 502 #-----------------------------------------------------------------------
 503
 504 if (BUILD_BINARIES)
 505     install(DIRECTORY
 506         setup/data/tools/base
 507         setup/data/tools/bitmaps
 508         setup/data/tools/gl
 509         setup/data/tools/plugins
 510         docs
 511         DESTINATION ${RADIANT_DATA_DIR}
 512     )
 513
 514     install(FILES
 515         setup/data/tools/global.xlink
 516         DESTINATION ${RADIANT_DATA_DIR}
 517     )
 518 endif ()
 519
 520 if (DOWNLOAD_GAMEPACKS)
 521     install(DIRECTORY
 522         ${PROJECT_BINARY_DIR}/gamepacks
 523         DESTINATION ${RADIANT_DATA_DIR}
 524     )
 525 endif ()
 526
 527 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 528     install(FILES
 529         icons/netradiant.png
 530         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 531     )
 532     install(FILES
 533         icons/netradiant.desktop
 534         DESTINATION ${RADIANT_SHARE_DIR}/applications
 535     )
 536     install(FILES
 537         icons/mime/map.xml
 538         DESTINATION ${RADIANT_SHARE_DIR}/mime/model
 539     )
 540 endif ()
 541
 542 if (APPLE)
 543     install(DIRECTORY
 544         setup/macos/Contents
 545         DESTINATION ${APPLE_INSTALL_PREFIX}
 546     )
 547     install(DIRECTORY
 548     ${PROJECT_BINARY_DIR}/themes
 549         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 550     )
 551     install(PROGRAMS
 552         setup/macos/NetRadiant
 553         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 554     )
 555 endif ()
 556
 557 include(cmake/scripts/package.cmake)