CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_BASENAME netradiant CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  27
  28 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  29 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  30 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31
  32 if (FHS_INSTALL)
  33     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  34     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  35     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  36 endif ()
  37
  38 #-----------------------------------------------------------------------
  39 # Version
  40 #-----------------------------------------------------------------------
  41
  42 # CMake 3.0+ would allow this in project()
  43 set(NetRadiant_VERSION_MAJOR 1)
  44 set(NetRadiant_VERSION_MINOR 5)
  45 set(NetRadiant_VERSION_PATCH 0)
  46 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  47
  48 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  49
  50 find_package(Git REQUIRED)
  51
  52 execute_process(
  53      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  54      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  55      OUTPUT_VARIABLE GIT_VERSION
  56      OUTPUT_STRIP_TRAILING_WHITESPACE
  57 )
  58
  59 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  60
  61 if (GIT_VERSION)
  62     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  63 endif ()
  64
  65 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  66
  67 #-----------------------------------------------------------------------
  68 # Language standard
  69 #-----------------------------------------------------------------------
  70
  71 if (BUILD_BINARIES)
  72     set(CMAKE_CXX_STANDARD 11)
  73     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  74     set(CMAKE_CXX_EXTENSIONS OFF)
  75
  76     if (CMAKE_VERSION VERSION_LESS "3.1")
  77         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  78             include(CheckCXXCompilerFlag)
  79             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  80             if (STD_CXX)
  81                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  82             else ()
  83                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  84             endif ()
  85         else ()
  86             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  87         endif ()
  88     endif ()
  89 endif ()
  90
  91 #-----------------------------------------------------------------------
  92 # Flags
  93 #-----------------------------------------------------------------------
  94
  95 if (BUILD_BINARIES)
  96     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  97
  98     macro (addflags_c args)
  99         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 100     endmacro ()
 101
 102     macro (addflags_cxx args)
 103         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 104     endmacro ()
 105
 106     macro (addflags args)
 107         addflags_c("${args}")
 108         addflags_cxx("${args}")
 109     endmacro ()
 110
 111     addflags("-fno-strict-aliasing")
 112     if (NOT WIN32)
 113         addflags("-fvisibility=hidden")
 114     endif ()
 115
 116     if (USE_WERROR)
 117         addflags("-Werror")
 118         addflags("-pedantic-errors")
 119     endif ()
 120
 121     addflags("-Wall")
 122     addflags("-Wextra")
 123     addflags("-pedantic")
 124
 125     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 126
 127     addflags("-Wno-unused-function")
 128     addflags("-Wno-unused-variable")
 129     addflags("-Wno-unused-parameter")
 130
 131     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 132 endif ()
 133
 134 if (BUILD_RADIANT)
 135     set(GTK_TARGET 2 CACHE STRING "GTK target")
 136     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 137 endif ()
 138
 139 #-----------------------------------------------------------------------
 140 # Defs
 141 #-----------------------------------------------------------------------
 142
 143 if (BUILD_BINARIES)
 144     add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 145     add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 146     add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 147     add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 148
 149     add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 150
 151     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 152         add_definitions(-D_DEBUG=1)
 153     endif ()
 154 endif ()
 155
 156 if (BUILD_RADIANT)
 157     macro (disable_deprecated name gtk2only)
 158         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 159         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 160             add_definitions(-D${name}_DISABLE_DEPRECATED)
 161         endif ()
 162     endmacro ()
 163
 164     disable_deprecated(ATK 0)
 165     disable_deprecated(G 0)
 166     disable_deprecated(GDK 0)
 167     disable_deprecated(GDK_PIXBUF 0)
 168     disable_deprecated(GTK 1)
 169     disable_deprecated(PANGO 0)
 170 endif ()
 171
 172 if (BUILD_BINARIES)
 173     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 174         link_directories(
 175             /usr/local/lib
 176         )
 177     endif ()
 178
 179     if (WIN32)
 180         add_definitions(
 181             -DWIN32=1
 182             -D_WIN32=1
 183         )
 184     else ()
 185         add_definitions(
 186             -DPOSIX=1
 187         )
 188     endif ()
 189 endif ()
 190
 191 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 192     set(XWINDOWS ON)
 193     find_package(X11 REQUIRED)
 194     include_directories(${X11_INCLUDE_DIR})
 195     add_definitions(-DXWINDOWS=1)
 196 endif ()
 197
 198 if (BUILD_BINARIES)
 199     include_directories("${PROJECT_SOURCE_DIR}/include")
 200     include_directories("${PROJECT_SOURCE_DIR}/libs")
 201
 202     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 203         set(BUNDLE_LIBRARIES_DEFAULT ON)
 204     else ()
 205         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 206     endif ()
 207
 208     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 209
 210     macro (copy_dlls target)
 211         if (BUNDLE_LIBRARIES AND WIN32)
 212             add_custom_command(TARGET ${target} POST_BUILD
 213                 COMMAND bash
 214                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 215                 VERBATIM
 216         )
 217         endif ()
 218     endmacro ()
 219
 220     macro (bundle_stuff target)
 221         if (BUNDLE_LIBRARIES AND WIN32)
 222             add_custom_command(TARGET ${target} POST_BUILD
 223                 COMMAND bash
 224                 ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 225                 VERBATIM
 226         )
 227
 228         file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 229
 230         install(FILES
 231             ${DLL_FILES}
 232             DESTINATION ${CMAKE_INSTALL_PREFIX}
 233         )
 234
 235         install(DIRECTORY
 236             ${PROJECT_BINARY_DIR}/lib
 237             ${PROJECT_BINARY_DIR}/share
 238             DESTINATION ${CMAKE_INSTALL_PREFIX}
 239         )
 240         endif ()
 241     endmacro ()
 242 endif ()
 243
 244 #-----------------------------------------------------------------------
 245 # Libraries
 246 #-----------------------------------------------------------------------
 247
 248 if (BUILD_BINARIES)
 249     add_subdirectory(libs)
 250 endif ()
 251
 252 if (BUILD_RADIANT)
 253     add_subdirectory(include)
 254 endif ()
 255
 256 #-----------------------------------------------------------------------
 257 # Plugins
 258 #-----------------------------------------------------------------------
 259
 260 if (BUILD_RADIANT)
 261     add_subdirectory(contrib)
 262 endif ()
 263
 264 #-----------------------------------------------------------------------
 265 # Modules
 266 #-----------------------------------------------------------------------
 267
 268 if (BUILD_RADIANT)
 269     add_subdirectory(plugins)
 270 endif ()
 271
 272 #-----------------------------------------------------------------------
 273 # Radiant
 274 #-----------------------------------------------------------------------
 275
 276 if (BUILD_BINARIES)
 277     if (CMAKE_EXECUTABLE_SUFFIX)
 278         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 279     endif ()
 280
 281     macro (radiant_tool name)
 282         add_executable(${name} ${ARGN})
 283
 284         copy_dlls(${name})
 285
 286         install(
 287             TARGETS ${name}
 288             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 289         )
 290     endmacro ()
 291
 292     if (BUILD_RADIANT)
 293         add_subdirectory(radiant _radiant)
 294         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 295         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 296     )
 297     endif ()
 298 endif ()
 299
 300 #-----------------------------------------------------------------------
 301 # Tools
 302 #-----------------------------------------------------------------------
 303
 304 if (BUILD_TOOLS)
 305     add_subdirectory(tools)
 306
 307     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 308
 309     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 310         # Copy data files from sources to the build directory
 311         message(STATUS "Copying data files")
 312         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 313     endif ()
 314 endif ()
 315
 316 #-----------------------------------------------------------------------
 317 # Game packs
 318 #-----------------------------------------------------------------------
 319
 320 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 321 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 322
 323 if (DOWNLOAD_GAMEPACKS)
 324     add_custom_target(game_packs ALL
 325        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${PROJECT_BINARY_DIR}/download" --install-dir "${PROJECT_BINARY_DIR}" --download --install
 326        COMMENT "Downloading ${GAMEPACKS_LICENSE_LIST} game packs"
 327     )
 328 endif ()
 329
 330 #-----------------------------------------------------------------------
 331 # Install
 332 #-----------------------------------------------------------------------
 333
 334 if (BUILD_BINARIES)
 335     install(DIRECTORY
 336         setup/data/tools/base
 337         setup/data/tools/bitmaps
 338         setup/data/tools/gl
 339         setup/data/tools/plugins
 340         docs
 341         DESTINATION ${RADIANT_DATA_DIR}
 342     )
 343 endif ()
 344
 345 if (DOWNLOAD_GAMEPACKS)
 346     if (FHS_INSTALL)
 347        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 348     else ()
 349        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 350     endif ()
 351
 352     file(GLOB GAME_DIRS ${PROJECT_BINARY_DIR}/*.game)
 353
 354     install(DIRECTORY
 355         ${PROJECT_BINARY_DIR}/games
 356         ${GAME_DIRS}
 357         DESTINATION ${RADIANT_DATA_DIR}
 358     )
 359 endif ()
 360
 361 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 362     install(FILES
 363         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 364         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 365     )
 366     install(FILES
 367         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 368         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 369     )
 370     install(FILES
 371         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 372         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 373     )
 374 endif ()
 375
 376 include(cmake/scripts/package.cmake)