qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  65 #endif
  66
  67         float i;
  68
  69         binddb = db_create();
  70         tempdb = db_create();
  71         ClientProgsDB = db_load("client.db");
  72         compressShortVector_init();
  73
  74         drawfont = FONT_USER+1;
  75         menu_visible = FALSE;
  76         menu_show = menu_show_error;
  77         menu_action = menu_sub_null;
  78
  79         for(i = 0; i < 255; ++i)
  80                 if(getplayerkey(i, "viewentity") == "")
  81                         break;
  82         maxclients = i;
  83
  84         //ctf_temp_1 = "";
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  86         //registercmd("ctf_menu");
  87         registercmd("ons_map");
  88         registercmd("hud_configure");
  89         registercmd("hud_save");
  90         //registercmd("menu_action");
  91
  92         registercmd("+button3");
  93         registercmd("-button3");
  94         registercmd("+button4");
  95         registercmd("-button4");
  96         registercmd("+showscores");registercmd("-showscores");
  97         registercmd("+showaccuracy");registercmd("-showaccuracy");
  98
  99 #ifndef CAMERATEST
 100         if(isdemo())
 101         {
 102 #endif
 103                 registercmd("+forward");registercmd("-forward");
 104                 registercmd("+back");registercmd("-back");
 105                 registercmd("+moveup");registercmd("-moveup");
 106                 registercmd("+movedown");registercmd("-movedown");
 107                 registercmd("+moveright");registercmd("-moveright");
 108                 registercmd("+moveleft");registercmd("-moveleft");
 109                 registercmd("+roll_right");registercmd("-roll_right");
 110                 registercmd("+roll_left");registercmd("-roll_left");
 111 #ifndef CAMERATEST
 112         }
 113 #endif
 114         registercvar("hud_usecsqc", "1");
 115         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 116
 117         gametype = 0;
 118
 119         // hud_fields uses strunzone on the titles!
 120         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 121                 hud_title[i] = strzone("(null)");
 122
 123         postinit = false;
 124
 125         calledhooks = 0;
 126
 127         teams = Sort_Spawn();
 128         players = Sort_Spawn();
 129
 130         GetTeam(COLOR_SPECTATOR, true); // add specs first
 131
 132         RegisterWeapons();
 133
 134         WaypointSprite_Load();
 135
 136         // precaches
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         get_mi_min_max_texcoords(1); // try the CLEVER way first
 151         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 152         shortmapname = mi_shortname;
 153
 154         if(precache_pic(minimapname) == "")
 155         {
 156                 // but maybe we have a non-clever minimap
 157                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 158                 if(precache_pic(minimapname) == "")
 159                         minimapname = ""; // FAIL
 160                 else
 161                         get_mi_min_max_texcoords(0); // load new texcoords
 162         }
 163
 164         mi_center = (mi_min + mi_max) * 0.5;
 165         mi_scale = mi_max - mi_min;
 166         minimapname = strzone(minimapname);
 167
 168         WarpZone_Init();
 169         hud_configure_prev = -1;
 170 }
 171
 172 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 173 void CSQC_Shutdown(void)
 174 {
 175 #ifdef USE_FTE
 176 #pragma TARGET id
 177         if(!__engine_check)
 178                 return 0;
 179 #pragma TARGET fte
 180 #endif
 181
 182         WarpZone_Shutdown();
 183
 184         remove(teams);
 185         remove(players);
 186         db_close(binddb);
 187         db_close(tempdb);
 188         if(autocvar_cl_db_saveasdump)
 189                 db_dump(ClientProgsDB, "client.db");
 190         else
 191                 db_save(ClientProgsDB, "client.db");
 192         db_close(ClientProgsDB);
 193
 194         cvar_clientsettemp_restore();
 195
 196         if(camera_active)
 197                 cvar_set("chase_active",ftos(chase_active_backup));
 198
 199         if not(isdemo())
 200         {
 201                 if not(calledhooks & HOOK_START)
 202                         localcmd("\n_cl_hook_gamestart nop\n");
 203                 if not(calledhooks & HOOK_END)
 204                         localcmd("\ncl_hook_gameend\n");
 205         }
 206 }
 207
 208 .float has_team;
 209 float SetTeam(entity o, float Team)
 210 {
 211         entity tm;
 212         if(teamplay)
 213         {
 214                 switch(Team)
 215                 {
 216                         case -1:
 217                         case COLOR_TEAM1:
 218                         case COLOR_TEAM2:
 219                         case COLOR_TEAM3:
 220                         case COLOR_TEAM4:
 221                                 break;
 222                         default:
 223                                 if(GetTeam(Team, false) == NULL)
 224                                 {
 225                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 226                                         Team = COLOR_SPECTATOR;
 227                                 }
 228                                 break;
 229                 }
 230         }
 231         else
 232         {
 233                 switch(Team)
 234                 {
 235                         case -1:
 236                         case 0:
 237                                 break;
 238                         default:
 239                                 if(GetTeam(Team, false) == NULL)
 240                                 {
 241                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 242                                         Team = COLOR_SPECTATOR;
 243                                 }
 244                                 break;
 245                 }
 246         }
 247         if(Team == -1) // leave
 248         {
 249                 if(o.has_team)
 250                 {
 251                         tm = GetTeam(o.team, false);
 252                         tm.team_size -= 1;
 253                         o.has_team = 0;
 254                         return TRUE;
 255                 }
 256         }
 257         else
 258         {
 259                 if not(o.has_team)
 260                 {
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         o.has_team = 1;
 265                         return TRUE;
 266                 }
 267                 else if(Team != o.team)
 268                 {
 269                         tm = GetTeam(o.team, false);
 270                         tm.team_size -= 1;
 271                         o.team = Team;
 272                         tm = GetTeam(Team, true);
 273                         tm.team_size += 1;
 274                         return TRUE;
 275                 }
 276         }
 277         return FALSE;
 278 }
 279
 280 void Playerchecker_Think()
 281 {
 282         float i;
 283         entity e;
 284         for(i = 0; i < maxclients; ++i)
 285         {
 286                 e = playerslots[i];
 287                 if(GetPlayerName(i) == "")
 288                 {
 289                         if(e.sort_prev)
 290                         {
 291                                 // player disconnected
 292                                 SetTeam(e, -1);
 293                                 RemovePlayer(e);
 294                                 e.sort_prev = world;
 295                                 //e.gotscores = 0;
 296                         }
 297                 }
 298                 else
 299                 {
 300                         if not(e.sort_prev)
 301                         {
 302                                 // player connected
 303                                 if not(e)
 304                                         playerslots[i] = e = spawn();
 305                                 e.sv_entnum = i;
 306                                 e.ping = 0;
 307                                 e.ping_packetloss = 0;
 308                                 e.ping_movementloss = 0;
 309                                 //e.gotscores = 0; // we might already have the scores...
 310                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 311                                 RegisterPlayer(e);
 312                                 HUD_UpdatePlayerPos(e);
 313                         }
 314                 }
 315         }
 316         self.nextthink = time + 0.2;
 317 }
 318
 319 void Porto_Init();
 320 void TrueAim_Init();
 321 void PostInit(void)
 322 {
 323         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 324
 325         entity playerchecker;
 326         playerchecker = spawn();
 327         playerchecker.think = Playerchecker_Think;
 328         playerchecker.nextthink = time + 0.2;
 329
 330         Porto_Init();
 331         TrueAim_Init();
 332
 333         postinit = true;
 334 }
 335
 336 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 337 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 338 float button_zoom;
 339 void Cmd_HUD_SetFields(float);
 340 void Cmd_HUD_Help(float);
 341 float CSQC_ConsoleCommand(string strMessage)
 342 {
 343         float argc;
 344         // Tokenize String
 345         //argc = tokenize(strMessage);
 346         argc = tokenize_console(strMessage);
 347
 348         // Acquire Command
 349         local string strCmd;
 350         strCmd = argv(0);
 351
 352         if(strCmd == "hud_configure") { // config hud
 353                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 354                 return true;
 355         } else if(strCmd == "hud_save") { // save hud config
 356                 if(argv(1) == "" || argv(2)) {
 357                         print(_("Usage:\n"));
 358                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 359                 }
 360                 else
 361                         HUD_Panel_ExportCfg(argv(1));
 362                 return true;
 363         } else if(strCmd == "+button4") { // zoom
 364                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 365                 if(ignore_plus_zoom)
 366                 {
 367                         --ignore_plus_zoom;
 368                         return false;
 369                 }
 370                 button_zoom = 1;
 371                 return true;
 372         } else if(strCmd == "-button4") { // zoom
 373                 if(ignore_minus_zoom)
 374                 {
 375                         --ignore_minus_zoom;
 376                         return false;
 377                 }
 378                 button_zoom = 0;
 379                 return true;
 380         } else if(strCmd == "+button3") { // secondary
 381                 button_attack2 = 1;
 382                 return false;
 383         } else if(strCmd == "-button3") { // secondary
 384                 button_attack2 = 0;
 385                 return false;
 386         } else if(strCmd == "+showscores") {
 387                 scoreboard_showscores = true;
 388                 return true;
 389         } else if(strCmd == "-showscores") {
 390                 scoreboard_showscores = false;
 391                 return true;
 392         } else if(strCmd == "+showaccuracy") {
 393                 scoreboard_showaccuracy = true;
 394                 return true;
 395         } else if(strCmd == "-showaccuracy") {
 396                 scoreboard_showaccuracy = false;
 397                 return true;
 398         }
 399
 400         if(camera_active)
 401         if(strCmd == "+forward" || strCmd == "-back") {
 402                 ++camera_direction_x;
 403                 return true;
 404         } else if(strCmd == "-forward" || strCmd == "+back") {
 405                 --camera_direction_x;
 406                 return true;
 407         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 408                 --camera_direction_y;
 409                 return true;
 410         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 411                 ++camera_direction_y;
 412                 return true;
 413         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 414                 ++camera_direction_z;
 415                 return true;
 416         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 417                 --camera_direction_z;
 418                 return true;
 419         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 420                 ++camera_roll;
 421                 return true;
 422         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 423                 --camera_roll;
 424                 return true;
 425         }
 426
 427         return false;
 428 }
 429
 430 .vector view_ofs;
 431 entity debug_shotorg;
 432 void ShotOrg_Draw()
 433 {
 434         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 435         self.angles = view_angles;
 436         self.angles_x = -self.angles_x;
 437         if not(self.cnt)
 438                 self.drawmask = MASK_NORMAL;
 439         else
 440                 self.drawmask = 0;
 441 }
 442 void ShotOrg_Draw2D()
 443 {
 444         vector coord2d_topleft, coord2d_topright, coord2d;
 445         string s;
 446         vector fs;
 447
 448         s = vtos(self.view_ofs);
 449         s = substring(s, 1, strlen(s) - 2);
 450         if(tokenize_console(s) == 3)
 451                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 452
 453         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 454         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 455
 456         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 457
 458         coord2d = coord2d_topleft;
 459         if(fs_x < 8)
 460         {
 461                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 462                 fs = '8 8 0';
 463         }
 464         coord2d_y -= fs_y;
 465         coord2d_z = 0;
 466         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 467 }
 468
 469 void ShotOrg_Spawn()
 470 {
 471         debug_shotorg = spawn();
 472         debug_shotorg.draw = ShotOrg_Draw;
 473         debug_shotorg.draw2d = ShotOrg_Draw2D;
 474         debug_shotorg.renderflags = RF_VIEWMODEL;
 475         debug_shotorg.effects = EF_FULLBRIGHT;
 476         precache_model("models/shotorg_adjuster.md3");
 477         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 478         debug_shotorg.scale = 2;
 479         debug_shotorg.view_ofs = '25 8 -8';
 480 }
 481
 482 void DrawDebugModel()
 483 {
 484         if(time - floor(time) > 0.5)
 485         {
 486                 PolyDrawModel(self);
 487                 self.drawmask = 0;
 488         }
 489         else
 490         {
 491                 self.renderflags = 0;
 492                 self.drawmask = MASK_NORMAL;
 493         }
 494 }
 495
 496 void GameCommand(string msg)
 497 {
 498         string s;
 499         float argc;
 500         entity e;
 501         argc = tokenize_console(msg);
 502
 503         if(argv(0) == "help" || argc == 0)
 504         {
 505                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 506                 print(_("  settemp cvar value\n"));
 507                 print(_("  scoreboard_columns_set ...\n"));
 508                 print(_("  scoreboard_columns_help\n"));
 509                 GameCommand_Generic("help");
 510                 return;
 511         }
 512
 513         if(GameCommand_Generic(msg))
 514                 return;
 515
 516         string cmd;
 517         cmd = argv(0);
 518         if(cmd == "mv_download") {
 519                 Cmd_MapVote_MapDownload(argc);
 520         }
 521         else if(cmd == "settemp") {
 522                 cvar_clientsettemp(argv(1), argv(2));
 523         }
 524         else if(cmd == "scoreboard_columns_set") {
 525                 Cmd_HUD_SetFields(argc);
 526         }
 527         else if(cmd == "scoreboard_columns_help") {
 528                 Cmd_HUD_Help(argc);
 529         }
 530 #ifdef BLURTEST
 531         else if(cmd == "blurtest") {
 532                 blurtest_time0 = time;
 533                 blurtest_time1 = time + stof(argv(1));
 534                 blurtest_radius = stof(argv(2));
 535                 blurtest_power = stof(argv(3));
 536         }
 537 #endif
 538         else if(cmd == "shotorg_move") {
 539                 if(!debug_shotorg)
 540                         ShotOrg_Spawn();
 541                 else
 542                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 543                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 544         }
 545         else if(cmd == "shotorg_movez") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_set") {
 553                 if(!debug_shotorg)
 554                         ShotOrg_Spawn();
 555                 else
 556                         debug_shotorg.view_ofs = stov(argv(1));
 557                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 558         }
 559         else if(cmd == "shotorg_setz") {
 560                 if(!debug_shotorg)
 561                         ShotOrg_Spawn();
 562                 else
 563                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 564                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 565         }
 566         else if(cmd == "shotorg_toggle_hide") {
 567                 if(debug_shotorg)
 568                 {
 569                         debug_shotorg.cnt = !debug_shotorg.cnt;
 570                 }
 571         }
 572         else if(cmd == "shotorg_end") {
 573                 if(debug_shotorg)
 574                 {
 575                         print(vtos(debug_shotorg.view_ofs), "\n");
 576                         remove(debug_shotorg);
 577                         debug_shotorg = world;
 578                 }
 579                 localcmd("sv_cmd debug_shotorg\n");
 580         }
 581         else if(cmd == "sendcvar") {
 582                 // W_FixWeaponOrder will trash argv, so save what we need.
 583                 string thiscvar;
 584                 thiscvar = strzone(argv(1));
 585                 s = cvar_string(thiscvar);
 586                 if(thiscvar == "cl_weaponpriority")
 587                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 588                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 589                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 590                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 591                 strunzone(thiscvar);
 592         }
 593         else if(cmd == "spawn") {
 594                 s = argv(1);
 595                 e = spawn();
 596                 precache_model(s);
 597                 setmodel(e, s);
 598                 setorigin(e, view_origin);
 599                 e.angles = view_angles;
 600                 e.draw = DrawDebugModel;
 601                 e.classname = "debugmodel";
 602         }
 603     else if(cmd == "vyes")
 604     {
 605         if(uid2name_dialog)
 606         {
 607             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 608             vote_prev = 0;
 609             cvar_set("cl_allow_uid2name", "1");
 610             vote_change = -9999;
 611         }
 612         else
 613         {
 614             localcmd("cmd vote yes\n");
 615         }
 616     }
 617     else if(cmd == "vno")
 618     {
 619         if(uid2name_dialog)
 620         {
 621             vote_active = 0;
 622             vote_prev = 0;
 623             cvar_set("cl_allow_uid2name", "0");
 624             vote_change = -9999;
 625         }
 626         else
 627         {
 628             localcmd("cmd vote no\n");
 629         }
 630     }
 631
 632         else
 633         {
 634                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 635         }
 636
 637         return;
 638 }
 639
 640 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 641 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 642 // All keys are in ascii.
 643 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 644 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 645 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 646 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 647 {
 648         local float bSkipKey;
 649         bSkipKey = false;
 650
 651         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 652                 return true;
 653
 654         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 655                 return true;
 656
 657         if(menu_visible)
 658                 if(menu_action(bInputType, nPrimary, nSecondary))
 659                         return TRUE;
 660
 661         return bSkipKey;
 662 }
 663
 664 // END REQUIRED CSQC FUNCTIONS
 665 // --------------------------------------------------------------------------
 666
 667 // --------------------------------------------------------------------------
 668 // BEGIN OPTIONAL CSQC FUNCTIONS
 669 void Ent_ReadEntCS()
 670 {
 671         InterpolateOrigin_Undo();
 672
 673         self.classname = "entcs_receiver";
 674         self.sv_entnum = ReadByte() - 1;
 675         self.origin_x = ReadShort();
 676         self.origin_y = ReadShort();
 677         self.origin_z = ReadShort();
 678         self.angles_y = ReadByte() * 360.0 / 256;
 679         self.origin_z = self.angles_x = self.angles_z = 0;
 680
 681         InterpolateOrigin_Note();
 682 }
 683
 684 void Ent_Remove();
 685
 686 void Ent_RemovePlayerScore()
 687 {
 688         float i;
 689
 690         if(self.owner)
 691         {
 692                 SetTeam(self.owner, -1);
 693                 self.owner.gotscores = 0;
 694                 for(i = 0; i < MAX_SCORE; ++i)
 695                         self.owner.(scores[i]) = 0; // clear all scores
 696         }
 697 }
 698
 699 void Ent_ReadPlayerScore()
 700 {
 701         float i, n;
 702         float isNew;
 703         entity o;
 704
 705         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 706         // (no I've never heard of M-x replace-string, sed, or anything like that)
 707         isNew = !self.owner; // workaround for DP bug
 708         n = ReadByte()-1;
 709
 710 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 711         if(!isNew && n != self.sv_entnum)
 712         {
 713                 print(_("A CSQC entity changed its owner!\n"));
 714                 isNew = true;
 715                 Ent_Remove();
 716                 self.enttype = ENT_CLIENT_SCORES;
 717         }
 718 #endif
 719
 720         self.sv_entnum = n;
 721
 722         if not(playerslots[self.sv_entnum])
 723                 playerslots[self.sv_entnum] = spawn();
 724         o = self.owner = playerslots[self.sv_entnum];
 725         o.sv_entnum = self.sv_entnum;
 726         o.gotscores = 1;
 727
 728         //if not(o.sort_prev)
 729         //      RegisterPlayer(o);
 730         //playerchecker will do this for us later, if it has not already done so
 731
 732         float sf, lf;
 733 #if MAX_SCORE <= 8
 734         sf = ReadByte();
 735         lf = ReadByte();
 736 #else
 737         sf = ReadShort();
 738         lf = ReadShort();
 739 #endif
 740         float p;
 741         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 742                 if(sf & p)
 743                 {
 744                         if(lf & p)
 745                                 o.(scores[i]) = ReadInt24_t();
 746                         else
 747                                 o.(scores[i]) = ReadChar();
 748                 }
 749
 750         if(o.sort_prev)
 751                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 752
 753         self.entremove = Ent_RemovePlayerScore;
 754 }
 755
 756 void Ent_ReadTeamScore()
 757 {
 758         float i;
 759         entity o;
 760
 761         self.team = ReadByte();
 762         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 763
 764         float sf, lf;
 765 #if MAX_TEAMSCORE <= 8
 766         sf = ReadByte();
 767         lf = ReadByte();
 768 #else
 769         sf = ReadShort();
 770         lf = ReadShort();
 771 #endif
 772         float p;
 773         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 774                 if(sf & p)
 775                 {
 776                         if(lf & p)
 777                                 o.(teamscores[i]) = ReadInt24_t();
 778                         else
 779                                 o.(teamscores[i]) = ReadChar();
 780                 }
 781
 782         HUD_UpdateTeamPos(o);
 783 }
 784
 785 void Net_Reset()
 786 {
 787 }
 788
 789 void Ent_ClientData()
 790 {
 791         float f;
 792         float newspectatee_status;
 793
 794         f = ReadByte();
 795
 796         scoreboard_showscores_force = (f & 1);
 797
 798         if(f & 2)
 799         {
 800                 newspectatee_status = ReadByte();
 801                 if(newspectatee_status == player_localentnum)
 802                         newspectatee_status = -1; // observing
 803         }
 804         else
 805                 newspectatee_status = 0;
 806
 807         spectatorbutton_zoom = (f & 4);
 808
 809         if(f & 8)
 810         {
 811                 angles_held_status = 1;
 812                 angles_held_x = ReadAngle();
 813                 angles_held_y = ReadAngle();
 814                 angles_held_z = 0;
 815         }
 816         else
 817                 angles_held_status = 0;
 818
 819         if(newspectatee_status != spectatee_status)
 820         {
 821                 float i;
 822
 823                 // clear race stuff
 824                 race_laptime = 0;
 825                 race_checkpointtime = 0;
 826         }
 827         spectatee_status = newspectatee_status;
 828 }
 829
 830 void Ent_Nagger()
 831 {
 832         float nags, i, j, b, f;
 833
 834         nags = ReadByte();
 835
 836         if(nags & 128)
 837         {
 838                 if(vote_called_vote)
 839                         strunzone(vote_called_vote);
 840                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 841         }
 842
 843         if(nags & 1)
 844         {
 845                 for(j = 0; j < maxclients; ++j)
 846                         if(playerslots[j])
 847                                 playerslots[j].ready = 1;
 848                 for(i = 1; i <= maxclients; i += 8)
 849                 {
 850                         f = ReadByte();
 851                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 852                                 if not(f & b)
 853                                         if(playerslots[j])
 854                                                 playerslots[j].ready = 0;
 855                 }
 856         }
 857
 858         ready_waiting = (nags & 1);
 859         ready_waiting_for_me = (nags & 2);
 860         vote_waiting = (nags & 4);
 861         vote_waiting_for_me = (nags & 8);
 862         warmup_stage = (nags & 16);
 863 }
 864
 865 void Ent_RandomSeed()
 866 {
 867         float s;
 868         prandom_debug();
 869         s = ReadShort();
 870         psrandom(s);
 871 }
 872
 873 void Ent_ReadAccuracy(void)
 874 {
 875         float sf, f, w, b;
 876         sf = ReadInt24_t();
 877         if(sf == 0)
 878         {
 879                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 880                         weapon_accuracy[w] = -1;
 881                 return;
 882         }
 883
 884         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 885         {
 886                 if(sf & f)
 887                 {
 888                         b = ReadByte();
 889                         if(b == 0)
 890                                 weapon_accuracy[w] = -1;
 891                         else if(b == 255)
 892                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 893                         else
 894                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 895                 }
 896         }
 897 }
 898
 899 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 900 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 901 void Ent_RadarLink();
 902 void Ent_Init();
 903 void Ent_ScoresInfo();
 904 void(float bIsNewEntity) CSQC_Ent_Update =
 905 {
 906         float t;
 907         float savetime;
 908         t = ReadByte();
 909
 910         // set up the "time" global for received entities to be correct for interpolation purposes
 911         savetime = time;
 912         if(servertime)
 913         {
 914                 time = servertime;
 915         }
 916         else
 917         {
 918                 serverprevtime = time;
 919                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 920                 time = serverprevtime + serverdeltatime;
 921         }
 922
 923 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 924         if(self.enttype)
 925                 if(t != self.enttype)
 926                 {
 927                         print(_("A CSQC entity changed its type!\n"));
 928                         Ent_Remove();
 929                         bIsNewEntity = 1;
 930                 }
 931 #endif
 932         self.enttype = t;
 933         switch(t)
 934         {
 935                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 936                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 937                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 938                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 939                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 940                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 941                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 942                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 943                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 944                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 945                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 946                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 947                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 948                 case ENT_CLIENT_INIT: Ent_Init(); break;
 949                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 950                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 951                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 952                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 953                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 954                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 955                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 956                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 957                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 958                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 959                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 960                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 961                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 962                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 963                 default:
 964                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 965                         break;
 966         }
 967
 968         time = savetime;
 969 };
 970 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 971 // used when an entity changes its type. For an entity that someone interacts
 972 // with others, make sure it can no longer do so.
 973 void Ent_Remove()
 974 {
 975         if(self.entremove)
 976                 self.entremove();
 977
 978         self.enttype = 0;
 979         self.classname = "";
 980         self.draw = menu_sub_null;
 981         self.entremove = menu_sub_null;
 982         // TODO possibly set more stuff to defaults
 983 }
 984 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 985 void CSQC_Ent_Remove()
 986 {
 987         if(self.enttype)
 988                 Ent_Remove();
 989         remove(self);
 990 }
 991
 992 void Gamemode_Init()
 993 {
 994         if(gametype == GAME_ONSLAUGHT) {
 995                 print(strcat("Using ", minimapname, " as minimap.\n"));
 996                 precache_pic("gfx/ons-cp-neutral.tga");
 997                 precache_pic("gfx/ons-cp-red.tga");
 998                 precache_pic("gfx/ons-cp-blue.tga");
 999                 precache_pic("gfx/ons-frame.tga");
1000                 precache_pic("gfx/ons-frame-team.tga");
1001         }
1002
1003         if not(isdemo())
1004         {
1005                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1006                 calledhooks |= HOOK_START;
1007         }
1008 }
1009 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1010 void CSQC_Parse_StuffCmd(string strMessage)
1011 {
1012         localcmd(strMessage);
1013 }
1014 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1015 void CSQC_Parse_Print(string strMessage)
1016 {
1017         print(ColorTranslateRGB(strMessage));
1018 }
1019
1020 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1021 void CSQC_Parse_CenterPrint(string strMessage)
1022 {
1023         centerprint(strMessage);
1024 }
1025
1026 string notranslate_fogcmd1 = "\nfog ";
1027 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1028 void Fog_Force()
1029 {
1030         // TODO somehow thwart prvm_globalset client ...
1031
1032         if(forcefog != "")
1033                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1034 }
1035
1036 void Gamemode_Init();
1037 void Ent_ScoresInfo()
1038 {
1039         float i;
1040         self.classname = "ent_client_scores_info";
1041         gametype = ReadByte();
1042         for(i = 0; i < MAX_SCORE; ++i)
1043         {
1044                 scores_label[i] = strzone(ReadString());
1045                 scores_flags[i] = ReadByte();
1046         }
1047         for(i = 0; i < MAX_TEAMSCORE; ++i)
1048         {
1049                 teamscores_label[i] = strzone(ReadString());
1050                 teamscores_flags[i] = ReadByte();
1051         }
1052         HUD_InitScores();
1053         Gamemode_Init();
1054 }
1055
1056 void Ent_Init()
1057 {
1058         self.classname = "ent_client_init";
1059
1060         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1061
1062         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1063         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1064         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1065         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1066         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1067         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1068         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1069         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1070         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1071         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1072         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1073         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1074
1075         if(forcefog)
1076                 strunzone(forcefog);
1077         forcefog = strzone(ReadString());
1078
1079         armorblockpercent = ReadByte() / 255.0;
1080
1081         g_weaponswitchdelay = ReadByte() / 255.0;
1082
1083         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1084         g_balance_grenadelauncher_bouncestop = ReadCoord();
1085         g_balance_electro_secondary_bouncefactor = ReadCoord();
1086         g_balance_electro_secondary_bouncestop = ReadCoord();
1087
1088         nex_scope = !ReadByte();
1089         sniperrifle_scope = !ReadByte();
1090
1091         serverflags = ReadByte();
1092
1093         cr_maxbullets = ReadByte();
1094
1095         g_trueaim_minrange = ReadCoord();
1096
1097         if(!postinit)
1098                 PostInit();
1099 }
1100
1101 void Net_ReadRace()
1102 {
1103         float b;
1104
1105         b = ReadByte();
1106
1107         switch(b)
1108         {
1109                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1110                         race_checkpoint = ReadByte();
1111                         race_time = ReadInt24_t();
1112                         race_previousbesttime = ReadInt24_t();
1113                         if(race_previousbestname)
1114                                 strunzone(race_previousbestname);
1115                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1116
1117                         race_checkpointtime = time;
1118
1119                         if(race_checkpoint == 0 || race_checkpoint == 254)
1120                         {
1121                                 race_penaltyaccumulator = 0;
1122                                 race_laptime = time; // valid
1123                         }
1124
1125                         break;
1126
1127                 case RACE_NET_CHECKPOINT_CLEAR:
1128                         race_laptime = 0;
1129                         race_checkpointtime = 0;
1130                         break;
1131
1132                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1133                         race_laptime = ReadCoord();
1134                         race_checkpointtime = -99999;
1135                         // fall through
1136                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1137                         race_nextcheckpoint = ReadByte();
1138
1139                         race_nextbesttime = ReadInt24_t();
1140                         if(race_nextbestname)
1141                                 strunzone(race_nextbestname);
1142                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1143                         break;
1144
1145                 case RACE_NET_CHECKPOINT_HIT_RACE:
1146                         race_mycheckpoint = ReadByte();
1147                         race_mycheckpointtime = time;
1148                         race_mycheckpointdelta = ReadInt24_t();
1149                         race_mycheckpointlapsdelta = ReadByte();
1150                         if(race_mycheckpointlapsdelta >= 128)
1151                                 race_mycheckpointlapsdelta -= 256;
1152                         if(race_mycheckpointenemy)
1153                                 strunzone(race_mycheckpointenemy);
1154                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1155                         break;
1156
1157                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1158                         race_othercheckpoint = ReadByte();
1159                         race_othercheckpointtime = time;
1160                         race_othercheckpointdelta = ReadInt24_t();
1161                         race_othercheckpointlapsdelta = ReadByte();
1162                         if(race_othercheckpointlapsdelta >= 128)
1163                                 race_othercheckpointlapsdelta -= 256;
1164                         if(race_othercheckpointenemy)
1165                                 strunzone(race_othercheckpointenemy);
1166                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1167                         break;
1168
1169                 case RACE_NET_PENALTY_RACE:
1170                         race_penaltyeventtime = time;
1171                         race_penaltytime = ReadShort();
1172                         //race_penaltyaccumulator += race_penaltytime;
1173                         if(race_penaltyreason)
1174                                 strunzone(race_penaltyreason);
1175                         race_penaltyreason = strzone(ReadString());
1176                         break;
1177
1178                 case RACE_NET_PENALTY_QUALIFYING:
1179                         race_penaltyeventtime = time;
1180                         race_penaltytime = ReadShort();
1181                         race_penaltyaccumulator += race_penaltytime;
1182                         if(race_penaltyreason)
1183                                 strunzone(race_penaltyreason);
1184                         race_penaltyreason = strzone(ReadString());
1185                         break;
1186
1187                 case RACE_NET_SERVER_RECORD:
1188                         race_server_record = ReadInt24_t();
1189                         break;
1190                 case RACE_NET_SPEED_AWARD:
1191                         race_speedaward = ReadInt24_t();
1192                         if(race_speedaward_holder)
1193                                 strunzone(race_speedaward_holder);
1194                         race_speedaward_holder = strzone(ReadString());
1195                         break;
1196                 case RACE_NET_SPEED_AWARD_BEST:
1197                         race_speedaward_alltimebest = ReadInt24_t();
1198                         if(race_speedaward_alltimebest_holder)
1199                                 strunzone(race_speedaward_alltimebest_holder);
1200                         race_speedaward_alltimebest_holder = strzone(ReadString());
1201                         break;
1202                 case RACE_NET_SERVER_RANKINGS:
1203                         float pos, prevpos, del;
1204                         pos = ReadShort();
1205                         prevpos = ReadShort();
1206                         del = ReadShort();
1207
1208                         // move other rankings out of the way
1209                         float i;
1210                         if (prevpos) {
1211                                 for (i=prevpos-1;i>pos-1;--i) {
1212                                         grecordtime[i] = grecordtime[i-1];
1213                                         if(grecordholder[i])
1214                                                 strunzone(grecordholder[i]);
1215                                         grecordholder[i] = strzone(grecordholder[i-1]);
1216                                 }
1217                         } else if (del) { // a record has been deleted by the admin
1218                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1219                                         if (i == RANKINGS_CNT-1) { // clear out last record
1220                                                 grecordtime[i] = 0;
1221                                                 if (grecordholder[i])
1222                                                         strunzone(grecordholder[i]);
1223                                                 grecordholder[i] = string_null;
1224                                         }
1225                                         else {
1226                                                 grecordtime[i] = grecordtime[i+1];
1227                                                 if (grecordholder[i])
1228                                                         strunzone(grecordholder[i]);
1229                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1230                                         }
1231                                 }
1232                         } else { // player has no ranked record yet
1233                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1234                                         grecordtime[i] = grecordtime[i-1];
1235                                         if(grecordholder[i])
1236                                                 strunzone(grecordholder[i]);
1237                                         grecordholder[i] = strzone(grecordholder[i-1]);
1238                                 }
1239                         }
1240
1241                         // store new ranking
1242                         if(grecordholder[pos-1] != "")
1243                                 strunzone(grecordholder[pos-1]);
1244                         grecordholder[pos-1] = strzone(ReadString());
1245                         grecordtime[pos-1] = ReadInt24_t();
1246                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1247                                 race_myrank = pos;
1248                         break;
1249                 case RACE_NET_SERVER_STATUS:
1250                         race_status = ReadShort();
1251                         if(race_status_name)
1252                                 strunzone(race_status_name);
1253                         race_status_name = strzone(ReadString());
1254         }
1255 }
1256
1257 void Net_ReadSpawn()
1258 {
1259         zoomin_effect = 1;
1260         current_viewzoom = 0.6;
1261 }
1262
1263 void Net_TeamNagger()
1264 {
1265         teamnagger = 1;
1266 }
1267
1268 void Net_ReadPingPLReport()
1269 {
1270         float e, pi, pl, ml;
1271         e = ReadByte();
1272         pi = ReadShort();
1273         pl = ReadByte();
1274         ml = ReadByte();
1275         if not(playerslots[e])
1276                 return;
1277         playerslots[e].ping = pi;
1278         playerslots[e].ping_packetloss = pl / 255.0;
1279         playerslots[e].ping_movementloss = ml / 255.0;
1280 }
1281
1282 void Net_VoteDialog(float highlight) {
1283         if(highlight) {
1284                 vote_highlighted = ReadByte();
1285                 return;
1286         }
1287
1288         vote_yescount = ReadByte();
1289         vote_nocount = ReadByte();
1290         vote_needed = ReadByte();
1291         vote_active = 1;
1292 }
1293
1294 void Net_VoteDialogReset() {
1295         vote_active = 0;
1296 }
1297
1298 void Net_Notify() {
1299         float type;
1300         type = ReadByte();
1301
1302         if(type == CSQC_KILLNOTIFY)
1303         {
1304                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1305         }
1306         else if(type == CSQC_CENTERPRINT)
1307         {
1308                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1309         }
1310 }
1311
1312 void Net_WeaponComplain() {
1313         complain_weapon = ReadByte();
1314
1315         if(complain_weapon_name)
1316                 strunzone(complain_weapon_name);
1317         complain_weapon_name = strzone(ReadString());
1318
1319         complain_weapon_type = ReadByte();
1320
1321         complain_weapon_time = time;
1322         weapontime = time; // ping the weapon panel
1323 }
1324
1325 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1326 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1327 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1328 float CSQC_Parse_TempEntity()
1329 {
1330         local float bHandled;
1331                 bHandled  = true;
1332         // Acquire TE ID
1333         local float nTEID;
1334                 nTEID = ReadByte();
1335
1336                 // NOTE: Could just do return instead of break...
1337         switch(nTEID)
1338         {
1339                 case TE_CSQC_TARGET_MUSIC:
1340                         Net_TargetMusic();
1341                         bHandled = true;
1342                         break;
1343                 case TE_CSQC_PICTURE:
1344                         Net_MapVote_Picture();
1345                         bHandled = true;
1346                         break;
1347                 case TE_CSQC_RACE:
1348                         Net_ReadRace();
1349                         bHandled = true;
1350                         break;
1351                 case TE_CSQC_SPAWN:
1352                         Net_ReadSpawn();
1353                         bHandled = true;
1354                         break;
1355                 case TE_CSQC_ZCURVEPARTICLES:
1356                         Net_ReadZCurveParticles();
1357                         bHandled = true;
1358                         break;
1359                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1360                         Net_ReadNexgunBeamParticle();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_TEAMNAGGER:
1364                         Net_TeamNagger();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_VOTE:
1368                         Net_VoteDialog(ReadByte());
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_VOTERESET:
1372                         Net_VoteDialogReset();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_LIGHTNINGARC:
1376                         Net_ReadLightningarc();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_PINGPLREPORT:
1380                         Net_ReadPingPLReport();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_ANNOUNCE:
1384                         announce_snd = strzone(ReadString());
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_NOTIFY:
1388                         Net_Notify();
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_WEAPONCOMPLAIN:
1392                         Net_WeaponComplain();
1393                         bHandled = true;
1394                         break;
1395                 default:
1396                         // No special logic for this temporary entity; return 0 so the engine can handle it
1397                         bHandled = false;
1398                         break;
1399         }
1400
1401         return bHandled;
1402 }
1403
1404 string getcommandkey(string text, string command)
1405 {
1406         string keys;
1407         float n, j, k, l;
1408
1409         if (!hud_showbinds)
1410                 return text;
1411
1412         keys = db_get(binddb, command);
1413         if (!keys)
1414         {
1415                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1416                 for(j = 0; j < n; ++j)
1417                 {
1418                         k = stof(argv(j));
1419                         if(k != -1)
1420                         {
1421                                 if ("" == keys)
1422                                         keys = keynumtostring(k);
1423                                 else
1424                                         keys = strcat(keys, ", ", keynumtostring(k));
1425
1426                                 ++l;
1427                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1428                         }
1429
1430                 }
1431                 db_put(binddb, command, keys);
1432         }
1433
1434         if ("" == keys) {
1435                 if (hud_showbinds > 1)
1436                         return sprintf(_("%s (not bound)"), text);
1437                 else
1438                         return text;
1439         }
1440         else if (hud_showbinds > 1)
1441                 return sprintf(_("%s (%s)"), text, keys);
1442         else
1443                 return keys;
1444 }