qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         turrets_precache();
 143         if(autocvar_cl_announcer != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 148         }
 149         Tuba_Precache();
 150
 151         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 152         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 153
 154         get_mi_min_max_texcoords(1); // try the CLEVER way first
 155         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 156         shortmapname = mi_shortname;
 157
 158         if(precache_pic(minimapname) == "")
 159         {
 160                 // but maybe we have a non-clever minimap
 161                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 162                 if(precache_pic(minimapname) == "")
 163                         minimapname = ""; // FAIL
 164                 else
 165                         get_mi_min_max_texcoords(0); // load new texcoords
 166         }
 167
 168         mi_center = (mi_min + mi_max) * 0.5;
 169         mi_scale = mi_max - mi_min;
 170         minimapname = strzone(minimapname);
 171
 172         WarpZone_Init();
 173
 174         hud_configure_prev = -1;
 175         tab_panel = -1;
 176 }
 177
 178 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 179 void CSQC_Shutdown(void)
 180 {
 181 #ifdef USE_FTE
 182 #pragma TARGET id
 183         if(!__engine_check)
 184                 return 0;
 185 #pragma TARGET fte
 186 #endif
 187
 188         WarpZone_Shutdown();
 189
 190         remove(teams);
 191         remove(players);
 192         db_close(binddb);
 193         db_close(tempdb);
 194         if(autocvar_cl_db_saveasdump)
 195                 db_dump(ClientProgsDB, "client.db");
 196         else
 197                 db_save(ClientProgsDB, "client.db");
 198         db_close(ClientProgsDB);
 199
 200         cvar_clientsettemp_restore();
 201
 202         if(camera_active)
 203                 cvar_set("chase_active",ftos(chase_active_backup));
 204
 205         // unset the event chasecam's chase_active
 206         if(autocvar_chase_active < 0)
 207                 cvar_set("chase_active", "0");
 208
 209         if not(isdemo())
 210         {
 211                 if not(calledhooks & HOOK_START)
 212                         localcmd("\n_cl_hook_gamestart nop\n");
 213                 if not(calledhooks & HOOK_END)
 214                         localcmd("\ncl_hook_gameend\n");
 215         }
 216 }
 217
 218 .float has_team;
 219 float SetTeam(entity o, float Team)
 220 {
 221         entity tm;
 222         if(teamplay)
 223         {
 224                 switch(Team)
 225                 {
 226                         case -1:
 227                         case COLOR_TEAM1:
 228                         case COLOR_TEAM2:
 229                         case COLOR_TEAM3:
 230                         case COLOR_TEAM4:
 231                                 break;
 232                         default:
 233                                 if(GetTeam(Team, false) == NULL)
 234                                 {
 235                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 236                                         Team = COLOR_SPECTATOR;
 237                                 }
 238                                 break;
 239                 }
 240         }
 241         else
 242         {
 243                 switch(Team)
 244                 {
 245                         case -1:
 246                         case 0:
 247                                 break;
 248                         default:
 249                                 if(GetTeam(Team, false) == NULL)
 250                                 {
 251                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 252                                         Team = COLOR_SPECTATOR;
 253                                 }
 254                                 break;
 255                 }
 256         }
 257         if(Team == -1) // leave
 258         {
 259                 if(o.has_team)
 260                 {
 261                         tm = GetTeam(o.team, false);
 262                         tm.team_size -= 1;
 263                         o.has_team = 0;
 264                         return TRUE;
 265                 }
 266         }
 267         else
 268         {
 269                 if not(o.has_team)
 270                 {
 271                         o.team = Team;
 272                         tm = GetTeam(Team, true);
 273                         tm.team_size += 1;
 274                         o.has_team = 1;
 275                         return TRUE;
 276                 }
 277                 else if(Team != o.team)
 278                 {
 279                         tm = GetTeam(o.team, false);
 280                         tm.team_size -= 1;
 281                         o.team = Team;
 282                         tm = GetTeam(Team, true);
 283                         tm.team_size += 1;
 284                         return TRUE;
 285                 }
 286         }
 287         return FALSE;
 288 }
 289
 290 void Playerchecker_Think()
 291 {
 292         float i;
 293         entity e;
 294         for(i = 0; i < maxclients; ++i)
 295         {
 296                 e = playerslots[i];
 297                 if(GetPlayerName(i) == "")
 298                 {
 299                         if(e.sort_prev)
 300                         {
 301                                 // player disconnected
 302                                 SetTeam(e, -1);
 303                                 RemovePlayer(e);
 304                                 e.sort_prev = world;
 305                                 //e.gotscores = 0;
 306                         }
 307                 }
 308                 else
 309                 {
 310                         if not(e.sort_prev)
 311                         {
 312                                 // player connected
 313                                 if not(e)
 314                                         playerslots[i] = e = spawn();
 315                                 e.sv_entnum = i;
 316                                 e.ping = 0;
 317                                 e.ping_packetloss = 0;
 318                                 e.ping_movementloss = 0;
 319                                 //e.gotscores = 0; // we might already have the scores...
 320                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 321                                 RegisterPlayer(e);
 322                                 HUD_UpdatePlayerPos(e);
 323                         }
 324                 }
 325         }
 326         self.nextthink = time + 0.2;
 327 }
 328
 329 void Porto_Init();
 330 void TrueAim_Init();
 331 void PostInit(void)
 332 {
 333         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 334
 335         entity playerchecker;
 336         playerchecker = spawn();
 337         playerchecker.think = Playerchecker_Think;
 338         playerchecker.nextthink = time + 0.2;
 339
 340         Porto_Init();
 341         TrueAim_Init();
 342
 343         postinit = true;
 344 }
 345
 346 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 347 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 348 float button_zoom;
 349 void Cmd_HUD_SetFields(float);
 350 void Cmd_HUD_Help(float);
 351 float CSQC_ConsoleCommand(string strMessage)
 352 {
 353         float argc;
 354         // Tokenize String
 355         //argc = tokenize(strMessage);
 356         argc = tokenize_console(strMessage);
 357
 358         // Acquire Command
 359         local string strCmd;
 360         strCmd = argv(0);
 361
 362         if(strCmd == "hud_configure") { // config hud
 363                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 364                 return true;
 365         } else if(strCmd == "hud_save") { // save hud config
 366                 if(argv(1) == "" || argv(2)) {
 367                         print(_("Usage:\n"));
 368                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 369                 }
 370                 else
 371                         HUD_Panel_ExportCfg(argv(1));
 372                 return true;
 373         } else if(strCmd == "+showscores") {
 374                 scoreboard_showscores = true;
 375                 return true;
 376         } else if(strCmd == "-showscores") {
 377                 scoreboard_showscores = false;
 378                 return true;
 379         } else if(strCmd == "+showaccuracy") {
 380                 scoreboard_showaccuracy = true;
 381                 return true;
 382         } else if(strCmd == "-showaccuracy") {
 383                 scoreboard_showaccuracy = false;
 384                 return true;
 385         }
 386
 387         if(camera_active)
 388         if(strCmd == "+forward" || strCmd == "-back") {
 389                 ++camera_direction_x;
 390                 return true;
 391         } else if(strCmd == "-forward" || strCmd == "+back") {
 392                 --camera_direction_x;
 393                 return true;
 394         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 395                 --camera_direction_y;
 396                 return true;
 397         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 398                 ++camera_direction_y;
 399                 return true;
 400         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 401                 ++camera_direction_z;
 402                 return true;
 403         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 404                 --camera_direction_z;
 405                 return true;
 406         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 407                 ++camera_roll;
 408                 return true;
 409         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 410                 --camera_roll;
 411                 return true;
 412         }
 413
 414         return false;
 415 }
 416
 417 .vector view_ofs;
 418 entity debug_shotorg;
 419 void ShotOrg_Draw()
 420 {
 421         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 422         self.angles = view_angles;
 423         self.angles_x = -self.angles_x;
 424         if not(self.cnt)
 425                 self.drawmask = MASK_NORMAL;
 426         else
 427                 self.drawmask = 0;
 428 }
 429 void ShotOrg_Draw2D()
 430 {
 431         vector coord2d_topleft, coord2d_topright, coord2d;
 432         string s;
 433         vector fs;
 434
 435         s = vtos(self.view_ofs);
 436         s = substring(s, 1, strlen(s) - 2);
 437         if(tokenize_console(s) == 3)
 438                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 439
 440         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 441         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 442
 443         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 444
 445         coord2d = coord2d_topleft;
 446         if(fs_x < 8)
 447         {
 448                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 449                 fs = '8 8 0';
 450         }
 451         coord2d_y -= fs_y;
 452         coord2d_z = 0;
 453         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 454 }
 455
 456 void ShotOrg_Spawn()
 457 {
 458         debug_shotorg = spawn();
 459         debug_shotorg.draw = ShotOrg_Draw;
 460         debug_shotorg.draw2d = ShotOrg_Draw2D;
 461         debug_shotorg.renderflags = RF_VIEWMODEL;
 462         debug_shotorg.effects = EF_FULLBRIGHT;
 463         precache_model("models/shotorg_adjuster.md3");
 464         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 465         debug_shotorg.scale = 2;
 466         debug_shotorg.view_ofs = '25 8 -8';
 467 }
 468
 469 void DrawDebugModel()
 470 {
 471         if(time - floor(time) > 0.5)
 472         {
 473                 PolyDrawModel(self);
 474                 self.drawmask = 0;
 475         }
 476         else
 477         {
 478                 self.renderflags = 0;
 479                 self.drawmask = MASK_NORMAL;
 480         }
 481 }
 482
 483 void GameCommand(string msg)
 484 {
 485         string s;
 486         float argc;
 487         entity e;
 488         argc = tokenize_console(msg);
 489
 490         if(argv(0) == "help" || argc == 0)
 491         {
 492                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 493                 print(_("  settemp cvar value\n"));
 494                 print(_("  scoreboard_columns_set ...\n"));
 495                 print(_("  scoreboard_columns_help\n"));
 496                 GameCommand_Generic("help");
 497                 return;
 498         }
 499
 500         if(GameCommand_Generic(msg))
 501                 return;
 502
 503         string cmd;
 504         cmd = argv(0);
 505         if(cmd == "mv_download") {
 506                 Cmd_MapVote_MapDownload(argc);
 507         }
 508         else if(cmd == "settemp") {
 509                 cvar_clientsettemp(argv(1), argv(2));
 510         }
 511         else if(cmd == "scoreboard_columns_set") {
 512                 Cmd_HUD_SetFields(argc);
 513         }
 514         else if(cmd == "scoreboard_columns_help") {
 515                 Cmd_HUD_Help(argc);
 516         }
 517 #ifdef BLURTEST
 518         else if(cmd == "blurtest") {
 519                 blurtest_time0 = time;
 520                 blurtest_time1 = time + stof(argv(1));
 521                 blurtest_radius = stof(argv(2));
 522                 blurtest_power = stof(argv(3));
 523         }
 524 #endif
 525         else if(cmd == "shotorg_move") {
 526                 if(!debug_shotorg)
 527                         ShotOrg_Spawn();
 528                 else
 529                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 530                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 531         }
 532         else if(cmd == "shotorg_movez") {
 533                 if(!debug_shotorg)
 534                         ShotOrg_Spawn();
 535                 else
 536                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 537                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 538         }
 539         else if(cmd == "shotorg_set") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = stov(argv(1));
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_setz") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_toggle_hide") {
 554                 if(debug_shotorg)
 555                 {
 556                         debug_shotorg.cnt = !debug_shotorg.cnt;
 557                 }
 558         }
 559         else if(cmd == "shotorg_end") {
 560                 if(debug_shotorg)
 561                 {
 562                         print(vtos(debug_shotorg.view_ofs), "\n");
 563                         remove(debug_shotorg);
 564                         debug_shotorg = world;
 565                 }
 566                 localcmd("sv_cmd debug_shotorg\n");
 567         }
 568         else if(cmd == "sendcvar") {
 569                 // W_FixWeaponOrder will trash argv, so save what we need.
 570                 string thiscvar;
 571                 thiscvar = strzone(argv(1));
 572                 s = cvar_string(thiscvar);
 573                 if(thiscvar == "cl_weaponpriority")
 574                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 575                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 576                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 577                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 578                 strunzone(thiscvar);
 579         }
 580         else if(cmd == "spawn") {
 581                 s = argv(1);
 582                 e = spawn();
 583                 precache_model(s);
 584                 setmodel(e, s);
 585                 setorigin(e, view_origin);
 586                 e.angles = view_angles;
 587                 e.draw = DrawDebugModel;
 588                 e.classname = "debugmodel";
 589         }
 590     else if(cmd == "vyes")
 591     {
 592         if(uid2name_dialog)
 593         {
 594             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 595             vote_prev = 0;
 596             cvar_set("cl_allow_uid2name", "1");
 597             vote_change = -9999;
 598                         uid2name_dialog = 0;
 599         }
 600         else
 601         {
 602             localcmd("cmd vote yes\n");
 603         }
 604     }
 605     else if(cmd == "vno")
 606     {
 607         if(uid2name_dialog)
 608         {
 609             vote_active = 0;
 610             vote_prev = 0;
 611             cvar_set("cl_allow_uid2name", "0");
 612             vote_change = -9999;
 613                         uid2name_dialog = 0;
 614         }
 615         else
 616         {
 617             localcmd("cmd vote no\n");
 618         }
 619     }
 620
 621         else
 622         {
 623                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 624         }
 625
 626         return;
 627 }
 628
 629 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 630 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 631 // All keys are in ascii.
 632 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 633 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 634 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 635 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 636 {
 637         local float bSkipKey;
 638         bSkipKey = false;
 639
 640         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 641                 return true;
 642
 643         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 644                 return true;
 645
 646         if(menu_visible)
 647                 if(menu_action(bInputType, nPrimary, nSecondary))
 648                         return TRUE;
 649
 650         return bSkipKey;
 651 }
 652
 653 // END REQUIRED CSQC FUNCTIONS
 654 // --------------------------------------------------------------------------
 655
 656 // --------------------------------------------------------------------------
 657 // BEGIN OPTIONAL CSQC FUNCTIONS
 658 void Ent_RemoveEntCS()
 659 {
 660         entcs_receiver[self.sv_entnum] = world;
 661 }
 662 void Ent_ReadEntCS()
 663 {
 664         float sf;
 665         InterpolateOrigin_Undo();
 666
 667         self.classname = "entcs_receiver";
 668         sf = ReadByte();
 669
 670         if(sf & 1)
 671                 self.sv_entnum = ReadByte();
 672         if(sf & 2)
 673         {
 674                 self.origin_x = ReadShort();
 675                 self.origin_y = ReadShort();
 676                 self.origin_z = ReadShort();
 677         }
 678         if(sf & 4)
 679         {
 680                 self.angles_y = ReadByte() * 360.0 / 256;
 681                 self.angles_x = self.angles_z = 0;
 682         }
 683         if(sf & 8)
 684                 self.healthvalue = ReadByte() * 10;
 685         if(sf & 16)
 686                 self.armorvalue = ReadByte() * 10;
 687
 688         entcs_receiver[self.sv_entnum] = self;
 689         self.entremove = Ent_RemoveEntCS;
 690
 691         InterpolateOrigin_Note();
 692 }
 693
 694 void Ent_Remove();
 695
 696 void Ent_RemovePlayerScore()
 697 {
 698         float i;
 699
 700         if(self.owner)
 701         {
 702                 SetTeam(self.owner, -1);
 703                 self.owner.gotscores = 0;
 704                 for(i = 0; i < MAX_SCORE; ++i)
 705                         self.owner.(scores[i]) = 0; // clear all scores
 706         }
 707 }
 708
 709 void Ent_ReadPlayerScore()
 710 {
 711         float i, n;
 712         float isNew;
 713         entity o;
 714
 715         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 716         // (no I've never heard of M-x replace-string, sed, or anything like that)
 717         isNew = !self.owner; // workaround for DP bug
 718         n = ReadByte()-1;
 719
 720 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 721         if(!isNew && n != self.sv_entnum)
 722         {
 723                 //print(_("A CSQC entity changed its owner!\n"));
 724                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 725                 isNew = true;
 726                 Ent_Remove();
 727                 self.enttype = ENT_CLIENT_SCORES;
 728         }
 729 #endif
 730
 731         self.sv_entnum = n;
 732
 733         if not(playerslots[self.sv_entnum])
 734                 playerslots[self.sv_entnum] = spawn();
 735         o = self.owner = playerslots[self.sv_entnum];
 736         o.sv_entnum = self.sv_entnum;
 737         o.gotscores = 1;
 738
 739         //if not(o.sort_prev)
 740         //      RegisterPlayer(o);
 741         //playerchecker will do this for us later, if it has not already done so
 742
 743         float sf, lf;
 744 #if MAX_SCORE <= 8
 745         sf = ReadByte();
 746         lf = ReadByte();
 747 #else
 748         sf = ReadShort();
 749         lf = ReadShort();
 750 #endif
 751         float p;
 752         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 753                 if(sf & p)
 754                 {
 755                         if(lf & p)
 756                                 o.(scores[i]) = ReadInt24_t();
 757                         else
 758                                 o.(scores[i]) = ReadChar();
 759                 }
 760
 761         if(o.sort_prev)
 762                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 763
 764         self.entremove = Ent_RemovePlayerScore;
 765 }
 766
 767 void Ent_ReadTeamScore()
 768 {
 769         float i;
 770         entity o;
 771
 772         self.team = ReadByte();
 773         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 774
 775         float sf, lf;
 776 #if MAX_TEAMSCORE <= 8
 777         sf = ReadByte();
 778         lf = ReadByte();
 779 #else
 780         sf = ReadShort();
 781         lf = ReadShort();
 782 #endif
 783         float p;
 784         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 785                 if(sf & p)
 786                 {
 787                         if(lf & p)
 788                                 o.(teamscores[i]) = ReadInt24_t();
 789                         else
 790                                 o.(teamscores[i]) = ReadChar();
 791                 }
 792
 793         HUD_UpdateTeamPos(o);
 794 }
 795
 796 void Ent_ClientData()
 797 {
 798         float f;
 799         float newspectatee_status;
 800
 801         f = ReadByte();
 802
 803         scoreboard_showscores_force = (f & 1);
 804
 805         if(f & 2)
 806         {
 807                 newspectatee_status = ReadByte();
 808                 if(newspectatee_status == player_localentnum)
 809                         newspectatee_status = -1; // observing
 810         }
 811         else
 812                 newspectatee_status = 0;
 813
 814         spectatorbutton_zoom = (f & 4);
 815
 816         if(f & 8)
 817         {
 818                 angles_held_status = 1;
 819                 angles_held_x = ReadAngle();
 820                 angles_held_y = ReadAngle();
 821                 angles_held_z = 0;
 822         }
 823         else
 824                 angles_held_status = 0;
 825
 826         if(newspectatee_status != spectatee_status)
 827         {
 828                 float i;
 829
 830                 // clear race stuff
 831                 race_laptime = 0;
 832                 race_checkpointtime = 0;
 833         }
 834         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 835         {
 836                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 837                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 838                 )
 839                         prev_p_health = -1;
 840                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 841                         prev_health = -1;
 842         }
 843         spectatee_status = newspectatee_status;
 844 }
 845
 846 void Ent_Nagger()
 847 {
 848         float nags, i, j, b, f;
 849
 850         nags = ReadByte();
 851
 852         if(!(nags & 4))
 853         {
 854                 if(vote_called_vote)
 855                         strunzone(vote_called_vote);
 856                 vote_called_vote = string_null;
 857         }
 858
 859         if(nags & 128)
 860         {
 861                 if(vote_called_vote)
 862                         strunzone(vote_called_vote);
 863                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 864         }
 865
 866         if(nags & 1)
 867         {
 868                 for(j = 0; j < maxclients; ++j)
 869                         if(playerslots[j])
 870                                 playerslots[j].ready = 1;
 871                 for(i = 1; i <= maxclients; i += 8)
 872                 {
 873                         f = ReadByte();
 874                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 875                                 if not(f & b)
 876                                         if(playerslots[j])
 877                                                 playerslots[j].ready = 0;
 878                 }
 879         }
 880
 881         ready_waiting = (nags & 1);
 882         ready_waiting_for_me = (nags & 2);
 883         vote_waiting = (nags & 4);
 884         vote_waiting_for_me = (nags & 8);
 885         warmup_stage = (nags & 16);
 886 }
 887
 888 void Ent_RandomSeed()
 889 {
 890         float s;
 891         prandom_debug();
 892         s = ReadShort();
 893         psrandom(s);
 894 }
 895
 896 void Ent_ReadAccuracy(void)
 897 {
 898         float sf, f, w, b;
 899         sf = ReadInt24_t();
 900         if(sf == 0)
 901         {
 902                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 903                         weapon_accuracy[w] = -1;
 904                 return;
 905         }
 906
 907         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 908         {
 909                 if(sf & f)
 910                 {
 911                         b = ReadByte();
 912                         if(b == 0)
 913                                 weapon_accuracy[w] = -1;
 914                         else if(b == 255)
 915                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 916                         else
 917                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 918                 }
 919         }
 920 }
 921
 922 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 923 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 924 void Ent_RadarLink();
 925 void Ent_Init();
 926 void Ent_ScoresInfo();
 927 void(float bIsNewEntity) CSQC_Ent_Update =
 928 {
 929         float t;
 930         float savetime;
 931         t = ReadByte();
 932
 933         // set up the "time" global for received entities to be correct for interpolation purposes
 934         savetime = time;
 935         if(servertime)
 936         {
 937                 time = servertime;
 938         }
 939         else
 940         {
 941                 serverprevtime = time;
 942                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 943                 time = serverprevtime + serverdeltatime;
 944         }
 945
 946 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 947         if(self.enttype)
 948                 if(t != self.enttype)
 949                 {
 950                         //print(_("A CSQC entity changed its type!\n"));
 951                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 952                         Ent_Remove();
 953                         bIsNewEntity = 1;
 954                 }
 955 #endif
 956         self.enttype = t;
 957         switch(t)
 958         {
 959                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 960                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 961                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 962                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 963                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 964                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 965                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 966                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 967                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 968                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 969                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 970                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 971                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 972                 case ENT_CLIENT_INIT: Ent_Init(); break;
 973                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 974                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 975                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 976                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 977                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 978                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 979                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 980                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 981                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 982                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 983                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 984                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 985                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 986                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 987                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 988                 case ENT_CLIENT_TURRET: ent_turret(); break;
 989                 default:
 990                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 991                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 992                         break;
 993         }
 994
 995         time = savetime;
 996 };
 997 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 998 // used when an entity changes its type. For an entity that someone interacts
 999 // with others, make sure it can no longer do so.
