qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 151         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 152
 153         get_mi_min_max_texcoords(1); // try the CLEVER way first
 154         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 155         shortmapname = mi_shortname;
 156
 157         if(precache_pic(minimapname) == "")
 158         {
 159                 // but maybe we have a non-clever minimap
 160                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 161                 if(precache_pic(minimapname) == "")
 162                         minimapname = ""; // FAIL
 163                 else
 164                         get_mi_min_max_texcoords(0); // load new texcoords
 165         }
 166
 167         mi_center = (mi_min + mi_max) * 0.5;
 168         mi_scale = mi_max - mi_min;
 169         minimapname = strzone(minimapname);
 170
 171         WarpZone_Init();
 172         hud_configure_prev = -1;
 173 }
 174
 175 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 176 void CSQC_Shutdown(void)
 177 {
 178 #ifdef USE_FTE
 179 #pragma TARGET id
 180         if(!__engine_check)
 181                 return 0;
 182 #pragma TARGET fte
 183 #endif
 184
 185         WarpZone_Shutdown();
 186
 187         remove(teams);
 188         remove(players);
 189         db_close(binddb);
 190         db_close(tempdb);
 191         if(autocvar_cl_db_saveasdump)
 192                 db_dump(ClientProgsDB, "client.db");
 193         else
 194                 db_save(ClientProgsDB, "client.db");
 195         db_close(ClientProgsDB);
 196
 197         cvar_clientsettemp_restore();
 198
 199         if(camera_active)
 200                 cvar_set("chase_active",ftos(chase_active_backup));
 201
 202         // unset the event chasecam's chase_active
 203         if(autocvar_chase_active < 0)
 204                 cvar_set("chase_active", "0");
 205
 206         if not(isdemo())
 207         {
 208                 if not(calledhooks & HOOK_START)
 209                         localcmd("\n_cl_hook_gamestart nop\n");
 210                 if not(calledhooks & HOOK_END)
 211                         localcmd("\ncl_hook_gameend\n");
 212         }
 213 }
 214
 215 .float has_team;
 216 float SetTeam(entity o, float Team)
 217 {
 218         entity tm;
 219         if(teamplay)
 220         {
 221                 switch(Team)
 222                 {
 223                         case -1:
 224                         case COLOR_TEAM1:
 225                         case COLOR_TEAM2:
 226                         case COLOR_TEAM3:
 227                         case COLOR_TEAM4:
 228                                 break;
 229                         default:
 230                                 if(GetTeam(Team, false) == NULL)
 231                                 {
 232                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 233                                         Team = COLOR_SPECTATOR;
 234                                 }
 235                                 break;
 236                 }
 237         }
 238         else
 239         {
 240                 switch(Team)
 241                 {
 242                         case -1:
 243                         case 0:
 244                                 break;
 245                         default:
 246                                 if(GetTeam(Team, false) == NULL)
 247                                 {
 248                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 249                                         Team = COLOR_SPECTATOR;
 250                                 }
 251                                 break;
 252                 }
 253         }
 254         if(Team == -1) // leave
 255         {
 256                 if(o.has_team)
 257                 {
 258                         tm = GetTeam(o.team, false);
 259                         tm.team_size -= 1;
 260                         o.has_team = 0;
 261                         return TRUE;
 262                 }
 263         }
 264         else
 265         {
 266                 if not(o.has_team)
 267                 {
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         o.has_team = 1;
 272                         return TRUE;
 273                 }
 274                 else if(Team != o.team)
 275                 {
 276                         tm = GetTeam(o.team, false);
 277                         tm.team_size -= 1;
 278                         o.team = Team;
 279                         tm = GetTeam(Team, true);
 280                         tm.team_size += 1;
 281                         return TRUE;
 282                 }
 283         }
 284         return FALSE;
 285 }
 286
 287 void Playerchecker_Think()
 288 {
 289         float i;
 290         entity e;
 291         for(i = 0; i < maxclients; ++i)
 292         {
 293                 e = playerslots[i];
 294                 if(GetPlayerName(i) == "")
 295                 {
 296                         if(e.sort_prev)
 297                         {
 298                                 // player disconnected
 299                                 SetTeam(e, -1);
 300                                 RemovePlayer(e);
 301                                 e.sort_prev = world;
 302                                 //e.gotscores = 0;
 303                         }
 304                 }
 305                 else
 306                 {
 307                         if not(e.sort_prev)
 308                         {
 309                                 // player connected
 310                                 if not(e)
 311                                         playerslots[i] = e = spawn();
 312                                 e.sv_entnum = i;
 313                                 e.ping = 0;
 314                                 e.ping_packetloss = 0;
 315                                 e.ping_movementloss = 0;
 316                                 //e.gotscores = 0; // we might already have the scores...
 317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 318                                 RegisterPlayer(e);
 319                                 HUD_UpdatePlayerPos(e);
 320                         }
 321                 }
 322         }
 323         self.nextthink = time + 0.2;
 324 }
 325
 326 void Porto_Init();
 327 void TrueAim_Init();
 328 void PostInit(void)
 329 {
 330         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 331
 332         entity playerchecker;
 333         playerchecker = spawn();
 334         playerchecker.think = Playerchecker_Think;
 335         playerchecker.nextthink = time + 0.2;
 336
 337         Porto_Init();
 338         TrueAim_Init();
 339
 340         postinit = true;
 341 }
 342
 343 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 344 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 345 float button_zoom;
 346 void Cmd_HUD_SetFields(float);
 347 void Cmd_HUD_Help(float);
 348 float CSQC_ConsoleCommand(string strMessage)
 349 {
 350         float argc;
 351         // Tokenize String
 352         //argc = tokenize(strMessage);
 353         argc = tokenize_console(strMessage);
 354
 355         // Acquire Command
 356         local string strCmd;
 357         strCmd = argv(0);
 358
 359         if(strCmd == "hud_configure") { // config hud
 360                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 361                 return true;
 362         } else if(strCmd == "hud_save") { // save hud config
 363                 if(argv(1) == "" || argv(2)) {
 364                         print(_("Usage:\n"));
 365                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 366                 }
 367                 else
 368                         HUD_Panel_ExportCfg(argv(1));
 369                 return true;
 370         } else if(strCmd == "+showscores") {
 371                 scoreboard_showscores = true;
 372                 return true;
 373         } else if(strCmd == "-showscores") {
 374                 scoreboard_showscores = false;
 375                 return true;
 376         } else if(strCmd == "+showaccuracy") {
 377                 scoreboard_showaccuracy = true;
 378                 return true;
 379         } else if(strCmd == "-showaccuracy") {
 380                 scoreboard_showaccuracy = false;
 381                 return true;
 382         }
 383
 384         if(camera_active)
 385         if(strCmd == "+forward" || strCmd == "-back") {
 386                 ++camera_direction_x;
 387                 return true;
 388         } else if(strCmd == "-forward" || strCmd == "+back") {
 389                 --camera_direction_x;
 390                 return true;
 391         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 392                 --camera_direction_y;
 393                 return true;
 394         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 395                 ++camera_direction_y;
 396                 return true;
 397         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 398                 ++camera_direction_z;
 399                 return true;
 400         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 401                 --camera_direction_z;
 402                 return true;
 403         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 404                 ++camera_roll;
 405                 return true;
 406         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 407                 --camera_roll;
 408                 return true;
 409         }
 410
 411         return false;
 412 }
 413
 414 .vector view_ofs;
 415 entity debug_shotorg;
 416 void ShotOrg_Draw()
 417 {
 418         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 419         self.angles = view_angles;
 420         self.angles_x = -self.angles_x;
 421         if not(self.cnt)
 422                 self.drawmask = MASK_NORMAL;
 423         else
 424                 self.drawmask = 0;
 425 }
 426 void ShotOrg_Draw2D()
 427 {
 428         vector coord2d_topleft, coord2d_topright, coord2d;
 429         string s;
 430         vector fs;
 431
 432         s = vtos(self.view_ofs);
 433         s = substring(s, 1, strlen(s) - 2);
 434         if(tokenize_console(s) == 3)
 435                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 436
 437         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 438         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 439
 440         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 441
 442         coord2d = coord2d_topleft;
 443         if(fs_x < 8)
 444         {
 445                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 446                 fs = '8 8 0';
 447         }
 448         coord2d_y -= fs_y;
 449         coord2d_z = 0;
 450         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 451 }
 452
 453 void ShotOrg_Spawn()
 454 {
 455         debug_shotorg = spawn();
 456         debug_shotorg.draw = ShotOrg_Draw;
 457         debug_shotorg.draw2d = ShotOrg_Draw2D;
 458         debug_shotorg.renderflags = RF_VIEWMODEL;
 459         debug_shotorg.effects = EF_FULLBRIGHT;
 460         precache_model("models/shotorg_adjuster.md3");
 461         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 462         debug_shotorg.scale = 2;
 463         debug_shotorg.view_ofs = '25 8 -8';
 464 }
 465
 466 void DrawDebugModel()
 467 {
 468         if(time - floor(time) > 0.5)
 469         {
 470                 PolyDrawModel(self);
 471                 self.drawmask = 0;
 472         }
 473         else
 474         {
 475                 self.renderflags = 0;
 476                 self.drawmask = MASK_NORMAL;
 477         }
 478 }
 479
 480 void GameCommand(string msg)
 481 {
 482         string s;
 483         float argc;
 484         entity e;
 485         argc = tokenize_console(msg);
 486
 487         if(argv(0) == "help" || argc == 0)
 488         {
 489                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 490                 print(_("  settemp cvar value\n"));
 491                 print(_("  scoreboard_columns_set ...\n"));
 492                 print(_("  scoreboard_columns_help\n"));
 493                 GameCommand_Generic("help");
 494                 return;
 495         }
 496
 497         if(GameCommand_Generic(msg))
 498                 return;
 499
 500         string cmd;
 501         cmd = argv(0);
 502         if(cmd == "mv_download") {
 503                 Cmd_MapVote_MapDownload(argc);
 504         }
 505         else if(cmd == "settemp") {
 506                 cvar_clientsettemp(argv(1), argv(2));
 507         }
 508         else if(cmd == "scoreboard_columns_set") {
 509                 Cmd_HUD_SetFields(argc);
 510         }
 511         else if(cmd == "scoreboard_columns_help") {
 512                 Cmd_HUD_Help(argc);
 513         }
 514 #ifdef BLURTEST
 515         else if(cmd == "blurtest") {
 516                 blurtest_time0 = time;
 517                 blurtest_time1 = time + stof(argv(1));
 518                 blurtest_radius = stof(argv(2));
 519                 blurtest_power = stof(argv(3));
 520         }
 521 #endif
 522         else if(cmd == "shotorg_move") {
 523                 if(!debug_shotorg)
 524                         ShotOrg_Spawn();
 525                 else
 526                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 527                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 528         }
 529         else if(cmd == "shotorg_movez") {
 530                 if(!debug_shotorg)
 531                         ShotOrg_Spawn();
 532                 else
 533                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 534                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 535         }
 536         else if(cmd == "shotorg_set") {
 537                 if(!debug_shotorg)
 538                         ShotOrg_Spawn();
 539                 else
 540                         debug_shotorg.view_ofs = stov(argv(1));
 541                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 542         }
 543         else if(cmd == "shotorg_setz") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_toggle_hide") {
 551                 if(debug_shotorg)
 552                 {
 553                         debug_shotorg.cnt = !debug_shotorg.cnt;
 554                 }
 555         }
 556         else if(cmd == "shotorg_end") {
 557                 if(debug_shotorg)
 558                 {
 559                         print(vtos(debug_shotorg.view_ofs), "\n");
 560                         remove(debug_shotorg);
 561                         debug_shotorg = world;
 562                 }
 563                 localcmd("sv_cmd debug_shotorg\n");
 564         }
 565         else if(cmd == "sendcvar") {
 566                 // W_FixWeaponOrder will trash argv, so save what we need.
 567                 string thiscvar;
 568                 thiscvar = strzone(argv(1));
 569                 s = cvar_string(thiscvar);
 570                 if(thiscvar == "cl_weaponpriority")
 571                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 572                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 573                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 574                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 575                 strunzone(thiscvar);
 576         }
 577         else if(cmd == "spawn") {
 578                 s = argv(1);
 579                 e = spawn();
 580                 precache_model(s);
 581                 setmodel(e, s);
 582                 setorigin(e, view_origin);
 583                 e.angles = view_angles;
 584                 e.draw = DrawDebugModel;
 585                 e.classname = "debugmodel";
 586         }
 587     else if(cmd == "vyes")
 588     {
 589         if(uid2name_dialog)
 590         {
 591             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 592             vote_prev = 0;
 593             cvar_set("cl_allow_uid2name", "1");
 594             vote_change = -9999;
 595         }
 596         else
 597         {
 598             localcmd("cmd vote yes\n");
 599         }
 600     }
 601     else if(cmd == "vno")
 602     {
 603         if(uid2name_dialog)
 604         {
 605             vote_active = 0;
 606             vote_prev = 0;
 607             cvar_set("cl_allow_uid2name", "0");
 608             vote_change = -9999;
 609         }
 610         else
 611         {
 612             localcmd("cmd vote no\n");
 613         }
 614     }
 615
 616         else
 617         {
 618                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 619         }
 620
 621         return;
 622 }
 623
 624 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 625 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 626 // All keys are in ascii.
 627 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 628 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 629 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 630 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 631 {
 632         local float bSkipKey;
 633         bSkipKey = false;
 634
 635         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 636                 return true;
 637
 638         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 639                 return true;
 640
 641         if(menu_visible)
 642                 if(menu_action(bInputType, nPrimary, nSecondary))
 643                         return TRUE;
 644
 645         return bSkipKey;
 646 }
 647
 648 // END REQUIRED CSQC FUNCTIONS
 649 // --------------------------------------------------------------------------
 650
 651 // --------------------------------------------------------------------------
 652 // BEGIN OPTIONAL CSQC FUNCTIONS
 653 void Ent_ReadEntCS()
 654 {
 655         InterpolateOrigin_Undo();
 656
 657         self.classname = "entcs_receiver";
 658         self.sv_entnum = ReadByte() - 1;
 659         self.origin_x = ReadShort();
 660         self.origin_y = ReadShort();
 661         self.origin_z = ReadShort();
 662         self.angles_y = ReadByte() * 360.0 / 256;
 663         self.origin_z = self.angles_x = self.angles_z = 0;
 664
 665         InterpolateOrigin_Note();
 666 }
 667
 668 void Ent_Remove();
 669
 670 void Ent_RemovePlayerScore()
 671 {
 672         float i;
 673
 674         if(self.owner)
 675         {
 676                 SetTeam(self.owner, -1);
 677                 self.owner.gotscores = 0;
 678                 for(i = 0; i < MAX_SCORE; ++i)
 679                         self.owner.(scores[i]) = 0; // clear all scores
 680         }
 681 }
 682
 683 void Ent_ReadPlayerScore()
 684 {
 685         float i, n;
 686         float isNew;
 687         entity o;
 688
 689         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 690         // (no I've never heard of M-x replace-string, sed, or anything like that)
 691         isNew = !self.owner; // workaround for DP bug
 692         n = ReadByte()-1;
 693
 694 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 695         if(!isNew && n != self.sv_entnum)
 696         {
 697                 print(_("A CSQC entity changed its owner!\n"));
 698                 isNew = true;
 699                 Ent_Remove();
 700                 self.enttype = ENT_CLIENT_SCORES;
 701         }
 702 #endif
 703
 704         self.sv_entnum = n;
 705
 706         if not(playerslots[self.sv_entnum])
 707                 playerslots[self.sv_entnum] = spawn();
 708         o = self.owner = playerslots[self.sv_entnum];
 709         o.sv_entnum = self.sv_entnum;
 710         o.gotscores = 1;
 711
 712         //if not(o.sort_prev)
 713         //      RegisterPlayer(o);
 714         //playerchecker will do this for us later, if it has not already done so
 715
 716         float sf, lf;
 717 #if MAX_SCORE <= 8
 718         sf = ReadByte();
 719         lf = ReadByte();
 720 #else
 721         sf = ReadShort();
 722         lf = ReadShort();
 723 #endif
 724         float p;
 725         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 726                 if(sf & p)
 727                 {
 728                         if(lf & p)
 729                                 o.(scores[i]) = ReadInt24_t();
 730                         else
 731                                 o.(scores[i]) = ReadChar();
 732                 }
 733
 734         if(o.sort_prev)
 735                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 736
 737         self.entremove = Ent_RemovePlayerScore;
 738 }
 739
 740 void Ent_ReadTeamScore()
 741 {
 742         float i;
 743         entity o;
 744
 745         self.team = ReadByte();
 746         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 747
 748         float sf, lf;
 749 #if MAX_TEAMSCORE <= 8
 750         sf = ReadByte();
 751         lf = ReadByte();
 752 #else
 753         sf = ReadShort();
 754         lf = ReadShort();
 755 #endif
 756         float p;
 757         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 758                 if(sf & p)
 759                 {
 760                         if(lf & p)
 761                                 o.(teamscores[i]) = ReadInt24_t();
 762                         else
 763                                 o.(teamscores[i]) = ReadChar();
 764                 }
 765
 766         HUD_UpdateTeamPos(o);
 767 }
 768
 769 void Net_Reset()
 770 {
 771 }
 772
 773 void Ent_ClientData()
 774 {
 775         float f;
 776         float newspectatee_status;
 777
 778         f = ReadByte();
 779
 780         scoreboard_showscores_force = (f & 1);
 781
 782         if(f & 2)
 783         {
 784                 newspectatee_status = ReadByte();
 785                 if(newspectatee_status == player_localentnum)
 786                         newspectatee_status = -1; // observing
 787         }
 788         else
 789                 newspectatee_status = 0;
 790
 791         spectatorbutton_zoom = (f & 4);
 792
 793         if(f & 8)
 794         {
 795                 angles_held_status = 1;
 796                 angles_held_x = ReadAngle();
 797                 angles_held_y = ReadAngle();
 798                 angles_held_z = 0;
 799         }
 800         else
 801                 angles_held_status = 0;
 802
 803         if(newspectatee_status != spectatee_status)
 804         {
 805                 float i;
 806
 807                 // clear race stuff
 808                 race_laptime = 0;
 809                 race_checkpointtime = 0;
 810         }
 811         spectatee_status = newspectatee_status;
 812 }
 813
 814 void Ent_Nagger()
 815 {
 816         float nags, i, j, b, f;
 817
 818         nags = ReadByte();
 819
 820         if(nags & 128)
 821         {
 822                 if(vote_called_vote)
 823                         strunzone(vote_called_vote);
 824                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 825         }
 826
 827         if(nags & 1)
 828         {
 829                 for(j = 0; j < maxclients; ++j)
 830                         if(playerslots[j])
 831                                 playerslots[j].ready = 1;
 832                 for(i = 1; i <= maxclients; i += 8)
 833                 {
 834                         f = ReadByte();
 835                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 836                                 if not(f & b)
 837                                         if(playerslots[j])
 838                                                 playerslots[j].ready = 0;
 839                 }
 840         }
 841
 842         ready_waiting = (nags & 1);
 843         ready_waiting_for_me = (nags & 2);
 844         vote_waiting = (nags & 4);
 845         vote_waiting_for_me = (nags & 8);
 846         warmup_stage = (nags & 16);
 847 }
 848
 849 void Ent_RandomSeed()
 850 {
 851         float s;
 852         prandom_debug();
 853         s = ReadShort();
 854         psrandom(s);
 855 }
 856
 857 void Ent_ReadAccuracy(void)
 858 {
 859         float sf, f, w, b;
 860         sf = ReadInt24_t();
 861         if(sf == 0)
 862         {
 863                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 864                         weapon_accuracy[w] = -1;
 865                 return;
 866         }
 867
 868         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 869         {
 870                 if(sf & f)
 871                 {
 872                         b = ReadByte();
 873                         if(b == 0)
 874                                 weapon_accuracy[w] = -1;
 875                         else if(b == 255)
 876                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 877                         else
 878                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 879                 }
 880         }
 881 }
 882
 883 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 884 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 885 void Ent_RadarLink();
 886 void Ent_Init();
 887 void Ent_ScoresInfo();
 888 void(float bIsNewEntity) CSQC_Ent_Update =
 889 {
 890         float t;
 891         float savetime;
 892         t = ReadByte();
 893
 894         // set up the "time" global for received entities to be correct for interpolation purposes
 895         savetime = time;
 896         if(servertime)
 897         {
 898                 time = servertime;
 899         }
 900         else
 901         {
 902                 serverprevtime = time;
 903                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 904                 time = serverprevtime + serverdeltatime;
 905         }
 906
 907 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 908         if(self.enttype)
 909                 if(t != self.enttype)
 910                 {
 911                         print(_("A CSQC entity changed its type!\n"));
 912                         Ent_Remove();
 913                         bIsNewEntity = 1;
 914                 }
 915 #endif
 916         self.enttype = t;
 917         switch(t)
 918         {
 919                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 920                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 921                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 922                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 923                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 924                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 925                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 926                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 927                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 928                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 929                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 930                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 931                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 932                 case ENT_CLIENT_INIT: Ent_Init(); break;
 933                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 934                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 935                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 936                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 937                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 938                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 939                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 940                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 941                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 942                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 943                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 944                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 945                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 946                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 947                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 948                 case ENT_CLIENT_DAMAGEEFFECT: Ent_DamageEffect(); break;
 949                 default:
 950                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 951                         break;
 952         }
 953
 954         time = savetime;
 955 };
 956 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 957 // used when an entity changes its type. For an entity that someone interacts
 958 // with others, make sure it can no longer do so.
 959 void Ent_Remove()
 960 {
 961         if(self.entremove)
 962                 self.entremove();
 963
 964         self.enttype = 0;
 965         self.classname = "";
 966         self.draw = menu_sub_null;
 967         self.entremove = menu_sub_null;
 968         // TODO possibly set more stuff to defaults
 969 }
 970 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 971 void CSQC_Ent_Remove()
 972 {
 973         if(self.enttype)
 974                 Ent_Remove();
 975         remove(self);
 976 }
 977
 978 void Gamemode_Init()
 979 {
 980         if(gametype == GAME_ONSLAUGHT) {
 981                 print(strcat("Using ", minimapname, " as minimap.\n"));
 982                 precache_pic("gfx/ons-cp-neutral.tga");
 983                 precache_pic("gfx/ons-cp-red.tga");
 984                 precache_pic("gfx/ons-cp-blue.tga");
 985                 precache_pic("gfx/ons-frame.tga");
 986                 precache_pic("gfx/ons-frame-team.tga");
 987         }
 988
 989         if not(isdemo())
 990         {
 991                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
 992                 calledhooks |= HOOK_START;
 993         }
 994 }
 995 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 996 void CSQC_Parse_StuffCmd(string strMessage)
 997 {
 998         localcmd(strMessage);
 999 }
