qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6 void menu_show_error()
   7 {
   8         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
   9 }
  10
  11 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  12 // Useful for precaching things
  13
  14 void menu_sub_null()
  15 {
  16 }
  17
  18 #ifdef USE_FTE
  19 float __engine_check;
  20 #endif
  21
  22 void precache_playermodel(string m)
  23 {
  24         string f;
  25
  26         if(substring(m, -9,5) == "_lod1")
  27                 return;
  28         if(substring(m, -9,5) == "_lod2")
  29                 return;
  30         precache_model(m);
  31         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  32         if(fexists(f))
  33                 precache_model(f);
  34         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  35         if(fexists(f))
  36                 precache_model(f);
  37
  38         /*
  39         float globhandle, i, n;
  40         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  41         if (globhandle < 0)
  42                 return;
  43         n = search_getsize(globhandle);
  44         for (i = 0; i < n; ++i)
  45         {
  46                 //print(search_getfilename(globhandle, i), "\n");
  47                 f = search_getfilename(globhandle, i);
  48                 PrecachePlayerSounds(f);
  49         }
  50         search_end(globhandle);
  51         */
  52 }
  53 void precache_all_playermodels(string pattern)
  54 {
  55         float globhandle, i, n;
  56         string f;
  57
  58         globhandle = search_begin(pattern, TRUE, FALSE);
  59         if (globhandle < 0)
  60                 return;
  61         n = search_getsize(globhandle);
  62         for (i = 0; i < n; ++i)
  63         {
  64                 //print(search_getfilename(globhandle, i), "\n");
  65                 f = search_getfilename(globhandle, i);
  66                 precache_playermodel(f);
  67         }
  68         search_end(globhandle);
  69 }
  70
  71 string forcefog;
  72 void WaypointSprite_Load();
  73 void ConsoleCommand_macro_init();
  74 void CSQC_Init(void)
  75 {
  76         prvm_language = cvar_string("prvm_language");
  77
  78 #ifdef USE_FTE
  79 #pragma target ID
  80         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  81         if(!__engine_check)
  82         {
  83                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  84                 localcmd("\ndisconnect\n");
  85                 return;
  86         }
  87 #pragma target FTE
  88 #endif
  89
  90         check_unacceptable_compiler_bugs();
  91
  92 #ifdef WATERMARK
  93         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  94 #endif
  95
  96         float i;
  97
  98 #ifdef COMPAT_XON050_ENGINE
  99         // old engine lacks implementation of player_localnum
 100         player_localnum = player_localentnum - 1;
 101 #endif
 102
 103         binddb = db_create();
 104         tempdb = db_create();
 105         ClientProgsDB = db_load("client.db");
 106         compressShortVector_init();
 107
 108         drawfont = FONT_USER+1;
 109         menu_visible = FALSE;
 110         menu_show = menu_show_error;
 111         menu_action = menu_sub_null;
 112
 113         for(i = 0; i < 255; ++i)
 114                 if(getplayerkeyvalue(i, "viewentity") == "")
 115                         break;
 116         maxclients = i;
 117
 118         //registercommand("hud_configure");
 119         //registercommand("hud_save");
 120         //registercommand("menu_action");
 121
 122         ConsoleCommand_macro_init();
 123
 124         registercvar("hud_usecsqc", "1");
 125         registercvar("scoreboard_columns", "default");
 126
 127         gametype = 0;
 128
 129         // hud_fields uses strunzone on the titles!
 130         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 131                 hud_title[i] = strzone("(null)");
 132
 133         postinit = false;
 134
 135         calledhooks = 0;
 136
 137         teams = Sort_Spawn();
 138         players = Sort_Spawn();
 139
 140         GetTeam(COLOR_SPECTATOR, true); // add specs first
 141
 142         // needs to be done so early because of the constants they create
 143         RegisterWeapons();
 144         RegisterGametypes();
 145
 146         WaypointSprite_Load();
 147
 148         // precaches
 149         precache_model("null");
 150         precache_sound("misc/hit.wav");
 151         precache_sound("misc/typehit.wav");
 152         if (autocvar_cl_precacheplayermodels)
 153         {
 154                 precache_all_playermodels("models/player/*.zym");
 155                 precache_all_playermodels("models/player/*.dpm");
 156                 precache_all_playermodels("models/player/*.md3");
 157                 precache_all_playermodels("models/player/*.psk");
 158                 precache_all_playermodels("models/player/*.iqm");
 159         }
 160
 161         Projectile_Precache();
 162         Hook_Precache();
 163         GibSplash_Precache();
 164         Casings_Precache();
 165         DamageInfo_Precache();
 166         Vehicles_Precache();
 167         turrets_precache();
 168   Announcer_Precache();
 169         Tuba_Precache();
 170
 171         if(autocvar_cl_reticle)
 172         {
 173                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 174                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 175         }
 176
 177         get_mi_min_max_texcoords(1); // try the CLEVER way first
 178         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179         shortmapname = mi_shortname;
 180
 181         if(precache_pic(minimapname) == "")
 182         {
 183                 // but maybe we have a non-clever minimap
 184                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                 if(precache_pic(minimapname) == "")
 186                         minimapname = ""; // FAIL
 187                 else
 188                         get_mi_min_max_texcoords(0); // load new texcoords
 189         }
 190
 191         mi_center = (mi_min + mi_max) * 0.5;
 192         mi_scale = mi_max - mi_min;
 193         minimapname = strzone(minimapname);
 194
 195         WarpZone_Init();
 196
 197         hud_configure_prev = -1;
 198         tab_panel = -1;
 199
 200         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 201 }
 202
 203 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 204 void Shutdown(void)
 205 {
 206 #ifdef USE_FTE
 207 #pragma TARGET id
 208         if(!__engine_check)
 209                 return 0;
 210 #pragma TARGET fte
 211 #endif
 212
 213         WarpZone_Shutdown();
 214
 215         remove(teams);
 216         remove(players);
 217         db_close(binddb);
 218         db_close(tempdb);
 219         if(autocvar_cl_db_saveasdump)
 220                 db_dump(ClientProgsDB, "client.db");
 221         else
 222                 db_save(ClientProgsDB, "client.db");
 223         db_close(ClientProgsDB);
 224
 225         if(camera_active)
 226                 cvar_set("chase_active",ftos(chase_active_backup));
 227
 228         // unset the event chasecam's chase_active
 229         if(autocvar_chase_active < 0)
 230                 cvar_set("chase_active", "0");
 231
 232         if not(isdemo())
 233         {
 234                 if not(calledhooks & HOOK_START)
 235                         localcmd("\n_cl_hook_gamestart nop\n");
 236                 if not(calledhooks & HOOK_END)
 237                         localcmd("\ncl_hook_gameend\n");
 238         }
 239 }
 240
 241 .float has_team;
 242 float SetTeam(entity o, float Team)
 243 {
 244         entity tm;
 245         if(teamplay)
 246         {
 247                 switch(Team)
 248                 {
 249                         case -1:
 250                         case COLOR_TEAM1:
 251                         case COLOR_TEAM2:
 252                         case COLOR_TEAM3:
 253                         case COLOR_TEAM4:
 254                                 break;
 255                         default:
 256                                 if(GetTeam(Team, false) == world)
 257                                 {
 258                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 259                                         Team = COLOR_SPECTATOR;
 260                                 }
 261                                 break;
 262                 }
 263         }
 264         else
 265         {
 266                 switch(Team)
 267                 {
 268                         case -1:
 269                         case 0:
 270                                 break;
 271                         default:
 272                                 if(GetTeam(Team, false) == world)
 273                                 {
 274                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 275                                         Team = COLOR_SPECTATOR;
 276                                 }
 277                                 break;
 278                 }
 279         }
 280         if(Team == -1) // leave
 281         {
 282                 if(o.has_team)
 283                 {
 284                         tm = GetTeam(o.team, false);
 285                         tm.team_size -= 1;
 286                         o.has_team = 0;
 287                         return TRUE;
 288                 }
 289         }
 290         else
 291         {
 292                 if not(o.has_team)
 293                 {
 294                         o.team = Team;
 295                         tm = GetTeam(Team, true);
 296                         tm.team_size += 1;
 297                         o.has_team = 1;
 298                         return TRUE;
 299                 }
 300                 else if(Team != o.team)
 301                 {
 302                         tm = GetTeam(o.team, false);
 303                         tm.team_size -= 1;
 304                         o.team = Team;
 305                         tm = GetTeam(Team, true);
 306                         tm.team_size += 1;
 307                         return TRUE;
 308                 }
 309         }
 310         return FALSE;
 311 }
 312
 313 void Playerchecker_Think()
 314 {
 315         float i;
 316         entity e;
 317         for(i = 0; i < maxclients; ++i)
 318         {
 319                 e = playerslots[i];
 320                 if(GetPlayerName(i) == "")
 321                 {
 322                         if(e.sort_prev)
 323                         {
 324                                 // player disconnected
 325                                 SetTeam(e, -1);
 326                                 RemovePlayer(e);
 327                                 e.sort_prev = world;
 328                                 //e.gotscores = 0;
 329                         }
 330                 }
 331                 else
 332                 {
 333                         if not(e.sort_prev)
 334                         {
 335                                 // player connected
 336                                 if not(e)
 337                                         playerslots[i] = e = spawn();
 338                                 e.sv_entnum = i;
 339                                 e.ping = 0;
 340                                 e.ping_packetloss = 0;
 341                                 e.ping_movementloss = 0;
 342                                 //e.gotscores = 0; // we might already have the scores...
 343                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 344                                 RegisterPlayer(e);
 345                                 HUD_UpdatePlayerPos(e);
 346                         }
 347                 }
 348         }
 349         self.nextthink = time + 0.2;
 350 }
 351
 352 void Porto_Init();
 353 void TrueAim_Init();
 354 void PostInit(void)
 355 {
 356         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 357
 358         entity playerchecker;
 359         playerchecker = spawn();
 360         playerchecker.think = Playerchecker_Think;
 361         playerchecker.nextthink = time + 0.2;
 362
 363         Porto_Init();
 364         TrueAim_Init();
 365
 366         postinit = true;
 367 }
 368
 369 float button_zoom;
 370
 371 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 372 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 373 // All keys are in ascii.
 374 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 375 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 376 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 377 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 378 {
 379         float bSkipKey;
 380         bSkipKey = false;
 381
 382         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 383                 return true;
 384
 385         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 386                 return true;
 387
 388         if(menu_visible)
 389                 if(menu_action(bInputType, nPrimary, nSecondary))
 390                         return TRUE;
 391
 392         return bSkipKey;
 393 }
 394
 395 // END REQUIRED CSQC FUNCTIONS
 396 // --------------------------------------------------------------------------
 397
 398 // --------------------------------------------------------------------------
 399 // BEGIN OPTIONAL CSQC FUNCTIONS
 400 void Ent_RemoveEntCS()
 401 {
 402         entcs_receiver[self.sv_entnum] = world;
 403 }
 404 void Ent_ReadEntCS()
 405 {
 406         float sf;
 407         InterpolateOrigin_Undo();
 408
 409         self.classname = "entcs_receiver";
 410         sf = ReadByte();
 411
 412         if(sf & 1)
 413                 self.sv_entnum = ReadByte();
 414         if(sf & 2)
 415         {
 416                 self.origin_x = ReadShort();
 417                 self.origin_y = ReadShort();
 418                 self.origin_z = ReadShort();
 419         }
 420         if(sf & 4)
 421         {
 422                 self.angles_y = ReadByte() * 360.0 / 256;
 423                 self.angles_x = self.angles_z = 0;
 424         }
 425         if(sf & 8)
 426                 self.healthvalue = ReadByte() * 10;
 427         if(sf & 16)
 428                 self.armorvalue = ReadByte() * 10;
 429
 430         entcs_receiver[self.sv_entnum] = self;
 431         self.entremove = Ent_RemoveEntCS;
 432
 433         InterpolateOrigin_Note();
 434 }
 435
 436 void Ent_Remove();
 437
 438 void Ent_RemovePlayerScore()
 439 {
 440         float i;
 441
 442         if(self.owner)
 443         {
 444                 SetTeam(self.owner, -1);
 445                 self.owner.gotscores = 0;
 446                 for(i = 0; i < MAX_SCORE; ++i)
 447                         self.owner.(scores[i]) = 0; // clear all scores
 448         }
 449 }
 450
 451 void Ent_ReadPlayerScore()
 452 {
 453         float i, n;
 454         float isNew;
 455         entity o;
 456
 457         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 458         // (no I've never heard of M-x replace-string, sed, or anything like that)
 459         isNew = !self.owner; // workaround for DP bug
 460         n = ReadByte()-1;
 461
 462 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 463         if(!isNew && n != self.sv_entnum)
 464         {
 465                 //print(_("A CSQC entity changed its owner!\n"));
 466                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 467                 isNew = true;
 468                 Ent_Remove();
 469                 self.enttype = ENT_CLIENT_SCORES;
 470         }
 471 #endif
 472
 473         self.sv_entnum = n;
 474
 475         if not(playerslots[self.sv_entnum])
 476                 playerslots[self.sv_entnum] = spawn();
 477         o = self.owner = playerslots[self.sv_entnum];
 478         o.sv_entnum = self.sv_entnum;
 479         o.gotscores = 1;
 480
 481         //if not(o.sort_prev)
 482         //      RegisterPlayer(o);
 483         //playerchecker will do this for us later, if it has not already done so
 484
 485         float sf, lf;
 486 #if MAX_SCORE <= 8
 487         sf = ReadByte();
 488         lf = ReadByte();
 489 #else
 490         sf = ReadShort();
 491         lf = ReadShort();
 492 #endif
 493         float p;
 494         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 495                 if(sf & p)
 496                 {
 497                         if(lf & p)
 498                                 o.(scores[i]) = ReadInt24_t();
 499                         else
 500                                 o.(scores[i]) = ReadChar();
 501                 }
 502
 503         if(o.sort_prev)
 504                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 505
 506         self.entremove = Ent_RemovePlayerScore;
 507 }
 508
 509 void Ent_ReadTeamScore()
 510 {
 511         float i;
 512         entity o;
 513
 514         self.team = ReadByte();
 515         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 516
 517         float sf, lf;
 518 #if MAX_TEAMSCORE <= 8
 519         sf = ReadByte();
 520         lf = ReadByte();
 521 #else
 522         sf = ReadShort();
 523         lf = ReadShort();
 524 #endif
 525         float p;
 526         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 527                 if(sf & p)
 528                 {
 529                         if(lf & p)
 530                                 o.(teamscores[i]) = ReadInt24_t();
 531                         else
 532                                 o.(teamscores[i]) = ReadChar();
 533                 }
 534
 535         HUD_UpdateTeamPos(o);
 536 }
 537
 538 void Ent_ClientData()
 539 {
 540         float f;
 541         float newspectatee_status;
 542
 543         f = ReadByte();
 544
 545         scoreboard_showscores_force = (f & 1);
 546
 547         if(f & 2)
 548         {
 549                 newspectatee_status = ReadByte();
 550                 if(newspectatee_status == player_localnum + 1)
 551                         newspectatee_status = -1; // observing
 552         }
 553         else
 554                 newspectatee_status = 0;
 555
 556         spectatorbutton_zoom = (f & 4);
 557
 558         if(f & 8)
 559         {
 560                 angles_held_status = 1;
 561                 angles_held_x = ReadAngle();
 562                 angles_held_y = ReadAngle();
 563                 angles_held_z = 0;
 564         }
 565         else
 566                 angles_held_status = 0;
 567
 568         if(newspectatee_status != spectatee_status)
 569         {
 570                 // clear race stuff
 571                 race_laptime = 0;
 572                 race_checkpointtime = 0;
 573         }
 574         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 575         {
 576                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 577                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 578                 )
 579                         prev_p_health = -1;
 580                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 581                         prev_health = -1;
 582         }
 583         spectatee_status = newspectatee_status;
 584
 585         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 586 }
 587
 588 void Ent_Nagger()
 589 {
 590         float nags, i, j, b, f;
 591
 592         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 593
 594         if(!(nags & 4))
 595         {
 596                 if(vote_called_vote)
 597                         strunzone(vote_called_vote);
 598                 vote_called_vote = string_null;
 599                 vote_active = 0;
 600         }
 601         else
 602         {
 603                 vote_active = 1;
 604         }
 605
 606         if(nags & 64)
 607         {
 608                 vote_yescount = ReadByte();
 609                 vote_nocount = ReadByte();
 610                 vote_needed = ReadByte();
 611                 vote_highlighted = ReadChar();
 612         }
 613
 614         if(nags & 128)
 615         {
 616                 if(vote_called_vote)
 617                         strunzone(vote_called_vote);
 618                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 619         }
 620
 621         if(nags & 1)
 622         {
 623                 for(j = 0; j < maxclients; ++j)
 624                         if(playerslots[j])
 625                                 playerslots[j].ready = 1;
 626                 for(i = 1; i <= maxclients; i += 8)
 627                 {
 628                         f = ReadByte();
 629                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 630                                 if not(f & b)
 631                                         if(playerslots[j])
 632                                                 playerslots[j].ready = 0;
 633                 }
 634         }
 635
 636         ready_waiting = (nags & 1);
 637         ready_waiting_for_me = (nags & 2);
 638         vote_waiting = (nags & 4);
 639         vote_waiting_for_me = (nags & 8);
 640         warmup_stage = (nags & 16);
 641 }
 642
 643 void Ent_RandomSeed()
 644 {
 645         float s;
 646         prandom_debug();
 647         s = ReadShort();
 648         psrandom(s);
 649 }
 650
 651 void Ent_ReadAccuracy(void)
 652 {
 653         float sf, f, w, b;
 654         sf = ReadInt24_t();
 655         if(sf == 0)
 656         {
 657                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 658                         weapon_accuracy[w] = -1;
 659                 return;
 660         }
 661
 662         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 663         {
 664                 if(sf & f)
 665                 {
 666                         b = ReadByte();
 667                         if(b == 0)
 668                                 weapon_accuracy[w] = -1;
 669                         else if(b == 255)
 670                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 671                         else
 672                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 673                 }
 674         }
 675 }
 676
 677 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 678 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 679 void Ent_RadarLink();
 680 void Ent_Init();
 681 void Ent_ScoresInfo();
 682 void CSQC_Ent_Update(float bIsNewEntity)
 683 {
 684         float t;
 685         float savetime;
 686         t = ReadByte();
 687
 688         // set up the "time" global for received entities to be correct for interpolation purposes
 689         savetime = time;
 690         if(servertime)
 691         {
 692                 time = servertime;
 693         }
 694         else
 695         {
 696                 serverprevtime = time;
 697                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 698                 time = serverprevtime + serverdeltatime;
 699         }
 700
 701 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 702         if(self.enttype)
 703         {
 704                 if(t != self.enttype || bIsNewEntity)
 705                 {
 706                         //print(_("A CSQC entity changed its type!\n"));
 707                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 708                         Ent_Remove();
 709                         bIsNewEntity = 1;
 710                 }
 711         }
 712         else
 713         {
 714                 if(!bIsNewEntity)
 715                 {
 716                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 717                         bIsNewEntity = 1;
 718                 }
 719         }
 720 #endif
 721         self.enttype = t;
 722         switch(t)
 723         {
 724                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 725                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 726                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 727                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 728                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 729                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 730                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 731                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 732                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 733                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 734                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 735                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 736                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 737                 case ENT_CLIENT_INIT: Ent_Init(); break;
 738                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 739                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 740                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 741                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 742                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 743                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 744                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 745                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 746                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 747                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 748                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 749                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 750                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 751                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 752                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 753                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 754                 case ENT_CLIENT_TURRET: ent_turret(); break;
 755                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 756                 default:
 757                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 758                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 759                         break;
 760         }
 761
 762         time = savetime;
 763 }
 764 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 765 // used when an entity changes its type. For an entity that someone interacts
 766 // with others, make sure it can no longer do so.
 767 void Ent_Remove()
 768 {
 769         if(self.entremove)
 770                 self.entremove();
 771
 772         self.enttype = 0;
 773         self.classname = "";
 774         self.draw = menu_sub_null;
 775         self.entremove = menu_sub_null;
 776         // TODO possibly set more stuff to defaults
 777 }
 778 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 779 void CSQC_Ent_Remove()
 780 {
 781         if(wasfreed(self))
 782         {
 783                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 784                 return;
 785         }
 786         if(self.enttype)
 787                 Ent_Remove();
 788         remove(self);
 789 }
 790
 791 void Gamemode_Init()
 792 {
 793         if not(isdemo())
 794         {
 795                 if(!(calledhooks & HOOK_START))
 796                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 797                 calledhooks |= HOOK_START;
 798         }
 799 }
 800 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 801 void CSQC_Parse_StuffCmd(string strMessage)
 802 {
 803         localcmd(strMessage);
 804 }
 805 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 806 void CSQC_Parse_Print(string strMessage)
 807 {
 808         print(ColorTranslateRGB(strMessage));
 809 }
 810
 811 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 812 void CSQC_Parse_CenterPrint(string strMessage)
 813 {
 814         centerprint_hud(strMessage);
 815 }
 816
 817 string notranslate_fogcmd1 = "\nfog ";
 818 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 819 void Fog_Force()
 820 {
 821         // TODO somehow thwart prvm_globalset client ...
 822
 823         if(forcefog != "")
 824                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 825 }
 826
 827 void Gamemode_Init();
 828 void Ent_ScoresInfo()
 829 {
 830         float i;
 831         self.classname = "ent_client_scores_info";
 832         gametype = ReadInt24_t();
 833         for(i = 0; i < MAX_SCORE; ++i)
 834         {
 835                 scores_label[i] = strzone(ReadString());
 836                 scores_flags[i] = ReadByte();
 837         }
 838         for(i = 0; i < MAX_TEAMSCORE; ++i)
 839         {
 840                 teamscores_label[i] = strzone(ReadString());
 841                 teamscores_flags[i] = ReadByte();
 842         }
 843         HUD_InitScores();
 844         Gamemode_Init();
 845 }
 846
 847 void Ent_Init()
 848 {
 849         self.classname = "ent_client_init";
 850
 851         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 852
 853         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 854         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 855         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 856         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 857         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 858         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 859         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 860         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 861         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 862         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 863         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 864         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 865
 866         if(forcefog)
 867                 strunzone(forcefog);
 868         forcefog = strzone(ReadString());
 869
 870         armorblockpercent = ReadByte() / 255.0;
 871
 872         g_weaponswitchdelay = ReadByte() / 255.0;
 873
 874         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 875         g_balance_grenadelauncher_bouncestop = ReadCoord();
 876         g_balance_electro_secondary_bouncefactor = ReadCoord();
 877         g_balance_electro_secondary_bouncestop = ReadCoord();
 878
 879         nex_scope = !ReadByte();
 880         rifle_scope = !ReadByte();
 881
 882         serverflags = ReadByte();
 883
 884         minelayer_maxmines = ReadByte();
 885
 886         hagar_maxrockets = ReadByte();
 887
 888         g_trueaim_minrange = ReadCoord();
 889         g_balance_porto_secondary = ReadByte();
 890
 891         if(!postinit)
 892                 PostInit();
 893 }
 894
 895 void Net_ReadRace()
 896 {
 897         float b;
 898
 899         b = ReadByte();
 900
 901         switch(b)
 902         {
 903                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 904                         race_checkpoint = ReadByte();
 905                         race_time = ReadInt24_t();
 906                         race_previousbesttime = ReadInt24_t();
 907                         if(race_previousbestname)
 908                                 strunzone(race_previousbestname);
 909                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 910
 911                         race_checkpointtime = time;
 912
 913                         if(race_checkpoint == 0 || race_checkpoint == 254)
 914                         {
 915                                 race_penaltyaccumulator = 0;
 916                                 race_laptime = time; // valid
 917                         }
 918
 919                         break;
 920
 921                 case RACE_NET_CHECKPOINT_CLEAR:
 922                         race_laptime = 0;
 923                         race_checkpointtime = 0;
 924                         break;
 925
 926                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 927                         race_laptime = ReadCoord();
 928                         race_checkpointtime = -99999;
 929                         // fall through
 930                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 931                         race_nextcheckpoint = ReadByte();
 932
 933                         race_nextbesttime = ReadInt24_t();
 934                         if(race_nextbestname)
 935                                 strunzone(race_nextbestname);
 936                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 937                         break;
 938
 939                 case RACE_NET_CHECKPOINT_HIT_RACE:
 940                         race_mycheckpoint = ReadByte();
 941                         race_mycheckpointtime = time;
 942                         race_mycheckpointdelta = ReadInt24_t();
 943                         race_mycheckpointlapsdelta = ReadByte();
 944                         if(race_mycheckpointlapsdelta >= 128)
 945                                 race_mycheckpointlapsdelta -= 256;
 946                         if(race_mycheckpointenemy)
 947                                 strunzone(race_mycheckpointenemy);
 948                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 949                         break;
 950
 951                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 952                         race_othercheckpoint = ReadByte();
 953                         race_othercheckpointtime = time;
 954                         race_othercheckpointdelta = ReadInt24_t();
 955                         race_othercheckpointlapsdelta = ReadByte();
 956                         if(race_othercheckpointlapsdelta >= 128)
 957                                 race_othercheckpointlapsdelta -= 256;
 958                         if(race_othercheckpointenemy)
 959                                 strunzone(race_othercheckpointenemy);
 960                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 961                         break;
 962
 963                 case RACE_NET_PENALTY_RACE:
 964                         race_penaltyeventtime = time;
 965                         race_penaltytime = ReadShort();
 966                         //race_penaltyaccumulator += race_penaltytime;
 967                         if(race_penaltyreason)
 968                                 strunzone(race_penaltyreason);
 969                         race_penaltyreason = strzone(ReadString());
 970                         break;
 971
 972                 case RACE_NET_PENALTY_QUALIFYING:
 973                         race_penaltyeventtime = time;
 974                         race_penaltytime = ReadShort();
 975                         race_penaltyaccumulator += race_penaltytime;
 976                         if(race_penaltyreason)
 977                                 strunzone(race_penaltyreason);
 978                         race_penaltyreason = strzone(ReadString());
 979                         break;
 980
 981                 case RACE_NET_SERVER_RECORD:
 982                         race_server_record = ReadInt24_t();
 983                         break;
 984                 case RACE_NET_SPEED_AWARD:
 985                         race_speedaward = ReadInt24_t();
 986                         if(race_speedaward_holder)
 987                                 strunzone(race_speedaward_holder);
 988                         race_speedaward_holder = strzone(ReadString());
 989                         break;
 990                 case RACE_NET_SPEED_AWARD_BEST:
 991                         race_speedaward_alltimebest = ReadInt24_t();
 992                         if(race_speedaward_alltimebest_holder)
 993                                 strunzone(race_speedaward_alltimebest_holder);
 994                         race_speedaward_alltimebest_holder = strzone(ReadString());
 995                         break;
 996                 case RACE_NET_SERVER_RANKINGS:
 997                         float pos, prevpos, del;
 998                         pos = ReadShort();
 999                         prevpos = ReadShort();
1000                         del = ReadShort();
1001
1002                         // move other rankings out of the way
1003                         float i;
1004                         if (prevpos) {
1005                                 for (i=prevpos-1;i>pos-1;--i) {
1006                                         grecordtime[i] = grecordtime[i-1];
1007                                         if(grecordholder[i])
1008                                                 strunzone(grecordholder[i]);
1009                                         grecordholder[i] = strzone(grecordholder[i-1]);
1010                                 }
1011                         } else if (del) { // a record has been deleted by the admin
1012                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1013                                         if (i == RANKINGS_CNT-1) { // clear out last record
1014                                                 grecordtime[i] = 0;
1015                                                 if (grecordholder[i])
1016                                                         strunzone(grecordholder[i]);
1017                                                 grecordholder[i] = string_null;
1018                                         }
1019                                         else {
1020                                                 grecordtime[i] = grecordtime[i+1];
1021                                                 if (grecordholder[i])
1022                                                         strunzone(grecordholder[i]);
1023                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1024                                         }
1025                                 }
1026                         } else { // player has no ranked record yet
1027                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1028                                         grecordtime[i] = grecordtime[i-1];
1029                                         if(grecordholder[i])
1030                                                 strunzone(grecordholder[i]);
1031                                         grecordholder[i] = strzone(grecordholder[i-1]);
1032                                 }
1033                         }
1034
1035                         // store new ranking
1036                         if(grecordholder[pos-1] != "")
1037                                 strunzone(grecordholder[pos-1]);
1038                         grecordholder[pos-1] = strzone(ReadString());
1039                         grecordtime[pos-1] = ReadInt24_t();
1040                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1041                                 race_myrank = pos;
1042                         break;
1043                 case RACE_NET_SERVER_STATUS:
1044                         race_status = ReadShort();
1045                         if(race_status_name)
1046                                 strunzone(race_status_name);
1047                         race_status_name = strzone(ReadString());
1048         }
1049 }
1050
1051 void Net_ReadSpawn()
1052 {
1053         zoomin_effect = 1;
1054         current_viewzoom = 0.6;
1055 }
1056
1057 void Net_TeamNagger()
1058 {
1059         teamnagger = 1;
1060 }
1061
1062 void Net_ReadPingPLReport()
1063 {
1064         float e, pi, pl, ml;
1065         e = ReadByte();
1066         pi = ReadShort();
1067         pl = ReadByte();
1068         ml = ReadByte();
1069         if not(playerslots[e])
1070                 return;
1071         playerslots[e].ping = pi;
1072         playerslots[e].ping_packetloss = pl / 255.0;
1073         playerslots[e].ping_movementloss = ml / 255.0;
1074 }
1075
1076 void Net_WeaponComplain() {
1077         complain_weapon = ReadByte();
1078
1079         if(complain_weapon_name)
1080                 strunzone(complain_weapon_name);
1081         complain_weapon_name = strzone(ReadString());
1082
1083         complain_weapon_type = ReadByte();
1084
1085         complain_weapon_time = time;
1086         weapontime = time; // ping the weapon panel
1087 }
1088
1089 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1090 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1091 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1092 float CSQC_Parse_TempEntity()
1093 {
1094         float bHandled;
1095                 bHandled  = true;
1096         // Acquire TE ID
1097         float nTEID;
1098                 nTEID = ReadByte();
1099
1100                 // NOTE: Could just do return instead of break...
1101         switch(nTEID)
1102         {
1103                 case TE_CSQC_TARGET_MUSIC:
1104                         Net_TargetMusic();
1105                         bHandled = true;
1106                         break;
1107                 case TE_CSQC_PICTURE:
1108                         Net_MapVote_Picture();
1109                         bHandled = true;
1110                         break;
1111                 case TE_CSQC_RACE:
1112                         Net_ReadRace();
1113                         bHandled = true;
1114                         break;
1115                 case TE_CSQC_SPAWN:
1116                         Net_ReadSpawn();
1117                         bHandled = true;
1118                         break;
1119                 case TE_CSQC_ZCURVEPARTICLES:
1120                         Net_ReadZCurveParticles();
1121                         bHandled = true;
1122                         break;
1123                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1124                         Net_ReadNexgunBeamParticle();
1125                         bHandled = true;
1126                         break;
1127                 case TE_CSQC_TEAMNAGGER:
1128                         Net_TeamNagger();
1129                         bHandled = true;
1130                         break;
1131                 case TE_CSQC_LIGHTNINGARC:
1132                         Net_ReadLightningarc();
1133                         bHandled = true;
1134                         break;
1135                 case TE_CSQC_PINGPLREPORT:
1136                         Net_ReadPingPLReport();
1137                         bHandled = true;
1138                         break;
1139                 case TE_CSQC_ANNOUNCE:
1140                         Announcer_Play(ReadString());
1141                         bHandled = true;
1142                         break;
1143                 case TE_CSQC_KILLNOTIFY:
1144                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1145                         bHandled = true;
1146                         break;
1147                 case TE_CSQC_KILLCENTERPRINT:
1148                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1149                         bHandled = true;
1150                         break;
1151                 case TE_CSQC_CENTERPRINT_GENERIC:
1152                         float id;
1153                         string s;
1154                         id = ReadByte();
1155                         s = ReadString();
1156                         if (id != 0 && s != "")
1157                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1158                         else
1159                                 centerprint_generic(id, s, 0, 0);
1160                         bHandled = true;
1161                         break;
1162                 case TE_CSQC_WEAPONCOMPLAIN:
1163                         Net_WeaponComplain();
1164                         bHandled = true;
1165                         break;
1166                 case TE_CSQC_VEHICLESETUP:
1167                         Net_VehicleSetup();
1168                         bHandled = true;
1169                         break;
1170                 case TE_CSQC_SVNOTICE:
1171                         cl_notice_read();
1172                         bHandled = true;
1173                         break;
1174                 default:
1175                         // No special logic for this temporary entity; return 0 so the engine can handle it
1176                         bHandled = false;
1177                         break;
1178         }
1179
1180         return bHandled;
1181 }
1182
1183 string getcommandkey(string text, string command)
1184 {
1185         string keys;
1186         float n, j, k, l;
1187
1188         if (!autocvar_hud_showbinds)
1189                 return text;
1190
1191         keys = db_get(binddb, command);
1192         if (!keys)
1193         {
1194                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1195                 for(j = 0; j < n; ++j)
1196                 {
1197                         k = stof(argv(j));
1198                         if(k != -1)
1199                         {
1200                                 if ("" == keys)
1201                                         keys = keynumtostring(k);
1202                                 else
1203                                         keys = strcat(keys, ", ", keynumtostring(k));
1204
1205                                 ++l;
1206                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1207                         }
1208
1209                 }
1210                 db_put(binddb, command, keys);
1211         }
1212
1213         if ("" == keys) {
1214                 if (autocvar_hud_showbinds > 1)
1215                         return sprintf(_("%s (not bound)"), text);
1216                 else
1217                         return text;
1218         }
1219         else if (autocvar_hud_showbinds > 1)
1220                 return sprintf(_("%s (%s)"), text, keys);
1221         else
1222                 return keys;
1223 }