1000 void Ent_Remove()
1001 {
1002         if(self.entremove)
1003                 self.entremove();
1004
1005         self.enttype = 0;
1006         self.classname = "";
1007         self.draw = menu_sub_null;
1008         self.entremove = menu_sub_null;
1009         // TODO possibly set more stuff to defaults
1010 }
1011 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1012 void CSQC_Ent_Remove()
1013 {
1014         if(self.enttype)
1015                 Ent_Remove();
1016         remove(self);
1017 }
1018
1019 void Gamemode_Init()
1020 {
1021         if not(isdemo())
1022         {
1023                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1024                 calledhooks |= HOOK_START;
1025         }
1026 }
1027 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1028 void CSQC_Parse_StuffCmd(string strMessage)
1029 {
1030         localcmd(strMessage);
1031 }
1032 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1033 void CSQC_Parse_Print(string strMessage)
1034 {
1035         print(ColorTranslateRGB(strMessage));
1036 }
1037
1038 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1039 void CSQC_Parse_CenterPrint(string strMessage)
1040 {
1041         centerprint(strMessage);
1042 }
1043
1044 string notranslate_fogcmd1 = "\nfog ";
1045 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1046 void Fog_Force()
1047 {
1048         // TODO somehow thwart prvm_globalset client ...
1049
1050         if(forcefog != "")
1051                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1052 }
1053
1054 void Gamemode_Init();
1055 void Ent_ScoresInfo()
1056 {
1057         float i;
1058         self.classname = "ent_client_scores_info";
1059         gametype = ReadByte();
1060         for(i = 0; i < MAX_SCORE; ++i)
1061         {
1062                 scores_label[i] = strzone(ReadString());
1063                 scores_flags[i] = ReadByte();
1064         }
1065         for(i = 0; i < MAX_TEAMSCORE; ++i)
1066         {
1067                 teamscores_label[i] = strzone(ReadString());
1068                 teamscores_flags[i] = ReadByte();
1069         }
1070         HUD_InitScores();
1071         Gamemode_Init();
1072 }
1073
1074 void Ent_Init()
1075 {
1076         self.classname = "ent_client_init";
1077
1078         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1079
1080         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1081         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1082         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1083         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1084         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1085         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1086         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1087         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1088         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1089         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1090         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1091         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1092
1093         if(forcefog)
1094                 strunzone(forcefog);
1095         forcefog = strzone(ReadString());
1096
1097         armorblockpercent = ReadByte() / 255.0;
1098
1099         g_weaponswitchdelay = ReadByte() / 255.0;
1100
1101         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1102         g_balance_grenadelauncher_bouncestop = ReadCoord();
1103         g_balance_electro_secondary_bouncefactor = ReadCoord();
1104         g_balance_electro_secondary_bouncestop = ReadCoord();
1105
1106         nex_scope = !ReadByte();
1107         rifle_scope = !ReadByte();
1108
1109         serverflags = ReadByte();
1110
1111         minelayer_maxmines = ReadByte();
1112
1113         hagar_maxrockets = ReadByte();
1114
1115         g_trueaim_minrange = ReadCoord();
1116
1117         if(!postinit)
1118                 PostInit();
1119 }
1120
1121 void Net_ReadRace()
1122 {
1123         float b;
1124
1125         b = ReadByte();
1126
1127         switch(b)
1128         {
1129                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1130                         race_checkpoint = ReadByte();
1131                         race_time = ReadInt24_t();
1132                         race_previousbesttime = ReadInt24_t();
1133                         if(race_previousbestname)
1134                                 strunzone(race_previousbestname);
1135                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1136
1137                         race_checkpointtime = time;
1138
1139                         if(race_checkpoint == 0 || race_checkpoint == 254)
1140                         {
1141                                 race_penaltyaccumulator = 0;
1142                                 race_laptime = time; // valid
1143                         }
1144
1145                         break;
1146
1147                 case RACE_NET_CHECKPOINT_CLEAR:
1148                         race_laptime = 0;
1149                         race_checkpointtime = 0;
1150                         break;
1151
1152                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1153                         race_laptime = ReadCoord();
1154                         race_checkpointtime = -99999;
1155                         // fall through
1156                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1157                         race_nextcheckpoint = ReadByte();
1158
1159                         race_nextbesttime = ReadInt24_t();
1160                         if(race_nextbestname)
1161                                 strunzone(race_nextbestname);
1162                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1163                         break;
1164
1165                 case RACE_NET_CHECKPOINT_HIT_RACE:
1166                         race_mycheckpoint = ReadByte();
1167                         race_mycheckpointtime = time;
1168                         race_mycheckpointdelta = ReadInt24_t();
1169                         race_mycheckpointlapsdelta = ReadByte();
1170                         if(race_mycheckpointlapsdelta >= 128)
1171                                 race_mycheckpointlapsdelta -= 256;
1172                         if(race_mycheckpointenemy)
1173                                 strunzone(race_mycheckpointenemy);
1174                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1175                         break;
1176
1177                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1178                         race_othercheckpoint = ReadByte();
1179                         race_othercheckpointtime = time;
1180                         race_othercheckpointdelta = ReadInt24_t();
1181                         race_othercheckpointlapsdelta = ReadByte();
1182                         if(race_othercheckpointlapsdelta >= 128)
1183                                 race_othercheckpointlapsdelta -= 256;
1184                         if(race_othercheckpointenemy)
1185                                 strunzone(race_othercheckpointenemy);
1186                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1187                         break;
1188
1189                 case RACE_NET_PENALTY_RACE:
1190                         race_penaltyeventtime = time;
1191                         race_penaltytime = ReadShort();
1192                         //race_penaltyaccumulator += race_penaltytime;
1193                         if(race_penaltyreason)
1194                                 strunzone(race_penaltyreason);
1195                         race_penaltyreason = strzone(ReadString());
1196                         break;
1197
1198                 case RACE_NET_PENALTY_QUALIFYING:
1199                         race_penaltyeventtime = time;
1200                         race_penaltytime = ReadShort();
1201                         race_penaltyaccumulator += race_penaltytime;
1202                         if(race_penaltyreason)
1203                                 strunzone(race_penaltyreason);
1204                         race_penaltyreason = strzone(ReadString());
1205                         break;
1206
1207                 case RACE_NET_SERVER_RECORD:
1208                         race_server_record = ReadInt24_t();
1209                         break;
1210                 case RACE_NET_SPEED_AWARD:
1211                         race_speedaward = ReadInt24_t();
1212                         if(race_speedaward_holder)
1213                                 strunzone(race_speedaward_holder);
1214                         race_speedaward_holder = strzone(ReadString());
1215                         break;
1216                 case RACE_NET_SPEED_AWARD_BEST:
1217                         race_speedaward_alltimebest = ReadInt24_t();
1218                         if(race_speedaward_alltimebest_holder)
1219                                 strunzone(race_speedaward_alltimebest_holder);
1220                         race_speedaward_alltimebest_holder = strzone(ReadString());
1221                         break;
1222                 case RACE_NET_SERVER_RANKINGS:
1223                         float pos, prevpos, del;
1224                         pos = ReadShort();
1225                         prevpos = ReadShort();
1226                         del = ReadShort();
1227
1228                         // move other rankings out of the way
1229                         float i;
1230                         if (prevpos) {
1231                                 for (i=prevpos-1;i>pos-1;--i) {
1232                                         grecordtime[i] = grecordtime[i-1];
1233                                         if(grecordholder[i])
1234                                                 strunzone(grecordholder[i]);
1235                                         grecordholder[i] = strzone(grecordholder[i-1]);
1236                                 }
1237                         } else if (del) { // a record has been deleted by the admin
1238                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1239                                         if (i == RANKINGS_CNT-1) { // clear out last record
1240                                                 grecordtime[i] = 0;
1241                                                 if (grecordholder[i])
1242                                                         strunzone(grecordholder[i]);
1243                                                 grecordholder[i] = string_null;
1244                                         }
1245                                         else {
1246                                                 grecordtime[i] = grecordtime[i+1];
1247                                                 if (grecordholder[i])
1248                                                         strunzone(grecordholder[i]);
1249                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1250                                         }
1251                                 }
1252                         } else { // player has no ranked record yet
1253                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1254                                         grecordtime[i] = grecordtime[i-1];
1255                                         if(grecordholder[i])
1256                                                 strunzone(grecordholder[i]);
1257                                         grecordholder[i] = strzone(grecordholder[i-1]);
1258                                 }
1259                         }
1260
1261                         // store new ranking
1262                         if(grecordholder[pos-1] != "")
1263                                 strunzone(grecordholder[pos-1]);
1264                         grecordholder[pos-1] = strzone(ReadString());
1265                         grecordtime[pos-1] = ReadInt24_t();
1266                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1267                                 race_myrank = pos;
1268                         break;
1269                 case RACE_NET_SERVER_STATUS:
1270                         race_status = ReadShort();
1271                         if(race_status_name)
1272                                 strunzone(race_status_name);
1273                         race_status_name = strzone(ReadString());
1274         }
1275 }
1276
1277 void Net_ReadSpawn()
1278 {
1279         zoomin_effect = 1;
1280         current_viewzoom = 0.6;
1281 }
1282
1283 void Net_TeamNagger()
1284 {
1285         teamnagger = 1;
1286 }
1287
1288 void Net_ReadPingPLReport()
1289 {
1290         float e, pi, pl, ml;
1291         e = ReadByte();
1292         pi = ReadShort();
1293         pl = ReadByte();
1294         ml = ReadByte();
1295         if not(playerslots[e])
1296                 return;
1297         playerslots[e].ping = pi;
1298         playerslots[e].ping_packetloss = pl / 255.0;
1299         playerslots[e].ping_movementloss = ml / 255.0;
1300 }
1301
1302 void Net_VoteDialog(float highlight) {
1303         if(highlight) {
1304                 vote_highlighted = ReadByte();
1305                 return;
1306         }
1307
1308         vote_yescount = ReadByte();
1309         vote_nocount = ReadByte();
1310         vote_needed = ReadByte();
1311         vote_active = 1;
1312 }
1313
1314 void Net_VoteDialogReset() {
1315         vote_active = 0;
1316 }
1317
1318 void Net_Notify() {
1319         float type;
1320         type = ReadByte();
1321
1322         if(type == CSQC_KILLNOTIFY)
1323         {
1324                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1325         }
1326         else if(type == CSQC_CENTERPRINT)
1327         {
1328                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1329         }
1330 }
1331
1332 void Net_WeaponComplain() {
1333         complain_weapon = ReadByte();
1334
1335         if(complain_weapon_name)
1336                 strunzone(complain_weapon_name);
1337         complain_weapon_name = strzone(ReadString());
1338
1339         complain_weapon_type = ReadByte();
1340
1341         complain_weapon_time = time;
1342         weapontime = time; // ping the weapon panel
1343 }
1344
1345 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1346 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1347 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1348 float CSQC_Parse_TempEntity()
1349 {
1350         local float bHandled;
1351                 bHandled  = true;
1352         // Acquire TE ID
1353         local float nTEID;
1354                 nTEID = ReadByte();
1355
1356                 // NOTE: Could just do return instead of break...
1357         switch(nTEID)
1358         {
1359                 case TE_CSQC_TARGET_MUSIC:
1360                         Net_TargetMusic();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_PICTURE:
1364                         Net_MapVote_Picture();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_RACE:
1368                         Net_ReadRace();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_SPAWN:
1372                         Net_ReadSpawn();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_ZCURVEPARTICLES:
1376                         Net_ReadZCurveParticles();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1380                         Net_ReadNexgunBeamParticle();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_TEAMNAGGER:
1384                         Net_TeamNagger();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_VOTE:
1388                         Net_VoteDialog(ReadByte());
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_VOTERESET:
1392                         Net_VoteDialogReset();
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_LIGHTNINGARC:
1396                         Net_ReadLightningarc();
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_PINGPLREPORT:
1400                         Net_ReadPingPLReport();
1401                         bHandled = true;
1402                         break;
1403                 case TE_CSQC_ANNOUNCE:
1404                         announce_snd = strzone(ReadString());
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_NOTIFY:
1408                         Net_Notify();
1409                         bHandled = true;
1410                         break;
1411                 case TE_CSQC_WEAPONCOMPLAIN:
1412                         Net_WeaponComplain();
1413                         bHandled = true;
1414                         break;
1415                 default:
1416                         // No special logic for this temporary entity; return 0 so the engine can handle it
1417                         bHandled = false;
1418                         break;
1419         }
1420
1421         return bHandled;
1422 }
1423
1424 string getcommandkey(string text, string command)
1425 {
1426         string keys;
1427         float n, j, k, l;
1428
1429         if (!autocvar_hud_showbinds)
1430                 return text;
1431
1432         keys = db_get(binddb, command);
1433         if (!keys)
1434         {
1435                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1436                 for(j = 0; j < n; ++j)
1437                 {
1438                         k = stof(argv(j));
1439                         if(k != -1)
1440                         {
1441                                 if ("" == keys)
1442                                         keys = keynumtostring(k);
1443                                 else
1444                                         keys = strcat(keys, ", ", keynumtostring(k));
1445
1446                                 ++l;
1447                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1448                         }
1449
1450                 }
1451                 db_put(binddb, command, keys);
1452         }
1453
1454         if ("" == keys) {
1455                 if (autocvar_hud_showbinds > 1)
1456                         return sprintf(_("%s (not bound)"), text);
1457                 else
1458                         return text;
1459         }
1460         else if (autocvar_hud_showbinds > 1)
1461                 return sprintf(_("%s (%s)"), text, keys);
1462         else
1463                 return keys;
1464 }