qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 155         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 156
 157         get_mi_min_max_texcoords(1); // try the CLEVER way first
 158         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159         shortmapname = mi_shortname;
 160
 161         if(precache_pic(minimapname) == "")
 162         {
 163                 // but maybe we have a non-clever minimap
 164                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                 if(precache_pic(minimapname) == "")
 166                         minimapname = ""; // FAIL
 167                 else
 168                         get_mi_min_max_texcoords(0); // load new texcoords
 169         }
 170
 171         mi_center = (mi_min + mi_max) * 0.5;
 172         mi_scale = mi_max - mi_min;
 173         minimapname = strzone(minimapname);
 174
 175         WarpZone_Init();
 176
 177         hud_configure_prev = -1;
 178         tab_panel = -1;
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void CSQC_Shutdown(void)
 183 {
 184 #ifdef USE_FTE
 185 #pragma TARGET id
 186         if(!__engine_check)
 187                 return 0;
 188 #pragma TARGET fte
 189 #endif
 190
 191         WarpZone_Shutdown();
 192
 193         remove(teams);
 194         remove(players);
 195         db_close(binddb);
 196         db_close(tempdb);
 197         if(autocvar_cl_db_saveasdump)
 198                 db_dump(ClientProgsDB, "client.db");
 199         else
 200                 db_save(ClientProgsDB, "client.db");
 201         db_close(ClientProgsDB);
 202
 203         cvar_clientsettemp_restore();
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         // unset the event chasecam's chase_active
 209         if(autocvar_chase_active < 0)
 210                 cvar_set("chase_active", "0");
 211
 212         if not(isdemo())
 213         {
 214                 if not(calledhooks & HOOK_START)
 215                         localcmd("\n_cl_hook_gamestart nop\n");
 216                 if not(calledhooks & HOOK_END)
 217                         localcmd("\ncl_hook_gameend\n");
 218         }
 219 }
 220
 221 .float has_team;
 222 float SetTeam(entity o, float Team)
 223 {
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case COLOR_TEAM1:
 231                         case COLOR_TEAM2:
 232                         case COLOR_TEAM3:
 233                         case COLOR_TEAM4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == NULL)
 237                                 {
 238                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 239                                         Team = COLOR_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == NULL)
 253                                 {
 254                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 255                                         Team = COLOR_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return TRUE;
 268                 }
 269         }
 270         else
 271         {
 272                 if not(o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return TRUE;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return TRUE;
 288                 }
 289         }
 290         return FALSE;
 291 }
 292
 293 void Playerchecker_Think()
 294 {
 295         float i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(GetPlayerName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if not(e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if not(e)
 317                                         playerslots[i] = e = spawn();
 318                                 e.sv_entnum = i;
 319                                 e.ping = 0;
 320                                 e.ping_packetloss = 0;
 321                                 e.ping_movementloss = 0;
 322                                 //e.gotscores = 0; // we might already have the scores...
 323                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 324                                 RegisterPlayer(e);
 325                                 HUD_UpdatePlayerPos(e);
 326                         }
 327                 }
 328         }
 329         self.nextthink = time + 0.2;
 330 }
 331
 332 void Porto_Init();
 333 void TrueAim_Init();
 334 void PostInit(void)
 335 {
 336         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 337
 338         entity playerchecker;
 339         playerchecker = spawn();
 340         playerchecker.think = Playerchecker_Think;
 341         playerchecker.nextthink = time + 0.2;
 342
 343         Porto_Init();
 344         TrueAim_Init();
 345
 346         postinit = true;
 347 }
 348
 349 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 350 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 351 float button_zoom;
 352 void Cmd_HUD_SetFields(float);
 353 void Cmd_HUD_Help(float);
 354 float CSQC_ConsoleCommand(string strMessage)
 355 {
 356         float argc;
 357         // Tokenize String
 358         //argc = tokenize(strMessage);
 359         argc = tokenize_console(strMessage);
 360
 361         // Acquire Command
 362         local string strCmd;
 363         strCmd = argv(0);
 364
 365         if(strCmd == "hud_configure") { // config hud
 366                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 367                 return true;
 368         } else if(strCmd == "hud_save") { // save hud config
 369                 if(argv(1) == "" || argv(2)) {
 370                         print(_("Usage:\n"));
 371                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 372                 }
 373                 else
 374                         HUD_Panel_ExportCfg(argv(1));
 375                 return true;
 376         } else if(strCmd == "+button4") { // zoom
 377                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 378                 if(ignore_plus_zoom)
 379                 {
 380                         --ignore_plus_zoom;
 381                         return false;
 382                 }
 383                 button_zoom = 1;
 384                 return true;
 385         } else if(strCmd == "-button4") { // zoom
 386                 if(ignore_minus_zoom)
 387                 {
 388                         --ignore_minus_zoom;
 389                         return false;
 390                 }
 391                 button_zoom = 0;
 392                 return true;
 393         } else if(strCmd == "+button3") { // secondary
 394                 button_attack2 = 1;
 395                 return false;
 396         } else if(strCmd == "-button3") { // secondary
 397                 button_attack2 = 0;
 398                 return false;
 399         } else if(strCmd == "+showscores") {
 400                 scoreboard_showscores = true;
 401                 return true;
 402         } else if(strCmd == "-showscores") {
 403                 scoreboard_showscores = false;
 404                 return true;
 405         } else if(strCmd == "+showaccuracy") {
 406                 scoreboard_showaccuracy = true;
 407                 return true;
 408         } else if(strCmd == "-showaccuracy") {
 409                 scoreboard_showaccuracy = false;
 410                 return true;
 411         }
 412
 413         if(camera_active)
 414         if(strCmd == "+forward" || strCmd == "-back") {
 415                 ++camera_direction_x;
 416                 return true;
 417         } else if(strCmd == "-forward" || strCmd == "+back") {
 418                 --camera_direction_x;
 419                 return true;
 420         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 421                 --camera_direction_y;
 422                 return true;
 423         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 424                 ++camera_direction_y;
 425                 return true;
 426         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 427                 ++camera_direction_z;
 428                 return true;
 429         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 430                 --camera_direction_z;
 431                 return true;
 432         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 433                 ++camera_roll;
 434                 return true;
 435         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 436                 --camera_roll;
 437                 return true;
 438         }
 439
 440         return false;
 441 }
 442
 443 .vector view_ofs;
 444 entity debug_shotorg;
 445 void ShotOrg_Draw()
 446 {
 447         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 448         self.angles = view_angles;
 449         self.angles_x = -self.angles_x;
 450         if not(self.cnt)
 451                 self.drawmask = MASK_NORMAL;
 452         else
 453                 self.drawmask = 0;
 454 }
 455 void ShotOrg_Draw2D()
 456 {
 457         vector coord2d_topleft, coord2d_topright, coord2d;
 458         string s;
 459         vector fs;
 460
 461         s = vtos(self.view_ofs);
 462         s = substring(s, 1, strlen(s) - 2);
 463         if(tokenize_console(s) == 3)
 464                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 465
 466         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 467         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 468
 469         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 470
 471         coord2d = coord2d_topleft;
 472         if(fs_x < 8)
 473         {
 474                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 475                 fs = '8 8 0';
 476         }
 477         coord2d_y -= fs_y;
 478         coord2d_z = 0;
 479         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 480 }
 481
 482 void ShotOrg_Spawn()
 483 {
 484         debug_shotorg = spawn();
 485         debug_shotorg.draw = ShotOrg_Draw;
 486         debug_shotorg.draw2d = ShotOrg_Draw2D;
 487         debug_shotorg.renderflags = RF_VIEWMODEL;
 488         debug_shotorg.effects = EF_FULLBRIGHT;
 489         precache_model("models/shotorg_adjuster.md3");
 490         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 491         debug_shotorg.scale = 2;
 492         debug_shotorg.view_ofs = '25 8 -8';
 493 }
 494
 495 void DrawDebugModel()
 496 {
 497         if(time - floor(time) > 0.5)
 498         {
 499                 PolyDrawModel(self);
 500                 self.drawmask = 0;
 501         }
 502         else
 503         {
 504                 self.renderflags = 0;
 505                 self.drawmask = MASK_NORMAL;
 506         }
 507 }
 508
 509 void GameCommand(string msg)
 510 {
 511         string s;
 512         float argc;
 513         entity e;
 514         argc = tokenize_console(msg);
 515
 516         if(argv(0) == "help" || argc == 0)
 517         {
 518                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 519                 print(_("  settemp cvar value\n"));
 520                 print(_("  scoreboard_columns_set ...\n"));
 521                 print(_("  scoreboard_columns_help\n"));
 522                 GameCommand_Generic("help");
 523                 return;
 524         }
 525
 526         if(GameCommand_Generic(msg))
 527                 return;
 528
 529         string cmd;
 530         cmd = argv(0);
 531         if(cmd == "mv_download") {
 532                 Cmd_MapVote_MapDownload(argc);
 533         }
 534         else if(cmd == "settemp") {
 535                 cvar_clientsettemp(argv(1), argv(2));
 536         }
 537         else if(cmd == "scoreboard_columns_set") {
 538                 Cmd_HUD_SetFields(argc);
 539         }
 540         else if(cmd == "scoreboard_columns_help") {
 541                 Cmd_HUD_Help(argc);
 542         }
 543 #ifdef BLURTEST
 544         else if(cmd == "blurtest") {
 545                 blurtest_time0 = time;
 546                 blurtest_time1 = time + stof(argv(1));
 547                 blurtest_radius = stof(argv(2));
 548                 blurtest_power = stof(argv(3));
 549         }
 550 #endif
 551         else if(cmd == "shotorg_move") {
 552                 if(!debug_shotorg)
 553                         ShotOrg_Spawn();
 554                 else
 555                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 556                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 557         }
 558         else if(cmd == "shotorg_movez") {
 559                 if(!debug_shotorg)
 560                         ShotOrg_Spawn();
 561                 else
 562                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 563                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 564         }
 565         else if(cmd == "shotorg_set") {
 566                 if(!debug_shotorg)
 567                         ShotOrg_Spawn();
 568                 else
 569                         debug_shotorg.view_ofs = stov(argv(1));
 570                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 571         }
 572         else if(cmd == "shotorg_setz") {
 573                 if(!debug_shotorg)
 574                         ShotOrg_Spawn();
 575                 else
 576                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 577                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 578         }
 579         else if(cmd == "shotorg_toggle_hide") {
 580                 if(debug_shotorg)
 581                 {
 582                         debug_shotorg.cnt = !debug_shotorg.cnt;
 583                 }
 584         }
 585         else if(cmd == "shotorg_end") {
 586                 if(debug_shotorg)
 587                 {
 588                         print(vtos(debug_shotorg.view_ofs), "\n");
 589                         remove(debug_shotorg);
 590                         debug_shotorg = world;
 591                 }
 592                 localcmd("sv_cmd debug_shotorg\n");
 593         }
 594         else if(cmd == "sendcvar") {
 595                 // W_FixWeaponOrder will trash argv, so save what we need.
 596                 string thiscvar;
 597                 thiscvar = strzone(argv(1));
 598                 s = cvar_string(thiscvar);
 599                 if(thiscvar == "cl_weaponpriority")
 600                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 601                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 602                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 603                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 604                 strunzone(thiscvar);
 605         }
 606         else if(cmd == "spawn") {
 607                 s = argv(1);
 608                 e = spawn();
 609                 precache_model(s);
 610                 setmodel(e, s);
 611                 setorigin(e, view_origin);
 612                 e.angles = view_angles;
 613                 e.draw = DrawDebugModel;
 614                 e.classname = "debugmodel";
 615         }
 616     else if(cmd == "vyes")
 617     {
 618         if(uid2name_dialog)
 619         {
 620             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 621             vote_prev = 0;
 622             cvar_set("cl_allow_uid2name", "1");
 623             vote_change = -9999;
 624                         uid2name_dialog = 0;
 625         }
 626         else
 627         {
 628             localcmd("cmd vote yes\n");
 629         }
 630     }
 631     else if(cmd == "vno")
 632     {
 633         if(uid2name_dialog)
 634         {
 635             vote_active = 0;
 636             vote_prev = 0;
 637             cvar_set("cl_allow_uid2name", "0");
 638             vote_change = -9999;
 639                         uid2name_dialog = 0;
 640         }
 641         else
 642         {
 643             localcmd("cmd vote no\n");
 644         }
 645     }
 646
 647         else
 648         {
 649                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 650         }
 651
 652         return;
 653 }
 654
 655 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 656 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 657 // All keys are in ascii.
 658 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 659 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 660 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 661 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 662 {
 663         local float bSkipKey;
 664         bSkipKey = false;
 665
 666         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 667                 return true;
 668
 669         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 670                 return true;
 671
 672         if(menu_visible)
 673                 if(menu_action(bInputType, nPrimary, nSecondary))
 674                         return TRUE;
 675
 676         return bSkipKey;
 677 }
 678
 679 // END REQUIRED CSQC FUNCTIONS
 680 // --------------------------------------------------------------------------
 681
 682 // --------------------------------------------------------------------------
 683 // BEGIN OPTIONAL CSQC FUNCTIONS
 684 void Ent_ReadEntCS()
 685 {
 686         InterpolateOrigin_Undo();
 687
 688         self.classname = "entcs_receiver";
 689         self.sv_entnum = ReadByte() - 1;
 690         self.origin_x = ReadShort();
 691         self.origin_y = ReadShort();
 692         self.origin_z = ReadShort();
 693         self.angles_y = ReadByte() * 360.0 / 256;
 694         self.origin_z = self.angles_x = self.angles_z = 0;
 695
 696         InterpolateOrigin_Note();
 697 }
 698
 699 void Ent_Remove();
 700
 701 void Ent_RemovePlayerScore()
 702 {
 703         float i;
 704
 705         if(self.owner)
 706         {
 707                 SetTeam(self.owner, -1);
 708                 self.owner.gotscores = 0;
 709                 for(i = 0; i < MAX_SCORE; ++i)
 710                         self.owner.(scores[i]) = 0; // clear all scores
 711         }
 712 }
 713
 714 void Ent_ReadPlayerScore()
 715 {
 716         float i, n;
 717         float isNew;
 718         entity o;
 719
 720         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 721         // (no I've never heard of M-x replace-string, sed, or anything like that)
 722         isNew = !self.owner; // workaround for DP bug
 723         n = ReadByte()-1;
 724
 725 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 726         if(!isNew && n != self.sv_entnum)
 727         {
 728                 print(_("A CSQC entity changed its owner!\n"));
 729                 isNew = true;
 730                 Ent_Remove();
 731                 self.enttype = ENT_CLIENT_SCORES;
 732         }
 733 #endif
 734
 735         self.sv_entnum = n;
 736
 737         if not(playerslots[self.sv_entnum])
 738                 playerslots[self.sv_entnum] = spawn();
 739         o = self.owner = playerslots[self.sv_entnum];
 740         o.sv_entnum = self.sv_entnum;
 741         o.gotscores = 1;
 742
 743         //if not(o.sort_prev)
 744         //      RegisterPlayer(o);
 745         //playerchecker will do this for us later, if it has not already done so
 746
 747         float sf, lf;
 748 #if MAX_SCORE <= 8
 749         sf = ReadByte();
 750         lf = ReadByte();
 751 #else
 752         sf = ReadShort();
 753         lf = ReadShort();
 754 #endif
 755         float p;
 756         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 757                 if(sf & p)
 758                 {
 759                         if(lf & p)
 760                                 o.(scores[i]) = ReadInt24_t();
 761                         else
 762                                 o.(scores[i]) = ReadChar();
 763                 }
 764
 765         if(o.sort_prev)
 766                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 767
 768         self.entremove = Ent_RemovePlayerScore;
 769 }
 770
 771 void Ent_ReadTeamScore()
 772 {
 773         float i;
 774         entity o;
 775
 776         self.team = ReadByte();
 777         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 778
 779         float sf, lf;
 780 #if MAX_TEAMSCORE <= 8
 781         sf = ReadByte();
 782         lf = ReadByte();
 783 #else
 784         sf = ReadShort();
 785         lf = ReadShort();
 786 #endif
 787         float p;
 788         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 789                 if(sf & p)
 790                 {
 791                         if(lf & p)
 792                                 o.(teamscores[i]) = ReadInt24_t();
 793                         else
 794                                 o.(teamscores[i]) = ReadChar();
 795                 }
 796
 797         HUD_UpdateTeamPos(o);
 798 }
 799
 800 void Net_Reset()
 801 {
 802 }
 803
 804 void Ent_ClientData()
 805 {
 806         float f;
 807         float newspectatee_status;
 808
 809         f = ReadByte();
 810
 811         scoreboard_showscores_force = (f & 1);
 812
 813         if(f & 2)
 814         {
 815                 newspectatee_status = ReadByte();
 816                 if(newspectatee_status == player_localentnum)
 817                         newspectatee_status = -1; // observing
 818         }
 819         else
 820                 newspectatee_status = 0;
 821
 822         spectatorbutton_zoom = (f & 4);
 823
 824         if(f & 8)
 825         {
 826                 angles_held_status = 1;
 827                 angles_held_x = ReadAngle();
 828                 angles_held_y = ReadAngle();
 829                 angles_held_z = 0;
 830         }
 831         else
 832                 angles_held_status = 0;
 833
 834         if(newspectatee_status != spectatee_status)
 835         {
 836                 float i;
 837
 838                 // clear race stuff
 839                 race_laptime = 0;
 840                 race_checkpointtime = 0;
 841         }
 842         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 843         {
 844                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 845                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 846                 )
 847                         prev_p_health = -1;
 848                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 849                         prev_health = -1;
 850         }
 851         spectatee_status = newspectatee_status;
 852 }
 853
 854 void Ent_Nagger()
 855 {
 856         float nags, i, j, b, f;
 857
 858         nags = ReadByte();
 859
 860         if(nags & 128)
 861         {
 862                 if(vote_called_vote)
 863                         strunzone(vote_called_vote);
 864                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 865         }
 866
 867         if(nags & 1)
 868         {
 869                 for(j = 0; j < maxclients; ++j)
 870                         if(playerslots[j])
 871                                 playerslots[j].ready = 1;
 872                 for(i = 1; i <= maxclients; i += 8)
 873                 {
 874                         f = ReadByte();
 875                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 876                                 if not(f & b)
 877                                         if(playerslots[j])
 878                                                 playerslots[j].ready = 0;
 879                 }
 880         }
 881
 882         ready_waiting = (nags & 1);
 883         ready_waiting_for_me = (nags & 2);
 884         vote_waiting = (nags & 4);
 885         vote_waiting_for_me = (nags & 8);
 886         warmup_stage = (nags & 16);
 887 }
 888
 889 void Ent_RandomSeed()
 890 {
 891         float s;
 892         prandom_debug();
 893         s = ReadShort();
 894         psrandom(s);
 895 }
 896
 897 void Ent_ReadAccuracy(void)
 898 {
 899         float sf, f, w, b;
 900         sf = ReadInt24_t();
 901         if(sf == 0)
 902         {
 903                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 904                         weapon_accuracy[w] = -1;
 905                 return;
 906         }
 907
 908         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 909         {
 910                 if(sf & f)
 911                 {
 912                         b = ReadByte();
 913                         if(b == 0)
 914                                 weapon_accuracy[w] = -1;
 915                         else if(b == 255)
 916                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 917                         else
 918                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 919                 }
 920         }
 921 }
 922
 923 void Ent_ShowNames()
 924 {
 925     float sf;
 926
 927     // entity init, TODO can this be done only once somehow?
 928     self.the_entnum = ReadByte(); // TODO: fixme to only send once somehow
 929     self.draw2d = Draw_ShowNames;
 930     //self.movetype = MOVETYPE_FLY; // movetype needed so we can traceline?
 931     self.mins = '-20 -20 -24';
 932     self.maxs = '20 20 45';
 933     self.classname = "shownames_tag";
 934
 935     sf = ReadByte();
 936
 937     if(sf & 1)
 938     {
 939         self.origin_x = ReadShort();
 940         self.origin_y = ReadShort();
 941         self.origin_z = ReadShort();
 942     }
 943     if(sf & 2)
 944     {
 945         self.healthvalue = ReadByte();
 946     }
 947     if(sf & 4)
 948     {
 949         self.armorvalue = ReadByte();
 950     }
 951
 952     if(sf & 128) // same team
 953         self.sameteam = TRUE;
 954     else
 955         self.sameteam = FALSE;
 956 }
 957
 958 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 959 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 960 void Ent_RadarLink();
 961 void Ent_Init();
 962 void Ent_ScoresInfo();
 963 void(float bIsNewEntity) CSQC_Ent_Update =
 964 {
 965         float t;
 966         float savetime;
 967         t = ReadByte();
 968
 969         // set up the "time" global for received entities to be correct for interpolation purposes
 970         savetime = time;
 971         if(servertime)
 972         {
 973                 time = servertime;
 974         }
 975         else
 976         {
 977                 serverprevtime = time;
 978                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 979                 time = serverprevtime + serverdeltatime;
 980         }
 981
 982 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 983         if(self.enttype)
 984                 if(t != self.enttype)
 985                 {
 986                         print(_("A CSQC entity changed its type!\n"));
 987                         Ent_Remove();
 988                         bIsNewEntity = 1;
 989                 }
 990 #endif
 991         self.enttype = t;
 992         switch(t)
 993         {
 994                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 995                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 996                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 997                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 998                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 999                 case ENT_CLIENT_LASER: Ent_Laser(); break;
1000                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
1001                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
1002                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
1003                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
1004                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
1005                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
1006                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
1007                 case ENT_CLIENT_INIT: Ent_Init(); break;
1008                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
1009                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
1010                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
1011                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
1012                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1013                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1014                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1015                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1016                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1017                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1018                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1019                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1020                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1021                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1022                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1023                 case ENT_CLIENT_SHOWNAMES: Ent_ShowNames(); break;
1024                 default:
1025                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1026                         break;
1027         }
1028
1029         time = savetime;
1030 };
1031 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1032 // used when an entity changes its type. For an entity that someone interacts
1033 // with others, make sure it can no longer do so.
1034 void Ent_Remove()
1035 {
1036         if(self.entremove)
1037                 self.entremove();
1038
1039         self.enttype = 0;
1040         self.classname = "";
1041         self.draw = menu_sub_null;
1042         self.entremove = menu_sub_null;
1043         // TODO possibly set more stuff to defaults
1044 }
1045 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1046 void CSQC_Ent_Remove()
1047 {
1048         if(self.enttype)
1049                 Ent_Remove();
1050         remove(self);
1051 }
1052
1053 void Gamemode_Init()
1054 {
1055         if not(isdemo())
1056         {
1057                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1058                 calledhooks |= HOOK_START;
1059         }
1060 }
1061 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1062 void CSQC_Parse_StuffCmd(string strMessage)
1063 {
1064         localcmd(strMessage);
1065 }
1066 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1067 void CSQC_Parse_Print(string strMessage)
1068 {
1069         print(ColorTranslateRGB(strMessage));
1070 }
1071
1072 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1073 void CSQC_Parse_CenterPrint(string strMessage)
1074 {
1075         centerprint(strMessage);
1076 }
1077
1078 string notranslate_fogcmd1 = "\nfog ";
1079 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1080 void Fog_Force()
1081 {
1082         // TODO somehow thwart prvm_globalset client ...
1083
1084         if(forcefog != "")
1085                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1086 }
1087
1088 void Gamemode_Init();
1089 void Ent_ScoresInfo()
1090 {
1091         float i;
1092         self.classname = "ent_client_scores_info";
1093         gametype = ReadByte();
1094         for(i = 0; i < MAX_SCORE; ++i)
1095         {
1096                 scores_label[i] = strzone(ReadString());
1097                 scores_flags[i] = ReadByte();
1098         }
1099         for(i = 0; i < MAX_TEAMSCORE; ++i)
1100         {
1101                 teamscores_label[i] = strzone(ReadString());
1102                 teamscores_flags[i] = ReadByte();
1103         }
1104         HUD_InitScores();
1105         Gamemode_Init();
1106 }
1107
1108 void Ent_Init()
1109 {
1110         self.classname = "ent_client_init";
1111
1112         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1113
1114         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1115         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1116         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1117         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1118         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1123         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1124         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1125         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1126
1127         if(forcefog)
1128                 strunzone(forcefog);
1129         forcefog = strzone(ReadString());
1130
1131         armorblockpercent = ReadByte() / 255.0;
1132
1133         g_weaponswitchdelay = ReadByte() / 255.0;
1134
1135         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1136         g_balance_grenadelauncher_bouncestop = ReadCoord();
1137         g_balance_electro_secondary_bouncefactor = ReadCoord();
1138         g_balance_electro_secondary_bouncestop = ReadCoord();
1139
1140         nex_scope = !ReadByte();
1141         sniperrifle_scope = !ReadByte();
1142
1143         serverflags = ReadByte();
1144
1145         minelayer_maxmines = ReadByte();
1146
1147         g_trueaim_minrange = ReadCoord();
1148
1149         if(!postinit)
1150                 PostInit();
1151 }
1152
1153 void Net_ReadRace()
1154 {
1155         float b;
1156
1157         b = ReadByte();
1158
1159         switch(b)
1160         {
1161                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1162                         race_checkpoint = ReadByte();
1163                         race_time = ReadInt24_t();
1164                         race_previousbesttime = ReadInt24_t();
1165                         if(race_previousbestname)
1166                                 strunzone(race_previousbestname);
1167                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1168
1169                         race_checkpointtime = time;
1170
1171                         if(race_checkpoint == 0 || race_checkpoint == 254)
1172                         {
1173                                 race_penaltyaccumulator = 0;
1174                                 race_laptime = time; // valid
1175                         }
1176
1177                         break;
1178
1179                 case RACE_NET_CHECKPOINT_CLEAR:
1180                         race_laptime = 0;
1181                         race_checkpointtime = 0;
1182                         break;
1183
1184                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1185                         race_laptime = ReadCoord();
1186                         race_checkpointtime = -99999;
1187                         // fall through
1188                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1189                         race_nextcheckpoint = ReadByte();
1190
1191                         race_nextbesttime = ReadInt24_t();
1192                         if(race_nextbestname)
1193                                 strunzone(race_nextbestname);
1194                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1195                         break;
1196
1197                 case RACE_NET_CHECKPOINT_HIT_RACE:
1198                         race_mycheckpoint = ReadByte();
1199                         race_mycheckpointtime = time;
1200                         race_mycheckpointdelta = ReadInt24_t();
1201                         race_mycheckpointlapsdelta = ReadByte();
1202                         if(race_mycheckpointlapsdelta >= 128)
1203                                 race_mycheckpointlapsdelta -= 256;
1204                         if(race_mycheckpointenemy)
1205                                 strunzone(race_mycheckpointenemy);
1206                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1207                         break;
1208
1209                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1210                         race_othercheckpoint = ReadByte();
1211                         race_othercheckpointtime = time;
1212                         race_othercheckpointdelta = ReadInt24_t();
1213                         race_othercheckpointlapsdelta = ReadByte();
1214                         if(race_othercheckpointlapsdelta >= 128)
1215                                 race_othercheckpointlapsdelta -= 256;
1216                         if(race_othercheckpointenemy)
1217                                 strunzone(race_othercheckpointenemy);
1218                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1219                         break;
1220
1221                 case RACE_NET_PENALTY_RACE:
1222                         race_penaltyeventtime = time;
1223                         race_penaltytime = ReadShort();
1224                         //race_penaltyaccumulator += race_penaltytime;
1225                         if(race_penaltyreason)
1226                                 strunzone(race_penaltyreason);
1227                         race_penaltyreason = strzone(ReadString());
1228                         break;
1229
1230                 case RACE_NET_PENALTY_QUALIFYING:
1231                         race_penaltyeventtime = time;
1232                         race_penaltytime = ReadShort();
1233                         race_penaltyaccumulator += race_penaltytime;
1234                         if(race_penaltyreason)
1235                                 strunzone(race_penaltyreason);
1236                         race_penaltyreason = strzone(ReadString());
1237                         break;
1238
1239                 case RACE_NET_SERVER_RECORD:
1240                         race_server_record = ReadInt24_t();
1241                         break;
1242                 case RACE_NET_SPEED_AWARD:
1243                         race_speedaward = ReadInt24_t();
1244                         if(race_speedaward_holder)
1245                                 strunzone(race_speedaward_holder);
1246                         race_speedaward_holder = strzone(ReadString());
1247                         break;
1248                 case RACE_NET_SPEED_AWARD_BEST:
1249                         race_speedaward_alltimebest = ReadInt24_t();
1250                         if(race_speedaward_alltimebest_holder)
1251                                 strunzone(race_speedaward_alltimebest_holder);
1252                         race_speedaward_alltimebest_holder = strzone(ReadString());
1253                         break;
1254                 case RACE_NET_SERVER_RANKINGS:
1255                         float pos, prevpos, del;
1256                         pos = ReadShort();
1257                         prevpos = ReadShort();
1258                         del = ReadShort();
1259
1260                         // move other rankings out of the way
1261                         float i;
1262                         if (prevpos) {
1263                                 for (i=prevpos-1;i>pos-1;--i) {
1264                                         grecordtime[i] = grecordtime[i-1];
1265                                         if(grecordholder[i])
1266                                                 strunzone(grecordholder[i]);
1267                                         grecordholder[i] = strzone(grecordholder[i-1]);
1268                                 }
1269                         } else if (del) { // a record has been deleted by the admin
1270                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1271                                         if (i == RANKINGS_CNT-1) { // clear out last record
1272                                                 grecordtime[i] = 0;
1273                                                 if (grecordholder[i])
1274                                                         strunzone(grecordholder[i]);
1275                                                 grecordholder[i] = string_null;
1276                                         }
1277                                         else {
1278                                                 grecordtime[i] = grecordtime[i+1];
1279                                                 if (grecordholder[i])
1280                                                         strunzone(grecordholder[i]);
1281                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1282                                         }
1283                                 }
1284                         } else { // player has no ranked record yet
1285                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1286                                         grecordtime[i] = grecordtime[i-1];
1287                                         if(grecordholder[i])
1288                                                 strunzone(grecordholder[i]);
1289                                         grecordholder[i] = strzone(grecordholder[i-1]);
1290                                 }
1291                         }
1292
1293                         // store new ranking
1294                         if(grecordholder[pos-1] != "")
1295                                 strunzone(grecordholder[pos-1]);
1296                         grecordholder[pos-1] = strzone(ReadString());
1297                         grecordtime[pos-1] = ReadInt24_t();
1298                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1299                                 race_myrank = pos;
1300                         break;
1301                 case RACE_NET_SERVER_STATUS:
1302                         race_status = ReadShort();
1303                         if(race_status_name)
1304                                 strunzone(race_status_name);
1305                         race_status_name = strzone(ReadString());
1306         }
1307 }
1308
1309 void Net_ReadSpawn()
1310 {
1311         zoomin_effect = 1;
1312         current_viewzoom = 0.6;
1313 }
1314
1315 void Net_TeamNagger()
1316 {
1317         teamnagger = 1;
1318 }
1319
1320 void Net_ReadPingPLReport()
1321 {
1322         float e, pi, pl, ml;
1323         e = ReadByte();
1324         pi = ReadShort();
1325         pl = ReadByte();
1326         ml = ReadByte();
1327         if not(playerslots[e])
1328                 return;
1329         playerslots[e].ping = pi;
1330         playerslots[e].ping_packetloss = pl / 255.0;
1331         playerslots[e].ping_movementloss = ml / 255.0;
1332 }
1333
1334 void Net_VoteDialog(float highlight) {
1335         if(highlight) {
1336                 vote_highlighted = ReadByte();
1337                 return;
1338         }
1339
1340         vote_yescount = ReadByte();
1341         vote_nocount = ReadByte();
1342         vote_needed = ReadByte();
1343         vote_active = 1;
1344 }
1345
1346 void Net_VoteDialogReset() {
1347         vote_active = 0;
1348 }
1349
1350 void Net_Notify() {
1351         float type;
1352         type = ReadByte();
1353
1354         if(type == CSQC_KILLNOTIFY)
1355         {
1356                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1357         }
1358         else if(type == CSQC_CENTERPRINT)
1359         {
1360                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1361         }
1362 }
1363
1364 void Net_WeaponComplain() {
1365         complain_weapon = ReadByte();
1366
1367         if(complain_weapon_name)
1368                 strunzone(complain_weapon_name);
1369         complain_weapon_name = strzone(ReadString());
1370
1371         complain_weapon_type = ReadByte();
1372
1373         complain_weapon_time = time;
1374         weapontime = time; // ping the weapon panel
1375 }
1376
1377 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1378 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1379 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1380 float CSQC_Parse_TempEntity()
1381 {
1382         local float bHandled;
1383                 bHandled  = true;
1384         // Acquire TE ID
1385         local float nTEID;
1386                 nTEID = ReadByte();
1387
1388                 // NOTE: Could just do return instead of break...
1389         switch(nTEID)
1390         {
1391                 case TE_CSQC_TARGET_MUSIC:
1392                         Net_TargetMusic();
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_PICTURE:
1396                         Net_MapVote_Picture();
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_RACE:
1400                         Net_ReadRace();
1401                         bHandled = true;
1402                         break;
1403                 case TE_CSQC_SPAWN:
1404                         Net_ReadSpawn();
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_ZCURVEPARTICLES:
1408                         Net_ReadZCurveParticles();
1409                         bHandled = true;
1410                         break;
1411                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1412                         Net_ReadNexgunBeamParticle();
1413                         bHandled = true;
1414                         break;
1415                 case TE_CSQC_TEAMNAGGER:
1416                         Net_TeamNagger();
1417                         bHandled = true;
1418                         break;
1419                 case TE_CSQC_VOTE:
1420                         Net_VoteDialog(ReadByte());
1421                         bHandled = true;
1422                         break;
1423                 case TE_CSQC_VOTERESET:
1424                         Net_VoteDialogReset();
1425                         bHandled = true;
1426                         break;
1427                 case TE_CSQC_LIGHTNINGARC:
1428                         Net_ReadLightningarc();
1429                         bHandled = true;
1430                         break;
1431                 case TE_CSQC_PINGPLREPORT:
1432                         Net_ReadPingPLReport();
1433                         bHandled = true;
1434                         break;
1435                 case TE_CSQC_ANNOUNCE:
1436                         announce_snd = strzone(ReadString());
1437                         bHandled = true;
1438                         break;
1439                 case TE_CSQC_NOTIFY:
1440                         Net_Notify();
1441                         bHandled = true;
1442                         break;
1443                 case TE_CSQC_WEAPONCOMPLAIN:
1444                         Net_WeaponComplain();
1445                         bHandled = true;
1446                         break;
1447                 default:
1448                         // No special logic for this temporary entity; return 0 so the engine can handle it
1449                         bHandled = false;
1450                         break;
1451         }
1452
1453         return bHandled;
1454 }
1455
1456 string getcommandkey(string text, string command)
1457 {
1458         string keys;
1459         float n, j, k, l;
1460
1461         if (!autocvar_hud_showbinds)
1462                 return text;
1463
1464         keys = db_get(binddb, command);
1465         if (!keys)
1466         {
1467                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1468                 for(j = 0; j < n; ++j)
1469                 {
1470                         k = stof(argv(j));
1471                         if(k != -1)
1472                         {
1473                                 if ("" == keys)
1474                                         keys = keynumtostring(k);
1475                                 else
1476                                         keys = strcat(keys, ", ", keynumtostring(k));
1477
1478                                 ++l;
1479                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1480                         }
1481
1482                 }
1483                 db_put(binddb, command, keys);
1484         }
1485
1486         if ("" == keys) {
1487                 if (autocvar_hud_showbinds > 1)
1488                         return sprintf(_("%s (not bound)"), text);
1489                 else
1490                         return text;
1491         }
1492         else if (autocvar_hud_showbinds > 1)
1493                 return sprintf(_("%s (%s)"), text, keys);
1494         else
1495                 return keys;
1496 }