qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = menu_sub_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(FL_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182     Announcer_Precache();
 183         Tuba_Precache();
 184
 185         if(autocvar_cl_reticle)
 186         {
 187                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 188                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 189         }
 190
 191         get_mi_min_max_texcoords(1); // try the CLEVER way first
 192         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 193         shortmapname = mi_shortname;
 194
 195         if(precache_pic(minimapname) == "")
 196         {
 197                 // but maybe we have a non-clever minimap
 198                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 199                 if(precache_pic(minimapname) == "")
 200                         minimapname = ""; // FAIL
 201                 else
 202                         get_mi_min_max_texcoords(0); // load new texcoords
 203         }
 204
 205         mi_center = (mi_min + mi_max) * 0.5;
 206         mi_scale = mi_max - mi_min;
 207         minimapname = strzone(minimapname);
 208
 209         WarpZone_Init();
 210
 211         hud_configure_prev = -1;
 212         tab_panel = -1;
 213
 214         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 215 }
 216
 217 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 218 void Shutdown(void)
 219 {
 220 #ifdef USE_FTE
 221 #pragma TARGET id
 222         if(!__engine_check)
 223                 return 0;
 224 #pragma TARGET fte
 225 #endif
 226
 227         WarpZone_Shutdown();
 228
 229         remove(teams);
 230         remove(players);
 231         db_close(binddb);
 232         db_close(tempdb);
 233         if(autocvar_cl_db_saveasdump)
 234                 db_dump(ClientProgsDB, "client.db");
 235         else
 236                 db_save(ClientProgsDB, "client.db");
 237         db_close(ClientProgsDB);
 238
 239         if(camera_active)
 240                 cvar_set("chase_active",ftos(chase_active_backup));
 241
 242         // unset the event chasecam's chase_active
 243         if(autocvar_chase_active < 0)
 244                 cvar_set("chase_active", "0");
 245
 246         if not(isdemo())
 247         {
 248                 if not(calledhooks & HOOK_START)
 249                         localcmd("\n_cl_hook_gamestart nop\n");
 250                 if not(calledhooks & HOOK_END)
 251                         localcmd("\ncl_hook_gameend\n");
 252         }
 253 }
 254
 255 .float has_team;
 256 float SetTeam(entity o, float Team)
 257 {
 258         entity tm;
 259         if(teamplay)
 260         {
 261                 switch(Team)
 262                 {
 263                         case -1:
 264                         case FL_TEAM_1:
 265                         case FL_TEAM_2:
 266                         case FL_TEAM_3:
 267                         case FL_TEAM_4:
 268                                 break;
 269                         default:
 270                                 if(GetTeam(Team, false) == world)
 271                                 {
 272                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 273                                         Team = FL_SPECTATOR;
 274                                 }
 275                                 break;
 276                 }
 277         }
 278         else
 279         {
 280                 switch(Team)
 281                 {
 282                         case -1:
 283                         case 0:
 284                                 break;
 285                         default:
 286                                 if(GetTeam(Team, false) == world)
 287                                 {
 288                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 289                                         Team = FL_SPECTATOR;
 290                                 }
 291                                 break;
 292                 }
 293         }
 294         if(Team == -1) // leave
 295         {
 296                 if(o.has_team)
 297                 {
 298                         tm = GetTeam(o.team, false);
 299                         tm.team_size -= 1;
 300                         o.has_team = 0;
 301                         return TRUE;
 302                 }
 303         }
 304         else
 305         {
 306                 if not(o.has_team)
 307                 {
 308                         o.team = Team;
 309                         tm = GetTeam(Team, true);
 310                         tm.team_size += 1;
 311                         o.has_team = 1;
 312                         return TRUE;
 313                 }
 314                 else if(Team != o.team)
 315                 {
 316                         tm = GetTeam(o.team, false);
 317                         tm.team_size -= 1;
 318                         o.team = Team;
 319                         tm = GetTeam(Team, true);
 320                         tm.team_size += 1;
 321                         return TRUE;
 322                 }
 323         }
 324         return FALSE;
 325 }
 326
 327 void Playerchecker_Think()
 328 {
 329         float i;
 330         entity e;
 331         for(i = 0; i < maxclients; ++i)
 332         {
 333                 e = playerslots[i];
 334                 if(GetPlayerName(i) == "")
 335                 {
 336                         if(e.sort_prev)
 337                         {
 338                                 // player disconnected
 339                                 SetTeam(e, -1);
 340                                 RemovePlayer(e);
 341                                 e.sort_prev = world;
 342                                 //e.gotscores = 0;
 343                         }
 344                 }
 345                 else
 346                 {
 347                         if not(e.sort_prev)
 348                         {
 349                                 // player connected
 350                                 if not(e)
 351                                         playerslots[i] = e = spawn();
 352                                 e.sv_entnum = i;
 353                                 e.ping = 0;
 354                                 e.ping_packetloss = 0;
 355                                 e.ping_movementloss = 0;
 356                                 //e.gotscores = 0; // we might already have the scores...
 357                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 358                                 RegisterPlayer(e);
 359                                 HUD_UpdatePlayerPos(e);
 360                         }
 361                 }
 362         }
 363         self.nextthink = time + 0.2;
 364 }
 365
 366 void Porto_Init();
 367 void TrueAim_Init();
 368 void PostInit(void)
 369 {
 370         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 371
 372         entity playerchecker;
 373         playerchecker = spawn();
 374         playerchecker.think = Playerchecker_Think;
 375         playerchecker.nextthink = time + 0.2;
 376
 377         Porto_Init();
 378         TrueAim_Init();
 379
 380         postinit = true;
 381 }
 382
 383 float button_zoom;
 384
 385 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 386 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 387 // All keys are in ascii.
 388 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 389 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 390 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 391 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 392 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 393 {
 394         float bSkipKey;
 395         bSkipKey = false;
 396
 397         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 398                 return true;
 399
 400         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 401                 return true;
 402
 403         if(menu_visible)
 404                 if(menu_action(bInputType, nPrimary, nSecondary))
 405                         return TRUE;
 406
 407         return bSkipKey;
 408 }
 409
 410 // END REQUIRED CSQC FUNCTIONS
 411 // --------------------------------------------------------------------------
 412
 413 // --------------------------------------------------------------------------
 414 // BEGIN OPTIONAL CSQC FUNCTIONS
 415 void Ent_RemoveEntCS()
 416 {
 417         entcs_receiver[self.sv_entnum] = world;
 418 }
 419 void Ent_ReadEntCS()
 420 {
 421         float sf;
 422         InterpolateOrigin_Undo();
 423
 424         self.classname = "entcs_receiver";
 425         sf = ReadByte();
 426
 427         if(sf & 1)
 428                 self.sv_entnum = ReadByte();
 429         if(sf & 2)
 430         {
 431                 self.origin_x = ReadShort();
 432                 self.origin_y = ReadShort();
 433                 self.origin_z = ReadShort();
 434         }
 435         if(sf & 4)
 436         {
 437                 self.angles_y = ReadByte() * 360.0 / 256;
 438                 self.angles_x = self.angles_z = 0;
 439         }
 440         if(sf & 8)
 441                 self.healthvalue = ReadByte() * 10;
 442         if(sf & 16)
 443                 self.armorvalue = ReadByte() * 10;
 444
 445         entcs_receiver[self.sv_entnum] = self;
 446         self.entremove = Ent_RemoveEntCS;
 447
 448         InterpolateOrigin_Note();
 449 }
 450
 451 void Ent_Remove();
 452
 453 void Ent_RemovePlayerScore()
 454 {
 455         float i;
 456
 457         if(self.owner)
 458         {
 459                 SetTeam(self.owner, -1);
 460                 self.owner.gotscores = 0;
 461                 for(i = 0; i < MAX_SCORE; ++i)
 462                         self.owner.(scores[i]) = 0; // clear all scores
 463         }
 464 }
 465
 466 void Ent_ReadPlayerScore()
 467 {
 468         float i, n;
 469         float isNew;
 470         entity o;
 471
 472         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 473         // (no I've never heard of M-x replace-string, sed, or anything like that)
 474         isNew = !self.owner; // workaround for DP bug
 475         n = ReadByte()-1;
 476
 477 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 478         if(!isNew && n != self.sv_entnum)
 479         {
 480                 //print(_("A CSQC entity changed its owner!\n"));
 481                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 482                 isNew = true;
 483                 Ent_Remove();
 484                 self.enttype = ENT_CLIENT_SCORES;
 485         }
 486 #endif
 487
 488         self.sv_entnum = n;
 489
 490         if not(playerslots[self.sv_entnum])
 491                 playerslots[self.sv_entnum] = spawn();
 492         o = self.owner = playerslots[self.sv_entnum];
 493         o.sv_entnum = self.sv_entnum;
 494         o.gotscores = 1;
 495
 496         //if not(o.sort_prev)
 497         //      RegisterPlayer(o);
 498         //playerchecker will do this for us later, if it has not already done so
 499
 500         float sf, lf;
 501 #if MAX_SCORE <= 8
 502         sf = ReadByte();
 503         lf = ReadByte();
 504 #else
 505         sf = ReadShort();
 506         lf = ReadShort();
 507 #endif
 508         float p;
 509         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 510                 if(sf & p)
 511                 {
 512                         if(lf & p)
 513                                 o.(scores[i]) = ReadInt24_t();
 514                         else
 515                                 o.(scores[i]) = ReadChar();
 516                 }
 517
 518         if(o.sort_prev)
 519                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 520
 521         self.entremove = Ent_RemovePlayerScore;
 522 }
 523
 524 void Ent_ReadTeamScore()
 525 {
 526         float i;
 527         entity o;
 528
 529         self.team = ReadByte();
 530         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 531
 532         float sf, lf;
 533 #if MAX_TEAMSCORE <= 8
 534         sf = ReadByte();
 535         lf = ReadByte();
 536 #else
 537         sf = ReadShort();
 538         lf = ReadShort();
 539 #endif
 540         float p;
 541         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 542                 if(sf & p)
 543                 {
 544                         if(lf & p)
 545                                 o.(teamscores[i]) = ReadInt24_t();
 546                         else
 547                                 o.(teamscores[i]) = ReadChar();
 548                 }
 549
 550         HUD_UpdateTeamPos(o);
 551 }
 552
 553 void Ent_ClientData()
 554 {
 555         float f;
 556         float newspectatee_status;
 557
 558         f = ReadByte();
 559
 560         scoreboard_showscores_force = (f & 1);
 561
 562         if(f & 2)
 563         {
 564                 newspectatee_status = ReadByte();
 565                 if(newspectatee_status == player_localnum + 1)
 566                         newspectatee_status = -1; // observing
 567         }
 568         else
 569                 newspectatee_status = 0;
 570
 571         spectatorbutton_zoom = (f & 4);
 572
 573         if(f & 8)
 574         {
 575                 angles_held_status = 1;
 576                 angles_held_x = ReadAngle();
 577                 angles_held_y = ReadAngle();
 578                 angles_held_z = 0;
 579         }
 580         else
 581                 angles_held_status = 0;
 582
 583         if(newspectatee_status != spectatee_status)
 584         {
 585                 // clear race stuff
 586                 race_laptime = 0;
 587                 race_checkpointtime = 0;
 588         }
 589         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 590         {
 591                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 592                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 593                 )
 594                         prev_p_health = -1;
 595                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 596                         prev_health = -1;
 597         }
 598         spectatee_status = newspectatee_status;
 599
 600         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 601 }
 602
 603 void Ent_Nagger()
 604 {
 605         float nags, i, j, b, f;
 606
 607         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 608
 609         if(!(nags & 4))
 610         {
 611                 if(vote_called_vote)
 612                         strunzone(vote_called_vote);
 613                 vote_called_vote = string_null;
 614                 vote_active = 0;
 615         }
 616         else
 617         {
 618                 vote_active = 1;
 619         }
 620
 621         if(nags & 64)
 622         {
 623                 vote_yescount = ReadByte();
 624                 vote_nocount = ReadByte();
 625                 vote_needed = ReadByte();
 626                 vote_highlighted = ReadChar();
 627         }
 628
 629         if(nags & 128)
 630         {
 631                 if(vote_called_vote)
 632                         strunzone(vote_called_vote);
 633                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 634         }
 635
 636         if(nags & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].ready = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if not(f & b)
 646                                         if(playerslots[j])
 647                                                 playerslots[j].ready = 0;
 648                 }
 649         }
 650
 651         ready_waiting = (nags & 1);
 652         ready_waiting_for_me = (nags & 2);
 653         vote_waiting = (nags & 4);
 654         vote_waiting_for_me = (nags & 8);
 655         warmup_stage = (nags & 16);
 656 }
 657
 658 void Ent_RandomSeed()
 659 {
 660         float s;
 661         prandom_debug();
 662         s = ReadShort();
 663         psrandom(s);
 664 }
 665
 666 void Ent_ReadAccuracy(void)
 667 {
 668         float sf, f, w, b;
 669         sf = ReadInt24_t();
 670         if(sf == 0)
 671         {
 672                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 673                         weapon_accuracy[w] = -1;
 674                 return;
 675         }
 676
 677         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 678         {
 679                 if(sf & f)
 680                 {
 681                         b = ReadByte();
 682                         if(b == 0)
 683                                 weapon_accuracy[w] = -1;
 684                         else if(b == 255)
 685                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 686                         else
 687                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 688                 }
 689                 if(f == 0x800000)
 690                         f = 1;
 691                 else
 692                         f *= 2;
 693         }
 694 }
 695
 696 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 697 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 698 void Ent_RadarLink();
 699 void Ent_Init();
 700 void Ent_ScoresInfo();
 701 void CSQC_Ent_Update(float bIsNewEntity)
 702 {
 703         float t;
 704         float savetime;
 705         t = ReadByte();
 706
 707         if(autocvar_developer_csqcentities)
 708                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 709
 710         // set up the "time" global for received entities to be correct for interpolation purposes
 711         savetime = time;
 712         if(servertime)
 713         {
 714                 time = servertime;
 715         }
 716         else
 717         {
 718                 serverprevtime = time;
 719                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 720                 time = serverprevtime + serverdeltatime;
 721         }
 722
 723 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 724         if(self.enttype)
 725         {
 726                 if(t != self.enttype || bIsNewEntity)
 727                 {
 728                         //print(_("A CSQC entity changed its type!\n"));
 729                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 730                         Ent_Remove();
 731                         clearentity(self);
 732                         bIsNewEntity = 1;
 733                 }
 734         }
 735         else
 736         {
 737                 if(!bIsNewEntity)
 738                 {
 739                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 740                         bIsNewEntity = 1;
 741                 }
 742         }
 743 #endif
 744         self.enttype = t;
 745         switch(t)
 746         {
 747                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 748                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 749                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 750                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 751                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 752                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 753                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 754                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 755                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 756                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 757                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 758                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 759                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 760                 case ENT_CLIENT_INIT: Ent_Init(); break;
 761                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 762                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 763                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 764                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 765                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 766                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 767                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 768                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 769                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 770                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 771                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 772                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 773                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 774                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 775                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 776                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 777                 case ENT_CLIENT_TURRET: ent_turret(); break;
 778                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 779                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 780                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 781                 default:
 782                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 783                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 784                         break;
 785         }
 786
 787         time = savetime;
 788 }
 789 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 790 // used when an entity changes its type. For an entity that someone interacts
 791 // with others, make sure it can no longer do so.
 792 void Ent_Remove()
 793 {
 794         if(self.entremove)
 795                 self.entremove();
 796
 797         self.enttype = 0;
 798         self.classname = "";
 799         self.draw = menu_sub_null;
 800         self.entremove = menu_sub_null;
 801         // TODO possibly set more stuff to defaults
 802 }
 803 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 804 void CSQC_Ent_Remove()
 805 {
 806         if(autocvar_developer_csqcentities)
 807                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 808
 809         if(wasfreed(self))
 810         {
 811                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 812                 return;
 813         }
 814         if(self.enttype)
 815                 Ent_Remove();
 816         remove(self);
 817 }
 818
 819 void Gamemode_Init()
 820 {
 821         if not(isdemo())
 822         {
 823                 if(!(calledhooks & HOOK_START))
 824                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 825                 calledhooks |= HOOK_START;
 826         }
 827 }
 828 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 829 void CSQC_Parse_StuffCmd(string strMessage)
 830 {
 831         if(autocvar_developer_csqcentities)
 832                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 833
 834         localcmd(strMessage);
 835 }
 836 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 837 void CSQC_Parse_Print(string strMessage)
 838 {
 839         if(autocvar_developer_csqcentities)
 840                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 841
 842         print(ColorTranslateRGB(strMessage));
 843 }
 844
 845 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 846 void CSQC_Parse_CenterPrint(string strMessage)
 847 {
 848         if(autocvar_developer_csqcentities)
 849                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 850
 851         centerprint_hud(strMessage);
 852 }
 853
 854 string notranslate_fogcmd1 = "\nfog ";
 855 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 856 void Fog_Force()
 857 {
 858         // TODO somehow thwart prvm_globalset client ...
 859
 860         if(forcefog != "")
 861                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 862 }
 863
 864 void Gamemode_Init();
 865 void Ent_ScoresInfo()
 866 {
 867         float i;
 868         self.classname = "ent_client_scores_info";
 869         gametype = ReadInt24_t();
 870         for(i = 0; i < MAX_SCORE; ++i)
 871         {
 872                 scores_label[i] = strzone(ReadString());
 873                 scores_flags[i] = ReadByte();
 874         }
 875         for(i = 0; i < MAX_TEAMSCORE; ++i)
 876         {
 877                 teamscores_label[i] = strzone(ReadString());
 878                 teamscores_flags[i] = ReadByte();
 879         }
 880         HUD_InitScores();
 881         Gamemode_Init();
 882 }
 883
 884 void Ent_Init()
 885 {
 886         self.classname = "ent_client_init";
 887
 888         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 889
 890         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 891         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 892         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 893         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 894         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 895         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 896         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 897         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 898         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 899         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 900         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 901         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 902
 903         if(forcefog)
 904                 strunzone(forcefog);
 905         forcefog = strzone(ReadString());
 906
 907         armorblockpercent = ReadByte() / 255.0;
 908
 909         g_weaponswitchdelay = ReadByte() / 255.0;
 910
 911         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 912         g_balance_grenadelauncher_bouncestop = ReadCoord();
 913         g_balance_electro_secondary_bouncefactor = ReadCoord();
 914         g_balance_electro_secondary_bouncestop = ReadCoord();
 915
 916         nex_scope = !ReadByte();
 917         rifle_scope = !ReadByte();
 918
 919         serverflags = ReadByte();
 920
 921         minelayer_maxmines = ReadByte();
 922
 923         hagar_maxrockets = ReadByte();
 924
 925         g_trueaim_minrange = ReadCoord();
 926         g_balance_porto_secondary = ReadByte();
 927
 928         if(!postinit)
 929                 PostInit();
 930 }
 931
 932 void Net_ReadRace()
 933 {
 934         float b;
 935
 936         b = ReadByte();
 937
 938         switch(b)
 939         {
 940                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 941                         race_checkpoint = ReadByte();
 942                         race_time = ReadInt24_t();
 943                         race_previousbesttime = ReadInt24_t();
 944                         if(race_previousbestname)
 945                                 strunzone(race_previousbestname);
 946                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 947
 948                         race_checkpointtime = time;
 949
 950                         if(race_checkpoint == 0 || race_checkpoint == 254)
 951                         {
 952                                 race_penaltyaccumulator = 0;
 953                                 race_laptime = time; // valid
 954                         }
 955
 956                         break;
 957
 958                 case RACE_NET_CHECKPOINT_CLEAR:
 959                         race_laptime = 0;
 960                         race_checkpointtime = 0;
 961                         break;
 962
 963                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 964                         race_laptime = ReadCoord();
 965                         race_checkpointtime = -99999;
 966                         // fall through
 967                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 968                         race_nextcheckpoint = ReadByte();
 969
 970                         race_nextbesttime = ReadInt24_t();
 971                         if(race_nextbestname)
 972                                 strunzone(race_nextbestname);
 973                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 974                         break;
 975
 976                 case RACE_NET_CHECKPOINT_HIT_RACE:
 977                         race_mycheckpoint = ReadByte();
 978                         race_mycheckpointtime = time;
 979                         race_mycheckpointdelta = ReadInt24_t();
 980                         race_mycheckpointlapsdelta = ReadByte();
 981                         if(race_mycheckpointlapsdelta >= 128)
 982                                 race_mycheckpointlapsdelta -= 256;
 983                         if(race_mycheckpointenemy)
 984                                 strunzone(race_mycheckpointenemy);
 985                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 986                         break;
 987
 988                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 989                         race_othercheckpoint = ReadByte();
 990                         race_othercheckpointtime = time;
 991                         race_othercheckpointdelta = ReadInt24_t();
 992                         race_othercheckpointlapsdelta = ReadByte();
 993                         if(race_othercheckpointlapsdelta >= 128)
 994                                 race_othercheckpointlapsdelta -= 256;
 995                         if(race_othercheckpointenemy)
 996                                 strunzone(race_othercheckpointenemy);
 997                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 998                         break;
 999
1000                 case RACE_NET_PENALTY_RACE:
1001                         race_penaltyeventtime = time;
1002                         race_penaltytime = ReadShort();
1003                         //race_penaltyaccumulator += race_penaltytime;
1004                         if(race_penaltyreason)
1005                                 strunzone(race_penaltyreason);
1006                         race_penaltyreason = strzone(ReadString());
1007                         break;
1008
1009                 case RACE_NET_PENALTY_QUALIFYING:
1010                         race_penaltyeventtime = time;
1011                         race_penaltytime = ReadShort();
1012                         race_penaltyaccumulator += race_penaltytime;
1013                         if(race_penaltyreason)
1014                                 strunzone(race_penaltyreason);
1015                         race_penaltyreason = strzone(ReadString());
1016                         break;
1017
1018                 case RACE_NET_SERVER_RECORD:
1019                         race_server_record = ReadInt24_t();
1020                         break;
1021                 case RACE_NET_SPEED_AWARD:
1022                         race_speedaward = ReadInt24_t();
1023                         if(race_speedaward_holder)
1024                                 strunzone(race_speedaward_holder);
1025                         race_speedaward_holder = strzone(ReadString());
1026                         break;
1027                 case RACE_NET_SPEED_AWARD_BEST:
1028                         race_speedaward_alltimebest = ReadInt24_t();
1029                         if(race_speedaward_alltimebest_holder)
1030                                 strunzone(race_speedaward_alltimebest_holder);
1031                         race_speedaward_alltimebest_holder = strzone(ReadString());
1032                         break;
1033                 case RACE_NET_SERVER_RANKINGS:
1034                         float pos, prevpos, del;
1035                         pos = ReadShort();
1036                         prevpos = ReadShort();
1037                         del = ReadShort();
1038
1039                         // move other rankings out of the way
1040                         float i;
1041                         if (prevpos) {
1042                                 for (i=prevpos-1;i>pos-1;--i) {
1043                                         grecordtime[i] = grecordtime[i-1];
1044                                         if(grecordholder[i])
1045                                                 strunzone(grecordholder[i]);
1046                                         grecordholder[i] = strzone(grecordholder[i-1]);
1047                                 }
1048                         } else if (del) { // a record has been deleted by the admin
1049                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1050                                         if (i == RANKINGS_CNT-1) { // clear out last record
1051                                                 grecordtime[i] = 0;
1052                                                 if (grecordholder[i])
1053                                                         strunzone(grecordholder[i]);
1054                                                 grecordholder[i] = string_null;
1055                                         }
1056                                         else {
1057                                                 grecordtime[i] = grecordtime[i+1];
1058                                                 if (grecordholder[i])
1059                                                         strunzone(grecordholder[i]);
1060                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1061                                         }
1062                                 }
1063                         } else { // player has no ranked record yet
1064                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1065                                         grecordtime[i] = grecordtime[i-1];
1066                                         if(grecordholder[i])
1067                                                 strunzone(grecordholder[i]);
1068                                         grecordholder[i] = strzone(grecordholder[i-1]);
1069                                 }
1070                         }
1071
1072                         // store new ranking
1073                         if(grecordholder[pos-1] != "")
1074                                 strunzone(grecordholder[pos-1]);
1075                         grecordholder[pos-1] = strzone(ReadString());
1076                         grecordtime[pos-1] = ReadInt24_t();
1077                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1078                                 race_myrank = pos;
1079                         break;
1080                 case RACE_NET_SERVER_STATUS:
1081                         race_status = ReadShort();
1082                         if(race_status_name)
1083                                 strunzone(race_status_name);
1084                         race_status_name = strzone(ReadString());
1085         }
1086 }
1087
1088 void Net_ReadSpawn()
1089 {
1090         zoomin_effect = 1;
1091         current_viewzoom = 0.6;
1092 }
1093
1094 void Net_TeamNagger()
1095 {
1096         teamnagger = 1;
1097 }
1098
1099 void Net_ReadPingPLReport()
1100 {
1101         float e, pi, pl, ml;
1102         e = ReadByte();
1103         pi = ReadShort();
1104         pl = ReadByte();
1105         ml = ReadByte();
1106         if not(playerslots[e])
1107                 return;
1108         playerslots[e].ping = pi;
1109         playerslots[e].ping_packetloss = pl / 255.0;
1110         playerslots[e].ping_movementloss = ml / 255.0;
1111 }
1112
1113 void Net_WeaponComplain() {
1114         complain_weapon = ReadByte();
1115
1116         if(complain_weapon_name)
1117                 strunzone(complain_weapon_name);
1118         complain_weapon_name = strzone(ReadString());
1119
1120         complain_weapon_type = ReadByte();
1121
1122         complain_weapon_time = time;
1123         weapontime = time; // ping the weapon panel
1124 }
1125
1126 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1127 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1128 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1129 float CSQC_Parse_TempEntity()
1130 {
1131         float bHandled;
1132                 bHandled  = true;
1133         // Acquire TE ID
1134         float nTEID;
1135                 nTEID = ReadByte();
1136
1137         if(autocvar_developer_csqcentities)
1138                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1139
1140                 // NOTE: Could just do return instead of break...
1141         switch(nTEID)
1142         {
1143                 case TE_CSQC_TARGET_MUSIC:
1144                         Net_TargetMusic();
1145                         bHandled = true;
1146                         break;
1147                 case TE_CSQC_PICTURE:
1148                         Net_MapVote_Picture();
1149                         bHandled = true;
1150                         break;
1151                 case TE_CSQC_RACE:
1152                         Net_ReadRace();
1153                         bHandled = true;
1154                         break;
1155                 case TE_CSQC_SPAWN:
1156                         Net_ReadSpawn();
1157                         bHandled = true;
1158                         break;
1159                 case TE_CSQC_ZCURVEPARTICLES:
1160                         Net_ReadZCurveParticles();
1161                         bHandled = true;
1162                         break;
1163                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1164                         Net_ReadNexgunBeamParticle();
1165                         bHandled = true;
1166                         break;
1167                 case TE_CSQC_TEAMNAGGER:
1168                         Net_TeamNagger();
1169                         bHandled = true;
1170                         break;
1171                 case TE_CSQC_LIGHTNINGARC:
1172                         Net_ReadLightningarc();
1173                         bHandled = true;
1174                         break;
1175                 case TE_CSQC_PINGPLREPORT:
1176                         Net_ReadPingPLReport();
1177                         bHandled = true;
1178                         break;
1179                 case TE_CSQC_ANNOUNCE:
1180                         Announcer_Play(ReadString());
1181                         bHandled = true;
1182                         break;
1183                 case TE_CSQC_KILLNOTIFY:
1184                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1185                         bHandled = true;
1186                         break;
1187                 case TE_CSQC_KILLCENTERPRINT:
1188                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1189                         bHandled = true;
1190                         break;
1191                 case TE_CSQC_CENTERPRINT_GENERIC:
1192                         float id;
1193                         string s;
1194                         id = ReadByte();
1195                         s = ReadString();
1196                         if (id != 0 && s != "")
1197                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1198                         else
1199                                 centerprint_generic(id, s, 0, 0);
1200                         bHandled = true;
1201                         break;
1202                 case TE_CSQC_WEAPONCOMPLAIN:
1203                         Net_WeaponComplain();
1204                         bHandled = true;
1205                         break;
1206                 case TE_CSQC_VEHICLESETUP:
1207                         Net_VehicleSetup();
1208                         bHandled = true;
1209                         break;
1210                 case TE_CSQC_SVNOTICE:
1211                         cl_notice_read();
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_NOTIFICATION:
1215                         Read_Notification();
1216                         bHandled = true;
1217                         break;
1218                 default:
1219                         // No special logic for this temporary entity; return 0 so the engine can handle it
1220                         bHandled = false;
1221                         break;
1222         }
1223
1224         return bHandled;
1225 }
1226
1227 string getcommandkey(string text, string command)
1228 {
1229         string keys;
1230         float n, j, k, l;
1231
1232         if (!autocvar_hud_showbinds)
1233                 return text;
1234
1235         keys = db_get(binddb, command);
1236         if (!keys)
1237         {
1238                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1239                 for(j = 0; j < n; ++j)
1240                 {
1241                         k = stof(argv(j));
1242                         if(k != -1)
1243                         {
1244                                 if ("" == keys)
1245                                         keys = keynumtostring(k);
1246                                 else
1247                                         keys = strcat(keys, ", ", keynumtostring(k));
1248
1249                                 ++l;
1250                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1251                         }
1252
1253                 }
1254                 db_put(binddb, command, keys);
1255         }
1256
1257         if ("" == keys) {
1258                 if (autocvar_hud_showbinds > 1)
1259                         return sprintf(_("%s (not bound)"), text);
1260                 else
1261                         return text;
1262         }
1263         else if (autocvar_hud_showbinds > 1)
1264                 return sprintf(_("%s (%s)"), text, keys);
1265         else
1266                 return keys;
1267 }