qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 148         }
 149         Tuba_Precache();
 150
 151         get_mi_min_max_texcoords(1); // try the CLEVER way first
 152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 153         shortmapname = mi_shortname;
 154
 155         if(precache_pic(minimapname) == "")
 156         {
 157                 // but maybe we have a non-clever minimap
 158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 159                 if(precache_pic(minimapname) == "")
 160                         minimapname = ""; // FAIL
 161                 else
 162                         get_mi_min_max_texcoords(0); // load new texcoords
 163         }
 164
 165         mi_center = (mi_min + mi_max) * 0.5;
 166         mi_scale = mi_max - mi_min;
 167         minimapname = strzone(minimapname);
 168
 169         WarpZone_Init();
 170         hud_configure_prev = -1;
 171 }
 172
 173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 174 void CSQC_Shutdown(void)
 175 {
 176 #ifdef USE_FTE
 177 #pragma TARGET id
 178         if(!__engine_check)
 179                 return 0;
 180 #pragma TARGET fte
 181 #endif
 182
 183         WarpZone_Shutdown();
 184
 185         remove(teams);
 186         remove(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         if(cvar("cl_db_saveasdump"))
 190                 db_dump(ClientProgsDB, "client.db");
 191         else
 192                 db_save(ClientProgsDB, "client.db");
 193         db_close(ClientProgsDB);
 194
 195         cvar_clientsettemp_restore();
 196
 197         if(camera_active)
 198                 cvar_set("chase_active",ftos(chase_active_backup));
 199
 200         if not(isdemo())
 201         {
 202                 if not(calledhooks & HOOK_START)
 203                         localcmd("\n_cl_hook_gamestart nop\n");
 204                 if not(calledhooks & HOOK_END)
 205                         localcmd("\ncl_hook_gameend\n");
 206         }
 207 }
 208
 209 .float has_team;
 210 float SetTeam(entity o, float Team)
 211 {
 212         entity tm;
 213         if(teamplay)
 214         {
 215                 switch(Team)
 216                 {
 217                         case -1:
 218                         case COLOR_TEAM1:
 219                         case COLOR_TEAM2:
 220                         case COLOR_TEAM3:
 221                         case COLOR_TEAM4:
 222                                 break;
 223                         default:
 224                                 if(GetTeam(Team, false) == NULL)
 225                                 {
 226                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 227                                         Team = COLOR_SPECTATOR;
 228                                 }
 229                                 break;
 230                 }
 231         }
 232         else
 233         {
 234                 switch(Team)
 235                 {
 236                         case -1:
 237                         case 0:
 238                                 break;
 239                         default:
 240                                 if(GetTeam(Team, false) == NULL)
 241                                 {
 242                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 243                                         Team = COLOR_SPECTATOR;
 244                                 }
 245                                 break;
 246                 }
 247         }
 248         if(Team == -1) // leave
 249         {
 250                 if(o.has_team)
 251                 {
 252                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 253                         tm = GetTeam(o.team, false);
 254                         tm.team_size -= 1;
 255                         o.has_team = 0;
 256                         return TRUE;
 257                 }
 258         }
 259         else
 260         {
 261                 if not(o.has_team)
 262                 {
 263                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 264                         o.team = Team;
 265                         tm = GetTeam(Team, true);
 266                         tm.team_size += 1;
 267                         o.has_team = 1;
 268                         return TRUE;
 269                 }
 270                 else if(Team != o.team)
 271                 {
 272                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.team = Team;
 276                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 277                         tm = GetTeam(Team, true);
 278                         tm.team_size += 1;
 279                         return TRUE;
 280                 }
 281         }
 282         return FALSE;
 283 }
 284
 285 void Playerchecker_Think()
 286 {
 287         float i;
 288         entity e;
 289         for(i = 0; i < maxclients; ++i)
 290         {
 291                 e = playerslots[i];
 292                 if(GetPlayerName(i) == "")
 293                 {
 294                         if(e.sort_prev)
 295                         {
 296                                 //print("playerchecker: KILL KILL KILL\n");
 297                                 // player disconnected
 298                                 SetTeam(e, -1);
 299                                 RemovePlayer(e);
 300                                 e.sort_prev = world;
 301                                 //e.gotscores = 0;
 302                         }
 303                 }
 304                 else
 305                 {
 306                         if not(e.sort_prev)
 307                         {
 308                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 309                                 // player connected
 310                                 if not(e)
 311                                         playerslots[i] = e = spawn();
 312                                 e.sv_entnum = i;
 313                                 e.ping = 0;
 314                                 e.ping_packetloss = 0;
 315                                 e.ping_movementloss = 0;
 316                                 //e.gotscores = 0; // we might already have the scores...
 317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 318                                 RegisterPlayer(e);
 319                                 HUD_UpdatePlayerPos(e);
 320                         }
 321                 }
 322         }
 323         self.nextthink = time + 0.2;
 324 }
 325
 326 void Porto_Init();
 327 void TrueAim_Init();
 328 void PostInit(void)
 329 {
 330         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 331         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
 332
 333         entity playerchecker;
 334         playerchecker = spawn();
 335         playerchecker.think = Playerchecker_Think;
 336         playerchecker.nextthink = time + 0.2;
 337
 338         Porto_Init();
 339         TrueAim_Init();
 340
 341         weaponorder_byimpulse = W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(cvar_string("cl_weaponpriority"))));
 342
 343         postinit = true;
 344 }
 345
 346 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 347 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 348 float button_zoom;
 349 void Cmd_HUD_SetFields(float);
 350 void Cmd_HUD_Help(float);
 351 float CSQC_ConsoleCommand(string strMessage)
 352 {
 353         float argc;
 354         // Tokenize String
 355         //argc = tokenize(strMessage);
 356         argc = tokenize_console(strMessage);
 357
 358         // Acquire Command
 359         local string strCmd;
 360         strCmd = argv(0);
 361
 362         if(strCmd == "hud_configure") { // config hud
 363                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
 364                 return true;
 365         } else if(strCmd == "hud_save") { // save hud config
 366                 if(argv(1) == "" || argv(2)) {
 367                         print("Usage:\n");
 368                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 369                 }
 370                 else
 371                         HUD_Panel_ExportCfg(argv(1));
 372                 return true;
 373         } else if(strCmd == "+button4") { // zoom
 374                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 375                 if(ignore_plus_zoom)
 376                 {
 377                         --ignore_plus_zoom;
 378                         return false;
 379                 }
 380                 button_zoom = 1;
 381                 return true;
 382         } else if(strCmd == "-button4") { // zoom
 383                 if(ignore_minus_zoom)
 384                 {
 385                         --ignore_minus_zoom;
 386                         return false;
 387                 }
 388                 button_zoom = 0;
 389                 return true;
 390         } else if(strCmd == "+button3") { // secondary
 391                 button_attack2 = 1;
 392                 return false;
 393         } else if(strCmd == "-button3") { // secondary
 394                 button_attack2 = 0;
 395                 return false;
 396         } else if(strCmd == "+showscores") {
 397                 scoreboard_showscores = true;
 398                 return true;
 399         } else if(strCmd == "-showscores") {
 400                 scoreboard_showscores = false;
 401                 return true;
 402         } else if(strCmd == "+showaccuracy") {
 403                 scoreboard_showaccuracy = true;
 404                 return true;
 405         } else if(strCmd == "-showaccuracy") {
 406                 scoreboard_showaccuracy = false;
 407                 return true;
 408         }
 409
 410         if(camera_active)
 411         if(strCmd == "+forward" || strCmd == "-back") {
 412                 ++camera_direction_x;
 413                 return true;
 414         } else if(strCmd == "-forward" || strCmd == "+back") {
 415                 --camera_direction_x;
 416                 return true;
 417         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 418                 --camera_direction_y;
 419                 return true;
 420         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 421                 ++camera_direction_y;
 422                 return true;
 423         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 424                 ++camera_direction_z;
 425                 return true;
 426         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 427                 --camera_direction_z;
 428                 return true;
 429         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 430                 ++camera_roll;
 431                 return true;
 432         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 433                 --camera_roll;
 434                 return true;
 435         }
 436
 437         return false;
 438 }
 439
 440 .vector view_ofs;
 441 entity debug_shotorg;
 442 void ShotOrg_Draw()
 443 {
 444         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 445         self.angles = view_angles;
 446         self.angles_x = -self.angles_x;
 447         if not(self.cnt)
 448                 self.drawmask = MASK_NORMAL;
 449         else
 450                 self.drawmask = 0;
 451 }
 452 void ShotOrg_Draw2D()
 453 {
 454         vector coord2d_topleft, coord2d_topright, coord2d;
 455         string s;
 456         vector fs;
 457
 458         s = vtos(self.view_ofs);
 459         s = substring(s, 1, strlen(s) - 2);
 460         if(tokenize_console(s) == 3)
 461                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 462
 463         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 464         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 465
 466         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 467
 468         coord2d = coord2d_topleft;
 469         if(fs_x < 8)
 470         {
 471                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 472                 fs = '8 8 0';
 473         }
 474         coord2d_y -= fs_y;
 475         coord2d_z = 0;
 476         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 477 }
 478
 479 void ShotOrg_Spawn()
 480 {
 481         debug_shotorg = spawn();
 482         debug_shotorg.draw = ShotOrg_Draw;
 483         debug_shotorg.draw2d = ShotOrg_Draw2D;
 484         debug_shotorg.renderflags = RF_VIEWMODEL;
 485         debug_shotorg.effects = EF_FULLBRIGHT;
 486         precache_model("models/shotorg_adjuster.md3");
 487         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 488         debug_shotorg.scale = 2;
 489         debug_shotorg.view_ofs = '25 8 -8';
 490 }
 491
 492 void DrawDebugModel()
 493 {
 494         if(time - floor(time) > 0.5)
 495         {
 496                 PolyDrawModel(self);
 497                 self.drawmask = 0;
 498         }
 499         else
 500         {
 501                 self.renderflags = 0;
 502                 self.drawmask = MASK_NORMAL;
 503         }
 504 }
 505
 506 void GameCommand(string msg)
 507 {
 508         string s;
 509         float argc;
 510         entity e;
 511         argc = tokenize_console(msg);
 512
 513         if(argv(0) == "help" || argc == 0)
 514         {
 515                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 516                 print("  settemp cvar value\n");
 517                 print("  scoreboard_columns_set ...\n");
 518                 print("  scoreboard_columns_help\n");
 519                 GameCommand_Generic("help");
 520                 return;
 521         }
 522
 523         if(GameCommand_Generic(msg))
 524                 return;
 525
 526         string cmd;
 527         cmd = argv(0);
 528         if(cmd == "mv_download") {
 529                 Cmd_MapVote_MapDownload(argc);
 530         }
 531         else if(cmd == "settemp") {
 532                 cvar_clientsettemp(argv(1), argv(2));
 533         }
 534         else if(cmd == "scoreboard_columns_set") {
 535                 Cmd_HUD_SetFields(argc);
 536         }
 537         else if(cmd == "scoreboard_columns_help") {
 538                 Cmd_HUD_Help(argc);
 539         }
 540 #ifdef BLURTEST
 541         else if(cmd == "blurtest") {
 542                 blurtest_time0 = time;
 543                 blurtest_time1 = time + stof(argv(1));
 544                 blurtest_radius = stof(argv(2));
 545                 blurtest_power = stof(argv(3));
 546         }
 547 #endif
 548         else if(cmd == "shotorg_move") {
 549                 if(!debug_shotorg)
 550                         ShotOrg_Spawn();
 551                 else
 552                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 553                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 554         }
 555         else if(cmd == "shotorg_movez") {
 556                 if(!debug_shotorg)
 557                         ShotOrg_Spawn();
 558                 else
 559                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 560                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 561         }
 562         else if(cmd == "shotorg_set") {
 563                 if(!debug_shotorg)
 564                         ShotOrg_Spawn();
 565                 else
 566                         debug_shotorg.view_ofs = stov(argv(1));
 567                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 568         }
 569         else if(cmd == "shotorg_setz") {
 570                 if(!debug_shotorg)
 571                         ShotOrg_Spawn();
 572                 else
 573                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 574                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 575         }
 576         else if(cmd == "shotorg_toggle_hide") {
 577                 if(debug_shotorg)
 578                 {
 579                         debug_shotorg.cnt = !debug_shotorg.cnt;
 580                 }
 581         }
 582         else if(cmd == "shotorg_end") {
 583                 if(debug_shotorg)
 584                 {
 585                         print(vtos(debug_shotorg.view_ofs), "\n");
 586                         remove(debug_shotorg);
 587                         debug_shotorg = world;
 588                 }
 589                 localcmd("sv_cmd debug_shotorg\n");
 590         }
 591         else if(cmd == "sendcvar") {
 592                 // W_FixWeaponOrder will trash argv, so save what we need.
 593                 string thiscvar;
 594                 thiscvar = strzone(argv(1));
 595                 s = cvar_string(thiscvar);
 596                 if(thiscvar == "cl_weaponpriority")
 597                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 598                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 599                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 600                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 601                 strunzone(thiscvar);
 602         }
 603         else if(cmd == "spawn") {
 604                 s = argv(1);
 605                 e = spawn();
 606                 precache_model(s);
 607                 setmodel(e, s);
 608                 setorigin(e, view_origin);
 609                 e.angles = view_angles;
 610                 e.draw = DrawDebugModel;
 611                 e.classname = "debugmodel";
 612         }
 613         else
 614         {
 615                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 616         }
 617
 618         return;
 619 }
 620
 621 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 622 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 623 // All keys are in ascii.
 624 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 625 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 626 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 627 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 628 {
 629         local float bSkipKey;
 630         bSkipKey = false;
 631
 632         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 633                 return true;
 634
 635         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 636                 return true;
 637
 638         if(menu_visible)
 639                 if(menu_action(bInputType, nPrimary, nSecondary))
 640                         return TRUE;
 641         return bSkipKey;
 642 }
 643
 644 // END REQUIRED CSQC FUNCTIONS
 645 // --------------------------------------------------------------------------
 646
 647 // --------------------------------------------------------------------------
 648 // BEGIN OPTIONAL CSQC FUNCTIONS
 649 void Ent_ReadEntCS()
 650 {
 651         InterpolateOrigin_Undo();
 652
 653         self.classname = "entcs_receiver";
 654         self.sv_entnum = ReadByte() - 1;
 655         self.origin_x = ReadShort();
 656         self.origin_y = ReadShort();
 657         self.origin_z = ReadShort();
 658         self.angles_y = ReadByte() * 360.0 / 256;
 659         self.origin_z = self.angles_x = self.angles_z = 0;
 660
 661         InterpolateOrigin_Note();
 662 }
 663
 664 void Ent_Remove();
 665
 666 void Ent_RemovePlayerScore()
 667 {
 668         float i;
 669
 670         if(self.owner)
 671         {
 672                 SetTeam(self.owner, -1);
 673                 self.owner.gotscores = 0;
 674                 for(i = 0; i < MAX_SCORE; ++i)
 675                         self.owner.(scores[i]) = 0; // clear all scores
 676         }
 677 }
 678
 679 void Ent_ReadPlayerScore()
 680 {
 681         float i, n;
 682         float isNew;
 683         entity o;
 684
 685         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 686         // (no I've never heard of M-x replace-string, sed, or anything like that)
 687         isNew = !self.owner; // workaround for DP bug
 688         n = ReadByte()-1;
 689
 690 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 691         if(!isNew && n != self.sv_entnum)
 692         {
 693                 print("A CSQC entity changed its owner!\n");
 694                 isNew = true;
 695                 Ent_Remove();
 696                 self.enttype = ENT_CLIENT_SCORES;
 697         }
 698 #endif
 699
 700         self.sv_entnum = n;
 701
 702         if not(playerslots[self.sv_entnum])
 703                 playerslots[self.sv_entnum] = spawn();
 704         o = self.owner = playerslots[self.sv_entnum];
 705         o.sv_entnum = self.sv_entnum;
 706         o.gotscores = 1;
 707
 708         //if not(o.sort_prev)
 709         //      RegisterPlayer(o);
 710         //playerchecker will do this for us later, if it has not already done so
 711
 712         float sf, lf;
 713 #if MAX_SCORE <= 8
 714         sf = ReadByte();
 715         lf = ReadByte();
 716 #else
 717         sf = ReadShort();
 718         lf = ReadShort();
 719 #endif
 720         float p;
 721         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 722                 if(sf & p)
 723                 {
 724                         if(lf & p)
 725                                 o.(scores[i]) = ReadInt24_t();
 726                         else
 727                                 o.(scores[i]) = ReadChar();
 728                 }
 729
 730         if(o.sort_prev)
 731                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 732
 733         self.entremove = Ent_RemovePlayerScore;
 734 }
 735
 736 void Ent_ReadTeamScore()
 737 {
 738         float i;
 739         entity o;
 740
 741         self.team = ReadByte();
 742         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 743
 744         float sf, lf;
 745 #if MAX_TEAMSCORE <= 8
 746         sf = ReadByte();
 747         lf = ReadByte();
 748 #else
 749         sf = ReadShort();
 750         lf = ReadShort();
 751 #endif
 752         float p;
 753         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 754                 if(sf & p)
 755                 {
 756                         if(lf & p)
 757                                 o.(teamscores[i]) = ReadInt24_t();
 758                         else
 759                                 o.(teamscores[i]) = ReadChar();
 760                 }
 761
 762         HUD_UpdateTeamPos(o);
 763 }
 764
 765 void Net_Reset()
 766 {
 767 }
 768
 769 void Ent_ClientData()
 770 {
 771         float f;
 772         float newspectatee_status;
 773
 774         f = ReadByte();
 775
 776         scoreboard_showscores_force = (f & 1);
 777
 778         if(f & 2)
 779         {
 780                 newspectatee_status = ReadByte();
 781                 if(newspectatee_status == player_localentnum)
 782                         newspectatee_status = -1; // observing
 783         }
 784         else
 785                 newspectatee_status = 0;
 786
 787         spectatorbutton_zoom = (f & 4);
 788
 789         if(f & 8)
 790         {
 791                 angles_held_status = 1;
 792                 angles_held_x = ReadAngle();
 793                 angles_held_y = ReadAngle();
 794                 angles_held_z = 0;
 795         }
 796         else
 797                 angles_held_status = 0;
 798
 799         if(newspectatee_status != spectatee_status)
 800         {
 801                 float i;
 802                 // clear the weapon accuracy stats
 803                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 804                         weapon_hits[i] = 0;
 805                         weapon_fired[i] = 0;
 806                 }
 807
 808                 // clear race stuff
 809                 race_laptime = 0;
 810                 race_checkpointtime = 0;
 811         }
 812         spectatee_status = newspectatee_status;
 813 }
 814
 815 void Ent_Nagger()
 816 {
 817         float nags, i, j, b, f;
 818
 819         nags = ReadByte();
 820
 821         if(nags & 128)
 822         {
 823                 if(vote_called_vote)
 824                         strunzone(vote_called_vote);
 825                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 826         }
 827
 828         if(nags & 1)
 829         {
 830                 for(j = 0; j < maxclients; ++j)
 831                         if(playerslots[j])
 832                                 playerslots[j].ready = 1;
 833                 for(i = 1; i <= maxclients; i += 8)
 834                 {
 835                         f = ReadByte();
 836                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 837                                 if not(f & b)
 838                                         if(playerslots[j])
 839                                                 playerslots[j].ready = 0;
 840                 }
 841         }
 842
 843         ready_waiting = (nags & 1);
 844         ready_waiting_for_me = (nags & 2);
 845         vote_waiting = (nags & 4);
 846         vote_waiting_for_me = (nags & 8);
 847         warmup_stage = (nags & 16);
 848 }
 849
 850 void Ent_RandomSeed()
 851 {
 852         float s;
 853         prandom_debug();
 854         s = ReadShort();
 855         psrandom(s);
 856 }
 857
 858 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 859 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 860 void Ent_RadarLink();
 861 void Ent_Init();
 862 void Ent_ScoresInfo();
 863 void(float bIsNewEntity) CSQC_Ent_Update =
 864 {
 865         float t;
 866         float savetime;
 867         t = ReadByte();
 868
 869         // set up the "time" global for received entities to be correct for interpolation purposes
 870         savetime = time;
 871         if(servertime)
 872         {
 873                 time = servertime;
 874         }
 875         else
 876         {
 877                 serverprevtime = time;
 878                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 879                 time = serverprevtime + serverdeltatime;
 880         }
 881
 882 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 883         if(self.enttype)
 884                 if(t != self.enttype)
 885                 {
 886                         print("A CSQC entity changed its type!\n");
 887                         Ent_Remove();
 888                         bIsNewEntity = 1;
 889                 }
 890 #endif
 891         self.enttype = t;
 892         switch(t)
 893         {
 894                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 895                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 896                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 897                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 898                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 899                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 900                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 901                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 902                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 903                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 904                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 905                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 906                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 907                 case ENT_CLIENT_INIT: Ent_Init(); break;
 908                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 909                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 910                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 911                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 912                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 913                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 914                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 915                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 916                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 917                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 918                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 919                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 920                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 921                 default:
 922                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 923                         break;
 924         }
 925
 926         time = savetime;
 927 };
 928 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 929 // used when an entity changes its type. For an entity that someone interacts
 930 // with others, make sure it can no longer do so.
 931 void Ent_Remove()
 932 {
 933         if(self.entremove)
 934                 self.entremove();
 935
 936         self.enttype = 0;
 937         self.classname = "";
 938         self.draw = menu_sub_null;
 939         self.entremove = menu_sub_null;
 940         // TODO possibly set more stuff to defaults
 941 }
 942 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 943 void CSQC_Ent_Remove()
 944 {
 945         if(self.enttype)
 946                 Ent_Remove();
 947         remove(self);
 948 }
 949
 950 void Gamemode_Init()
 951 {
 952         if(gametype == GAME_ONSLAUGHT) {
 953                 print(strcat("Using ", minimapname, " as minimap.\n"));
 954                 precache_pic("gfx/ons-cp-neutral.tga");
 955                 precache_pic("gfx/ons-cp-red.tga");
 956                 precache_pic("gfx/ons-cp-blue.tga");
 957                 precache_pic("gfx/ons-frame.tga");
 958                 precache_pic("gfx/ons-frame-team.tga");
 959         }
 960
 961         if not(isdemo())
 962         {
 963                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
 964                 calledhooks |= HOOK_START;
 965         }
 966 }
 967 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 968 void CSQC_Parse_StuffCmd(string strMessage)
 969 {
 970         localcmd(strMessage);
 971 }
 972 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 973 void CSQC_Parse_Print(string strMessage)
 974 {
 975         print(ColorTranslateRGB(strMessage));
 976 }
 977
 978 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 979 void CSQC_Parse_CenterPrint(string strMessage)
 980 {
 981         centerprint(strMessage);
 982 }
 983
 984 string notranslate_fogcmd1 = "\nfog ";
 985 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 986 void Fog_Force()
 987 {
 988         // TODO somehow thwart prvm_globalset client ...
 989
 990         if(forcefog != "")
 991                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 992 }
 993
 994 void Gamemode_Init();
 995 void Ent_ScoresInfo()
 996 {
 997         float i;
 998         self.classname = "ent_client_scores_info";
 999         gametype = ReadByte();
1000         for(i = 0; i < MAX_SCORE; ++i)
1001         {
1002                 scores_label[i] = strzone(ReadString());
1003                 scores_flags[i] = ReadByte();
1004         }
1005         for(i = 0; i < MAX_TEAMSCORE; ++i)
1006         {
1007                 teamscores_label[i] = strzone(ReadString());
1008                 teamscores_flags[i] = ReadByte();
1009         }
1010         HUD_InitScores();
1011         Gamemode_Init();
1012 }
1013
1014 void Ent_Init()
1015 {
1016         self.classname = "ent_client_init";
1017
1018         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1019
1020         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1021         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1022         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1023         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1024         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1025         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1026         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1027         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1028         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1029         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1030         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1031         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1032
1033         if(forcefog)
1034                 strunzone(forcefog);
1035         forcefog = strzone(ReadString());
1036
1037         armorblockpercent = ReadByte() / 255.0;
1038
1039         g_weaponswitchdelay = ReadByte() / 255.0;
1040
1041         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1042         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1043
1044         nex_scope = !ReadByte();
1045         campingrifle_scope = !ReadByte();
1046
1047         if(!postinit)
1048                 PostInit();
1049 }
1050
1051 void Net_ReadRace()
1052 {
1053         float b;
1054
1055         b = ReadByte();
1056
1057         switch(b)
1058         {
1059                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1060                         race_checkpoint = ReadByte();
1061                         race_time = ReadInt24_t();
1062                         race_previousbesttime = ReadInt24_t();
1063                         if(race_previousbestname)
1064                                 strunzone(race_previousbestname);
1065                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1066
1067                         race_checkpointtime = time;
1068
1069                         if(race_checkpoint == 0 || race_checkpoint == 254)
1070                         {
1071                                 race_penaltyaccumulator = 0;
1072                                 race_laptime = time; // valid
1073                         }
1074
1075                         break;
1076
1077                 case RACE_NET_CHECKPOINT_CLEAR:
1078                         race_laptime = 0;
1079                         race_checkpointtime = 0;
1080                         break;
1081
1082                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1083                         race_laptime = ReadCoord();
1084                         race_checkpointtime = -99999;
1085                         // fall through
1086                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1087                         race_nextcheckpoint = ReadByte();
1088
1089                         race_nextbesttime = ReadInt24_t();
1090                         if(race_nextbestname)
1091                                 strunzone(race_nextbestname);
1092                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1093                         break;
1094
1095                 case RACE_NET_CHECKPOINT_HIT_RACE:
1096                         race_mycheckpoint = ReadByte();
1097                         race_mycheckpointtime = time;
1098                         race_mycheckpointdelta = ReadInt24_t();
1099                         race_mycheckpointlapsdelta = ReadByte();
1100                         if(race_mycheckpointlapsdelta >= 128)
1101                                 race_mycheckpointlapsdelta -= 256;
1102                         if(race_mycheckpointenemy)
1103                                 strunzone(race_mycheckpointenemy);
1104                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1105                         break;
1106
1107                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1108                         race_othercheckpoint = ReadByte();
1109                         race_othercheckpointtime = time;
1110                         race_othercheckpointdelta = ReadInt24_t();
1111                         race_othercheckpointlapsdelta = ReadByte();
1112                         if(race_othercheckpointlapsdelta >= 128)
1113                                 race_othercheckpointlapsdelta -= 256;
1114                         if(race_othercheckpointenemy)
1115                                 strunzone(race_othercheckpointenemy);
1116                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1117                         break;
1118
1119                 case RACE_NET_PENALTY_RACE:
1120                         race_penaltyeventtime = time;
1121                         race_penaltytime = ReadShort();
1122                         //race_penaltyaccumulator += race_penaltytime;
1123                         if(race_penaltyreason)
1124                                 strunzone(race_penaltyreason);
1125                         race_penaltyreason = strzone(ReadString());
1126                         break;
1127
1128                 case RACE_NET_PENALTY_QUALIFYING:
1129                         race_penaltyeventtime = time;
1130                         race_penaltytime = ReadShort();
1131                         race_penaltyaccumulator += race_penaltytime;
1132                         if(race_penaltyreason)
1133                                 strunzone(race_penaltyreason);
1134                         race_penaltyreason = strzone(ReadString());
1135                         break;
1136
1137                 case RACE_NET_SERVER_RECORD:
1138                         race_server_record = ReadInt24_t();
1139                         break;
1140                 case RACE_NET_SPEED_AWARD:
1141                         race_speedaward = ReadInt24_t();
1142                         if(race_speedaward_holder)
1143                                 strunzone(race_speedaward_holder);
1144                         race_speedaward_holder = strzone(ReadString());
1145                         break;
1146                 case RACE_NET_SPEED_AWARD_BEST:
1147                         race_speedaward_alltimebest = ReadInt24_t();
1148                         if(race_speedaward_alltimebest_holder)
1149                                 strunzone(race_speedaward_alltimebest_holder);
1150                         race_speedaward_alltimebest_holder = strzone(ReadString());
1151                         break;
1152                 case RACE_NET_SERVER_RANKINGS:
1153                         float pos, prevpos, del;
1154                         pos = ReadShort();
1155                         prevpos = ReadShort();
1156                         del = ReadShort();
1157
1158                         // move other rankings out of the way
1159                         float i;
1160                         if (prevpos) {
1161                                 for (i=prevpos-1;i>pos-1;--i) {
1162                                         grecordtime[i] = grecordtime[i-1];
1163                                         if(grecordholder[i])
1164                                                 strunzone(grecordholder[i]);
1165                                         grecordholder[i] = strzone(grecordholder[i-1]);
1166                                 }
1167                         } else if (del) { // a record has been deleted by the admin
1168                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1169                                         if (i == RANKINGS_CNT-1) { // clear out last record
1170                                                 grecordtime[i] = 0;
1171                                                 if (grecordholder[i])
1172                                                         strunzone(grecordholder[i]);
1173                                                 grecordholder[i] = string_null;
1174                                         }
1175                                         else {
1176                                                 grecordtime[i] = grecordtime[i+1];
1177                                                 if (grecordholder[i])
1178                                                         strunzone(grecordholder[i]);
1179                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1180                                         }
1181                                 }
1182                         } else { // player has no ranked record yet
1183                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1184                                         grecordtime[i] = grecordtime[i-1];
1185                                         if(grecordholder[i])
1186                                                 strunzone(grecordholder[i]);
1187                                         grecordholder[i] = strzone(grecordholder[i-1]);
1188                                 }
1189                         }
1190
1191                         // store new ranking
1192                         if(grecordholder[pos-1] != "")
1193                                 strunzone(grecordholder[pos-1]);
1194                         grecordholder[pos-1] = strzone(ReadString());
1195                         grecordtime[pos-1] = ReadInt24_t();
1196                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1197                                 race_myrank = pos;
1198                         break;
1199                 case RACE_NET_SERVER_STATUS:
1200                         race_status = ReadShort();
1201                         if(race_status_name)
1202                                 strunzone(race_status_name);
1203                         race_status_name = strzone(ReadString());
1204         }
1205 }
1206
1207 void Net_ReadSpawn()
1208 {
1209         zoomin_effect = 1;
1210         current_viewzoom = 0.6;
1211 }
1212
1213 void Net_TeamNagger()
1214 {
1215         teamnagger = 1;
1216 }
1217
1218 void Net_ReadPingPLReport()
1219 {
1220         float e, pi, pl, ml;
1221         e = ReadByte();
1222         pi = ReadShort();
1223         pl = ReadByte();
1224         ml = ReadByte();
1225         if not(playerslots[e])
1226                 return;
1227         playerslots[e].ping = pi;
1228         playerslots[e].ping_packetloss = pl / 255.0;
1229         playerslots[e].ping_movementloss = ml / 255.0;
1230 }
1231
1232 void Net_VoteDialog(float highlight) {
1233         if(highlight) {
1234                 vote_highlighted = ReadByte();
1235                 return;
1236         }
1237
1238         vote_yescount = ReadByte();
1239         vote_nocount = ReadByte();
1240         vote_needed = ReadByte();
1241         vote_active = 1;
1242 }
1243
1244 void Net_VoteDialogReset() {
1245         vote_active = 0;
1246 }
1247
1248 void Net_Notify() {
1249         float type;
1250         type = ReadByte();
1251
1252         if(type == CSQC_KILLNOTIFY)
1253         {
1254                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1255         }
1256         else if(type == CSQC_CENTERPRINT)
1257         {
1258                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1259         }
1260 }
1261
1262 void Net_WeaponComplain() {
1263         complain_weapon = ReadByte();
1264
1265         if(complain_weapon_name)
1266                 strunzone(complain_weapon_name);
1267         complain_weapon_name = strzone(ReadString());
1268
1269         complain_weapon_type = ReadByte();
1270
1271         complain_weapon_time = time;
1272         weapontime = time; // ping the weapon panel
1273 }
1274
1275 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1276 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1277 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1278 float CSQC_Parse_TempEntity()
1279 {
1280         local float bHandled;
1281                 bHandled  = true;
1282         // Acquire TE ID
1283         local float nTEID;
1284                 nTEID = ReadByte();
1285
1286                 // NOTE: Could just do return instead of break...
1287         switch(nTEID)
1288         {
1289                 case TE_CSQC_TARGET_MUSIC:
1290                         Net_TargetMusic();
1291                         bHandled = true;
1292                         break;
1293                 case TE_CSQC_PICTURE:
1294                         Net_MapVote_Picture();
1295                         bHandled = true;
1296                         break;
1297                 case TE_CSQC_RACE:
1298                         Net_ReadRace();
1299                         bHandled = true;
1300                         break;
1301                 case TE_CSQC_SPAWN:
1302                         Net_ReadSpawn();
1303                         bHandled = true;
1304                         break;
1305                 case TE_CSQC_ZCURVEPARTICLES:
1306                         Net_ReadZCurveParticles();
1307                         bHandled = true;
1308                         break;
1309                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1310                         Net_ReadNexgunBeamParticle();
1311                         bHandled = true;
1312                         break;
1313                 case TE_CSQC_TEAMNAGGER:
1314                         Net_TeamNagger();
1315                         bHandled = true;
1316                         break;
1317                 case TE_CSQC_VOTE:
1318                         Net_VoteDialog(ReadByte());
1319                         bHandled = true;
1320                         break;
1321                 case TE_CSQC_VOTERESET:
1322                         Net_VoteDialogReset();
1323                         bHandled = true;
1324                         break;
1325                 case TE_CSQC_LIGHTNINGARC:
1326                         Net_ReadLightningarc();
1327                         bHandled = true;
1328                         break;
1329                 case TE_CSQC_PINGPLREPORT:
1330                         Net_ReadPingPLReport();
1331                         bHandled = true;
1332                         break;
1333                 case TE_CSQC_ANNOUNCE:
1334                         announce_snd = strzone(ReadString());
1335                         bHandled = true;
1336                         break;
1337                 case TE_CSQC_NOTIFY:
1338                         Net_Notify();
1339                         bHandled = true;
1340                         break;
1341                 case TE_CSQC_WEAPONCOMPLAIN:
1342                         Net_WeaponComplain();
1343                         bHandled = true;
1344                         break;
1345                 case TE_CSQC_CR_MAXBULLETS:
1346                         cr_maxbullets = ReadByte();
1347                         bHandled = true;
1348                         break;
1349                 default:
1350                         // No special logic for this temporary entity; return 0 so the engine can handle it
1351                         bHandled = false;
1352                         break;
1353         }
1354
1355         return bHandled;
1356 }
1357
1358 string getcommandkey(string text, string command)
1359 {
1360         string keys;
1361         float n, j, k, l;
1362
1363         if (!hud_showbinds)
1364                 return text;
1365
1366         keys = db_get(binddb, command);
1367         if (!keys)
1368         {
1369                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1370                 for(j = 0; j < n; ++j)
1371                 {
1372                         k = stof(argv(j));
1373                         if(k != -1)
1374                         {
1375                                 if ("" == keys)
1376                                         keys = keynumtostring(k);
1377                                 else
1378                                         keys = strcat(keys, ", ", keynumtostring(k));
1379
1380                                 ++l;
1381                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1382                         }
1383
1384                 }
1385                 db_put(binddb, command, keys);
1386         }
1387
1388         if ("" == keys) {
1389                 if (hud_showbinds > 1)
1390                         return strcat(text, " (not bound)");
1391                 else
1392                         return text;
1393         }
1394         else if (hud_showbinds > 1)
1395                 return strcat(text, " (", keys, ")");
1396         else
1397                 return keys;
1398 }