qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 151         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 152
 153         get_mi_min_max_texcoords(1); // try the CLEVER way first
 154         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 155         shortmapname = mi_shortname;
 156
 157         if(precache_pic(minimapname) == "")
 158         {
 159                 // but maybe we have a non-clever minimap
 160                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 161                 if(precache_pic(minimapname) == "")
 162                         minimapname = ""; // FAIL
 163                 else
 164                         get_mi_min_max_texcoords(0); // load new texcoords
 165         }
 166
 167         mi_center = (mi_min + mi_max) * 0.5;
 168         mi_scale = mi_max - mi_min;
 169         minimapname = strzone(minimapname);
 170
 171         WarpZone_Init();
 172         hud_configure_prev = -1;
 173 }
 174
 175 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 176 void CSQC_Shutdown(void)
 177 {
 178 #ifdef USE_FTE
 179 #pragma TARGET id
 180         if(!__engine_check)
 181                 return 0;
 182 #pragma TARGET fte
 183 #endif
 184
 185         WarpZone_Shutdown();
 186
 187         remove(teams);
 188         remove(players);
 189         db_close(binddb);
 190         db_close(tempdb);
 191         if(autocvar_cl_db_saveasdump)
 192                 db_dump(ClientProgsDB, "client.db");
 193         else
 194                 db_save(ClientProgsDB, "client.db");
 195         db_close(ClientProgsDB);
 196
 197         cvar_clientsettemp_restore();
 198
 199         if(camera_active)
 200                 cvar_set("chase_active",ftos(chase_active_backup));
 201
 202         // unset the event chasecam's chase_active
 203         if(autocvar_chase_active < 0)
 204                 cvar_set("chase_active", "0");
 205
 206         if not(isdemo())
 207         {
 208                 if not(calledhooks & HOOK_START)
 209                         localcmd("\n_cl_hook_gamestart nop\n");
 210                 if not(calledhooks & HOOK_END)
 211                         localcmd("\ncl_hook_gameend\n");
 212         }
 213 }
 214
 215 .float has_team;
 216 float SetTeam(entity o, float Team)
 217 {
 218         entity tm;
 219         if(teamplay)
 220         {
 221                 switch(Team)
 222                 {
 223                         case -1:
 224                         case COLOR_TEAM1:
 225                         case COLOR_TEAM2:
 226                         case COLOR_TEAM3:
 227                         case COLOR_TEAM4:
 228                                 break;
 229                         default:
 230                                 if(GetTeam(Team, false) == NULL)
 231                                 {
 232                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 233                                         Team = COLOR_SPECTATOR;
 234                                 }
 235                                 break;
 236                 }
 237         }
 238         else
 239         {
 240                 switch(Team)
 241                 {
 242                         case -1:
 243                         case 0:
 244                                 break;
 245                         default:
 246                                 if(GetTeam(Team, false) == NULL)
 247                                 {
 248                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 249                                         Team = COLOR_SPECTATOR;
 250                                 }
 251                                 break;
 252                 }
 253         }
 254         if(Team == -1) // leave
 255         {
 256                 if(o.has_team)
 257                 {
 258                         tm = GetTeam(o.team, false);
 259                         tm.team_size -= 1;
 260                         o.has_team = 0;
 261                         return TRUE;
 262                 }
 263         }
 264         else
 265         {
 266                 if not(o.has_team)
 267                 {
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         o.has_team = 1;
 272                         return TRUE;
 273                 }
 274                 else if(Team != o.team)
 275                 {
 276                         tm = GetTeam(o.team, false);
 277                         tm.team_size -= 1;
 278                         o.team = Team;
 279                         tm = GetTeam(Team, true);
 280                         tm.team_size += 1;
 281                         return TRUE;
 282                 }
 283         }
 284         return FALSE;
 285 }
 286
 287 void Playerchecker_Think()
 288 {
 289         float i;
 290         entity e;
 291         for(i = 0; i < maxclients; ++i)
 292         {
 293                 e = playerslots[i];
 294                 if(GetPlayerName(i) == "")
 295                 {
 296                         if(e.sort_prev)
 297                         {
 298                                 // player disconnected
 299                                 SetTeam(e, -1);
 300                                 RemovePlayer(e);
 301                                 e.sort_prev = world;
 302                                 //e.gotscores = 0;
 303                         }
 304                 }
 305                 else
 306                 {
 307                         if not(e.sort_prev)
 308                         {
 309                                 // player connected
 310                                 if not(e)
 311                                         playerslots[i] = e = spawn();
 312                                 e.sv_entnum = i;
 313                                 e.ping = 0;
 314                                 e.ping_packetloss = 0;
 315                                 e.ping_movementloss = 0;
 316                                 //e.gotscores = 0; // we might already have the scores...
 317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 318                                 RegisterPlayer(e);
 319                                 HUD_UpdatePlayerPos(e);
 320                         }
 321                 }
 322         }
 323         self.nextthink = time + 0.2;
 324 }
 325
 326 void Porto_Init();
 327 void TrueAim_Init();
 328 void PostInit(void)
 329 {
 330         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 331
 332         entity playerchecker;
 333         playerchecker = spawn();
 334         playerchecker.think = Playerchecker_Think;
 335         playerchecker.nextthink = time + 0.2;
 336
 337         Porto_Init();
 338         TrueAim_Init();
 339
 340         postinit = true;
 341 }
 342
 343 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 344 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 345 float button_zoom;
 346 void Cmd_HUD_SetFields(float);
 347 void Cmd_HUD_Help(float);
 348 float CSQC_ConsoleCommand(string strMessage)
 349 {
 350         float argc;
 351         // Tokenize String
 352         //argc = tokenize(strMessage);
 353         argc = tokenize_console(strMessage);
 354
 355         // Acquire Command
 356         local string strCmd;
 357         strCmd = argv(0);
 358
 359         if(strCmd == "hud_configure") { // config hud
 360                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 361                 return true;
 362         } else if(strCmd == "hud_save") { // save hud config
 363                 if(argv(1) == "" || argv(2)) {
 364                         print(_("Usage:\n"));
 365                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 366                 }
 367                 else
 368                         HUD_Panel_ExportCfg(argv(1));
 369                 return true;
 370         } else if(strCmd == "+showscores") {
 371                 scoreboard_showscores = true;
 372                 return true;
 373         } else if(strCmd == "-showscores") {
 374                 scoreboard_showscores = false;
 375                 return true;
 376         } else if(strCmd == "+showaccuracy") {
 377                 scoreboard_showaccuracy = true;
 378                 return true;
 379         } else if(strCmd == "-showaccuracy") {
 380                 scoreboard_showaccuracy = false;
 381                 return true;
 382         }
 383
 384         if(camera_active)
 385         if(strCmd == "+forward" || strCmd == "-back") {
 386                 ++camera_direction_x;
 387                 return true;
 388         } else if(strCmd == "-forward" || strCmd == "+back") {
 389                 --camera_direction_x;
 390                 return true;
 391         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 392                 --camera_direction_y;
 393                 return true;
 394         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 395                 ++camera_direction_y;
 396                 return true;
 397         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 398                 ++camera_direction_z;
 399                 return true;
 400         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 401                 --camera_direction_z;
 402                 return true;
 403         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 404                 ++camera_roll;
 405                 return true;
 406         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 407                 --camera_roll;
 408                 return true;
 409         }
 410
 411         return false;
 412 }
 413
 414 .vector view_ofs;
 415 entity debug_shotorg;
 416 void ShotOrg_Draw()
 417 {
 418         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 419         self.angles = view_angles;
 420         self.angles_x = -self.angles_x;
 421         if not(self.cnt)
 422                 self.drawmask = MASK_NORMAL;
 423         else
 424                 self.drawmask = 0;
 425 }
 426 void ShotOrg_Draw2D()
 427 {
 428         vector coord2d_topleft, coord2d_topright, coord2d;
 429         string s;
 430         vector fs;
 431
 432         s = vtos(self.view_ofs);
 433         s = substring(s, 1, strlen(s) - 2);
 434         if(tokenize_console(s) == 3)
 435                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 436
 437         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 438         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 439
 440         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 441
 442         coord2d = coord2d_topleft;
 443         if(fs_x < 8)
 444         {
 445                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 446                 fs = '8 8 0';
 447         }
 448         coord2d_y -= fs_y;
 449         coord2d_z = 0;
 450         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 451 }
 452
 453 void ShotOrg_Spawn()
 454 {
 455         debug_shotorg = spawn();
 456         debug_shotorg.draw = ShotOrg_Draw;
 457         debug_shotorg.draw2d = ShotOrg_Draw2D;
 458         debug_shotorg.renderflags = RF_VIEWMODEL;
 459         debug_shotorg.effects = EF_FULLBRIGHT;
 460         precache_model("models/shotorg_adjuster.md3");
 461         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 462         debug_shotorg.scale = 2;
 463         debug_shotorg.view_ofs = '25 8 -8';
 464 }
 465
 466 void DrawDebugModel()
 467 {
 468         if(time - floor(time) > 0.5)
 469         {
 470                 PolyDrawModel(self);
 471                 self.drawmask = 0;
 472         }
 473         else
 474         {
 475                 self.renderflags = 0;
 476                 self.drawmask = MASK_NORMAL;
 477         }
 478 }
 479
 480 void GameCommand(string msg)
 481 {
 482         string s;
 483         float argc;
 484         entity e;
 485         argc = tokenize_console(msg);
 486
 487         if(argv(0) == "help" || argc == 0)
 488         {
 489                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 490                 print(_("  settemp cvar value\n"));
 491                 print(_("  scoreboard_columns_set ...\n"));
 492                 print(_("  scoreboard_columns_help\n"));
 493                 GameCommand_Generic("help");
 494                 return;
 495         }
 496
 497         if(GameCommand_Generic(msg))
 498                 return;
 499
 500         string cmd;
 501         cmd = argv(0);
 502         if(cmd == "mv_download") {
 503                 Cmd_MapVote_MapDownload(argc);
 504         }
 505         else if(cmd == "settemp") {
 506                 cvar_clientsettemp(argv(1), argv(2));
 507         }
 508         else if(cmd == "scoreboard_columns_set") {
 509                 Cmd_HUD_SetFields(argc);
 510         }
 511         else if(cmd == "scoreboard_columns_help") {
 512                 Cmd_HUD_Help(argc);
 513         }
 514 #ifdef BLURTEST
 515         else if(cmd == "blurtest") {
 516                 blurtest_time0 = time;
 517                 blurtest_time1 = time + stof(argv(1));
 518                 blurtest_radius = stof(argv(2));
 519                 blurtest_power = stof(argv(3));
 520         }
 521 #endif
 522         else if(cmd == "shotorg_move") {
 523                 if(!debug_shotorg)
 524                         ShotOrg_Spawn();
 525                 else
 526                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 527                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 528         }
 529         else if(cmd == "shotorg_movez") {
 530                 if(!debug_shotorg)
 531                         ShotOrg_Spawn();
 532                 else
 533                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 534                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 535         }
 536         else if(cmd == "shotorg_set") {
 537                 if(!debug_shotorg)
 538                         ShotOrg_Spawn();
 539                 else
 540                         debug_shotorg.view_ofs = stov(argv(1));
 541                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 542         }
 543         else if(cmd == "shotorg_setz") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_toggle_hide") {
 551                 if(debug_shotorg)
 552                 {
 553                         debug_shotorg.cnt = !debug_shotorg.cnt;
 554                 }
 555         }
 556         else if(cmd == "shotorg_end") {
 557                 if(debug_shotorg)
 558                 {
 559                         print(vtos(debug_shotorg.view_ofs), "\n");
 560                         remove(debug_shotorg);
 561                         debug_shotorg = world;
 562                 }
 563                 localcmd("sv_cmd debug_shotorg\n");
 564         }
 565         else if(cmd == "sendcvar") {
 566                 // W_FixWeaponOrder will trash argv, so save what we need.
 567                 string thiscvar;
 568                 thiscvar = strzone(argv(1));
 569                 s = cvar_string(thiscvar);
 570                 if(thiscvar == "cl_weaponpriority")
 571                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 572                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 573                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 574                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 575                 strunzone(thiscvar);
 576         }
 577         else if(cmd == "spawn") {
 578                 s = argv(1);
 579                 e = spawn();
 580                 precache_model(s);
 581                 setmodel(e, s);
 582                 setorigin(e, view_origin);
 583                 e.angles = view_angles;
 584                 e.draw = DrawDebugModel;
 585                 e.classname = "debugmodel";
 586         }
 587     else if(cmd == "vyes")
 588     {
 589         if(uid2name_dialog)
 590         {
 591             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 592             vote_prev = 0;
 593             cvar_set("cl_allow_uid2name", "1");
 594             vote_change = -9999;
 595         }
 596         else
 597         {
 598             localcmd("cmd vote yes\n");
 599         }
 600     }
 601     else if(cmd == "vno")
 602     {
 603         if(uid2name_dialog)
 604         {
 605             vote_active = 0;
 606             vote_prev = 0;
 607             cvar_set("cl_allow_uid2name", "0");
 608             vote_change = -9999;
 609         }
 610         else
 611         {
 612             localcmd("cmd vote no\n");
 613         }
 614     }
 615
 616         else
 617         {
 618                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 619         }
 620
 621         return;
 622 }
 623
 624 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 625 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 626 // All keys are in ascii.
 627 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 628 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 629 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 630 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 631 {
 632         local float bSkipKey;
 633         bSkipKey = false;
 634
 635         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 636                 return true;
 637
 638         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 639                 return true;
 640
 641         if(menu_visible)
 642                 if(menu_action(bInputType, nPrimary, nSecondary))
 643                         return TRUE;
 644
 645         return bSkipKey;
 646 }
 647
 648 // END REQUIRED CSQC FUNCTIONS
 649 // --------------------------------------------------------------------------
 650
 651 // --------------------------------------------------------------------------
 652 // BEGIN OPTIONAL CSQC FUNCTIONS
 653 void Ent_ReadEntCS()
 654 {
 655         InterpolateOrigin_Undo();
 656
 657         self.classname = "entcs_receiver";
 658         self.sv_entnum = ReadByte() - 1;
 659         self.origin_x = ReadShort();
 660         self.origin_y = ReadShort();
 661         self.origin_z = ReadShort();
 662         self.angles_y = ReadByte() * 360.0 / 256;
 663         self.origin_z = self.angles_x = self.angles_z = 0;
 664
 665         InterpolateOrigin_Note();
 666 }
 667
 668 void Ent_Remove();
 669
 670 void Ent_RemovePlayerScore()
 671 {
 672         float i;
 673
 674         if(self.owner)
 675         {
 676                 SetTeam(self.owner, -1);
 677                 self.owner.gotscores = 0;
 678                 for(i = 0; i < MAX_SCORE; ++i)
 679                         self.owner.(scores[i]) = 0; // clear all scores
 680         }
 681 }
 682
 683 void Ent_ReadPlayerScore()
 684 {
 685         float i, n;
 686         float isNew;
 687         entity o;
 688
 689         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 690         // (no I've never heard of M-x replace-string, sed, or anything like that)
 691         isNew = !self.owner; // workaround for DP bug
 692         n = ReadByte()-1;
 693
 694 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 695         if(!isNew && n != self.sv_entnum)
 696         {
 697                 //print(_("A CSQC entity changed its owner!\n"));
 698                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 699                 isNew = true;
 700                 Ent_Remove();
 701                 self.enttype = ENT_CLIENT_SCORES;
 702         }
 703 #endif
 704
 705         self.sv_entnum = n;
 706
 707         if not(playerslots[self.sv_entnum])
 708                 playerslots[self.sv_entnum] = spawn();
 709         o = self.owner = playerslots[self.sv_entnum];
 710         o.sv_entnum = self.sv_entnum;
 711         o.gotscores = 1;
 712
 713         //if not(o.sort_prev)
 714         //      RegisterPlayer(o);
 715         //playerchecker will do this for us later, if it has not already done so
 716
 717         float sf, lf;
 718 #if MAX_SCORE <= 8
 719         sf = ReadByte();
 720         lf = ReadByte();
 721 #else
 722         sf = ReadShort();
 723         lf = ReadShort();
 724 #endif
 725         float p;
 726         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 727                 if(sf & p)
 728                 {
 729                         if(lf & p)
 730                                 o.(scores[i]) = ReadInt24_t();
 731                         else
 732                                 o.(scores[i]) = ReadChar();
 733                 }
 734
 735         if(o.sort_prev)
 736                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 737
 738         self.entremove = Ent_RemovePlayerScore;
 739 }
 740
 741 void Ent_ReadTeamScore()
 742 {
 743         float i;
 744         entity o;
 745
 746         self.team = ReadByte();
 747         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 748
 749         float sf, lf;
 750 #if MAX_TEAMSCORE <= 8
 751         sf = ReadByte();
 752         lf = ReadByte();
 753 #else
 754         sf = ReadShort();
 755         lf = ReadShort();
 756 #endif
 757         float p;
 758         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 759                 if(sf & p)
 760                 {
 761                         if(lf & p)
 762                                 o.(teamscores[i]) = ReadInt24_t();
 763                         else
 764                                 o.(teamscores[i]) = ReadChar();
 765                 }
 766
 767         HUD_UpdateTeamPos(o);
 768 }
 769
 770 void Ent_ClientData()
 771 {
 772         float f;
 773         float newspectatee_status;
 774
 775         f = ReadByte();
 776
 777         scoreboard_showscores_force = (f & 1);
 778
 779         if(f & 2)
 780         {
 781                 newspectatee_status = ReadByte();
 782                 if(newspectatee_status == player_localentnum)
 783                         newspectatee_status = -1; // observing
 784         }
 785         else
 786                 newspectatee_status = 0;
 787
 788         spectatorbutton_zoom = (f & 4);
 789
 790         if(f & 8)
 791         {
 792                 angles_held_status = 1;
 793                 angles_held_x = ReadAngle();
 794                 angles_held_y = ReadAngle();
 795                 angles_held_z = 0;
 796         }
 797         else
 798                 angles_held_status = 0;
 799
 800         if(newspectatee_status != spectatee_status)
 801         {
 802                 float i;
 803
 804                 // clear race stuff
 805                 race_laptime = 0;
 806                 race_checkpointtime = 0;
 807         }
 808         spectatee_status = newspectatee_status;
 809 }
 810
 811 void Ent_Nagger()
 812 {
 813         float nags, i, j, b, f;
 814
 815         nags = ReadByte();
 816
 817         if(nags & 128)
 818         {
 819                 if(vote_called_vote)
 820                         strunzone(vote_called_vote);
 821                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 822         }
 823
 824         if(nags & 1)
 825         {
 826                 for(j = 0; j < maxclients; ++j)
 827                         if(playerslots[j])
 828                                 playerslots[j].ready = 1;
 829                 for(i = 1; i <= maxclients; i += 8)
 830                 {
 831                         f = ReadByte();
 832                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 833                                 if not(f & b)
 834                                         if(playerslots[j])
 835                                                 playerslots[j].ready = 0;
 836                 }
 837         }
 838
 839         ready_waiting = (nags & 1);
 840         ready_waiting_for_me = (nags & 2);
 841         vote_waiting = (nags & 4);
 842         vote_waiting_for_me = (nags & 8);
 843         warmup_stage = (nags & 16);
 844 }
 845
 846 void Ent_RandomSeed()
 847 {
 848         float s;
 849         prandom_debug();
 850         s = ReadShort();
 851         psrandom(s);
 852 }
 853
 854 void Ent_ReadAccuracy(void)
 855 {
 856         float sf, f, w, b;
 857         sf = ReadInt24_t();
 858         if(sf == 0)
 859         {
 860                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 861                         weapon_accuracy[w] = -1;
 862                 return;
 863         }
 864
 865         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 866         {
 867                 if(sf & f)
 868                 {
 869                         b = ReadByte();
 870                         if(b == 0)
 871                                 weapon_accuracy[w] = -1;
 872                         else if(b == 255)
 873                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 874                         else
 875                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 876                 }
 877         }
 878 }
 879
 880 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 881 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 882 void Ent_RadarLink();
 883 void Ent_Init();
 884 void Ent_ScoresInfo();
 885 void(float bIsNewEntity) CSQC_Ent_Update =
 886 {
 887         float t;
 888         float savetime;
 889         t = ReadByte();
 890
 891         // set up the "time" global for received entities to be correct for interpolation purposes
 892         savetime = time;
 893         if(servertime)
 894         {
 895                 time = servertime;
 896         }
 897         else
 898         {
 899                 serverprevtime = time;
 900                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 901                 time = serverprevtime + serverdeltatime;
 902         }
 903
 904 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 905         if(self.enttype)
 906                 if(t != self.enttype)
 907                 {
 908                         //print(_("A CSQC entity changed its type!\n"));
 909                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 910                         Ent_Remove();
 911                         bIsNewEntity = 1;
 912                 }
 913 #endif
 914         self.enttype = t;
 915         switch(t)
 916         {
 917                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 918                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 919                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 920                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 921                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 922                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 923                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 924                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 925                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 926                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 927                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 928                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 929                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 930                 case ENT_CLIENT_INIT: Ent_Init(); break;
 931                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 932                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 933                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 934                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 935                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 936                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 937                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 938                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 939                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 940                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 941                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 942                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 943                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 944                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 945                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 946                 default:
 947                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 948                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 949                         break;
 950         }
 951
 952         time = savetime;
 953 };
 954 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 955 // used when an entity changes its type. For an entity that someone interacts
 956 // with others, make sure it can no longer do so.
 957 void Ent_Remove()
 958 {
 959         if(self.entremove)
 960                 self.entremove();
 961
 962         self.enttype = 0;
 963         self.classname = "";
 964         self.draw = menu_sub_null;
 965         self.entremove = menu_sub_null;
 966         // TODO possibly set more stuff to defaults
 967 }
 968 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 969 void CSQC_Ent_Remove()
 970 {
 971         if(self.enttype)
 972                 Ent_Remove();
 973         remove(self);
 974 }
 975
 976 void Gamemode_Init()
 977 {
 978         if(gametype == GAME_ONSLAUGHT) {
 979                 print(strcat("Using ", minimapname, " as minimap.\n"));
 980                 precache_pic("gfx/ons-cp-neutral.tga");
 981                 precache_pic("gfx/ons-cp-red.tga");
 982                 precache_pic("gfx/ons-cp-blue.tga");
 983                 precache_pic("gfx/ons-frame.tga");
 984                 precache_pic("gfx/ons-frame-team.tga");
 985         }
 986
 987         if not(isdemo())
 988         {
 989                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
 990                 calledhooks |= HOOK_START;
 991         }
 992 }
 993 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 994 void CSQC_Parse_StuffCmd(string strMessage)
 995 {
 996         localcmd(strMessage);
 997 }
 998 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 999 void CSQC_Parse_Print(string strMessage)