1000 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1001 void CSQC_Parse_Print(string strMessage)
1002 {
1003         print(ColorTranslateRGB(strMessage));
1004 }
1005
1006 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1007 void CSQC_Parse_CenterPrint(string strMessage)
1008 {
1009         centerprint(strMessage);
1010 }
1011
1012 string notranslate_fogcmd1 = "\nfog ";
1013 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1014 void Fog_Force()
1015 {
1016         // TODO somehow thwart prvm_globalset client ...
1017
1018         if(forcefog != "")
1019                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1020 }
1021
1022 void Gamemode_Init();
1023 void Ent_ScoresInfo()
1024 {
1025         float i;
1026         self.classname = "ent_client_scores_info";
1027         gametype = ReadByte();
1028         for(i = 0; i < MAX_SCORE; ++i)
1029         {
1030                 scores_label[i] = strzone(ReadString());
1031                 scores_flags[i] = ReadByte();
1032         }
1033         for(i = 0; i < MAX_TEAMSCORE; ++i)
1034         {
1035                 teamscores_label[i] = strzone(ReadString());
1036                 teamscores_flags[i] = ReadByte();
1037         }
1038         HUD_InitScores();
1039         Gamemode_Init();
1040 }
1041
1042 void Ent_Init()
1043 {
1044         self.classname = "ent_client_init";
1045
1046         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1047
1048         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1049         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1050         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1051         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1052         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1053         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1054         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1055         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1056         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1057         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1058         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1059         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1060
1061         if(forcefog)
1062                 strunzone(forcefog);
1063         forcefog = strzone(ReadString());
1064
1065         armorblockpercent = ReadByte() / 255.0;
1066
1067         g_weaponswitchdelay = ReadByte() / 255.0;
1068
1069         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1070         g_balance_grenadelauncher_bouncestop = ReadCoord();
1071         g_balance_electro_secondary_bouncefactor = ReadCoord();
1072         g_balance_electro_secondary_bouncestop = ReadCoord();
1073
1074         nex_scope = !ReadByte();
1075         sniperrifle_scope = !ReadByte();
1076
1077         serverflags = ReadByte();
1078
1079         minelayer_maxmines = ReadByte();
1080
1081         hagar_maxrockets = ReadByte();
1082
1083         g_trueaim_minrange = ReadCoord();
1084
1085         if(!postinit)
1086                 PostInit();
1087 }
1088
1089 void Net_ReadRace()
1090 {
1091         float b;
1092
1093         b = ReadByte();
1094
1095         switch(b)
1096         {
1097                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1098                         race_checkpoint = ReadByte();
1099                         race_time = ReadInt24_t();
1100                         race_previousbesttime = ReadInt24_t();
1101                         if(race_previousbestname)
1102                                 strunzone(race_previousbestname);
1103                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1104
1105                         race_checkpointtime = time;
1106
1107                         if(race_checkpoint == 0 || race_checkpoint == 254)
1108                         {
1109                                 race_penaltyaccumulator = 0;
1110                                 race_laptime = time; // valid
1111                         }
1112
1113                         break;
1114
1115                 case RACE_NET_CHECKPOINT_CLEAR:
1116                         race_laptime = 0;
1117                         race_checkpointtime = 0;
1118                         break;
1119
1120                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1121                         race_laptime = ReadCoord();
1122                         race_checkpointtime = -99999;
1123                         // fall through
1124                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1125                         race_nextcheckpoint = ReadByte();
1126
1127                         race_nextbesttime = ReadInt24_t();
1128                         if(race_nextbestname)
1129                                 strunzone(race_nextbestname);
1130                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1131                         break;
1132
1133                 case RACE_NET_CHECKPOINT_HIT_RACE:
1134                         race_mycheckpoint = ReadByte();
1135                         race_mycheckpointtime = time;
1136                         race_mycheckpointdelta = ReadInt24_t();
1137                         race_mycheckpointlapsdelta = ReadByte();
1138                         if(race_mycheckpointlapsdelta >= 128)
1139                                 race_mycheckpointlapsdelta -= 256;
1140                         if(race_mycheckpointenemy)
1141                                 strunzone(race_mycheckpointenemy);
1142                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1143                         break;
1144
1145                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1146                         race_othercheckpoint = ReadByte();
1147                         race_othercheckpointtime = time;
1148                         race_othercheckpointdelta = ReadInt24_t();
1149                         race_othercheckpointlapsdelta = ReadByte();
1150                         if(race_othercheckpointlapsdelta >= 128)
1151                                 race_othercheckpointlapsdelta -= 256;
1152                         if(race_othercheckpointenemy)
1153                                 strunzone(race_othercheckpointenemy);
1154                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1155                         break;
1156
1157                 case RACE_NET_PENALTY_RACE:
1158                         race_penaltyeventtime = time;
1159                         race_penaltytime = ReadShort();
1160                         //race_penaltyaccumulator += race_penaltytime;
1161                         if(race_penaltyreason)
1162                                 strunzone(race_penaltyreason);
1163                         race_penaltyreason = strzone(ReadString());
1164                         break;
1165
1166                 case RACE_NET_PENALTY_QUALIFYING:
1167                         race_penaltyeventtime = time;
1168                         race_penaltytime = ReadShort();
1169                         race_penaltyaccumulator += race_penaltytime;
1170                         if(race_penaltyreason)
1171                                 strunzone(race_penaltyreason);
1172                         race_penaltyreason = strzone(ReadString());
1173                         break;
1174
1175                 case RACE_NET_SERVER_RECORD:
1176                         race_server_record = ReadInt24_t();
1177                         break;
1178                 case RACE_NET_SPEED_AWARD:
1179                         race_speedaward = ReadInt24_t();
1180                         if(race_speedaward_holder)
1181                                 strunzone(race_speedaward_holder);
1182                         race_speedaward_holder = strzone(ReadString());
1183                         break;
1184                 case RACE_NET_SPEED_AWARD_BEST:
1185                         race_speedaward_alltimebest = ReadInt24_t();
1186                         if(race_speedaward_alltimebest_holder)
1187                                 strunzone(race_speedaward_alltimebest_holder);
1188                         race_speedaward_alltimebest_holder = strzone(ReadString());
1189                         break;
1190                 case RACE_NET_SERVER_RANKINGS:
1191                         float pos, prevpos, del;
1192                         pos = ReadShort();
1193                         prevpos = ReadShort();
1194                         del = ReadShort();
1195
1196                         // move other rankings out of the way
1197                         float i;
1198                         if (prevpos) {
1199                                 for (i=prevpos-1;i>pos-1;--i) {
1200                                         grecordtime[i] = grecordtime[i-1];
1201                                         if(grecordholder[i])
1202                                                 strunzone(grecordholder[i]);
1203                                         grecordholder[i] = strzone(grecordholder[i-1]);
1204                                 }
1205                         } else if (del) { // a record has been deleted by the admin
1206                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1207                                         if (i == RANKINGS_CNT-1) { // clear out last record
1208                                                 grecordtime[i] = 0;
1209                                                 if (grecordholder[i])
1210                                                         strunzone(grecordholder[i]);
1211                                                 grecordholder[i] = string_null;
1212                                         }
1213                                         else {
1214                                                 grecordtime[i] = grecordtime[i+1];
1215                                                 if (grecordholder[i])
1216                                                         strunzone(grecordholder[i]);
1217                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1218                                         }
1219                                 }
1220                         } else { // player has no ranked record yet
1221                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1222                                         grecordtime[i] = grecordtime[i-1];
1223                                         if(grecordholder[i])
1224                                                 strunzone(grecordholder[i]);
1225                                         grecordholder[i] = strzone(grecordholder[i-1]);
1226                                 }
1227                         }
1228
1229                         // store new ranking
1230                         if(grecordholder[pos-1] != "")
1231                                 strunzone(grecordholder[pos-1]);
1232                         grecordholder[pos-1] = strzone(ReadString());
1233                         grecordtime[pos-1] = ReadInt24_t();
1234                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1235                                 race_myrank = pos;
1236                         break;
1237                 case RACE_NET_SERVER_STATUS:
1238                         race_status = ReadShort();
1239                         if(race_status_name)
1240                                 strunzone(race_status_name);
1241                         race_status_name = strzone(ReadString());
1242         }
1243 }
1244
1245 void Net_ReadSpawn()
1246 {
1247         zoomin_effect = 1;
1248         current_viewzoom = 0.6;
1249 }
1250
1251 void Net_TeamNagger()
1252 {
1253         teamnagger = 1;
1254 }
1255
1256 void Net_ReadPingPLReport()
1257 {
1258         float e, pi, pl, ml;
1259         e = ReadByte();
1260         pi = ReadShort();
1261         pl = ReadByte();
1262         ml = ReadByte();
1263         if not(playerslots[e])
1264                 return;
1265         playerslots[e].ping = pi;
1266         playerslots[e].ping_packetloss = pl / 255.0;
1267         playerslots[e].ping_movementloss = ml / 255.0;
1268 }
1269
1270 void Net_VoteDialog(float highlight) {
1271         if(highlight) {
1272                 vote_highlighted = ReadByte();
1273                 return;
1274         }
1275
1276         vote_yescount = ReadByte();
1277         vote_nocount = ReadByte();
1278         vote_needed = ReadByte();
1279         vote_active = 1;
1280 }
1281
1282 void Net_VoteDialogReset() {
1283         vote_active = 0;
1284 }
1285
1286 void Net_Notify() {
1287         float type;
1288         type = ReadByte();
1289
1290         if(type == CSQC_KILLNOTIFY)
1291         {
1292                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1293         }
1294         else if(type == CSQC_CENTERPRINT)
1295         {
1296                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1297         }
1298 }
1299
1300 void Net_WeaponComplain() {
1301         complain_weapon = ReadByte();
1302
1303         if(complain_weapon_name)
1304                 strunzone(complain_weapon_name);
1305         complain_weapon_name = strzone(ReadString());
1306
1307         complain_weapon_type = ReadByte();
1308
1309         complain_weapon_time = time;
1310         weapontime = time; // ping the weapon panel
1311 }
1312
1313 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1314 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1315 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1316 float CSQC_Parse_TempEntity()
1317 {
1318         local float bHandled;
1319                 bHandled  = true;
1320         // Acquire TE ID
1321         local float nTEID;
1322                 nTEID = ReadByte();
1323
1324                 // NOTE: Could just do return instead of break...
1325         switch(nTEID)
1326         {
1327                 case TE_CSQC_TARGET_MUSIC:
1328                         Net_TargetMusic();
1329                         bHandled = true;
1330                         break;
1331                 case TE_CSQC_PICTURE:
1332                         Net_MapVote_Picture();
1333                         bHandled = true;
1334                         break;
1335                 case TE_CSQC_RACE:
1336                         Net_ReadRace();
1337                         bHandled = true;
1338                         break;
1339                 case TE_CSQC_SPAWN:
1340                         Net_ReadSpawn();
1341                         bHandled = true;
1342                         break;
1343                 case TE_CSQC_ZCURVEPARTICLES:
1344                         Net_ReadZCurveParticles();
1345                         bHandled = true;
1346                         break;
1347                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1348                         Net_ReadNexgunBeamParticle();
1349                         bHandled = true;
1350                         break;
1351                 case TE_CSQC_TEAMNAGGER:
1352                         Net_TeamNagger();
1353                         bHandled = true;
1354                         break;
1355                 case TE_CSQC_VOTE:
1356                         Net_VoteDialog(ReadByte());
1357                         bHandled = true;
1358                         break;
1359                 case TE_CSQC_VOTERESET:
1360                         Net_VoteDialogReset();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_LIGHTNINGARC:
1364                         Net_ReadLightningarc();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_PINGPLREPORT:
1368                         Net_ReadPingPLReport();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_ANNOUNCE:
1372                         announce_snd = strzone(ReadString());
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_NOTIFY:
1376                         Net_Notify();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_WEAPONCOMPLAIN:
1380                         Net_WeaponComplain();
1381                         bHandled = true;
1382                         break;
1383                 default:
1384                         // No special logic for this temporary entity; return 0 so the engine can handle it
1385                         bHandled = false;
1386                         break;
1387         }
1388
1389         return bHandled;
1390 }
1391
1392 string getcommandkey(string text, string command)
1393 {
1394         string keys;
1395         float n, j, k, l;
1396
1397         if (!hud_showbinds)
1398                 return text;
1399
1400         keys = db_get(binddb, command);
1401         if (!keys)
1402         {
1403                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1404                 for(j = 0; j < n; ++j)
1405                 {
1406                         k = stof(argv(j));
1407                         if(k != -1)
1408                         {
1409                                 if ("" == keys)
1410                                         keys = keynumtostring(k);
1411                                 else
1412                                         keys = strcat(keys, ", ", keynumtostring(k));
1413
1414                                 ++l;
1415                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1416                         }
1417
1418                 }
1419                 db_put(binddb, command, keys);
1420         }
1421
1422         if ("" == keys) {
1423                 if (hud_showbinds > 1)
1424                         return sprintf(_("%s (not bound)"), text);
1425                 else
1426                         return text;
1427         }
1428         else if (hud_showbinds > 1)
1429                 return sprintf(_("%s (%s)"), text, keys);
1430         else
1431                 return keys;
1432 }