qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = menu_sub_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(COLOR_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164         if (autocvar_cl_precacheplayermodels)
 165         {
 166                 precache_all_playermodels("models/player/*.zym");
 167                 precache_all_playermodels("models/player/*.dpm");
 168                 precache_all_playermodels("models/player/*.md3");
 169                 precache_all_playermodels("models/player/*.psk");
 170                 precache_all_playermodels("models/player/*.iqm");
 171         }
 172
 173         Projectile_Precache();
 174         Hook_Precache();
 175         GibSplash_Precache();
 176         Casings_Precache();
 177         DamageInfo_Precache();
 178         Vehicles_Precache();
 179         turrets_precache();
 180     Announcer_Precache();
 181         Tuba_Precache();
 182
 183         if(autocvar_cl_reticle)
 184         {
 185                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 186                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 187         }
 188
 189         get_mi_min_max_texcoords(1); // try the CLEVER way first
 190         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 191         shortmapname = mi_shortname;
 192
 193         if(precache_pic(minimapname) == "")
 194         {
 195                 // but maybe we have a non-clever minimap
 196                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 197                 if(precache_pic(minimapname) == "")
 198                         minimapname = ""; // FAIL
 199                 else
 200                         get_mi_min_max_texcoords(0); // load new texcoords
 201         }
 202
 203         mi_center = (mi_min + mi_max) * 0.5;
 204         mi_scale = mi_max - mi_min;
 205         minimapname = strzone(minimapname);
 206
 207         WarpZone_Init();
 208
 209         hud_configure_prev = -1;
 210         tab_panel = -1;
 211
 212         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 213 }
 214
 215 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 216 void Shutdown(void)
 217 {
 218 #ifdef USE_FTE
 219 #pragma TARGET id
 220         if(!__engine_check)
 221                 return 0;
 222 #pragma TARGET fte
 223 #endif
 224
 225         WarpZone_Shutdown();
 226
 227         remove(teams);
 228         remove(players);
 229         db_close(binddb);
 230         db_close(tempdb);
 231         if(autocvar_cl_db_saveasdump)
 232                 db_dump(ClientProgsDB, "client.db");
 233         else
 234                 db_save(ClientProgsDB, "client.db");
 235         db_close(ClientProgsDB);
 236
 237         if(camera_active)
 238                 cvar_set("chase_active",ftos(chase_active_backup));
 239
 240         // unset the event chasecam's chase_active
 241         if(autocvar_chase_active < 0)
 242                 cvar_set("chase_active", "0");
 243
 244         if not(isdemo())
 245         {
 246                 if not(calledhooks & HOOK_START)
 247                         localcmd("\n_cl_hook_gamestart nop\n");
 248                 if not(calledhooks & HOOK_END)
 249                         localcmd("\ncl_hook_gameend\n");
 250         }
 251 }
 252
 253 .float has_team;
 254 float SetTeam(entity o, float Team)
 255 {
 256         entity tm;
 257         if(teamplay)
 258         {
 259                 switch(Team)
 260                 {
 261                         case -1:
 262                         case COLOR_TEAM1:
 263                         case COLOR_TEAM2:
 264                         case COLOR_TEAM3:
 265                         case COLOR_TEAM4:
 266                                 break;
 267                         default:
 268                                 if(GetTeam(Team, false) == world)
 269                                 {
 270                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 271                                         Team = COLOR_SPECTATOR;
 272                                 }
 273                                 break;
 274                 }
 275         }
 276         else
 277         {
 278                 switch(Team)
 279                 {
 280                         case -1:
 281                         case 0:
 282                                 break;
 283                         default:
 284                                 if(GetTeam(Team, false) == world)
 285                                 {
 286                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 287                                         Team = COLOR_SPECTATOR;
 288                                 }
 289                                 break;
 290                 }
 291         }
 292         if(Team == -1) // leave
 293         {
 294                 if(o.has_team)
 295                 {
 296                         tm = GetTeam(o.team, false);
 297                         tm.team_size -= 1;
 298                         o.has_team = 0;
 299                         return TRUE;
 300                 }
 301         }
 302         else
 303         {
 304                 if not(o.has_team)
 305                 {
 306                         o.team = Team;
 307                         tm = GetTeam(Team, true);
 308                         tm.team_size += 1;
 309                         o.has_team = 1;
 310                         return TRUE;
 311                 }
 312                 else if(Team != o.team)
 313                 {
 314                         tm = GetTeam(o.team, false);
 315                         tm.team_size -= 1;
 316                         o.team = Team;
 317                         tm = GetTeam(Team, true);
 318                         tm.team_size += 1;
 319                         return TRUE;
 320                 }
 321         }
 322         return FALSE;
 323 }
 324
 325 void Playerchecker_Think()
 326 {
 327         float i;
 328         entity e;
 329         for(i = 0; i < maxclients; ++i)
 330         {
 331                 e = playerslots[i];
 332                 if(GetPlayerName(i) == "")
 333                 {
 334                         if(e.sort_prev)
 335                         {
 336                                 // player disconnected
 337                                 SetTeam(e, -1);
 338                                 RemovePlayer(e);
 339                                 e.sort_prev = world;
 340                                 //e.gotscores = 0;
 341                         }
 342                 }
 343                 else
 344                 {
 345                         if not(e.sort_prev)
 346                         {
 347                                 // player connected
 348                                 if not(e)
 349                                         playerslots[i] = e = spawn();
 350                                 e.sv_entnum = i;
 351                                 e.ping = 0;
 352                                 e.ping_packetloss = 0;
 353                                 e.ping_movementloss = 0;
 354                                 //e.gotscores = 0; // we might already have the scores...
 355                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 356                                 RegisterPlayer(e);
 357                                 HUD_UpdatePlayerPos(e);
 358                         }
 359                 }
 360         }
 361         self.nextthink = time + 0.2;
 362 }
 363
 364 void Porto_Init();
 365 void TrueAim_Init();
 366 void PostInit(void)
 367 {
 368         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 369
 370         entity playerchecker;
 371         playerchecker = spawn();
 372         playerchecker.think = Playerchecker_Think;
 373         playerchecker.nextthink = time + 0.2;
 374
 375         Porto_Init();
 376         TrueAim_Init();
 377
 378         postinit = true;
 379 }
 380
 381 float button_zoom;
 382
 383 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 384 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 385 // All keys are in ascii.
 386 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 387 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 388 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 389 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 390 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 391 {
 392         float bSkipKey;
 393         bSkipKey = false;
 394
 395         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 396                 return true;
 397
 398         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if(menu_visible)
 402                 if(menu_action(bInputType, nPrimary, nSecondary))
 403                         return TRUE;
 404
 405         return bSkipKey;
 406 }
 407
 408 // END REQUIRED CSQC FUNCTIONS
 409 // --------------------------------------------------------------------------
 410
 411 // --------------------------------------------------------------------------
 412 // BEGIN OPTIONAL CSQC FUNCTIONS
 413 void Ent_RemoveEntCS()
 414 {
 415         entcs_receiver[self.sv_entnum] = world;
 416 }
 417 void Ent_ReadEntCS()
 418 {
 419         float sf;
 420         InterpolateOrigin_Undo();
 421
 422         self.classname = "entcs_receiver";
 423         sf = ReadByte();
 424
 425         if(sf & 1)
 426                 self.sv_entnum = ReadByte();
 427         if(sf & 2)
 428         {
 429                 self.origin_x = ReadShort();
 430                 self.origin_y = ReadShort();
 431                 self.origin_z = ReadShort();
 432         }
 433         if(sf & 4)
 434         {
 435                 self.angles_y = ReadByte() * 360.0 / 256;
 436                 self.angles_x = self.angles_z = 0;
 437         }
 438         if(sf & 8)
 439                 self.healthvalue = ReadByte() * 10;
 440         if(sf & 16)
 441                 self.armorvalue = ReadByte() * 10;
 442
 443         entcs_receiver[self.sv_entnum] = self;
 444         self.entremove = Ent_RemoveEntCS;
 445
 446         InterpolateOrigin_Note();
 447 }
 448
 449 void Ent_Remove();
 450
 451 void Ent_RemovePlayerScore()
 452 {
 453         float i;
 454
 455         if(self.owner)
 456         {
 457                 SetTeam(self.owner, -1);
 458                 self.owner.gotscores = 0;
 459                 for(i = 0; i < MAX_SCORE; ++i)
 460                         self.owner.(scores[i]) = 0; // clear all scores
 461         }
 462 }
 463
 464 void Ent_ReadPlayerScore()
 465 {
 466         float i, n;
 467         float isNew;
 468         entity o;
 469
 470         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 471         // (no I've never heard of M-x replace-string, sed, or anything like that)
 472         isNew = !self.owner; // workaround for DP bug
 473         n = ReadByte()-1;
 474
 475 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 476         if(!isNew && n != self.sv_entnum)
 477         {
 478                 //print(_("A CSQC entity changed its owner!\n"));
 479                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 480                 isNew = true;
 481                 Ent_Remove();
 482                 self.enttype = ENT_CLIENT_SCORES;
 483         }
 484 #endif
 485
 486         self.sv_entnum = n;
 487
 488         if not(playerslots[self.sv_entnum])
 489                 playerslots[self.sv_entnum] = spawn();
 490         o = self.owner = playerslots[self.sv_entnum];
 491         o.sv_entnum = self.sv_entnum;
 492         o.gotscores = 1;
 493
 494         //if not(o.sort_prev)
 495         //      RegisterPlayer(o);
 496         //playerchecker will do this for us later, if it has not already done so
 497
 498         float sf, lf;
 499 #if MAX_SCORE <= 8
 500         sf = ReadByte();
 501         lf = ReadByte();
 502 #else
 503         sf = ReadShort();
 504         lf = ReadShort();
 505 #endif
 506         float p;
 507         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 508                 if(sf & p)
 509                 {
 510                         if(lf & p)
 511                                 o.(scores[i]) = ReadInt24_t();
 512                         else
 513                                 o.(scores[i]) = ReadChar();
 514                 }
 515
 516         if(o.sort_prev)
 517                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 518
 519         self.entremove = Ent_RemovePlayerScore;
 520 }
 521
 522 void Ent_ReadTeamScore()
 523 {
 524         float i;
 525         entity o;
 526
 527         self.team = ReadByte();
 528         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 529
 530         float sf, lf;
 531 #if MAX_TEAMSCORE <= 8
 532         sf = ReadByte();
 533         lf = ReadByte();
 534 #else
 535         sf = ReadShort();
 536         lf = ReadShort();
 537 #endif
 538         float p;
 539         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 540                 if(sf & p)
 541                 {
 542                         if(lf & p)
 543                                 o.(teamscores[i]) = ReadInt24_t();
 544                         else
 545                                 o.(teamscores[i]) = ReadChar();
 546                 }
 547
 548         HUD_UpdateTeamPos(o);
 549 }
 550
 551 void Ent_ClientData()
 552 {
 553         float f;
 554         float newspectatee_status;
 555
 556         f = ReadByte();
 557
 558         scoreboard_showscores_force = (f & 1);
 559
 560         if(f & 2)
 561         {
 562                 newspectatee_status = ReadByte();
 563                 if(newspectatee_status == player_localnum + 1)
 564                         newspectatee_status = -1; // observing
 565         }
 566         else
 567                 newspectatee_status = 0;
 568
 569         spectatorbutton_zoom = (f & 4);
 570
 571         if(f & 8)
 572         {
 573                 angles_held_status = 1;
 574                 angles_held_x = ReadAngle();
 575                 angles_held_y = ReadAngle();
 576                 angles_held_z = 0;
 577         }
 578         else
 579                 angles_held_status = 0;
 580
 581         if(newspectatee_status != spectatee_status)
 582         {
 583                 // clear race stuff
 584                 race_laptime = 0;
 585                 race_checkpointtime = 0;
 586         }
 587         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 588         {
 589                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 590                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 591                 )
 592                         prev_p_health = -1;
 593                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 594                         prev_health = -1;
 595         }
 596         spectatee_status = newspectatee_status;
 597
 598         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 599 }
 600
 601 void Ent_Nagger()
 602 {
 603         float nags, i, j, b, f;
 604
 605         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 606
 607         if(!(nags & 4))
 608         {
 609                 if(vote_called_vote)
 610                         strunzone(vote_called_vote);
 611                 vote_called_vote = string_null;
 612                 vote_active = 0;
 613         }
 614         else
 615         {
 616                 vote_active = 1;
 617         }
 618
 619         if(nags & 64)
 620         {
 621                 vote_yescount = ReadByte();
 622                 vote_nocount = ReadByte();
 623                 vote_needed = ReadByte();
 624                 vote_highlighted = ReadChar();
 625         }
 626
 627         if(nags & 128)
 628         {
 629                 if(vote_called_vote)
 630                         strunzone(vote_called_vote);
 631                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 632         }
 633
 634         if(nags & 1)
 635         {
 636                 for(j = 0; j < maxclients; ++j)
 637                         if(playerslots[j])
 638                                 playerslots[j].ready = 1;
 639                 for(i = 1; i <= maxclients; i += 8)
 640                 {
 641                         f = ReadByte();
 642                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 643                                 if not(f & b)
 644                                         if(playerslots[j])
 645                                                 playerslots[j].ready = 0;
 646                 }
 647         }
 648
 649         ready_waiting = (nags & 1);
 650         ready_waiting_for_me = (nags & 2);
 651         vote_waiting = (nags & 4);
 652         vote_waiting_for_me = (nags & 8);
 653         warmup_stage = (nags & 16);
 654 }
 655
 656 void Ent_RandomSeed()
 657 {
 658         float s;
 659         prandom_debug();
 660         s = ReadShort();
 661         psrandom(s);
 662 }
 663
 664 void Ent_ReadAccuracy(void)
 665 {
 666         float sf, f, w, b;
 667         sf = ReadInt24_t();
 668         if(sf == 0)
 669         {
 670                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 671                         weapon_accuracy[w] = -1;
 672                 return;
 673         }
 674
 675         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 676         {
 677                 if(sf & f)
 678                 {
 679                         b = ReadByte();
 680                         if(b == 0)
 681                                 weapon_accuracy[w] = -1;
 682                         else if(b == 255)
 683                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 684                         else
 685                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 686                 }
 687                 if(f == 0x800000)
 688                         f = 1;
 689                 else
 690                         f *= 2;
 691         }
 692 }
 693
 694 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 695 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 696 void Ent_RadarLink();
 697 void Ent_Init();
 698 void Ent_ScoresInfo();
 699 void CSQC_Ent_Update(float bIsNewEntity)
 700 {
 701         float t;
 702         float savetime;
 703         t = ReadByte();
 704
 705         if(autocvar_developer_csqcentities)
 706                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 707
 708         // set up the "time" global for received entities to be correct for interpolation purposes
 709         savetime = time;
 710         if(servertime)
 711         {
 712                 time = servertime;
 713         }
 714         else
 715         {
 716                 serverprevtime = time;
 717                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 718                 time = serverprevtime + serverdeltatime;
 719         }
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(self.enttype)
 723         {
 724                 if(t != self.enttype || bIsNewEntity)
 725                 {
 726                         //print(_("A CSQC entity changed its type!\n"));
 727                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 728                         Ent_Remove();
 729                         clearentity(self);
 730                         bIsNewEntity = 1;
 731                 }
 732         }
 733         else
 734         {
 735                 if(!bIsNewEntity)
 736                 {
 737                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 738                         bIsNewEntity = 1;
 739                 }
 740         }
 741 #endif
 742         self.enttype = t;
 743         switch(t)
 744         {
 745                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 746                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 747                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 748                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 749                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 750                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 751                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 752                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 753                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 754                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 755                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 756                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 757                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 758                 case ENT_CLIENT_INIT: Ent_Init(); break;
 759                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 760                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 761                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 762                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 763                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 764                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 765                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 766                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 767                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 768                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 769                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 770                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 771                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 772                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 773                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 774                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 775                 case ENT_CLIENT_TURRET: ent_turret(); break;
 776                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 777                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 778                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 779                 default:
 780                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 781                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 782                         break;
 783         }
 784
 785         time = savetime;
 786 }
 787 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 788 // used when an entity changes its type. For an entity that someone interacts
 789 // with others, make sure it can no longer do so.
 790 void Ent_Remove()
 791 {
 792         if(self.entremove)
 793                 self.entremove();
 794
 795         if(self.skeletonindex)
 796         {
 797                 skel_delete(self.skeletonindex);
 798                 self.skeletonindex = 0;
 799         }
 800
 801         self.enttype = 0;
 802         self.classname = "";
 803         self.draw = menu_sub_null;
 804         self.entremove = menu_sub_null;
 805         // TODO possibly set more stuff to defaults
 806 }
 807 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 808 void CSQC_Ent_Remove()
 809 {
 810         if(autocvar_developer_csqcentities)
 811                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 812
 813         if(wasfreed(self))
 814         {
 815                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 816                 return;
 817         }
 818         if(self.enttype)
 819                 Ent_Remove();
 820         remove(self);
 821 }
 822
 823 void Gamemode_Init()
 824 {
 825         if not(isdemo())
 826         {
 827                 if(!(calledhooks & HOOK_START))
 828                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 829                 calledhooks |= HOOK_START;
 830         }
 831 }
 832 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 833 void CSQC_Parse_StuffCmd(string strMessage)
 834 {
 835         if(autocvar_developer_csqcentities)
 836                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 837
 838         localcmd(strMessage);
 839 }
 840 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 841 void CSQC_Parse_Print(string strMessage)
 842 {
 843         if(autocvar_developer_csqcentities)
 844                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 845
 846         print(ColorTranslateRGB(strMessage));
 847 }
 848
 849 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 850 void CSQC_Parse_CenterPrint(string strMessage)
 851 {
 852         if(autocvar_developer_csqcentities)
 853                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 854
 855         centerprint_hud(strMessage);
 856 }
 857
 858 string notranslate_fogcmd1 = "\nfog ";
 859 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 860 void Fog_Force()
 861 {
 862         // TODO somehow thwart prvm_globalset client ...
 863
 864         if(forcefog != "")
 865                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 866 }
 867
 868 void Gamemode_Init();
 869 void Ent_ScoresInfo()
 870 {
 871         float i;
 872         self.classname = "ent_client_scores_info";
 873         gametype = ReadInt24_t();
 874         for(i = 0; i < MAX_SCORE; ++i)
 875         {
 876                 scores_label[i] = strzone(ReadString());
 877                 scores_flags[i] = ReadByte();
 878         }
 879         for(i = 0; i < MAX_TEAMSCORE; ++i)
 880         {
 881                 teamscores_label[i] = strzone(ReadString());
 882                 teamscores_flags[i] = ReadByte();
 883         }
 884         HUD_InitScores();
 885         Gamemode_Init();
 886 }
 887
 888 void Ent_Init()
 889 {
 890         self.classname = "ent_client_init";
 891
 892         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 893
 894         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 895         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 896         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 897         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 898         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 899         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 900         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 901         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 902         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 903         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 904         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 905         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 906
 907         if(forcefog)
 908                 strunzone(forcefog);
 909         forcefog = strzone(ReadString());
 910
 911         armorblockpercent = ReadByte() / 255.0;
 912
 913         g_weaponswitchdelay = ReadByte() / 255.0;
 914
 915         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 916         g_balance_grenadelauncher_bouncestop = ReadCoord();
 917         g_balance_electro_secondary_bouncefactor = ReadCoord();
 918         g_balance_electro_secondary_bouncestop = ReadCoord();
 919
 920         nex_scope = !ReadByte();
 921         rifle_scope = !ReadByte();
 922
 923         serverflags = ReadByte();
 924
 925         minelayer_maxmines = ReadByte();
 926
 927         hagar_maxrockets = ReadByte();
 928
 929         g_trueaim_minrange = ReadCoord();
 930         g_balance_porto_secondary = ReadByte();
 931
 932         if(!postinit)
 933                 PostInit();
 934 }
 935
 936 void Net_ReadRace()
 937 {
 938         float b;
 939
 940         b = ReadByte();
 941
 942         switch(b)
 943         {
 944                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 945                         race_checkpoint = ReadByte();
 946                         race_time = ReadInt24_t();
 947                         race_previousbesttime = ReadInt24_t();
 948                         if(race_previousbestname)
 949                                 strunzone(race_previousbestname);
 950                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 951
 952                         race_checkpointtime = time;
 953
 954                         if(race_checkpoint == 0 || race_checkpoint == 254)
 955                         {
 956                                 race_penaltyaccumulator = 0;
 957                                 race_laptime = time; // valid
 958                         }
 959
 960                         break;
 961
 962                 case RACE_NET_CHECKPOINT_CLEAR:
 963                         race_laptime = 0;
 964                         race_checkpointtime = 0;
 965                         break;
 966
 967                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 968                         race_laptime = ReadCoord();
 969                         race_checkpointtime = -99999;
 970                         // fall through
 971                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 972                         race_nextcheckpoint = ReadByte();
 973
 974                         race_nextbesttime = ReadInt24_t();
 975                         if(race_nextbestname)
 976                                 strunzone(race_nextbestname);
 977                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 978                         break;
 979
 980                 case RACE_NET_CHECKPOINT_HIT_RACE:
 981                         race_mycheckpoint = ReadByte();
 982                         race_mycheckpointtime = time;
 983                         race_mycheckpointdelta = ReadInt24_t();
 984                         race_mycheckpointlapsdelta = ReadByte();
 985                         if(race_mycheckpointlapsdelta >= 128)
 986                                 race_mycheckpointlapsdelta -= 256;
 987                         if(race_mycheckpointenemy)
 988                                 strunzone(race_mycheckpointenemy);
 989                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 990                         break;
 991
 992                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 993                         race_othercheckpoint = ReadByte();
 994                         race_othercheckpointtime = time;
 995                         race_othercheckpointdelta = ReadInt24_t();
 996                         race_othercheckpointlapsdelta = ReadByte();
 997                         if(race_othercheckpointlapsdelta >= 128)
 998                                 race_othercheckpointlapsdelta -= 256;
 999                         if(race_othercheckpointenemy)
1000                                 strunzone(race_othercheckpointenemy);
1001                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1002                         break;
1003
1004                 case RACE_NET_PENALTY_RACE:
1005                         race_penaltyeventtime = time;
1006                         race_penaltytime = ReadShort();
1007                         //race_penaltyaccumulator += race_penaltytime;
1008                         if(race_penaltyreason)
1009                                 strunzone(race_penaltyreason);
1010                         race_penaltyreason = strzone(ReadString());
1011                         break;
1012
1013                 case RACE_NET_PENALTY_QUALIFYING:
1014                         race_penaltyeventtime = time;
1015                         race_penaltytime = ReadShort();
1016                         race_penaltyaccumulator += race_penaltytime;
1017                         if(race_penaltyreason)
1018                                 strunzone(race_penaltyreason);
1019                         race_penaltyreason = strzone(ReadString());
1020                         break;
1021
1022                 case RACE_NET_SERVER_RECORD:
1023                         race_server_record = ReadInt24_t();
1024                         break;
1025                 case RACE_NET_SPEED_AWARD:
1026                         race_speedaward = ReadInt24_t();
1027                         if(race_speedaward_holder)
1028                                 strunzone(race_speedaward_holder);
1029                         race_speedaward_holder = strzone(ReadString());
1030                         break;
1031                 case RACE_NET_SPEED_AWARD_BEST:
1032                         race_speedaward_alltimebest = ReadInt24_t();
1033                         if(race_speedaward_alltimebest_holder)
1034                                 strunzone(race_speedaward_alltimebest_holder);
1035                         race_speedaward_alltimebest_holder = strzone(ReadString());
1036                         break;
1037                 case RACE_NET_SERVER_RANKINGS:
1038                         float pos, prevpos, del;
1039                         pos = ReadShort();
1040                         prevpos = ReadShort();
1041                         del = ReadShort();
1042
1043                         // move other rankings out of the way
1044                         float i;
1045                         if (prevpos) {
1046                                 for (i=prevpos-1;i>pos-1;--i) {
1047                                         grecordtime[i] = grecordtime[i-1];
1048                                         if(grecordholder[i])
1049                                                 strunzone(grecordholder[i]);
1050                                         grecordholder[i] = strzone(grecordholder[i-1]);
1051                                 }
1052                         } else if (del) { // a record has been deleted by the admin
1053                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1054                                         if (i == RANKINGS_CNT-1) { // clear out last record
1055                                                 grecordtime[i] = 0;
1056                                                 if (grecordholder[i])
1057                                                         strunzone(grecordholder[i]);
1058                                                 grecordholder[i] = string_null;
1059                                         }
1060                                         else {
1061                                                 grecordtime[i] = grecordtime[i+1];
1062                                                 if (grecordholder[i])
1063                                                         strunzone(grecordholder[i]);
1064                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1065                                         }
1066                                 }
1067                         } else { // player has no ranked record yet
1068                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1069                                         grecordtime[i] = grecordtime[i-1];
1070                                         if(grecordholder[i])
1071                                                 strunzone(grecordholder[i]);
1072                                         grecordholder[i] = strzone(grecordholder[i-1]);
1073                                 }
1074                         }
1075
1076                         // store new ranking
1077                         if(grecordholder[pos-1] != "")
1078                                 strunzone(grecordholder[pos-1]);
1079                         grecordholder[pos-1] = strzone(ReadString());
1080                         grecordtime[pos-1] = ReadInt24_t();
1081                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1082                                 race_myrank = pos;
1083                         break;
1084                 case RACE_NET_SERVER_STATUS:
1085                         race_status = ReadShort();
1086                         if(race_status_name)
1087                                 strunzone(race_status_name);
1088                         race_status_name = strzone(ReadString());
1089         }
1090 }
1091
1092 void Net_ReadSpawn()
1093 {
1094         zoomin_effect = 1;
1095         current_viewzoom = 0.6;
1096 }
1097
1098 void Net_TeamNagger()
1099 {
1100         teamnagger = 1;
1101 }
1102
1103 void Net_ReadPingPLReport()
1104 {
1105         float e, pi, pl, ml;
1106         e = ReadByte();
1107         pi = ReadShort();
1108         pl = ReadByte();
1109         ml = ReadByte();
1110         if not(playerslots[e])
1111                 return;
1112         playerslots[e].ping = pi;
1113         playerslots[e].ping_packetloss = pl / 255.0;
1114         playerslots[e].ping_movementloss = ml / 255.0;
1115 }
1116
1117 void Net_WeaponComplain() {
1118         complain_weapon = ReadByte();
1119
1120         if(complain_weapon_name)
1121                 strunzone(complain_weapon_name);
1122         complain_weapon_name = strzone(ReadString());
1123
1124         complain_weapon_type = ReadByte();
1125
1126         complain_weapon_time = time;
1127         weapontime = time; // ping the weapon panel
1128 }
1129
1130 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1131 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1132 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1133 float CSQC_Parse_TempEntity()
1134 {
1135         float bHandled;
1136                 bHandled  = true;
1137         // Acquire TE ID
1138         float nTEID;
1139                 nTEID = ReadByte();
1140
1141         if(autocvar_developer_csqcentities)
1142                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1143
1144                 // NOTE: Could just do return instead of break...
1145         switch(nTEID)
1146         {
1147                 case TE_CSQC_TARGET_MUSIC:
1148                         Net_TargetMusic();
1149                         bHandled = true;
1150                         break;
1151                 case TE_CSQC_PICTURE:
1152                         Net_MapVote_Picture();
1153                         bHandled = true;
1154                         break;
1155                 case TE_CSQC_RACE:
1156                         Net_ReadRace();
1157                         bHandled = true;
1158                         break;
1159                 case TE_CSQC_SPAWN:
1160                         Net_ReadSpawn();
1161                         bHandled = true;
1162                         break;
1163                 case TE_CSQC_ZCURVEPARTICLES:
1164                         Net_ReadZCurveParticles();
1165                         bHandled = true;
1166                         break;
1167                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1168                         Net_ReadNexgunBeamParticle();
1169                         bHandled = true;
1170                         break;
1171                 case TE_CSQC_TEAMNAGGER:
1172                         Net_TeamNagger();
1173                         bHandled = true;
1174                         break;
1175                 case TE_CSQC_LIGHTNINGARC:
1176                         Net_ReadLightningarc();
1177                         bHandled = true;
1178                         break;
1179                 case TE_CSQC_PINGPLREPORT:
1180                         Net_ReadPingPLReport();
1181                         bHandled = true;
1182                         break;
1183                 case TE_CSQC_ANNOUNCE:
1184                         Announcer_Play(ReadString());
1185                         bHandled = true;
1186                         break;
1187                 case TE_CSQC_KILLNOTIFY:
1188                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1189                         bHandled = true;
1190                         break;
1191                 case TE_CSQC_KILLCENTERPRINT:
1192                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1193                         bHandled = true;
1194                         break;
1195                 case TE_CSQC_CENTERPRINT_GENERIC:
1196                         float id;
1197                         string s;
1198                         id = ReadByte();
1199                         s = ReadString();
1200                         if (id != 0 && s != "")
1201                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1202                         else
1203                                 centerprint_generic(id, s, 0, 0);
1204                         bHandled = true;
1205                         break;
1206                 case TE_CSQC_WEAPONCOMPLAIN:
1207                         Net_WeaponComplain();
1208                         bHandled = true;
1209                         break;
1210                 case TE_CSQC_VEHICLESETUP:
1211                         Net_VehicleSetup();
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_SVNOTICE:
1215                         cl_notice_read();
1216                         bHandled = true;
1217                         break;
1218                 default:
1219                         // No special logic for this temporary entity; return 0 so the engine can handle it
1220                         bHandled = false;
1221                         break;
1222         }
1223
1224         return bHandled;
1225 }
1226
1227 string getcommandkey(string text, string command)
1228 {
1229         string keys;
1230         float n, j, k, l;
1231
1232         if (!autocvar_hud_showbinds)
1233                 return text;
1234
1235         keys = db_get(binddb, command);
1236         if (!keys)
1237         {
1238                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1239                 for(j = 0; j < n; ++j)
1240                 {
1241                         k = stof(argv(j));
1242                         if(k != -1)
1243                         {
1244                                 if ("" == keys)
1245                                         keys = keynumtostring(k);
1246                                 else
1247                                         keys = strcat(keys, ", ", keynumtostring(k));
1248
1249                                 ++l;
1250                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1251                         }
1252
1253                 }
1254                 db_put(binddb, command, keys);
1255         }
1256
1257         if ("" == keys) {
1258                 if (autocvar_hud_showbinds > 1)
1259                         return sprintf(_("%s (not bound)"), text);
1260                 else
1261                         return text;
1262         }
1263         else if (autocvar_hud_showbinds > 1)
1264                 return sprintf(_("%s (%s)"), text, keys);
1265         else
1266                 return keys;
1267 }