1000 {
1001         print(ColorTranslateRGB(strMessage));
1002 }
1003
1004 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1005 void CSQC_Parse_CenterPrint(string strMessage)
1006 {
1007         centerprint(strMessage);
1008 }
1009
1010 string notranslate_fogcmd1 = "\nfog ";
1011 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1012 void Fog_Force()
1013 {
1014         // TODO somehow thwart prvm_globalset client ...
1015
1016         if(forcefog != "")
1017                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1018 }
1019
1020 void Gamemode_Init();
1021 void Ent_ScoresInfo()
1022 {
1023         float i;
1024         self.classname = "ent_client_scores_info";
1025         gametype = ReadByte();
1026         for(i = 0; i < MAX_SCORE; ++i)
1027         {
1028                 scores_label[i] = strzone(ReadString());
1029                 scores_flags[i] = ReadByte();
1030         }
1031         for(i = 0; i < MAX_TEAMSCORE; ++i)
1032         {
1033                 teamscores_label[i] = strzone(ReadString());
1034                 teamscores_flags[i] = ReadByte();
1035         }
1036         HUD_InitScores();
1037         Gamemode_Init();
1038 }
1039
1040 void Ent_Init()
1041 {
1042         self.classname = "ent_client_init";
1043
1044         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1045
1046         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1047         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1048         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1049         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1050         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1051         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1052         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1053         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1054         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1055         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1056         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1057         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1058
1059         if(forcefog)
1060                 strunzone(forcefog);
1061         forcefog = strzone(ReadString());
1062
1063         armorblockpercent = ReadByte() / 255.0;
1064
1065         g_weaponswitchdelay = ReadByte() / 255.0;
1066
1067         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1068         g_balance_grenadelauncher_bouncestop = ReadCoord();
1069         g_balance_electro_secondary_bouncefactor = ReadCoord();
1070         g_balance_electro_secondary_bouncestop = ReadCoord();
1071
1072         nex_scope = !ReadByte();
1073         sniperrifle_scope = !ReadByte();
1074
1075         serverflags = ReadByte();
1076
1077         minelayer_maxmines = ReadByte();
1078
1079         hagar_maxrockets = ReadByte();
1080
1081         g_trueaim_minrange = ReadCoord();
1082
1083         if(!postinit)
1084                 PostInit();
1085 }
1086
1087 void Net_ReadRace()
1088 {
1089         float b;
1090
1091         b = ReadByte();
1092
1093         switch(b)
1094         {
1095                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1096                         race_checkpoint = ReadByte();
1097                         race_time = ReadInt24_t();
1098                         race_previousbesttime = ReadInt24_t();
1099                         if(race_previousbestname)
1100                                 strunzone(race_previousbestname);
1101                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1102
1103                         race_checkpointtime = time;
1104
1105                         if(race_checkpoint == 0 || race_checkpoint == 254)
1106                         {
1107                                 race_penaltyaccumulator = 0;
1108                                 race_laptime = time; // valid
1109                         }
1110
1111                         break;
1112
1113                 case RACE_NET_CHECKPOINT_CLEAR:
1114                         race_laptime = 0;
1115                         race_checkpointtime = 0;
1116                         break;
1117
1118                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1119                         race_laptime = ReadCoord();
1120                         race_checkpointtime = -99999;
1121                         // fall through
1122                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1123                         race_nextcheckpoint = ReadByte();
1124
1125                         race_nextbesttime = ReadInt24_t();
1126                         if(race_nextbestname)
1127                                 strunzone(race_nextbestname);
1128                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1129                         break;
1130
1131                 case RACE_NET_CHECKPOINT_HIT_RACE:
1132                         race_mycheckpoint = ReadByte();
1133                         race_mycheckpointtime = time;
1134                         race_mycheckpointdelta = ReadInt24_t();
1135                         race_mycheckpointlapsdelta = ReadByte();
1136                         if(race_mycheckpointlapsdelta >= 128)
1137                                 race_mycheckpointlapsdelta -= 256;
1138                         if(race_mycheckpointenemy)
1139                                 strunzone(race_mycheckpointenemy);
1140                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1141                         break;
1142
1143                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1144                         race_othercheckpoint = ReadByte();
1145                         race_othercheckpointtime = time;
1146                         race_othercheckpointdelta = ReadInt24_t();
1147                         race_othercheckpointlapsdelta = ReadByte();
1148                         if(race_othercheckpointlapsdelta >= 128)
1149                                 race_othercheckpointlapsdelta -= 256;
1150                         if(race_othercheckpointenemy)
1151                                 strunzone(race_othercheckpointenemy);
1152                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1153                         break;
1154
1155                 case RACE_NET_PENALTY_RACE:
1156                         race_penaltyeventtime = time;
1157                         race_penaltytime = ReadShort();
1158                         //race_penaltyaccumulator += race_penaltytime;
1159                         if(race_penaltyreason)
1160                                 strunzone(race_penaltyreason);
1161                         race_penaltyreason = strzone(ReadString());
1162                         break;
1163
1164                 case RACE_NET_PENALTY_QUALIFYING:
1165                         race_penaltyeventtime = time;
1166                         race_penaltytime = ReadShort();
1167                         race_penaltyaccumulator += race_penaltytime;
1168                         if(race_penaltyreason)
1169                                 strunzone(race_penaltyreason);
1170                         race_penaltyreason = strzone(ReadString());
1171                         break;
1172
1173                 case RACE_NET_SERVER_RECORD:
1174                         race_server_record = ReadInt24_t();
1175                         break;
1176                 case RACE_NET_SPEED_AWARD:
1177                         race_speedaward = ReadInt24_t();
1178                         if(race_speedaward_holder)
1179                                 strunzone(race_speedaward_holder);
1180                         race_speedaward_holder = strzone(ReadString());
1181                         break;
1182                 case RACE_NET_SPEED_AWARD_BEST:
1183                         race_speedaward_alltimebest = ReadInt24_t();
1184                         if(race_speedaward_alltimebest_holder)
1185                                 strunzone(race_speedaward_alltimebest_holder);
1186                         race_speedaward_alltimebest_holder = strzone(ReadString());
1187                         break;
1188                 case RACE_NET_SERVER_RANKINGS:
1189                         float pos, prevpos, del;
1190                         pos = ReadShort();
1191                         prevpos = ReadShort();
1192                         del = ReadShort();
1193
1194                         // move other rankings out of the way
1195                         float i;
1196                         if (prevpos) {
1197                                 for (i=prevpos-1;i>pos-1;--i) {
1198                                         grecordtime[i] = grecordtime[i-1];
1199                                         if(grecordholder[i])
1200                                                 strunzone(grecordholder[i]);
1201                                         grecordholder[i] = strzone(grecordholder[i-1]);
1202                                 }
1203                         } else if (del) { // a record has been deleted by the admin
1204                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1205                                         if (i == RANKINGS_CNT-1) { // clear out last record
1206                                                 grecordtime[i] = 0;
1207                                                 if (grecordholder[i])
1208                                                         strunzone(grecordholder[i]);
1209                                                 grecordholder[i] = string_null;
1210                                         }
1211                                         else {
1212                                                 grecordtime[i] = grecordtime[i+1];
1213                                                 if (grecordholder[i])
1214                                                         strunzone(grecordholder[i]);
1215                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1216                                         }
1217                                 }
1218                         } else { // player has no ranked record yet
1219                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1220                                         grecordtime[i] = grecordtime[i-1];
1221                                         if(grecordholder[i])
1222                                                 strunzone(grecordholder[i]);
1223                                         grecordholder[i] = strzone(grecordholder[i-1]);
1224                                 }
1225                         }
1226
1227                         // store new ranking
1228                         if(grecordholder[pos-1] != "")
1229                                 strunzone(grecordholder[pos-1]);
1230                         grecordholder[pos-1] = strzone(ReadString());
1231                         grecordtime[pos-1] = ReadInt24_t();
1232                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1233                                 race_myrank = pos;
1234                         break;
1235                 case RACE_NET_SERVER_STATUS:
1236                         race_status = ReadShort();
1237                         if(race_status_name)
1238                                 strunzone(race_status_name);
1239                         race_status_name = strzone(ReadString());
1240         }
1241 }
1242
1243 void Net_ReadSpawn()
1244 {
1245         zoomin_effect = 1;
1246         current_viewzoom = 0.6;
1247 }
1248
1249 void Net_TeamNagger()
1250 {
1251         teamnagger = 1;
1252 }
1253
1254 void Net_ReadPingPLReport()
1255 {
1256         float e, pi, pl, ml;
1257         e = ReadByte();
1258         pi = ReadShort();
1259         pl = ReadByte();
1260         ml = ReadByte();
1261         if not(playerslots[e])
1262                 return;
1263         playerslots[e].ping = pi;
1264         playerslots[e].ping_packetloss = pl / 255.0;
1265         playerslots[e].ping_movementloss = ml / 255.0;
1266 }
1267
1268 void Net_VoteDialog(float highlight) {
1269         if(highlight) {
1270                 vote_highlighted = ReadByte();
1271                 return;
1272         }
1273
1274         vote_yescount = ReadByte();
1275         vote_nocount = ReadByte();
1276         vote_needed = ReadByte();
1277         vote_active = 1;
1278 }
1279
1280 void Net_VoteDialogReset() {
1281         vote_active = 0;
1282 }
1283
1284 void Net_Notify() {
1285         float type;
1286         type = ReadByte();
1287
1288         if(type == CSQC_KILLNOTIFY)
1289         {
1290                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1291         }
1292         else if(type == CSQC_CENTERPRINT)
1293         {
1294                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1295         }
1296 }
1297
1298 void Net_WeaponComplain() {
1299         complain_weapon = ReadByte();
1300
1301         if(complain_weapon_name)
1302                 strunzone(complain_weapon_name);
1303         complain_weapon_name = strzone(ReadString());
1304
1305         complain_weapon_type = ReadByte();
1306
1307         complain_weapon_time = time;
1308         weapontime = time; // ping the weapon panel
1309 }
1310
1311 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1312 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1313 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1314 float CSQC_Parse_TempEntity()
1315 {
1316         local float bHandled;
1317                 bHandled  = true;
1318         // Acquire TE ID
1319         local float nTEID;
1320                 nTEID = ReadByte();
1321
1322                 // NOTE: Could just do return instead of break...
1323         switch(nTEID)
1324         {
1325                 case TE_CSQC_TARGET_MUSIC:
1326                         Net_TargetMusic();
1327                         bHandled = true;
1328                         break;
1329                 case TE_CSQC_PICTURE:
1330                         Net_MapVote_Picture();
1331                         bHandled = true;
1332                         break;
1333                 case TE_CSQC_RACE:
1334                         Net_ReadRace();
1335                         bHandled = true;
1336                         break;
1337                 case TE_CSQC_SPAWN:
1338                         Net_ReadSpawn();
1339                         bHandled = true;
1340                         break;
1341                 case TE_CSQC_ZCURVEPARTICLES:
1342                         Net_ReadZCurveParticles();
1343                         bHandled = true;
1344                         break;
1345                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1346                         Net_ReadNexgunBeamParticle();
1347                         bHandled = true;
1348                         break;
1349                 case TE_CSQC_TEAMNAGGER:
1350                         Net_TeamNagger();
1351                         bHandled = true;
1352                         break;
1353                 case TE_CSQC_VOTE:
1354                         Net_VoteDialog(ReadByte());
1355                         bHandled = true;
1356                         break;
1357                 case TE_CSQC_VOTERESET:
1358                         Net_VoteDialogReset();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_LIGHTNINGARC:
1362                         Net_ReadLightningarc();
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_PINGPLREPORT:
1366                         Net_ReadPingPLReport();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_ANNOUNCE:
1370                         announce_snd = strzone(ReadString());
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_NOTIFY:
1374                         Net_Notify();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_WEAPONCOMPLAIN:
1378                         Net_WeaponComplain();
1379                         bHandled = true;
1380                         break;
1381                 default:
1382                         // No special logic for this temporary entity; return 0 so the engine can handle it
1383                         bHandled = false;
1384                         break;
1385         }
1386
1387         return bHandled;
1388 }
1389
1390 string getcommandkey(string text, string command)
1391 {
1392         string keys;
1393         float n, j, k, l;
1394
1395         if (!hud_showbinds)
1396                 return text;
1397
1398         keys = db_get(binddb, command);
1399         if (!keys)
1400         {
1401                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1402                 for(j = 0; j < n; ++j)
1403                 {
1404                         k = stof(argv(j));
1405                         if(k != -1)
1406                         {
1407                                 if ("" == keys)
1408                                         keys = keynumtostring(k);
1409                                 else
1410                                         keys = strcat(keys, ", ", keynumtostring(k));
1411
1412                                 ++l;
1413                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1414                         }
1415
1416                 }
1417                 db_put(binddb, command, keys);
1418         }
1419
1420         if ("" == keys) {
1421                 if (hud_showbinds > 1)
1422                         return sprintf(_("%s (not bound)"), text);
1423                 else
1424                         return text;
1425         }
1426         else if (hud_showbinds > 1)
1427                 return sprintf(_("%s (%s)"), text, keys);
1428         else
1429                 return keys;
1430 }