qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(COLOR_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164         if (autocvar_cl_precacheplayermodels)
 165         {
 166                 precache_all_playermodels("models/player/*.zym");
 167                 precache_all_playermodels("models/player/*.dpm");
 168                 precache_all_playermodels("models/player/*.md3");
 169                 precache_all_playermodels("models/player/*.psk");
 170                 precache_all_playermodels("models/player/*.iqm");
 171         }
 172
 173         Projectile_Precache();
 174         Hook_Precache();
 175         GibSplash_Precache();
 176         Casings_Precache();
 177         DamageInfo_Precache();
 178         Vehicles_Precache();
 179         turrets_precache();
 180     Announcer_Precache();
 181         Tuba_Precache();
 182         CSQCPlayer_Precache();
 183
 184         if(autocvar_cl_reticle)
 185         {
 186                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 187                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 188         }
 189
 190         get_mi_min_max_texcoords(1); // try the CLEVER way first
 191         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 192         shortmapname = mi_shortname;
 193
 194         if(precache_pic(minimapname) == "")
 195         {
 196                 // but maybe we have a non-clever minimap
 197                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 198                 if(precache_pic(minimapname) == "")
 199                         minimapname = ""; // FAIL
 200                 else
 201                         get_mi_min_max_texcoords(0); // load new texcoords
 202         }
 203
 204         mi_center = (mi_min + mi_max) * 0.5;
 205         mi_scale = mi_max - mi_min;
 206         minimapname = strzone(minimapname);
 207
 208         WarpZone_Init();
 209
 210         hud_configure_prev = -1;
 211         tab_panel = -1;
 212
 213         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 214 }
 215
 216 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 217 void Shutdown(void)
 218 {
 219 #ifdef USE_FTE
 220 #pragma TARGET id
 221         if(!__engine_check)
 222                 return 0;
 223 #pragma TARGET fte
 224 #endif
 225
 226         WarpZone_Shutdown();
 227
 228         remove(teams);
 229         remove(players);
 230         db_close(binddb);
 231         db_close(tempdb);
 232         if(autocvar_cl_db_saveasdump)
 233                 db_dump(ClientProgsDB, "client.db");
 234         else
 235                 db_save(ClientProgsDB, "client.db");
 236         db_close(ClientProgsDB);
 237
 238         if(camera_active)
 239                 cvar_set("chase_active",ftos(chase_active_backup));
 240
 241         // unset the event chasecam's chase_active
 242         if(autocvar_chase_active < 0)
 243                 cvar_set("chase_active", "0");
 244
 245         if not(isdemo())
 246         {
 247                 if not(calledhooks & HOOK_START)
 248                         localcmd("\n_cl_hook_gamestart nop\n");
 249                 if not(calledhooks & HOOK_END)
 250                         localcmd("\ncl_hook_gameend\n");
 251         }
 252 }
 253
 254 .float has_team;
 255 float SetTeam(entity o, float Team)
 256 {
 257         entity tm;
 258         if(teamplay)
 259         {
 260                 switch(Team)
 261                 {
 262                         case -1:
 263                         case COLOR_TEAM1:
 264                         case COLOR_TEAM2:
 265                         case COLOR_TEAM3:
 266                         case COLOR_TEAM4:
 267                                 break;
 268                         default:
 269                                 if(GetTeam(Team, false) == world)
 270                                 {
 271                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 272                                         Team = COLOR_SPECTATOR;
 273                                 }
 274                                 break;
 275                 }
 276         }
 277         else
 278         {
 279                 switch(Team)
 280                 {
 281                         case -1:
 282                         case 0:
 283                                 break;
 284                         default:
 285                                 if(GetTeam(Team, false) == world)
 286                                 {
 287                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 288                                         Team = COLOR_SPECTATOR;
 289                                 }
 290                                 break;
 291                 }
 292         }
 293         if(Team == -1) // leave
 294         {
 295                 if(o.has_team)
 296                 {
 297                         tm = GetTeam(o.team, false);
 298                         tm.team_size -= 1;
 299                         o.has_team = 0;
 300                         return TRUE;
 301                 }
 302         }
 303         else
 304         {
 305                 if not(o.has_team)
 306                 {
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         o.has_team = 1;
 311                         return TRUE;
 312                 }
 313                 else if(Team != o.team)
 314                 {
 315                         tm = GetTeam(o.team, false);
 316                         tm.team_size -= 1;
 317                         o.team = Team;
 318                         tm = GetTeam(Team, true);
 319                         tm.team_size += 1;
 320                         return TRUE;
 321                 }
 322         }
 323         return FALSE;
 324 }
 325
 326 void Playerchecker_Think()
 327 {
 328         float i;
 329         entity e;
 330         for(i = 0; i < maxclients; ++i)
 331         {
 332                 e = playerslots[i];
 333                 if(GetPlayerName(i) == "")
 334                 {
 335                         if(e.sort_prev)
 336                         {
 337                                 // player disconnected
 338                                 SetTeam(e, -1);
 339                                 RemovePlayer(e);
 340                                 e.sort_prev = world;
 341                                 //e.gotscores = 0;
 342                         }
 343                 }
 344                 else
 345                 {
 346                         if not(e.sort_prev)
 347                         {
 348                                 // player connected
 349                                 if not(e)
 350                                         playerslots[i] = e = spawn();
 351                                 e.sv_entnum = i;
 352                                 e.ping = 0;
 353                                 e.ping_packetloss = 0;
 354                                 e.ping_movementloss = 0;
 355                                 //e.gotscores = 0; // we might already have the scores...
 356                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 357                                 RegisterPlayer(e);
 358                                 HUD_UpdatePlayerPos(e);
 359                         }
 360                 }
 361         }
 362         self.nextthink = time + 0.2;
 363 }
 364
 365 void Porto_Init();
 366 void TrueAim_Init();
 367 void PostInit(void)
 368 {
 369         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 370
 371         entity playerchecker;
 372         playerchecker = spawn();
 373         playerchecker.think = Playerchecker_Think;
 374         playerchecker.nextthink = time + 0.2;
 375
 376         Porto_Init();
 377         TrueAim_Init();
 378
 379         postinit = true;
 380 }
 381
 382 float button_zoom;
 383
 384 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 385 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 386 // All keys are in ascii.
 387 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 388 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 389 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 390 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 391 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 392 {
 393         float bSkipKey;
 394         bSkipKey = false;
 395
 396         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 397                 return true;
 398
 399         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 400                 return true;
 401
 402         if(menu_visible && menu_action)
 403                 if(menu_action(bInputType, nPrimary, nSecondary))
 404                         return TRUE;
 405
 406         return bSkipKey;
 407 }
 408
 409 // END REQUIRED CSQC FUNCTIONS
 410 // --------------------------------------------------------------------------
 411
 412 // --------------------------------------------------------------------------
 413 // BEGIN OPTIONAL CSQC FUNCTIONS
 414 void Ent_RemoveEntCS()
 415 {
 416         entcs_receiver[self.sv_entnum] = world;
 417 }
 418 void Ent_ReadEntCS()
 419 {
 420         float sf;
 421         InterpolateOrigin_Undo();
 422
 423         self.classname = "entcs_receiver";
 424         sf = ReadByte();
 425
 426         if(sf & 1)
 427                 self.sv_entnum = ReadByte();
 428         if(sf & 2)
 429         {
 430                 self.origin_x = ReadShort();
 431                 self.origin_y = ReadShort();
 432                 self.origin_z = ReadShort();
 433         }
 434         if(sf & 4)
 435         {
 436                 self.angles_y = ReadByte() * 360.0 / 256;
 437                 self.angles_x = self.angles_z = 0;
 438         }
 439         if(sf & 8)
 440                 self.healthvalue = ReadByte() * 10;
 441         if(sf & 16)
 442                 self.armorvalue = ReadByte() * 10;
 443
 444         entcs_receiver[self.sv_entnum] = self;
 445         self.entremove = Ent_RemoveEntCS;
 446
 447         InterpolateOrigin_Note();
 448 }
 449
 450 void Ent_Remove();
 451
 452 void Ent_RemovePlayerScore()
 453 {
 454         float i;
 455
 456         if(self.owner)
 457         {
 458                 SetTeam(self.owner, -1);
 459                 self.owner.gotscores = 0;
 460                 for(i = 0; i < MAX_SCORE; ++i)
 461                         self.owner.(scores[i]) = 0; // clear all scores
 462         }
 463 }
 464
 465 void Ent_ReadPlayerScore()
 466 {
 467         float i, n;
 468         float isNew;
 469         entity o;
 470
 471         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 472         // (no I've never heard of M-x replace-string, sed, or anything like that)
 473         isNew = !self.owner; // workaround for DP bug
 474         n = ReadByte()-1;
 475
 476 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 477         if(!isNew && n != self.sv_entnum)
 478         {
 479                 //print(_("A CSQC entity changed its owner!\n"));
 480                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 481                 isNew = true;
 482                 Ent_Remove();
 483                 self.enttype = ENT_CLIENT_SCORES;
 484         }
 485 #endif
 486
 487         self.sv_entnum = n;
 488
 489         if not(playerslots[self.sv_entnum])
 490                 playerslots[self.sv_entnum] = spawn();
 491         o = self.owner = playerslots[self.sv_entnum];
 492         o.sv_entnum = self.sv_entnum;
 493         o.gotscores = 1;
 494
 495         //if not(o.sort_prev)
 496         //      RegisterPlayer(o);
 497         //playerchecker will do this for us later, if it has not already done so
 498
 499         float sf, lf;
 500 #if MAX_SCORE <= 8
 501         sf = ReadByte();
 502         lf = ReadByte();
 503 #else
 504         sf = ReadShort();
 505         lf = ReadShort();
 506 #endif
 507         float p;
 508         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 509                 if(sf & p)
 510                 {
 511                         if(lf & p)
 512                                 o.(scores[i]) = ReadInt24_t();
 513                         else
 514                                 o.(scores[i]) = ReadChar();
 515                 }
 516
 517         if(o.sort_prev)
 518                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 519
 520         self.entremove = Ent_RemovePlayerScore;
 521 }
 522
 523 void Ent_ReadTeamScore()
 524 {
 525         float i;
 526         entity o;
 527
 528         self.team = ReadByte();
 529         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 530
 531         float sf, lf;
 532 #if MAX_TEAMSCORE <= 8
 533         sf = ReadByte();
 534         lf = ReadByte();
 535 #else
 536         sf = ReadShort();
 537         lf = ReadShort();
 538 #endif
 539         float p;
 540         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 541                 if(sf & p)
 542                 {
 543                         if(lf & p)
 544                                 o.(teamscores[i]) = ReadInt24_t();
 545                         else
 546                                 o.(teamscores[i]) = ReadChar();
 547                 }
 548
 549         HUD_UpdateTeamPos(o);
 550 }
 551
 552 void Ent_ClientData()
 553 {
 554         float f;
 555         float newspectatee_status;
 556
 557         f = ReadByte();
 558
 559         scoreboard_showscores_force = (f & 1);
 560
 561         if(f & 2)
 562         {
 563                 newspectatee_status = ReadByte();
 564                 if(newspectatee_status == player_localnum + 1)
 565                         newspectatee_status = -1; // observing
 566         }
 567         else
 568                 newspectatee_status = 0;
 569
 570         spectatorbutton_zoom = (f & 4);
 571
 572         if(f & 8)
 573         {
 574                 angles_held_status = 1;
 575                 angles_held_x = ReadAngle();
 576                 angles_held_y = ReadAngle();
 577                 angles_held_z = 0;
 578         }
 579         else
 580                 angles_held_status = 0;
 581
 582         if(newspectatee_status != spectatee_status)
 583         {
 584                 // clear race stuff
 585                 race_laptime = 0;
 586                 race_checkpointtime = 0;
 587         }
 588         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 589         {
 590                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 591                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 592                 )
 593                         prev_p_health = -1;
 594                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 595                         prev_health = -1;
 596         }
 597         spectatee_status = newspectatee_status;
 598
 599         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 600 }
 601
 602 void Ent_Nagger()
 603 {
 604         float nags, i, j, b, f;
 605
 606         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 607
 608         if(!(nags & 4))
 609         {
 610                 if(vote_called_vote)
 611                         strunzone(vote_called_vote);
 612                 vote_called_vote = string_null;
 613                 vote_active = 0;
 614         }
 615         else
 616         {
 617                 vote_active = 1;
 618         }
 619
 620         if(nags & 64)
 621         {
 622                 vote_yescount = ReadByte();
 623                 vote_nocount = ReadByte();
 624                 vote_needed = ReadByte();
 625                 vote_highlighted = ReadChar();
 626         }
 627
 628         if(nags & 128)
 629         {
 630                 if(vote_called_vote)
 631                         strunzone(vote_called_vote);
 632                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 633         }
 634
 635         if(nags & 1)
 636         {
 637                 for(j = 0; j < maxclients; ++j)
 638                         if(playerslots[j])
 639                                 playerslots[j].ready = 1;
 640                 for(i = 1; i <= maxclients; i += 8)
 641                 {
 642                         f = ReadByte();
 643                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 644                                 if not(f & b)
 645                                         if(playerslots[j])
 646                                                 playerslots[j].ready = 0;
 647                 }
 648         }
 649
 650         ready_waiting = (nags & 1);
 651         ready_waiting_for_me = (nags & 2);
 652         vote_waiting = (nags & 4);
 653         vote_waiting_for_me = (nags & 8);
 654         warmup_stage = (nags & 16);
 655 }
 656
 657 void Ent_RandomSeed()
 658 {
 659         float s;
 660         prandom_debug();
 661         s = ReadShort();
 662         psrandom(s);
 663 }
 664
 665 void Ent_ReadAccuracy(void)
 666 {
 667         float sf, f, w, b;
 668         sf = ReadInt24_t();
 669         if(sf == 0)
 670         {
 671                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 672                         weapon_accuracy[w] = -1;
 673                 return;
 674         }
 675
 676         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 677         {
 678                 if(sf & f)
 679                 {
 680                         b = ReadByte();
 681                         if(b == 0)
 682                                 weapon_accuracy[w] = -1;
 683                         else if(b == 255)
 684                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 685                         else
 686                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 687                 }
 688                 if(f == 0x800000)
 689                         f = 1;
 690                 else
 691                         f *= 2;
 692         }
 693 }
 694
 695 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 696 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 697 void Ent_RadarLink();
 698 void Ent_Init();
 699 void Ent_ScoresInfo();
 700 void CSQC_Ent_Update(float bIsNewEntity)
 701 {
 702         float t;
 703         float savetime;
 704         t = ReadByte();
 705
 706         if(autocvar_developer_csqcentities)
 707                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 708
 709         // set up the "time" global for received entities to be correct for interpolation purposes
 710         savetime = time;
 711         if(servertime)
 712         {
 713                 time = servertime;
 714         }
 715         else
 716         {
 717                 serverprevtime = time;
 718                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 719                 time = serverprevtime + serverdeltatime;
 720         }
 721
 722 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 723         if(self.enttype)
 724         {
 725                 if(t != self.enttype || bIsNewEntity)
 726                 {
 727                         //print(_("A CSQC entity changed its type!\n"));
 728                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 729                         Ent_Remove();
 730                         clearentity(self);
 731                         bIsNewEntity = 1;
 732                 }
 733         }
 734         else
 735         {
 736                 if(!bIsNewEntity)
 737                 {
 738                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 739                         bIsNewEntity = 1;
 740                 }
 741         }
 742 #endif
 743         self.enttype = t;
 744         switch(t)
 745         {
 746                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 747                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 748                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 749                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 750                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 751                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 752                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 753                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 754                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 755                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 756                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 757                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 758                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 759                 case ENT_CLIENT_INIT: Ent_Init(); break;
 760                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 761                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 762                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 763                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 764                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 765                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 766                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 767                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 768                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 769                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 770                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 771                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 772                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 773                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 774                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 775                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 776                 case ENT_CLIENT_TURRET: ent_turret(); break;
 777                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 778                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 779                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 780                 default:
 781                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 782                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 783                         break;
 784         }
 785
 786         time = savetime;
 787 }
 788 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 789 // used when an entity changes its type. For an entity that someone interacts
 790 // with others, make sure it can no longer do so.
 791 void Ent_Remove()
 792 {
 793         if(self.entremove)
 794                 self.entremove();
 795
 796         if(self.skeletonindex)
 797         {
 798                 skel_delete(self.skeletonindex);
 799                 self.skeletonindex = 0;
 800         }
 801
 802         if(self.snd_looping > 0)
 803         {
 804                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 805                 self.snd_looping = 0;
 806         }
 807
 808         self.enttype = 0;
 809         self.classname = "";
 810         self.draw = menu_sub_null;
 811         self.entremove = menu_sub_null;
 812         // TODO possibly set more stuff to defaults
 813 }
 814 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 815 void CSQC_Ent_Remove()
 816 {
 817         if(autocvar_developer_csqcentities)
 818                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 819
 820         if(wasfreed(self))
 821         {
 822                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 823                 return;
 824         }
 825         if(self.enttype)
 826                 Ent_Remove();
 827         remove(self);
 828 }
 829
 830 void Gamemode_Init()
 831 {
 832         if not(isdemo())
 833         {
 834                 if(!(calledhooks & HOOK_START))
 835                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 836                 calledhooks |= HOOK_START;
 837         }
 838 }
 839 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 840 void CSQC_Parse_StuffCmd(string strMessage)
 841 {
 842         if(autocvar_developer_csqcentities)
 843                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 844
 845         localcmd(strMessage);
 846 }
 847 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 848 void CSQC_Parse_Print(string strMessage)
 849 {
 850         if(autocvar_developer_csqcentities)
 851                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 852
 853         print(ColorTranslateRGB(strMessage));
 854 }
 855
 856 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 857 void CSQC_Parse_CenterPrint(string strMessage)
 858 {
 859         if(autocvar_developer_csqcentities)
 860                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 861
 862         centerprint_hud(strMessage);
 863 }
 864
 865 string notranslate_fogcmd1 = "\nfog ";
 866 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 867 void Fog_Force()
 868 {
 869         // TODO somehow thwart prvm_globalset client ...
 870
 871         if(forcefog != "")
 872                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 873 }
 874
 875 void Gamemode_Init();
 876 void Ent_ScoresInfo()
 877 {
 878         float i;
 879         self.classname = "ent_client_scores_info";
 880         gametype = ReadInt24_t();
 881         for(i = 0; i < MAX_SCORE; ++i)
 882         {
 883                 scores_label[i] = strzone(ReadString());
 884                 scores_flags[i] = ReadByte();
 885         }
 886         for(i = 0; i < MAX_TEAMSCORE; ++i)
 887         {
 888                 teamscores_label[i] = strzone(ReadString());
 889                 teamscores_flags[i] = ReadByte();
 890         }
 891         HUD_InitScores();
 892         Gamemode_Init();
 893 }
 894
 895 void Ent_Init()
 896 {
 897         self.classname = "ent_client_init";
 898
 899         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 900
 901         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 902         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 903         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 904         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 905         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 906         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 907         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 908         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 909         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 910         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 911         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 912         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 913
 914         if(forcefog)
 915                 strunzone(forcefog);
 916         forcefog = strzone(ReadString());
 917
 918         armorblockpercent = ReadByte() / 255.0;
 919
 920         g_weaponswitchdelay = ReadByte() / 255.0;
 921
 922         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 923         g_balance_grenadelauncher_bouncestop = ReadCoord();
 924         g_balance_electro_secondary_bouncefactor = ReadCoord();
 925         g_balance_electro_secondary_bouncestop = ReadCoord();
 926
 927         nex_scope = !ReadByte();
 928         rifle_scope = !ReadByte();
 929
 930         serverflags = ReadByte();
 931
 932         minelayer_maxmines = ReadByte();
 933
 934         hagar_maxrockets = ReadByte();
 935
 936         g_trueaim_minrange = ReadCoord();
 937         g_balance_porto_secondary = ReadByte();
 938
 939         if(!postinit)
 940                 PostInit();
 941 }
 942
 943 void Net_ReadRace()
 944 {
 945         float b;
 946
 947         b = ReadByte();
 948
 949         switch(b)
 950         {
 951                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 952                         race_checkpoint = ReadByte();
 953                         race_time = ReadInt24_t();
 954                         race_previousbesttime = ReadInt24_t();
 955                         if(race_previousbestname)
 956                                 strunzone(race_previousbestname);
 957                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 958
 959                         race_checkpointtime = time;
 960
 961                         if(race_checkpoint == 0 || race_checkpoint == 254)
 962                         {
 963                                 race_penaltyaccumulator = 0;
 964                                 race_laptime = time; // valid
 965                         }
 966
 967                         break;
 968
 969                 case RACE_NET_CHECKPOINT_CLEAR:
 970                         race_laptime = 0;
 971                         race_checkpointtime = 0;
 972                         break;
 973
 974                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 975                         race_laptime = ReadCoord();
 976                         race_checkpointtime = -99999;
 977                         // fall through
 978                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 979                         race_nextcheckpoint = ReadByte();
 980
 981                         race_nextbesttime = ReadInt24_t();
 982                         if(race_nextbestname)
 983                                 strunzone(race_nextbestname);
 984                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 985                         break;
 986
 987                 case RACE_NET_CHECKPOINT_HIT_RACE:
 988                         race_mycheckpoint = ReadByte();
 989                         race_mycheckpointtime = time;
 990                         race_mycheckpointdelta = ReadInt24_t();
 991                         race_mycheckpointlapsdelta = ReadByte();
 992                         if(race_mycheckpointlapsdelta >= 128)
 993                                 race_mycheckpointlapsdelta -= 256;
 994                         if(race_mycheckpointenemy)
 995                                 strunzone(race_mycheckpointenemy);
 996                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 997                         break;
 998
 999                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1000                         race_othercheckpoint = ReadByte();
1001                         race_othercheckpointtime = time;
1002                         race_othercheckpointdelta = ReadInt24_t();
1003                         race_othercheckpointlapsdelta = ReadByte();
1004                         if(race_othercheckpointlapsdelta >= 128)
1005                                 race_othercheckpointlapsdelta -= 256;
1006                         if(race_othercheckpointenemy)
1007                                 strunzone(race_othercheckpointenemy);
1008                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1009                         break;
1010
1011                 case RACE_NET_PENALTY_RACE:
1012                         race_penaltyeventtime = time;
1013                         race_penaltytime = ReadShort();
1014                         //race_penaltyaccumulator += race_penaltytime;
1015                         if(race_penaltyreason)
1016                                 strunzone(race_penaltyreason);
1017                         race_penaltyreason = strzone(ReadString());
1018                         break;
1019
1020                 case RACE_NET_PENALTY_QUALIFYING:
1021                         race_penaltyeventtime = time;
1022                         race_penaltytime = ReadShort();
1023                         race_penaltyaccumulator += race_penaltytime;
1024                         if(race_penaltyreason)
1025                                 strunzone(race_penaltyreason);
1026                         race_penaltyreason = strzone(ReadString());
1027                         break;
1028
1029                 case RACE_NET_SERVER_RECORD:
1030                         race_server_record = ReadInt24_t();
1031                         break;
1032                 case RACE_NET_SPEED_AWARD:
1033                         race_speedaward = ReadInt24_t();
1034                         if(race_speedaward_holder)
1035                                 strunzone(race_speedaward_holder);
1036                         race_speedaward_holder = strzone(ReadString());
1037                         break;
1038                 case RACE_NET_SPEED_AWARD_BEST:
1039                         race_speedaward_alltimebest = ReadInt24_t();
1040                         if(race_speedaward_alltimebest_holder)
1041                                 strunzone(race_speedaward_alltimebest_holder);
1042                         race_speedaward_alltimebest_holder = strzone(ReadString());
1043                         break;
1044                 case RACE_NET_SERVER_RANKINGS:
1045                         float pos, prevpos, del;
1046                         pos = ReadShort();
1047                         prevpos = ReadShort();
1048                         del = ReadShort();
1049
1050                         // move other rankings out of the way
1051                         float i;
1052                         if (prevpos) {
1053                                 for (i=prevpos-1;i>pos-1;--i) {
1054                                         grecordtime[i] = grecordtime[i-1];
1055                                         if(grecordholder[i])
1056                                                 strunzone(grecordholder[i]);
1057                                         grecordholder[i] = strzone(grecordholder[i-1]);
1058                                 }
1059                         } else if (del) { // a record has been deleted by the admin
1060                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1061                                         if (i == RANKINGS_CNT-1) { // clear out last record
1062                                                 grecordtime[i] = 0;
1063                                                 if (grecordholder[i])
1064                                                         strunzone(grecordholder[i]);
1065                                                 grecordholder[i] = string_null;
1066                                         }
1067                                         else {
1068                                                 grecordtime[i] = grecordtime[i+1];
1069                                                 if (grecordholder[i])
1070                                                         strunzone(grecordholder[i]);
1071                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1072                                         }
1073                                 }
1074                         } else { // player has no ranked record yet
1075                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1076                                         grecordtime[i] = grecordtime[i-1];
1077                                         if(grecordholder[i])
1078                                                 strunzone(grecordholder[i]);
1079                                         grecordholder[i] = strzone(grecordholder[i-1]);
1080                                 }
1081                         }
1082
1083                         // store new ranking
1084                         if(grecordholder[pos-1] != "")
1085                                 strunzone(grecordholder[pos-1]);
1086                         grecordholder[pos-1] = strzone(ReadString());
1087                         grecordtime[pos-1] = ReadInt24_t();
1088                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1089                                 race_myrank = pos;
1090                         break;
1091                 case RACE_NET_SERVER_STATUS:
1092                         race_status = ReadShort();
1093                         if(race_status_name)
1094                                 strunzone(race_status_name);
1095                         race_status_name = strzone(ReadString());
1096         }
1097 }
1098
1099 void Net_ReadSpawn()
1100 {
1101         zoomin_effect = 1;
1102         current_viewzoom = 0.6;
1103 }
1104
1105 void Net_TeamNagger()
1106 {
1107         teamnagger = 1;
1108 }
1109
1110 void Net_ReadPingPLReport()
1111 {
1112         float e, pi, pl, ml;
1113         e = ReadByte();
1114         pi = ReadShort();
1115         pl = ReadByte();
1116         ml = ReadByte();
1117         if not(playerslots[e])
1118                 return;
1119         playerslots[e].ping = pi;
1120         playerslots[e].ping_packetloss = pl / 255.0;
1121         playerslots[e].ping_movementloss = ml / 255.0;
1122 }
1123
1124 void Net_WeaponComplain() {
1125         complain_weapon = ReadByte();
1126
1127         if(complain_weapon_name)
1128                 strunzone(complain_weapon_name);
1129         complain_weapon_name = strzone(ReadString());
1130
1131         complain_weapon_type = ReadByte();
1132
1133         complain_weapon_time = time;
1134         weapontime = time; // ping the weapon panel
1135 }
1136
1137 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1138 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1139 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1140 float CSQC_Parse_TempEntity()
1141 {
1142         float bHandled;
1143                 bHandled  = true;
1144         // Acquire TE ID
1145         float nTEID;
1146                 nTEID = ReadByte();
1147
1148         if(autocvar_developer_csqcentities)
1149                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1150
1151                 // NOTE: Could just do return instead of break...
1152         switch(nTEID)
1153         {
1154                 case TE_CSQC_TARGET_MUSIC:
1155                         Net_TargetMusic();
1156                         bHandled = true;
1157                         break;
1158                 case TE_CSQC_PICTURE:
1159                         Net_MapVote_Picture();
1160                         bHandled = true;
1161                         break;
1162                 case TE_CSQC_RACE:
1163                         Net_ReadRace();
1164                         bHandled = true;
1165                         break;
1166                 case TE_CSQC_SPAWN:
1167                         Net_ReadSpawn();
1168                         bHandled = true;
1169                         break;
1170                 case TE_CSQC_ZCURVEPARTICLES:
1171                         Net_ReadZCurveParticles();
1172                         bHandled = true;
1173                         break;
1174                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1175                         Net_ReadNexgunBeamParticle();
1176                         bHandled = true;
1177                         break;
1178                 case TE_CSQC_TEAMNAGGER:
1179                         Net_TeamNagger();
1180                         bHandled = true;
1181                         break;
1182                 case TE_CSQC_LIGHTNINGARC:
1183                         Net_ReadLightningarc();
1184                         bHandled = true;
1185                         break;
1186                 case TE_CSQC_PINGPLREPORT:
1187                         Net_ReadPingPLReport();
1188                         bHandled = true;
1189                         break;
1190                 case TE_CSQC_ANNOUNCE:
1191                         Announcer_Play(ReadString());
1192                         bHandled = true;
1193                         break;
1194                 case TE_CSQC_KILLNOTIFY:
1195                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1196                         bHandled = true;
1197                         break;
1198                 case TE_CSQC_KILLCENTERPRINT:
1199                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1200                         bHandled = true;
1201                         break;
1202                 case TE_CSQC_CENTERPRINT_GENERIC:
1203                         float id;
1204                         string s;
1205                         id = ReadByte();
1206                         s = ReadString();
1207                         if (id != 0 && s != "")
1208                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1209                         else
1210                                 centerprint_generic(id, s, 0, 0);
1211                         bHandled = true;
1212                         break;
1213                 case TE_CSQC_WEAPONCOMPLAIN:
1214                         Net_WeaponComplain();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_VEHICLESETUP:
1218                         Net_VehicleSetup();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_SVNOTICE:
1222                         cl_notice_read();
1223                         bHandled = true;
1224                         break;
1225                 default:
1226                         // No special logic for this temporary entity; return 0 so the engine can handle it
1227                         bHandled = false;
1228                         break;
1229         }
1230
1231         return bHandled;
1232 }
1233
1234 string getcommandkey(string text, string command)
1235 {
1236         string keys;
1237         float n, j, k, l = 0;
1238
1239         if (!autocvar_hud_showbinds)
1240                 return text;
1241
1242         keys = db_get(binddb, command);
1243         if (!keys)
1244         {
1245                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1246                 for(j = 0; j < n; ++j)
1247                 {
1248                         k = stof(argv(j));
1249                         if(k != -1)
1250                         {
1251                                 if ("" == keys)
1252                                         keys = keynumtostring(k);
1253                                 else
1254                                         keys = strcat(keys, ", ", keynumtostring(k));
1255
1256                                 ++l;
1257                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1258                         }
1259
1260                 }
1261                 db_put(binddb, command, keys);
1262         }
1263
1264         if ("" == keys) {
1265                 if (autocvar_hud_showbinds > 1)
1266                         return sprintf(_("%s (not bound)"), text);
1267                 else
1268                         return text;
1269         }
1270         else if (autocvar_hud_showbinds > 1)
1271                 return sprintf(_("%s (%s)"), text, keys);
1272         else
1273                 return keys;
1274 }