Merge branch 'master' into terencehill/centerprint_stuff
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
6
7 void cvar_clientsettemp(string cv, string val)
8 {
9         entity e;
10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
11                 if(e.netname == cv)
12                         goto saved;
13         e = spawn();
14         e.classname = "saved_cvar_value";
15         e.netname = strzone(cv);
16         e.message = strzone(cvar_string(cv));
17 :saved
18         cvar_set(cv, val);
19 }
20
21 void cvar_clientsettemp_restore()
22 {
23         entity e;
24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
25                         cvar_set(e.netname, e.message);
26 }
27
28 void() menu_show_error =
29 {
30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
31 };
32
33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
34 // Useful for precaching things
35
36 void() menu_sub_null =
37 {
38 };
39
40 #ifdef USE_FTE
41 float __engine_check;
42 #endif
43
44 string forcefog;
45 string cl_announcer_prev;
46 void WaypointSprite_Load();
47 void CSQC_Init(void)
48 {
49         prvm_language = cvar_string("prvm_language");
50
51 #ifdef USE_FTE
52 #pragma target ID
53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
54         if(!__engine_check)
55         {
56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
57                 localcmd("\ndisconnect\n");
58                 return;
59         }
60 #pragma target FTE
61 #endif
62
63         check_unacceptable_compiler_bugs();
64
65 #ifdef WATERMARK
66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
67 #endif
68
69         float i;
70
71         binddb = db_create();
72         tempdb = db_create();
73         ClientProgsDB = db_load("client.db");
74         compressShortVector_init();
75
76         drawfont = FONT_USER+1;
77         menu_visible = FALSE;
78         menu_show = menu_show_error;
79         menu_action = menu_sub_null;
80
81         for(i = 0; i < 255; ++i)
82                 if(getplayerkey(i, "viewentity") == "")
83                         break;
84         maxclients = i;
85
86         //ctf_temp_1 = "";
87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
88         //registercmd("ctf_menu");
89         registercmd("ons_map");
90         registercmd("hud_configure");
91         registercmd("hud_save");
92         //registercmd("menu_action");
93
94         registercmd("+showscores");registercmd("-showscores");
95         registercmd("+showaccuracy");registercmd("-showaccuracy");
96
97 #ifndef CAMERATEST
98         if(isdemo())
99         {
100 #endif
101                 registercmd("+forward");registercmd("-forward");
102                 registercmd("+back");registercmd("-back");
103                 registercmd("+moveup");registercmd("-moveup");
104                 registercmd("+movedown");registercmd("-movedown");
105                 registercmd("+moveright");registercmd("-moveright");
106                 registercmd("+moveleft");registercmd("-moveleft");
107                 registercmd("+roll_right");registercmd("-roll_right");
108                 registercmd("+roll_left");registercmd("-roll_left");
109 #ifndef CAMERATEST
110         }
111 #endif
112         registercvar("hud_usecsqc", "1");
113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
114
115         gametype = 0;
116
117         // hud_fields uses strunzone on the titles!
118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
119                 hud_title[i] = strzone("(null)");
120
121         postinit = false;
122
123         calledhooks = 0;
124
125         teams = Sort_Spawn();
126         players = Sort_Spawn();
127
128         GetTeam(COLOR_SPECTATOR, true); // add specs first
129
130         RegisterWeapons();
131
132         WaypointSprite_Load();
133
134         // precaches
135         precache_sound("misc/hit.wav");
136         precache_sound("misc/typehit.wav");
137         Projectile_Precache();
138         Hook_Precache();
139         GibSplash_Precache();
140         Casings_Precache();
141         DamageInfo_Precache();
142         Vehicles_Precache();
143         turrets_precache();
144
145         if(autocvar_cl_announcer != cl_announcer_prev) {
146                 Announcer_Precache();
147                 if(cl_announcer_prev)
148                         strunzone(cl_announcer_prev);
149                 cl_announcer_prev = strzone(autocvar_cl_announcer);
150         }
151         Tuba_Precache();
152
153         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
154         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
155
156         get_mi_min_max_texcoords(1); // try the CLEVER way first
157         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
158         shortmapname = mi_shortname;
159
160         if(precache_pic(minimapname) == "")
161         {
162                 // but maybe we have a non-clever minimap
163                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
164                 if(precache_pic(minimapname) == "")
165                         minimapname = ""; // FAIL
166                 else
167                         get_mi_min_max_texcoords(0); // load new texcoords
168         }
169
170         mi_center = (mi_min + mi_max) * 0.5;
171         mi_scale = mi_max - mi_min;
172         minimapname = strzone(minimapname);
173
174         WarpZone_Init();
175
176         hud_configure_prev = -1;
177         tab_panel = -1;
178 }
179
180 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
181 void CSQC_Shutdown(void)
182 {
183 #ifdef USE_FTE
184 #pragma TARGET id
185         if(!__engine_check)
186                 return 0;
187 #pragma TARGET fte
188 #endif
189
190         WarpZone_Shutdown();
191
192         remove(teams);
193         remove(players);
194         db_close(binddb);
195         db_close(tempdb);
196         if(autocvar_cl_db_saveasdump)
197                 db_dump(ClientProgsDB, "client.db");
198         else
199                 db_save(ClientProgsDB, "client.db");
200         db_close(ClientProgsDB);
201
202         cvar_clientsettemp_restore();
203
204         if(camera_active)
205                 cvar_set("chase_active",ftos(chase_active_backup));
206
207         // unset the event chasecam's chase_active
208         if(autocvar_chase_active < 0)
209                 cvar_set("chase_active", "0");
210
211         if not(isdemo())
212         {
213                 if not(calledhooks & HOOK_START)
214                         localcmd("\n_cl_hook_gamestart nop\n");
215                 if not(calledhooks & HOOK_END)
216                         localcmd("\ncl_hook_gameend\n");
217         }
218 }
219
220 .float has_team;
221 float SetTeam(entity o, float Team)
222 {
223         entity tm;
224         if(teamplay)
225         {
226                 switch(Team)
227                 {
228                         case -1:
229                         case COLOR_TEAM1:
230                         case COLOR_TEAM2:
231                         case COLOR_TEAM3:
232                         case COLOR_TEAM4:
233                                 break;
234                         default:
235                                 if(GetTeam(Team, false) == NULL)
236                                 {
237                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
238                                         Team = COLOR_SPECTATOR;
239                                 }
240                                 break;
241                 }
242         }
243         else
244         {
245                 switch(Team)
246                 {
247                         case -1:
248                         case 0:
249                                 break;
250                         default:
251                                 if(GetTeam(Team, false) == NULL)
252                                 {
253                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
254                                         Team = COLOR_SPECTATOR;
255                                 }
256                                 break;
257                 }
258         }
259         if(Team == -1) // leave
260         {
261                 if(o.has_team)
262                 {
263                         tm = GetTeam(o.team, false);
264                         tm.team_size -= 1;
265                         o.has_team = 0;
266                         return TRUE;
267                 }
268         }
269         else
270         {
271                 if not(o.has_team)
272                 {
273                         o.team = Team;
274                         tm = GetTeam(Team, true);
275                         tm.team_size += 1;
276                         o.has_team = 1;
277                         return TRUE;
278                 }
279                 else if(Team != o.team)
280                 {
281                         tm = GetTeam(o.team, false);
282                         tm.team_size -= 1;
283                         o.team = Team;
284                         tm = GetTeam(Team, true);
285                         tm.team_size += 1;
286                         return TRUE;
287                 }
288         }
289         return FALSE;
290 }
291
292 void Playerchecker_Think()
293 {
294         float i;
295         entity e;
296         for(i = 0; i < maxclients; ++i)
297         {
298                 e = playerslots[i];
299                 if(GetPlayerName(i) == "")
300                 {
301                         if(e.sort_prev)
302                         {
303                                 // player disconnected
304                                 SetTeam(e, -1);
305                                 RemovePlayer(e);
306                                 e.sort_prev = world;
307                                 //e.gotscores = 0;
308                         }
309                 }
310                 else
311                 {
312                         if not(e.sort_prev)
313                         {
314                                 // player connected
315                                 if not(e)
316                                         playerslots[i] = e = spawn();
317                                 e.sv_entnum = i;
318                                 e.ping = 0;
319                                 e.ping_packetloss = 0;
320                                 e.ping_movementloss = 0;
321                                 //e.gotscores = 0; // we might already have the scores...
322                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
323                                 RegisterPlayer(e);
324                                 HUD_UpdatePlayerPos(e);
325                         }
326                 }
327         }
328         self.nextthink = time + 0.2;
329 }
330
331 void Porto_Init();
332 void TrueAim_Init();
333 void PostInit(void)
334 {
335         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
336
337         entity playerchecker;
338         playerchecker = spawn();
339         playerchecker.think = Playerchecker_Think;
340         playerchecker.nextthink = time + 0.2;
341
342         Porto_Init();
343         TrueAim_Init();
344
345         postinit = true;
346 }
347
348 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
349 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
350 float button_zoom;
351 void Cmd_HUD_SetFields(float);
352 void Cmd_HUD_Help(float);
353 float CSQC_ConsoleCommand(string strMessage)
354 {
355         float argc;
356         // Tokenize String
357         //argc = tokenize(strMessage);
358         argc = tokenize_console(strMessage);
359
360         // Acquire Command
361         local string strCmd;
362         strCmd = argv(0);
363
364         if(strCmd == "hud_configure") { // config hud
365                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
366                 return true;
367         } else if(strCmd == "hud_save") { // save hud config
368                 if(argv(1) == "" || argv(2)) {
369                         print(_("Usage:\n"));
370                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
371                 }
372                 else
373                         HUD_Panel_ExportCfg(argv(1));
374                 return true;
375         } else if(strCmd == "+showscores") {
376                 scoreboard_showscores = true;
377                 return true;
378         } else if(strCmd == "-showscores") {
379                 scoreboard_showscores = false;
380                 return true;
381         } else if(strCmd == "+showaccuracy") {
382                 scoreboard_showaccuracy = true;
383                 return true;
384         } else if(strCmd == "-showaccuracy") {
385                 scoreboard_showaccuracy = false;
386                 return true;
387         }
388
389         if(camera_active)
390         if(strCmd == "+forward" || strCmd == "-back") {
391                 ++camera_direction_x;
392                 return true;
393         } else if(strCmd == "-forward" || strCmd == "+back") {
394                 --camera_direction_x;
395                 return true;
396         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
397                 --camera_direction_y;
398                 return true;
399         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
400                 ++camera_direction_y;
401                 return true;
402         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
403                 ++camera_direction_z;
404                 return true;
405         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
406                 --camera_direction_z;
407                 return true;
408         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
409                 ++camera_roll;
410                 return true;
411         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
412                 --camera_roll;
413                 return true;
414         }
415
416         return false;
417 }
418
419 .vector view_ofs;
420 entity debug_shotorg;
421 void ShotOrg_Draw()
422 {
423         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
424         self.angles = view_angles;
425         self.angles_x = -self.angles_x;
426         if not(self.cnt)
427                 self.drawmask = MASK_NORMAL;
428         else
429                 self.drawmask = 0;
430 }
431 void ShotOrg_Draw2D()
432 {
433         vector coord2d_topleft, coord2d_topright, coord2d;
434         string s;
435         vector fs;
436
437         s = vtos(self.view_ofs);
438         s = substring(s, 1, strlen(s) - 2);
439         if(tokenize_console(s) == 3)
440                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
441
442         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
443         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
444
445         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
446
447         coord2d = coord2d_topleft;
448         if(fs_x < 8)
449         {
450                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
451                 fs = '8 8 0';
452         }
453         coord2d_y -= fs_y;
454         coord2d_z = 0;
455         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
456 }
457
458 void ShotOrg_Spawn()
459 {
460         debug_shotorg = spawn();
461         debug_shotorg.draw = ShotOrg_Draw;
462         debug_shotorg.draw2d = ShotOrg_Draw2D;
463         debug_shotorg.renderflags = RF_VIEWMODEL;
464         debug_shotorg.effects = EF_FULLBRIGHT;
465         precache_model("models/shotorg_adjuster.md3");
466         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
467         debug_shotorg.scale = 2;
468         debug_shotorg.view_ofs = '25 8 -8';
469 }
470
471 void DrawDebugModel()
472 {
473         if(time - floor(time) > 0.5)
474         {
475                 PolyDrawModel(self);
476                 self.drawmask = 0;
477         }
478         else
479         {
480                 self.renderflags = 0;
481                 self.drawmask = MASK_NORMAL;
482         }
483 }
484
485 void GameCommand(string msg)
486 {
487         string s;
488         float argc;
489         entity e;
490         argc = tokenize_console(msg);
491
492         if(argv(0) == "help" || argc == 0)
493         {
494                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
495                 print(_("  settemp cvar value\n"));
496                 print(_("  scoreboard_columns_set ...\n"));
497                 print(_("  scoreboard_columns_help\n"));
498                 GameCommand_Generic("help");
499                 return;
500         }
501
502         if(GameCommand_Generic(msg))
503                 return;
504
505         string cmd;
506         cmd = argv(0);
507         if(cmd == "mv_download") {
508                 Cmd_MapVote_MapDownload(argc);
509         }
510         else if(cmd == "settemp") {
511                 cvar_clientsettemp(argv(1), argv(2));
512         }
513         else if(cmd == "scoreboard_columns_set") {
514                 Cmd_HUD_SetFields(argc);
515         }
516         else if(cmd == "scoreboard_columns_help") {
517                 Cmd_HUD_Help(argc);
518         }
519 #ifdef BLURTEST
520         else if(cmd == "blurtest") {
521                 blurtest_time0 = time;
522                 blurtest_time1 = time + stof(argv(1));
523                 blurtest_radius = stof(argv(2));
524                 blurtest_power = stof(argv(3));
525         }
526 #endif
527         else if(cmd == "shotorg_move") {
528                 if(!debug_shotorg)
529                         ShotOrg_Spawn();
530                 else
531                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
532                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
533         }
534         else if(cmd == "shotorg_movez") {
535                 if(!debug_shotorg)
536                         ShotOrg_Spawn();
537                 else
538                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
539                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
540         }
541         else if(cmd == "shotorg_set") {
542                 if(!debug_shotorg)
543                         ShotOrg_Spawn();
544                 else
545                         debug_shotorg.view_ofs = stov(argv(1));
546                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
547         }
548         else if(cmd == "shotorg_setz") {
549                 if(!debug_shotorg)
550                         ShotOrg_Spawn();
551                 else
552                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
553                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
554         }
555         else if(cmd == "shotorg_toggle_hide") {
556                 if(debug_shotorg)
557                 {
558                         debug_shotorg.cnt = !debug_shotorg.cnt;
559                 }
560         }
561         else if(cmd == "shotorg_end") {
562                 if(debug_shotorg)
563                 {
564                         print(vtos(debug_shotorg.view_ofs), "\n");
565                         remove(debug_shotorg);
566                         debug_shotorg = world;
567                 }
568                 localcmd("sv_cmd debug_shotorg\n");
569         }
570         else if(cmd == "sendcvar") {
571                 // W_FixWeaponOrder will trash argv, so save what we need.
572                 string thiscvar;
573                 thiscvar = strzone(argv(1));
574                 s = cvar_string(thiscvar);
575                 if(thiscvar == "cl_weaponpriority")
576                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
577                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
578                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
579                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
580                 strunzone(thiscvar);
581         }
582         else if(cmd == "spawn") {
583                 s = argv(1);
584                 e = spawn();
585                 precache_model(s);
586                 setmodel(e, s);
587                 setorigin(e, view_origin);
588                 e.angles = view_angles;
589                 e.draw = DrawDebugModel;
590                 e.classname = "debugmodel";
591         }
592     else if(cmd == "vyes")
593     {
594         if(uid2name_dialog)
595         {
596             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
597             vote_prev = 0;
598             cvar_set("cl_allow_uid2name", "1");
599             vote_change = -9999;
600                         uid2name_dialog = 0;
601         }
602         else
603         {
604             localcmd("cmd vote yes\n");
605         }
606     }
607     else if(cmd == "vno")
608     {
609         if(uid2name_dialog)
610         {
611             vote_active = 0;
612             vote_prev = 0;
613             cvar_set("cl_allow_uid2name", "0");
614             vote_change = -9999;
615                         uid2name_dialog = 0;
616         }
617         else
618         {
619             localcmd("cmd vote no\n");
620         }
621     }
622
623         else
624         {
625                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
626         }
627
628         return;
629 }
630
631 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
632 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
633 // All keys are in ascii.
634 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
635 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
636 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
637 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
638 {
639         local float bSkipKey;
640         bSkipKey = false;
641
642         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
643                 return true;
644
645         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
646                 return true;
647
648         if(menu_visible)
649                 if(menu_action(bInputType, nPrimary, nSecondary))
650                         return TRUE;
651
652         return bSkipKey;
653 }
654
655 // END REQUIRED CSQC FUNCTIONS
656 // --------------------------------------------------------------------------
657
658 // --------------------------------------------------------------------------
659 // BEGIN OPTIONAL CSQC FUNCTIONS
660 void Ent_RemoveEntCS()
661 {
662         entcs_receiver[self.sv_entnum] = world;
663 }
664 void Ent_ReadEntCS()
665 {
666         float sf;
667         InterpolateOrigin_Undo();
668
669         self.classname = "entcs_receiver";
670         sf = ReadByte();
671
672         if(sf & 1)
673                 self.sv_entnum = ReadByte();
674         if(sf & 2)
675         {
676                 self.origin_x = ReadShort();
677                 self.origin_y = ReadShort();
678                 self.origin_z = ReadShort();
679         }
680         if(sf & 4)
681         {
682                 self.angles_y = ReadByte() * 360.0 / 256;
683                 self.angles_x = self.angles_z = 0;
684         }
685         if(sf & 8)
686                 self.healthvalue = ReadByte() * 10;
687         if(sf & 16)
688                 self.armorvalue = ReadByte() * 10;
689
690         entcs_receiver[self.sv_entnum] = self;
691         self.entremove = Ent_RemoveEntCS;
692
693         InterpolateOrigin_Note();
694 }
695
696 void Ent_Remove();
697
698 void Ent_RemovePlayerScore()
699 {
700         float i;
701
702         if(self.owner)
703         {
704                 SetTeam(self.owner, -1);
705                 self.owner.gotscores = 0;
706                 for(i = 0; i < MAX_SCORE; ++i)
707                         self.owner.(scores[i]) = 0; // clear all scores
708         }
709 }
710
711 void Ent_ReadPlayerScore()
712 {
713         float i, n;
714         float isNew;
715         entity o;
716
717         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
718         // (no I've never heard of M-x replace-string, sed, or anything like that)
719         isNew = !self.owner; // workaround for DP bug
720         n = ReadByte()-1;
721
722 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
723         if(!isNew && n != self.sv_entnum)
724         {
725                 //print(_("A CSQC entity changed its owner!\n"));
726                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
727                 isNew = true;
728                 Ent_Remove();
729                 self.enttype = ENT_CLIENT_SCORES;
730         }
731 #endif
732
733         self.sv_entnum = n;
734
735         if not(playerslots[self.sv_entnum])
736                 playerslots[self.sv_entnum] = spawn();
737         o = self.owner = playerslots[self.sv_entnum];
738         o.sv_entnum = self.sv_entnum;
739         o.gotscores = 1;
740
741         //if not(o.sort_prev)
742         //      RegisterPlayer(o);
743         //playerchecker will do this for us later, if it has not already done so
744
745         float sf, lf;
746 #if MAX_SCORE <= 8
747         sf = ReadByte();
748         lf = ReadByte();
749 #else
750         sf = ReadShort();
751         lf = ReadShort();
752 #endif
753         float p;
754         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
755                 if(sf & p)
756                 {
757                         if(lf & p)
758                                 o.(scores[i]) = ReadInt24_t();
759                         else
760                                 o.(scores[i]) = ReadChar();
761                 }
762
763         if(o.sort_prev)
764                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
765
766         self.entremove = Ent_RemovePlayerScore;
767 }
768
769 void Ent_ReadTeamScore()
770 {
771         float i;
772         entity o;
773
774         self.team = ReadByte();
775         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
776
777         float sf, lf;
778 #if MAX_TEAMSCORE <= 8
779         sf = ReadByte();
780         lf = ReadByte();
781 #else
782         sf = ReadShort();
783         lf = ReadShort();
784 #endif
785         float p;
786         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
787                 if(sf & p)
788                 {
789                         if(lf & p)
790                                 o.(teamscores[i]) = ReadInt24_t();
791                         else
792                                 o.(teamscores[i]) = ReadChar();
793                 }
794
795         HUD_UpdateTeamPos(o);
796 }
797
798 void Ent_ClientData()
799 {
800         float f;
801         float newspectatee_status;
802
803         f = ReadByte();
804
805         scoreboard_showscores_force = (f & 1);
806
807         if(f & 2)
808         {
809                 newspectatee_status = ReadByte();
810                 if(newspectatee_status == player_localentnum)
811                         newspectatee_status = -1; // observing
812         }
813         else
814                 newspectatee_status = 0;
815
816         spectatorbutton_zoom = (f & 4);
817
818         if(f & 8)
819         {
820                 angles_held_status = 1;
821                 angles_held_x = ReadAngle();
822                 angles_held_y = ReadAngle();
823                 angles_held_z = 0;
824         }
825         else
826                 angles_held_status = 0;
827
828         if(newspectatee_status != spectatee_status)
829         {
830                 // clear race stuff
831                 race_laptime = 0;
832                 race_checkpointtime = 0;
833         }
834         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
835         {
836                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
837                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
838                 )
839                         prev_p_health = -1;
840                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
841                         prev_health = -1;
842         }
843         spectatee_status = newspectatee_status;
844 }
845
846 void Ent_Nagger()
847 {
848         float nags, i, j, b, f;
849
850         nags = ReadByte();
851
852         if(!(nags & 4))
853         {
854                 if(vote_called_vote)
855                         strunzone(vote_called_vote);
856                 vote_called_vote = string_null;
857         }
858
859         if(nags & 128)
860         {
861                 if(vote_called_vote)
862                         strunzone(vote_called_vote);
863                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
864         }
865
866         if(nags & 1)
867         {
868                 for(j = 0; j < maxclients; ++j)
869                         if(playerslots[j])
870                                 playerslots[j].ready = 1;
871                 for(i = 1; i <= maxclients; i += 8)
872                 {
873                         f = ReadByte();
874                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
875                                 if not(f & b)
876                                         if(playerslots[j])
877                                                 playerslots[j].ready = 0;
878                 }
879         }
880
881         ready_waiting = (nags & 1);
882         ready_waiting_for_me = (nags & 2);
883         vote_waiting = (nags & 4);
884         vote_waiting_for_me = (nags & 8);
885         warmup_stage = (nags & 16);
886 }
887
888 void Ent_RandomSeed()
889 {
890         float s;
891         prandom_debug();
892         s = ReadShort();
893         psrandom(s);
894 }
895
896 void Ent_ReadAccuracy(void)
897 {
898         float sf, f, w, b;
899         sf = ReadInt24_t();
900         if(sf == 0)
901         {
902                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
903                         weapon_accuracy[w] = -1;
904                 return;
905         }
906
907         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
908         {
909                 if(sf & f)
910                 {
911                         b = ReadByte();
912                         if(b == 0)
913                                 weapon_accuracy[w] = -1;
914                         else if(b == 255)
915                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
916                         else
917                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
918                 }
919         }
920 }
921
922 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
923 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
924 void Ent_RadarLink();
925 void Ent_Init();
926 void Ent_ScoresInfo();
927 void(float bIsNewEntity) CSQC_Ent_Update =
928 {
929         float t;
930         float savetime;
931         t = ReadByte();
932
933         // set up the "time" global for received entities to be correct for interpolation purposes
934         savetime = time;
935         if(servertime)
936         {
937                 time = servertime;
938         }
939         else
940         {
941                 serverprevtime = time;
942                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
943                 time = serverprevtime + serverdeltatime;
944         }
945
946 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
947         if(self.enttype)
948                 if(t != self.enttype)
949                 {
950                         //print(_("A CSQC entity changed its type!\n"));
951                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
952                         Ent_Remove();
953                         bIsNewEntity = 1;
954                 }
955 #endif
956         self.enttype = t;
957         switch(t)
958         {
959                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
960                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
961                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
962                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
963                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
964                 case ENT_CLIENT_LASER: Ent_Laser(); break;
965                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
966                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
967                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
968                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
969                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
970                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
971                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
972                 case ENT_CLIENT_INIT: Ent_Init(); break;
973                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
974                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
975                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
976                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
977                 case ENT_CLIENT_WALL: Ent_Wall(); break;
978                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
979                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
980                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
981                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
982                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
983                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
984                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
985                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
986                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
987                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
988                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
989                 case ENT_CLIENT_TURRET: ent_turret(); break; 
990                 default:
991                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
992                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
993                         break;
994         }
995
996         time = savetime;
997 };
998 // Destructor, but does NOT deallocate the entity by calling remove(). Also
999 // used when an entity changes its type. For an entity that someone interacts
1000 // with others, make sure it can no longer do so.
1001 void Ent_Remove()
1002 {
1003         if(self.entremove)
1004                 self.entremove();
1005
1006         self.enttype = 0;
1007         self.classname = "";
1008         self.draw = menu_sub_null;
1009         self.entremove = menu_sub_null;
1010         // TODO possibly set more stuff to defaults
1011 }
1012 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1013 void CSQC_Ent_Remove()
1014 {
1015         if(self.enttype)
1016                 Ent_Remove();
1017         remove(self);
1018 }
1019
1020 void Gamemode_Init()
1021 {
1022         if not(isdemo())
1023         {
1024                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1025                 calledhooks |= HOOK_START;
1026         }
1027 }
1028 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1029 void CSQC_Parse_StuffCmd(string strMessage)
1030 {
1031         localcmd(strMessage);
1032 }
1033 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1034 void CSQC_Parse_Print(string strMessage)
1035 {
1036         print(ColorTranslateRGB(strMessage));
1037 }
1038
1039 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1040 void CSQC_Parse_CenterPrint(string strMessage)
1041 {
1042         centerprint(strMessage);
1043 }
1044
1045 string notranslate_fogcmd1 = "\nfog ";
1046 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1047 void Fog_Force()
1048 {
1049         // TODO somehow thwart prvm_globalset client ...
1050
1051         if(forcefog != "")
1052                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1053 }
1054
1055 void Gamemode_Init();
1056 void Ent_ScoresInfo()
1057 {
1058         float i;
1059         self.classname = "ent_client_scores_info";
1060         gametype = ReadByte();
1061         for(i = 0; i < MAX_SCORE; ++i)
1062         {
1063                 scores_label[i] = strzone(ReadString());
1064                 scores_flags[i] = ReadByte();
1065         }
1066         for(i = 0; i < MAX_TEAMSCORE; ++i)
1067         {
1068                 teamscores_label[i] = strzone(ReadString());
1069                 teamscores_flags[i] = ReadByte();
1070         }
1071         HUD_InitScores();
1072         Gamemode_Init();
1073 }
1074
1075 void Ent_Init()
1076 {
1077         self.classname = "ent_client_init";
1078
1079         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1080
1081         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1082         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1083         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1084         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1085         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1086         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1087         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1088         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1089         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1090         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1091         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1092         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1093
1094         if(forcefog)
1095                 strunzone(forcefog);
1096         forcefog = strzone(ReadString());
1097
1098         armorblockpercent = ReadByte() / 255.0;
1099
1100         g_weaponswitchdelay = ReadByte() / 255.0;
1101
1102         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1103         g_balance_grenadelauncher_bouncestop = ReadCoord();
1104         g_balance_electro_secondary_bouncefactor = ReadCoord();
1105         g_balance_electro_secondary_bouncestop = ReadCoord();
1106
1107         nex_scope = !ReadByte();
1108         rifle_scope = !ReadByte();
1109
1110         serverflags = ReadByte();
1111
1112         minelayer_maxmines = ReadByte();
1113
1114         hagar_maxrockets = ReadByte();
1115
1116         g_trueaim_minrange = ReadCoord();
1117
1118         if(!postinit)
1119                 PostInit();
1120 }
1121
1122 void Net_ReadRace()
1123 {
1124         float b;
1125
1126         b = ReadByte();
1127
1128         switch(b)
1129         {
1130                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1131                         race_checkpoint = ReadByte();
1132                         race_time = ReadInt24_t();
1133                         race_previousbesttime = ReadInt24_t();
1134                         if(race_previousbestname)
1135                                 strunzone(race_previousbestname);
1136                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1137
1138                         race_checkpointtime = time;
1139
1140                         if(race_checkpoint == 0 || race_checkpoint == 254)
1141                         {
1142                                 race_penaltyaccumulator = 0;
1143                                 race_laptime = time; // valid
1144                         }
1145
1146                         break;
1147
1148                 case RACE_NET_CHECKPOINT_CLEAR:
1149                         race_laptime = 0;
1150                         race_checkpointtime = 0;
1151                         break;
1152
1153                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1154                         race_laptime = ReadCoord();
1155                         race_checkpointtime = -99999;
1156                         // fall through
1157                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1158                         race_nextcheckpoint = ReadByte();
1159
1160                         race_nextbesttime = ReadInt24_t();
1161                         if(race_nextbestname)
1162                                 strunzone(race_nextbestname);
1163                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1164                         break;
1165
1166                 case RACE_NET_CHECKPOINT_HIT_RACE:
1167                         race_mycheckpoint = ReadByte();
1168                         race_mycheckpointtime = time;
1169                         race_mycheckpointdelta = ReadInt24_t();
1170                         race_mycheckpointlapsdelta = ReadByte();
1171                         if(race_mycheckpointlapsdelta >= 128)
1172                                 race_mycheckpointlapsdelta -= 256;
1173                         if(race_mycheckpointenemy)
1174                                 strunzone(race_mycheckpointenemy);
1175                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1176                         break;
1177
1178                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1179                         race_othercheckpoint = ReadByte();
1180                         race_othercheckpointtime = time;
1181                         race_othercheckpointdelta = ReadInt24_t();
1182                         race_othercheckpointlapsdelta = ReadByte();
1183                         if(race_othercheckpointlapsdelta >= 128)
1184                                 race_othercheckpointlapsdelta -= 256;
1185                         if(race_othercheckpointenemy)
1186                                 strunzone(race_othercheckpointenemy);
1187                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1188                         break;
1189
1190                 case RACE_NET_PENALTY_RACE:
1191                         race_penaltyeventtime = time;
1192                         race_penaltytime = ReadShort();
1193                         //race_penaltyaccumulator += race_penaltytime;
1194                         if(race_penaltyreason)
1195                                 strunzone(race_penaltyreason);
1196                         race_penaltyreason = strzone(ReadString());
1197                         break;
1198
1199                 case RACE_NET_PENALTY_QUALIFYING:
1200                         race_penaltyeventtime = time;
1201                         race_penaltytime = ReadShort();
1202                         race_penaltyaccumulator += race_penaltytime;
1203                         if(race_penaltyreason)
1204                                 strunzone(race_penaltyreason);
1205                         race_penaltyreason = strzone(ReadString());
1206                         break;
1207
1208                 case RACE_NET_SERVER_RECORD:
1209                         race_server_record = ReadInt24_t();
1210                         break;
1211                 case RACE_NET_SPEED_AWARD:
1212                         race_speedaward = ReadInt24_t();
1213                         if(race_speedaward_holder)
1214                                 strunzone(race_speedaward_holder);
1215                         race_speedaward_holder = strzone(ReadString());
1216                         break;
1217                 case RACE_NET_SPEED_AWARD_BEST:
1218                         race_speedaward_alltimebest = ReadInt24_t();
1219                         if(race_speedaward_alltimebest_holder)
1220                                 strunzone(race_speedaward_alltimebest_holder);
1221                         race_speedaward_alltimebest_holder = strzone(ReadString());
1222                         break;
1223                 case RACE_NET_SERVER_RANKINGS:
1224                         float pos, prevpos, del;
1225                         pos = ReadShort();
1226                         prevpos = ReadShort();
1227                         del = ReadShort();
1228
1229                         // move other rankings out of the way
1230                         float i;
1231                         if (prevpos) {
1232                                 for (i=prevpos-1;i>pos-1;--i) {
1233                                         grecordtime[i] = grecordtime[i-1];
1234                                         if(grecordholder[i])
1235                                                 strunzone(grecordholder[i]);
1236                                         grecordholder[i] = strzone(grecordholder[i-1]);
1237                                 }
1238                         } else if (del) { // a record has been deleted by the admin
1239                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1240                                         if (i == RANKINGS_CNT-1) { // clear out last record
1241                                                 grecordtime[i] = 0;
1242                                                 if (grecordholder[i])
1243                                                         strunzone(grecordholder[i]);
1244                                                 grecordholder[i] = string_null;
1245                                         }
1246                                         else {
1247                                                 grecordtime[i] = grecordtime[i+1];
1248                                                 if (grecordholder[i])
1249                                                         strunzone(grecordholder[i]);
1250                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1251                                         }
1252                                 }
1253                         } else { // player has no ranked record yet
1254                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1255                                         grecordtime[i] = grecordtime[i-1];
1256                                         if(grecordholder[i])
1257                                                 strunzone(grecordholder[i]);
1258                                         grecordholder[i] = strzone(grecordholder[i-1]);
1259                                 }
1260                         }
1261
1262                         // store new ranking
1263                         if(grecordholder[pos-1] != "")
1264                                 strunzone(grecordholder[pos-1]);
1265                         grecordholder[pos-1] = strzone(ReadString());
1266                         grecordtime[pos-1] = ReadInt24_t();
1267                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1268                                 race_myrank = pos;
1269                         break;
1270                 case RACE_NET_SERVER_STATUS:
1271                         race_status = ReadShort();
1272                         if(race_status_name)
1273                                 strunzone(race_status_name);
1274                         race_status_name = strzone(ReadString());
1275         }
1276 }
1277
1278 void Net_ReadSpawn()
1279 {
1280         zoomin_effect = 1;
1281         current_viewzoom = 0.6;
1282 }
1283
1284 void Net_TeamNagger()
1285 {
1286         teamnagger = 1;
1287 }
1288
1289 void Net_ReadPingPLReport()
1290 {
1291         float e, pi, pl, ml;
1292         e = ReadByte();
1293         pi = ReadShort();
1294         pl = ReadByte();
1295         ml = ReadByte();
1296         if not(playerslots[e])
1297                 return;
1298         playerslots[e].ping = pi;
1299         playerslots[e].ping_packetloss = pl / 255.0;
1300         playerslots[e].ping_movementloss = ml / 255.0;
1301 }
1302
1303 void Net_VoteDialog(float highlight) {
1304         if(highlight) {
1305                 vote_highlighted = ReadByte();
1306                 return;
1307         }
1308
1309         vote_yescount = ReadByte();
1310         vote_nocount = ReadByte();
1311         vote_needed = ReadByte();
1312         vote_active = 1;
1313 }
1314
1315 void Net_VoteDialogReset() {
1316         vote_active = 0;
1317 }
1318
1319 void Net_Notify() {
1320         float type;
1321         type = ReadByte();
1322
1323         if(type == CSQC_KILLNOTIFY)
1324         {
1325                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1326         }
1327         else if(type == CSQC_CENTERPRINT)
1328         {
1329                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1330         }
1331         else if(type == CSQC_CENTERPRINT_GENERIC)
1332         {
1333                 float id;
1334                 string s;
1335                 id = ReadByte();
1336                 s = ReadString();
1337                 if (id != 0 && s != "")
1338                         centerprint_generic(id, s, ReadByte(), ReadByte());
1339                 else
1340                         centerprint_generic(id, s, 0, 0);
1341         }
1342 }
1343
1344 void Net_WeaponComplain() {
1345         complain_weapon = ReadByte();
1346
1347         if(complain_weapon_name)
1348                 strunzone(complain_weapon_name);
1349         complain_weapon_name = strzone(ReadString());
1350
1351         complain_weapon_type = ReadByte();
1352
1353         complain_weapon_time = time;
1354         weapontime = time; // ping the weapon panel
1355 }
1356
1357 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1358 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1359 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1360 float CSQC_Parse_TempEntity()
1361 {
1362         local float bHandled;
1363                 bHandled  = true;
1364         // Acquire TE ID
1365         local float nTEID;
1366                 nTEID = ReadByte();
1367
1368                 // NOTE: Could just do return instead of break...
1369         switch(nTEID)
1370         {
1371                 case TE_CSQC_TARGET_MUSIC:
1372                         Net_TargetMusic();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_PICTURE:
1376                         Net_MapVote_Picture();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_RACE:
1380                         Net_ReadRace();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_SPAWN:
1384                         Net_ReadSpawn();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_ZCURVEPARTICLES:
1388                         Net_ReadZCurveParticles();
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1392                         Net_ReadNexgunBeamParticle();
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_TEAMNAGGER:
1396                         Net_TeamNagger();
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_VOTE:
1400                         Net_VoteDialog(ReadByte());
1401                         bHandled = true;
1402                         break;
1403                 case TE_CSQC_VOTERESET:
1404                         Net_VoteDialogReset();
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_LIGHTNINGARC:
1408                         Net_ReadLightningarc();
1409                         bHandled = true;
1410                         break;
1411                 case TE_CSQC_PINGPLREPORT:
1412                         Net_ReadPingPLReport();
1413                         bHandled = true;
1414                         break;
1415                 case TE_CSQC_ANNOUNCE:
1416                         announce_snd = strzone(ReadString());
1417                         bHandled = true;
1418                         break;
1419                 case TE_CSQC_NOTIFY:
1420                         Net_Notify();
1421                         bHandled = true;
1422                         break;
1423                 case TE_CSQC_WEAPONCOMPLAIN:
1424                         Net_WeaponComplain();
1425                         bHandled = true;
1426                         break;
1427         case TE_CSQC_VEHICLESETUP:
1428             Net_VehicleSetup();
1429             bHandled = true;
1430             break;
1431                 default:
1432                         // No special logic for this temporary entity; return 0 so the engine can handle it
1433                         bHandled = false;
1434                         break;
1435         }
1436
1437         return bHandled;
1438 }
1439
1440 string getcommandkey(string text, string command)
1441 {
1442         string keys;
1443         float n, j, k, l;
1444
1445         if (!autocvar_hud_showbinds)
1446                 return text;
1447
1448         keys = db_get(binddb, command);
1449         if (!keys)
1450         {
1451                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1452                 for(j = 0; j < n; ++j)
1453                 {
1454                         k = stof(argv(j));
1455                         if(k != -1)
1456                         {
1457                                 if ("" == keys)
1458                                         keys = keynumtostring(k);
1459                                 else
1460                                         keys = strcat(keys, ", ", keynumtostring(k));
1461
1462                                 ++l;
1463                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1464                         }
1465
1466                 }
1467                 db_put(binddb, command, keys);
1468         }
1469
1470         if ("" == keys) {
1471                 if (autocvar_hud_showbinds > 1)
1472                         return sprintf(_("%s (not bound)"), text);
1473                 else
1474                         return text;
1475         }
1476         else if (autocvar_hud_showbinds > 1)
1477                 return sprintf(_("%s (%s)"), text, keys);
1478         else
1479                 return keys;
1480 }