qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  65 #endif
  66
  67         float i;
  68
  69         binddb = db_create();
  70         tempdb = db_create();
  71         ClientProgsDB = db_load("client.db");
  72         compressShortVector_init();
  73
  74         drawfont = FONT_USER+1;
  75         menu_visible = FALSE;
  76         menu_show = menu_show_error;
  77         menu_action = menu_sub_null;
  78
  79         for(i = 0; i < 255; ++i)
  80                 if(getplayerkey(i, "viewentity") == "")
  81                         break;
  82         maxclients = i;
  83
  84         //ctf_temp_1 = "";
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  86         //registercmd("ctf_menu");
  87         registercmd("ons_map");
  88         registercmd("hud_configure");
  89         registercmd("hud_save");
  90         //registercmd("menu_action");
  91
  92         registercmd("+button3");
  93         registercmd("-button3");
  94         registercmd("+button4");
  95         registercmd("-button4");
  96         registercmd("+showscores");registercmd("-showscores");
  97         registercmd("+showaccuracy");registercmd("-showaccuracy");
  98
  99 #ifndef CAMERATEST
 100         if(isdemo())
 101         {
 102 #endif
 103                 registercmd("+forward");registercmd("-forward");
 104                 registercmd("+back");registercmd("-back");
 105                 registercmd("+moveup");registercmd("-moveup");
 106                 registercmd("+movedown");registercmd("-movedown");
 107                 registercmd("+moveright");registercmd("-moveright");
 108                 registercmd("+moveleft");registercmd("-moveleft");
 109                 registercmd("+roll_right");registercmd("-roll_right");
 110                 registercmd("+roll_left");registercmd("-roll_left");
 111 #ifndef CAMERATEST
 112         }
 113 #endif
 114         registercvar("hud_usecsqc", "1");
 115         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 116
 117         gametype = 0;
 118
 119         // hud_fields uses strunzone on the titles!
 120         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 121                 hud_title[i] = strzone("(null)");
 122
 123         postinit = false;
 124
 125         calledhooks = 0;
 126
 127         teams = Sort_Spawn();
 128         players = Sort_Spawn();
 129
 130         GetTeam(COLOR_SPECTATOR, true); // add specs first
 131
 132         RegisterWeapons();
 133
 134         WaypointSprite_Load();
 135
 136         // precaches
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         get_mi_min_max_texcoords(1); // try the CLEVER way first
 151         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 152         shortmapname = mi_shortname;
 153
 154         if(precache_pic(minimapname) == "")
 155         {
 156                 // but maybe we have a non-clever minimap
 157                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 158                 if(precache_pic(minimapname) == "")
 159                         minimapname = ""; // FAIL
 160                 else
 161                         get_mi_min_max_texcoords(0); // load new texcoords
 162         }
 163
 164         mi_center = (mi_min + mi_max) * 0.5;
 165         mi_scale = mi_max - mi_min;
 166         minimapname = strzone(minimapname);
 167
 168         WarpZone_Init();
 169
 170         hud_configure_prev = -1;
 171         tab_panel = -1;
 172 }
 173
 174 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 175 void CSQC_Shutdown(void)
 176 {
 177 #ifdef USE_FTE
 178 #pragma TARGET id
 179         if(!__engine_check)
 180                 return 0;
 181 #pragma TARGET fte
 182 #endif
 183
 184         WarpZone_Shutdown();
 185
 186         remove(teams);
 187         remove(players);
 188         db_close(binddb);
 189         db_close(tempdb);
 190         if(autocvar_cl_db_saveasdump)
 191                 db_dump(ClientProgsDB, "client.db");
 192         else
 193                 db_save(ClientProgsDB, "client.db");
 194         db_close(ClientProgsDB);
 195
 196         cvar_clientsettemp_restore();
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         if not(isdemo())
 202         {
 203                 if not(calledhooks & HOOK_START)
 204                         localcmd("\n_cl_hook_gamestart nop\n");
 205                 if not(calledhooks & HOOK_END)
 206                         localcmd("\ncl_hook_gameend\n");
 207         }
 208 }
 209
 210 .float has_team;
 211 float SetTeam(entity o, float Team)
 212 {
 213         entity tm;
 214         if(teamplay)
 215         {
 216                 switch(Team)
 217                 {
 218                         case -1:
 219                         case COLOR_TEAM1:
 220                         case COLOR_TEAM2:
 221                         case COLOR_TEAM3:
 222                         case COLOR_TEAM4:
 223                                 break;
 224                         default:
 225                                 if(GetTeam(Team, false) == NULL)
 226                                 {
 227                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 228                                         Team = COLOR_SPECTATOR;
 229                                 }
 230                                 break;
 231                 }
 232         }
 233         else
 234         {
 235                 switch(Team)
 236                 {
 237                         case -1:
 238                         case 0:
 239                                 break;
 240                         default:
 241                                 if(GetTeam(Team, false) == NULL)
 242                                 {
 243                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 244                                         Team = COLOR_SPECTATOR;
 245                                 }
 246                                 break;
 247                 }
 248         }
 249         if(Team == -1) // leave
 250         {
 251                 if(o.has_team)
 252                 {
 253                         tm = GetTeam(o.team, false);
 254                         tm.team_size -= 1;
 255                         o.has_team = 0;
 256                         return TRUE;
 257                 }
 258         }
 259         else
 260         {
 261                 if not(o.has_team)
 262                 {
 263                         o.team = Team;
 264                         tm = GetTeam(Team, true);
 265                         tm.team_size += 1;
 266                         o.has_team = 1;
 267                         return TRUE;
 268                 }
 269                 else if(Team != o.team)
 270                 {
 271                         tm = GetTeam(o.team, false);
 272                         tm.team_size -= 1;
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         return TRUE;
 277                 }
 278         }
 279         return FALSE;
 280 }
 281
 282 void Playerchecker_Think()
 283 {
 284         float i;
 285         entity e;
 286         for(i = 0; i < maxclients; ++i)
 287         {
 288                 e = playerslots[i];
 289                 if(GetPlayerName(i) == "")
 290                 {
 291                         if(e.sort_prev)
 292                         {
 293                                 // player disconnected
 294                                 SetTeam(e, -1);
 295                                 RemovePlayer(e);
 296                                 e.sort_prev = world;
 297                                 //e.gotscores = 0;
 298                         }
 299                 }
 300                 else
 301                 {
 302                         if not(e.sort_prev)
 303                         {
 304                                 // player connected
 305                                 if not(e)
 306                                         playerslots[i] = e = spawn();
 307                                 e.sv_entnum = i;
 308                                 e.ping = 0;
 309                                 e.ping_packetloss = 0;
 310                                 e.ping_movementloss = 0;
 311                                 //e.gotscores = 0; // we might already have the scores...
 312                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 313                                 RegisterPlayer(e);
 314                                 HUD_UpdatePlayerPos(e);
 315                         }
 316                 }
 317         }
 318         self.nextthink = time + 0.2;
 319 }
 320
 321 void Porto_Init();
 322 void TrueAim_Init();
 323 void PostInit(void)
 324 {
 325         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 326
 327         entity playerchecker;
 328         playerchecker = spawn();
 329         playerchecker.think = Playerchecker_Think;
 330         playerchecker.nextthink = time + 0.2;
 331
 332         Porto_Init();
 333         TrueAim_Init();
 334
 335         postinit = true;
 336 }
 337
 338 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 339 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 340 float button_zoom;
 341 void Cmd_HUD_SetFields(float);
 342 void Cmd_HUD_Help(float);
 343 float CSQC_ConsoleCommand(string strMessage)
 344 {
 345         float argc;
 346         // Tokenize String
 347         //argc = tokenize(strMessage);
 348         argc = tokenize_console(strMessage);
 349
 350         // Acquire Command
 351         local string strCmd;
 352         strCmd = argv(0);
 353
 354         if(strCmd == "hud_configure") { // config hud
 355                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 356                 return true;
 357         } else if(strCmd == "hud_save") { // save hud config
 358                 if(argv(1) == "" || argv(2)) {
 359                         print(_("Usage:\n"));
 360                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 361                 }
 362                 else
 363                         HUD_Panel_ExportCfg(argv(1));
 364                 return true;
 365         } else if(strCmd == "+button4") { // zoom
 366                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 367                 if(ignore_plus_zoom)
 368                 {
 369                         --ignore_plus_zoom;
 370                         return false;
 371                 }
 372                 button_zoom = 1;
 373                 return true;
 374         } else if(strCmd == "-button4") { // zoom
 375                 if(ignore_minus_zoom)
 376                 {
 377                         --ignore_minus_zoom;
 378                         return false;
 379                 }
 380                 button_zoom = 0;
 381                 return true;
 382         } else if(strCmd == "+button3") { // secondary
 383                 button_attack2 = 1;
 384                 return false;
 385         } else if(strCmd == "-button3") { // secondary
 386                 button_attack2 = 0;
 387                 return false;
 388         } else if(strCmd == "+showscores") {
 389                 scoreboard_showscores = true;
 390                 return true;
 391         } else if(strCmd == "-showscores") {
 392                 scoreboard_showscores = false;
 393                 return true;
 394         } else if(strCmd == "+showaccuracy") {
 395                 scoreboard_showaccuracy = true;
 396                 return true;
 397         } else if(strCmd == "-showaccuracy") {
 398                 scoreboard_showaccuracy = false;
 399                 return true;
 400         }
 401
 402         if(camera_active)
 403         if(strCmd == "+forward" || strCmd == "-back") {
 404                 ++camera_direction_x;
 405                 return true;
 406         } else if(strCmd == "-forward" || strCmd == "+back") {
 407                 --camera_direction_x;
 408                 return true;
 409         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 410                 --camera_direction_y;
 411                 return true;
 412         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 413                 ++camera_direction_y;
 414                 return true;
 415         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 416                 ++camera_direction_z;
 417                 return true;
 418         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 419                 --camera_direction_z;
 420                 return true;
 421         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 422                 ++camera_roll;
 423                 return true;
 424         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 425                 --camera_roll;
 426                 return true;
 427         }
 428
 429         return false;
 430 }
 431
 432 .vector view_ofs;
 433 entity debug_shotorg;
 434 void ShotOrg_Draw()
 435 {
 436         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 437         self.angles = view_angles;
 438         self.angles_x = -self.angles_x;
 439         if not(self.cnt)
 440                 self.drawmask = MASK_NORMAL;
 441         else
 442                 self.drawmask = 0;
 443 }
 444 void ShotOrg_Draw2D()
 445 {
 446         vector coord2d_topleft, coord2d_topright, coord2d;
 447         string s;
 448         vector fs;
 449
 450         s = vtos(self.view_ofs);
 451         s = substring(s, 1, strlen(s) - 2);
 452         if(tokenize_console(s) == 3)
 453                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 454
 455         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 456         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 457
 458         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 459
 460         coord2d = coord2d_topleft;
 461         if(fs_x < 8)
 462         {
 463                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 464                 fs = '8 8 0';
 465         }
 466         coord2d_y -= fs_y;
 467         coord2d_z = 0;
 468         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 469 }
 470
 471 void ShotOrg_Spawn()
 472 {
 473         debug_shotorg = spawn();
 474         debug_shotorg.draw = ShotOrg_Draw;
 475         debug_shotorg.draw2d = ShotOrg_Draw2D;
 476         debug_shotorg.renderflags = RF_VIEWMODEL;
 477         debug_shotorg.effects = EF_FULLBRIGHT;
 478         precache_model("models/shotorg_adjuster.md3");
 479         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 480         debug_shotorg.scale = 2;
 481         debug_shotorg.view_ofs = '25 8 -8';
 482 }
 483
 484 void DrawDebugModel()
 485 {
 486         if(time - floor(time) > 0.5)
 487         {
 488                 PolyDrawModel(self);
 489                 self.drawmask = 0;
 490         }
 491         else
 492         {
 493                 self.renderflags = 0;
 494                 self.drawmask = MASK_NORMAL;
 495         }
 496 }
 497
 498 void GameCommand(string msg)
 499 {
 500         string s;
 501         float argc;
 502         entity e;
 503         argc = tokenize_console(msg);
 504
 505         if(argv(0) == "help" || argc == 0)
 506         {
 507                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 508                 print(_("  settemp cvar value\n"));
 509                 print(_("  scoreboard_columns_set ...\n"));
 510                 print(_("  scoreboard_columns_help\n"));
 511                 GameCommand_Generic("help");
 512                 return;
 513         }
 514
 515         if(GameCommand_Generic(msg))
 516                 return;
 517
 518         string cmd;
 519         cmd = argv(0);
 520         if(cmd == "mv_download") {
 521                 Cmd_MapVote_MapDownload(argc);
 522         }
 523         else if(cmd == "settemp") {
 524                 cvar_clientsettemp(argv(1), argv(2));
 525         }
 526         else if(cmd == "scoreboard_columns_set") {
 527                 Cmd_HUD_SetFields(argc);
 528         }
 529         else if(cmd == "scoreboard_columns_help") {
 530                 Cmd_HUD_Help(argc);
 531         }
 532 #ifdef BLURTEST
 533         else if(cmd == "blurtest") {
 534                 blurtest_time0 = time;
 535                 blurtest_time1 = time + stof(argv(1));
 536                 blurtest_radius = stof(argv(2));
 537                 blurtest_power = stof(argv(3));
 538         }
 539 #endif
 540         else if(cmd == "shotorg_move") {
 541                 if(!debug_shotorg)
 542                         ShotOrg_Spawn();
 543                 else
 544                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 545                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 546         }
 547         else if(cmd == "shotorg_movez") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_set") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = stov(argv(1));
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_setz") {
 562                 if(!debug_shotorg)
 563                         ShotOrg_Spawn();
 564                 else
 565                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 566                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 567         }
 568         else if(cmd == "shotorg_toggle_hide") {
 569                 if(debug_shotorg)
 570                 {
 571                         debug_shotorg.cnt = !debug_shotorg.cnt;
 572                 }
 573         }
 574         else if(cmd == "shotorg_end") {
 575                 if(debug_shotorg)
 576                 {
 577                         print(vtos(debug_shotorg.view_ofs), "\n");
 578                         remove(debug_shotorg);
 579                         debug_shotorg = world;
 580                 }
 581                 localcmd("sv_cmd debug_shotorg\n");
 582         }
 583         else if(cmd == "sendcvar") {
 584                 // W_FixWeaponOrder will trash argv, so save what we need.
 585                 string thiscvar;
 586                 thiscvar = strzone(argv(1));
 587                 s = cvar_string(thiscvar);
 588                 if(thiscvar == "cl_weaponpriority")
 589                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 590                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 591                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 592                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 593                 strunzone(thiscvar);
 594         }
 595         else if(cmd == "spawn") {
 596                 s = argv(1);
 597                 e = spawn();
 598                 precache_model(s);
 599                 setmodel(e, s);
 600                 setorigin(e, view_origin);
 601                 e.angles = view_angles;
 602                 e.draw = DrawDebugModel;
 603                 e.classname = "debugmodel";
 604         }
 605     else if(cmd == "vyes")
 606     {
 607         if(uid2name_dialog)
 608         {
 609             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 610             vote_prev = 0;
 611             cvar_set("cl_allow_uid2name", "1");
 612             vote_change = -9999;
 613                         uid2name_dialog = 0;
 614         }
 615         else
 616         {
 617             localcmd("cmd vote yes\n");
 618         }
 619     }
 620     else if(cmd == "vno")
 621     {
 622         if(uid2name_dialog)
 623         {
 624             vote_active = 0;
 625             vote_prev = 0;
 626             cvar_set("cl_allow_uid2name", "0");
 627             vote_change = -9999;
 628                         uid2name_dialog = 0;
 629         }
 630         else
 631         {
 632             localcmd("cmd vote no\n");
 633         }
 634     }
 635
 636         else
 637         {
 638                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 639         }
 640
 641         return;
 642 }
 643
 644 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 645 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 646 // All keys are in ascii.
 647 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 648 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 649 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 650 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 651 {
 652         local float bSkipKey;
 653         bSkipKey = false;
 654
 655         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 656                 return true;
 657
 658         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 659                 return true;
 660
 661         if(menu_visible)
 662                 if(menu_action(bInputType, nPrimary, nSecondary))
 663                         return TRUE;
 664
 665         return bSkipKey;
 666 }
 667
 668 // END REQUIRED CSQC FUNCTIONS
 669 // --------------------------------------------------------------------------
 670
 671 // --------------------------------------------------------------------------
 672 // BEGIN OPTIONAL CSQC FUNCTIONS
 673 void Ent_ReadEntCS()
 674 {
 675         InterpolateOrigin_Undo();
 676
 677         self.classname = "entcs_receiver";
 678         self.sv_entnum = ReadByte() - 1;
 679         self.origin_x = ReadShort();
 680         self.origin_y = ReadShort();
 681         self.origin_z = ReadShort();
 682         self.angles_y = ReadByte() * 360.0 / 256;
 683         self.origin_z = self.angles_x = self.angles_z = 0;
 684
 685         InterpolateOrigin_Note();
 686 }
 687
 688 void Ent_Remove();
 689
 690 void Ent_RemovePlayerScore()
 691 {
 692         float i;
 693
 694         if(self.owner)
 695         {
 696                 SetTeam(self.owner, -1);
 697                 self.owner.gotscores = 0;
 698                 for(i = 0; i < MAX_SCORE; ++i)
 699                         self.owner.(scores[i]) = 0; // clear all scores
 700         }
 701 }
 702
 703 void Ent_ReadPlayerScore()
 704 {
 705         float i, n;
 706         float isNew;
 707         entity o;
 708
 709         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 710         // (no I've never heard of M-x replace-string, sed, or anything like that)
 711         isNew = !self.owner; // workaround for DP bug
 712         n = ReadByte()-1;
 713
 714 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 715         if(!isNew && n != self.sv_entnum)
 716         {
 717                 print(_("A CSQC entity changed its owner!\n"));
 718                 isNew = true;
 719                 Ent_Remove();
 720                 self.enttype = ENT_CLIENT_SCORES;
 721         }
 722 #endif
 723
 724         self.sv_entnum = n;
 725
 726         if not(playerslots[self.sv_entnum])
 727                 playerslots[self.sv_entnum] = spawn();
 728         o = self.owner = playerslots[self.sv_entnum];
 729         o.sv_entnum = self.sv_entnum;
 730         o.gotscores = 1;
 731
 732         //if not(o.sort_prev)
 733         //      RegisterPlayer(o);
 734         //playerchecker will do this for us later, if it has not already done so
 735
 736         float sf, lf;
 737 #if MAX_SCORE <= 8
 738         sf = ReadByte();
 739         lf = ReadByte();
 740 #else
 741         sf = ReadShort();
 742         lf = ReadShort();
 743 #endif
 744         float p;
 745         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 746                 if(sf & p)
 747                 {
 748                         if(lf & p)
 749                                 o.(scores[i]) = ReadInt24_t();
 750                         else
 751                                 o.(scores[i]) = ReadChar();
 752                 }
 753
 754         if(o.sort_prev)
 755                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 756
 757         self.entremove = Ent_RemovePlayerScore;
 758 }
 759
 760 void Ent_ReadTeamScore()
 761 {
 762         float i;
 763         entity o;
 764
 765         self.team = ReadByte();
 766         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 767
 768         float sf, lf;
 769 #if MAX_TEAMSCORE <= 8
 770         sf = ReadByte();
 771         lf = ReadByte();
 772 #else
 773         sf = ReadShort();
 774         lf = ReadShort();
 775 #endif
 776         float p;
 777         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 778                 if(sf & p)
 779                 {
 780                         if(lf & p)
 781                                 o.(teamscores[i]) = ReadInt24_t();
 782                         else
 783                                 o.(teamscores[i]) = ReadChar();
 784                 }
 785
 786         HUD_UpdateTeamPos(o);
 787 }
 788
 789 void Net_Reset()
 790 {
 791 }
 792
 793 void Ent_ClientData()
 794 {
 795         float f;
 796         float newspectatee_status;
 797
 798         f = ReadByte();
 799
 800         scoreboard_showscores_force = (f & 1);
 801
 802         if(f & 2)
 803         {
 804                 newspectatee_status = ReadByte();
 805                 if(newspectatee_status == player_localentnum)
 806                         newspectatee_status = -1; // observing
 807         }
 808         else
 809                 newspectatee_status = 0;
 810
 811         spectatorbutton_zoom = (f & 4);
 812
 813         if(f & 8)
 814         {
 815                 angles_held_status = 1;
 816                 angles_held_x = ReadAngle();
 817                 angles_held_y = ReadAngle();
 818                 angles_held_z = 0;
 819         }
 820         else
 821                 angles_held_status = 0;
 822
 823         if(newspectatee_status != spectatee_status)
 824         {
 825                 float i;
 826
 827                 // clear race stuff
 828                 race_laptime = 0;
 829                 race_checkpointtime = 0;
 830         }
 831         spectatee_status = newspectatee_status;
 832 }
 833
 834 void Ent_Nagger()
 835 {
 836         float nags, i, j, b, f;
 837
 838         nags = ReadByte();
 839
 840         if(nags & 128)
 841         {
 842                 if(vote_called_vote)
 843                         strunzone(vote_called_vote);
 844                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 845         }
 846
 847         if(nags & 1)
 848         {
 849                 for(j = 0; j < maxclients; ++j)
 850                         if(playerslots[j])
 851                                 playerslots[j].ready = 1;
 852                 for(i = 1; i <= maxclients; i += 8)
 853                 {
 854                         f = ReadByte();
 855                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 856                                 if not(f & b)
 857                                         if(playerslots[j])
 858                                                 playerslots[j].ready = 0;
 859                 }
 860         }
 861
 862         ready_waiting = (nags & 1);
 863         ready_waiting_for_me = (nags & 2);
 864         vote_waiting = (nags & 4);
 865         vote_waiting_for_me = (nags & 8);
 866         warmup_stage = (nags & 16);
 867 }
 868
 869 void Ent_RandomSeed()
 870 {
 871         float s;
 872         prandom_debug();
 873         s = ReadShort();
 874         psrandom(s);
 875 }
 876
 877 void Ent_ReadAccuracy(void)
 878 {
 879         float sf, f, w, b;
 880         sf = ReadInt24_t();
 881         if(sf == 0)
 882         {
 883                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 884                         weapon_accuracy[w] = -1;
 885                 return;
 886         }
 887
 888         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 889         {
 890                 if(sf & f)
 891                 {
 892                         b = ReadByte();
 893                         if(b == 0)
 894                                 weapon_accuracy[w] = -1;
 895                         else if(b == 255)
 896                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 897                         else
 898                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 899                 }
 900         }
 901 }
 902
 903 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 904 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 905 void Ent_RadarLink();
 906 void Ent_Init();
 907 void Ent_ScoresInfo();
 908 void(float bIsNewEntity) CSQC_Ent_Update =
 909 {
 910         float t;
 911         float savetime;
 912         t = ReadByte();
 913
 914         // set up the "time" global for received entities to be correct for interpolation purposes
 915         savetime = time;
 916         if(servertime)
 917         {
 918                 time = servertime;
 919         }
 920         else
 921         {
 922                 serverprevtime = time;
 923                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 924                 time = serverprevtime + serverdeltatime;
 925         }
 926
 927 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 928         if(self.enttype)
 929                 if(t != self.enttype)
 930                 {
 931                         print(_("A CSQC entity changed its type!\n"));
 932                         Ent_Remove();
 933                         bIsNewEntity = 1;
 934                 }
 935 #endif
 936         self.enttype = t;
 937         switch(t)
 938         {
 939                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 940                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 941                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 942                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 943                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 944                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 945                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 946                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 947                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 948                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 949                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 950                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 951                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 952                 case ENT_CLIENT_INIT: Ent_Init(); break;
 953                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 954                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 955                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 956                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 957                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 958                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 959                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 960                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 961                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 962                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 963                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 964                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 965                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 966                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 967                 default:
 968                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 969                         break;
 970         }
 971
 972         time = savetime;
 973 };
 974 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 975 // used when an entity changes its type. For an entity that someone interacts
 976 // with others, make sure it can no longer do so.
 977 void Ent_Remove()
 978 {
 979         if(self.entremove)
 980                 self.entremove();
 981
 982         self.enttype = 0;
 983         self.classname = "";
 984         self.draw = menu_sub_null;
 985         self.entremove = menu_sub_null;
 986         // TODO possibly set more stuff to defaults
 987 }
 988 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 989 void CSQC_Ent_Remove()
 990 {
 991         if(self.enttype)
 992                 Ent_Remove();
 993         remove(self);
 994 }
 995
 996 void Gamemode_Init()
 997 {
 998         if not(isdemo())
 999         {
1000                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1001                 calledhooks |= HOOK_START;
1002         }
1003 }
1004 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1005 void CSQC_Parse_StuffCmd(string strMessage)
1006 {
1007         localcmd(strMessage);
1008 }
1009 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1010 void CSQC_Parse_Print(string strMessage)
1011 {
1012         print(ColorTranslateRGB(strMessage));
1013 }
1014
1015 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1016 void CSQC_Parse_CenterPrint(string strMessage)
1017 {
1018         centerprint(strMessage);
1019 }
1020
1021 string notranslate_fogcmd1 = "\nfog ";
1022 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1023 void Fog_Force()
1024 {
1025         // TODO somehow thwart prvm_globalset client ...
1026
1027         if(forcefog != "")
1028                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1029 }
1030
1031 void Gamemode_Init();
1032 void Ent_ScoresInfo()
1033 {
1034         float i;
1035         self.classname = "ent_client_scores_info";
1036         gametype = ReadByte();
1037         for(i = 0; i < MAX_SCORE; ++i)
1038         {
1039                 scores_label[i] = strzone(ReadString());
1040                 scores_flags[i] = ReadByte();
1041         }
1042         for(i = 0; i < MAX_TEAMSCORE; ++i)
1043         {
1044                 teamscores_label[i] = strzone(ReadString());
1045                 teamscores_flags[i] = ReadByte();
1046         }
1047         HUD_InitScores();
1048         Gamemode_Init();
1049 }
1050
1051 void Ent_Init()
1052 {
1053         self.classname = "ent_client_init";
1054
1055         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1056
1057         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1058         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1059         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1060         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1061         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1062         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1063         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1064         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1065         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1066         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1067         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1068         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1069
1070         if(forcefog)
1071                 strunzone(forcefog);
1072         forcefog = strzone(ReadString());
1073
1074         armorblockpercent = ReadByte() / 255.0;
1075
1076         g_weaponswitchdelay = ReadByte() / 255.0;
1077
1078         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1079         g_balance_grenadelauncher_bouncestop = ReadCoord();
1080         g_balance_electro_secondary_bouncefactor = ReadCoord();
1081         g_balance_electro_secondary_bouncestop = ReadCoord();
1082
1083         nex_scope = !ReadByte();
1084         sniperrifle_scope = !ReadByte();
1085
1086         serverflags = ReadByte();
1087
1088         cr_maxbullets = ReadByte();
1089
1090         g_trueaim_minrange = ReadCoord();
1091
1092         if(!postinit)
1093                 PostInit();
1094 }
1095
1096 void Net_ReadRace()
1097 {
1098         float b;
1099
1100         b = ReadByte();
1101
1102         switch(b)
1103         {
1104                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1105                         race_checkpoint = ReadByte();
1106                         race_time = ReadInt24_t();
1107                         race_previousbesttime = ReadInt24_t();
1108                         if(race_previousbestname)
1109                                 strunzone(race_previousbestname);
1110                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1111
1112                         race_checkpointtime = time;
1113
1114                         if(race_checkpoint == 0 || race_checkpoint == 254)
1115                         {
1116                                 race_penaltyaccumulator = 0;
1117                                 race_laptime = time; // valid
1118                         }
1119
1120                         break;
1121
1122                 case RACE_NET_CHECKPOINT_CLEAR:
1123                         race_laptime = 0;
1124                         race_checkpointtime = 0;
1125                         break;
1126
1127                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1128                         race_laptime = ReadCoord();
1129                         race_checkpointtime = -99999;
1130                         // fall through
1131                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1132                         race_nextcheckpoint = ReadByte();
1133
1134                         race_nextbesttime = ReadInt24_t();
1135                         if(race_nextbestname)
1136                                 strunzone(race_nextbestname);
1137                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1138                         break;
1139
1140                 case RACE_NET_CHECKPOINT_HIT_RACE:
1141                         race_mycheckpoint = ReadByte();
1142                         race_mycheckpointtime = time;
1143                         race_mycheckpointdelta = ReadInt24_t();
1144                         race_mycheckpointlapsdelta = ReadByte();
1145                         if(race_mycheckpointlapsdelta >= 128)
1146                                 race_mycheckpointlapsdelta -= 256;
1147                         if(race_mycheckpointenemy)
1148                                 strunzone(race_mycheckpointenemy);
1149                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1150                         break;
1151
1152                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1153                         race_othercheckpoint = ReadByte();
1154                         race_othercheckpointtime = time;
1155                         race_othercheckpointdelta = ReadInt24_t();
1156                         race_othercheckpointlapsdelta = ReadByte();
1157                         if(race_othercheckpointlapsdelta >= 128)
1158                                 race_othercheckpointlapsdelta -= 256;
1159                         if(race_othercheckpointenemy)
1160                                 strunzone(race_othercheckpointenemy);
1161                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1162                         break;
1163
1164                 case RACE_NET_PENALTY_RACE:
1165                         race_penaltyeventtime = time;
1166                         race_penaltytime = ReadShort();
1167                         //race_penaltyaccumulator += race_penaltytime;
1168                         if(race_penaltyreason)
1169                                 strunzone(race_penaltyreason);
1170                         race_penaltyreason = strzone(ReadString());
1171                         break;
1172
1173                 case RACE_NET_PENALTY_QUALIFYING:
1174                         race_penaltyeventtime = time;
1175                         race_penaltytime = ReadShort();
1176                         race_penaltyaccumulator += race_penaltytime;
1177                         if(race_penaltyreason)
1178                                 strunzone(race_penaltyreason);
1179                         race_penaltyreason = strzone(ReadString());
1180                         break;
1181
1182                 case RACE_NET_SERVER_RECORD:
1183                         race_server_record = ReadInt24_t();
1184                         break;
1185                 case RACE_NET_SPEED_AWARD:
1186                         race_speedaward = ReadInt24_t();
1187                         if(race_speedaward_holder)
1188                                 strunzone(race_speedaward_holder);
1189                         race_speedaward_holder = strzone(ReadString());
1190                         break;
1191                 case RACE_NET_SPEED_AWARD_BEST:
1192                         race_speedaward_alltimebest = ReadInt24_t();
1193                         if(race_speedaward_alltimebest_holder)
1194                                 strunzone(race_speedaward_alltimebest_holder);
1195                         race_speedaward_alltimebest_holder = strzone(ReadString());
1196                         break;
1197                 case RACE_NET_SERVER_RANKINGS:
1198                         float pos, prevpos, del;
1199                         pos = ReadShort();
1200                         prevpos = ReadShort();
1201                         del = ReadShort();
1202
1203                         // move other rankings out of the way
1204                         float i;
1205                         if (prevpos) {
1206                                 for (i=prevpos-1;i>pos-1;--i) {
1207                                         grecordtime[i] = grecordtime[i-1];
1208                                         if(grecordholder[i])
1209                                                 strunzone(grecordholder[i]);
1210                                         grecordholder[i] = strzone(grecordholder[i-1]);
1211                                 }
1212                         } else if (del) { // a record has been deleted by the admin
1213                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1214                                         if (i == RANKINGS_CNT-1) { // clear out last record
1215                                                 grecordtime[i] = 0;
1216                                                 if (grecordholder[i])
1217                                                         strunzone(grecordholder[i]);
1218                                                 grecordholder[i] = string_null;
1219                                         }
1220                                         else {
1221                                                 grecordtime[i] = grecordtime[i+1];
1222                                                 if (grecordholder[i])
1223                                                         strunzone(grecordholder[i]);
1224                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1225                                         }
1226                                 }
1227                         } else { // player has no ranked record yet
1228                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1229                                         grecordtime[i] = grecordtime[i-1];
1230                                         if(grecordholder[i])
1231                                                 strunzone(grecordholder[i]);
1232                                         grecordholder[i] = strzone(grecordholder[i-1]);
1233                                 }
1234                         }
1235
1236                         // store new ranking
1237                         if(grecordholder[pos-1] != "")
1238                                 strunzone(grecordholder[pos-1]);
1239                         grecordholder[pos-1] = strzone(ReadString());
1240                         grecordtime[pos-1] = ReadInt24_t();
1241                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1242                                 race_myrank = pos;
1243                         break;
1244                 case RACE_NET_SERVER_STATUS:
1245                         race_status = ReadShort();
1246                         if(race_status_name)
1247                                 strunzone(race_status_name);
1248                         race_status_name = strzone(ReadString());
1249         }
1250 }
1251
1252 void Net_ReadSpawn()
1253 {
1254         zoomin_effect = 1;
1255         current_viewzoom = 0.6;
1256 }
1257
1258 void Net_TeamNagger()
1259 {
1260         teamnagger = 1;
1261 }
1262
1263 void Net_ReadPingPLReport()
1264 {
1265         float e, pi, pl, ml;
1266         e = ReadByte();
1267         pi = ReadShort();
1268         pl = ReadByte();
1269         ml = ReadByte();
1270         if not(playerslots[e])
1271                 return;
1272         playerslots[e].ping = pi;
1273         playerslots[e].ping_packetloss = pl / 255.0;
1274         playerslots[e].ping_movementloss = ml / 255.0;
1275 }
1276
1277 void Net_VoteDialog(float highlight) {
1278         if(highlight) {
1279                 vote_highlighted = ReadByte();
1280                 return;
1281         }
1282
1283         vote_yescount = ReadByte();
1284         vote_nocount = ReadByte();
1285         vote_needed = ReadByte();
1286         vote_active = 1;
1287 }
1288
1289 void Net_VoteDialogReset() {
1290         vote_active = 0;
1291 }
1292
1293 void Net_Notify() {
1294         float type;
1295         type = ReadByte();
1296
1297         if(type == CSQC_KILLNOTIFY)
1298         {
1299                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1300         }
1301         else if(type == CSQC_CENTERPRINT)
1302         {
1303                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1304         }
1305 }
1306
1307 void Net_WeaponComplain() {
1308         complain_weapon = ReadByte();
1309
1310         if(complain_weapon_name)
1311                 strunzone(complain_weapon_name);
1312         complain_weapon_name = strzone(ReadString());
1313
1314         complain_weapon_type = ReadByte();
1315
1316         complain_weapon_time = time;
1317         weapontime = time; // ping the weapon panel
1318 }
1319
1320 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1321 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1322 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1323 float CSQC_Parse_TempEntity()
1324 {
1325         local float bHandled;
1326                 bHandled  = true;
1327         // Acquire TE ID
1328         local float nTEID;
1329                 nTEID = ReadByte();
1330
1331                 // NOTE: Could just do return instead of break...
1332         switch(nTEID)
1333         {
1334                 case TE_CSQC_TARGET_MUSIC:
1335                         Net_TargetMusic();
1336                         bHandled = true;
1337                         break;
1338                 case TE_CSQC_PICTURE:
1339                         Net_MapVote_Picture();
1340                         bHandled = true;
1341                         break;
1342                 case TE_CSQC_RACE:
1343                         Net_ReadRace();
1344                         bHandled = true;
1345                         break;
1346                 case TE_CSQC_SPAWN:
1347                         Net_ReadSpawn();
1348                         bHandled = true;
1349                         break;
1350                 case TE_CSQC_ZCURVEPARTICLES:
1351                         Net_ReadZCurveParticles();
1352                         bHandled = true;
1353                         break;
1354                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1355                         Net_ReadNexgunBeamParticle();
1356                         bHandled = true;
1357                         break;
1358                 case TE_CSQC_TEAMNAGGER:
1359                         Net_TeamNagger();
1360                         bHandled = true;
1361                         break;
1362                 case TE_CSQC_VOTE:
1363                         Net_VoteDialog(ReadByte());
1364                         bHandled = true;
1365                         break;
1366                 case TE_CSQC_VOTERESET:
1367                         Net_VoteDialogReset();
1368                         bHandled = true;
1369                         break;
1370                 case TE_CSQC_LIGHTNINGARC:
1371                         Net_ReadLightningarc();
1372                         bHandled = true;
1373                         break;
1374                 case TE_CSQC_PINGPLREPORT:
1375                         Net_ReadPingPLReport();
1376                         bHandled = true;
1377                         break;
1378                 case TE_CSQC_ANNOUNCE:
1379                         announce_snd = strzone(ReadString());
1380                         bHandled = true;
1381                         break;
1382                 case TE_CSQC_NOTIFY:
1383                         Net_Notify();
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_WEAPONCOMPLAIN:
1387                         Net_WeaponComplain();
1388                         bHandled = true;
1389                         break;
1390                 default:
1391                         // No special logic for this temporary entity; return 0 so the engine can handle it
1392                         bHandled = false;
1393                         break;
1394         }
1395
1396         return bHandled;
1397 }
1398
1399 string getcommandkey(string text, string command)
1400 {
1401         string keys;
1402         float n, j, k, l;
1403
1404         if (!autocvar_hud_showbinds)
1405                 return text;
1406
1407         keys = db_get(binddb, command);
1408         if (!keys)
1409         {
1410                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1411                 for(j = 0; j < n; ++j)
1412                 {
1413                         k = stof(argv(j));
1414                         if(k != -1)
1415                         {
1416                                 if ("" == keys)
1417                                         keys = keynumtostring(k);
1418                                 else
1419                                         keys = strcat(keys, ", ", keynumtostring(k));
1420
1421                                 ++l;
1422                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1423                         }
1424
1425                 }
1426                 db_put(binddb, command, keys);
1427         }
1428
1429         if ("" == keys) {
1430                 if (autocvar_hud_showbinds > 1)
1431                         return sprintf(_("%s (not bound)"), text);
1432                 else
1433                         return text;
1434         }
1435         else if (autocvar_hud_showbinds > 1)
1436                 return sprintf(_("%s (%s)"), text, keys);
1437         else
1438                 return keys;
1439 }