qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 148         }
 149         Tuba_Precache();
 150
 151         get_mi_min_max_texcoords(1); // try the CLEVER way first
 152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 153         shortmapname = mi_shortname;
 154
 155         if(precache_pic(minimapname) == "")
 156         {
 157                 // but maybe we have a non-clever minimap
 158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 159                 if(precache_pic(minimapname) == "")
 160                         minimapname = ""; // FAIL
 161                 else
 162                         get_mi_min_max_texcoords(0); // load new texcoords
 163         }
 164
 165         mi_center = (mi_min + mi_max) * 0.5;
 166         mi_scale = mi_max - mi_min;
 167         minimapname = strzone(minimapname);
 168
 169         WarpZone_Init();
 170         hud_configure_prev = -1;
 171 }
 172
 173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 174 void CSQC_Shutdown(void)
 175 {
 176 #ifdef USE_FTE
 177 #pragma TARGET id
 178         if(!__engine_check)
 179                 return 0;
 180 #pragma TARGET fte
 181 #endif
 182
 183         WarpZone_Shutdown();
 184
 185         remove(teams);
 186         remove(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         db_save(ClientProgsDB, "client.db");
 190         db_close(ClientProgsDB);
 191
 192         cvar_clientsettemp_restore();
 193
 194         if(camera_active)
 195                 cvar_set("chase_active",ftos(chase_active_backup));
 196
 197         if not(isdemo())
 198         {
 199                 if not(calledhooks & HOOK_START)
 200                         localcmd("\n_cl_hook_gamestart nop\n");
 201                 if not(calledhooks & HOOK_END)
 202                         localcmd("\ncl_hook_gameend\n");
 203         }
 204 }
 205
 206 .float has_team;
 207 float SetTeam(entity o, float Team)
 208 {
 209         entity tm;
 210         if(teamplay)
 211         {
 212                 switch(Team)
 213                 {
 214                         case -1:
 215                         case COLOR_TEAM1:
 216                         case COLOR_TEAM2:
 217                         case COLOR_TEAM3:
 218                         case COLOR_TEAM4:
 219                                 break;
 220                         default:
 221                                 if(GetTeam(Team, false) == NULL)
 222                                 {
 223                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 224                                         Team = COLOR_SPECTATOR;
 225                                 }
 226                                 break;
 227                 }
 228         }
 229         else
 230         {
 231                 switch(Team)
 232                 {
 233                         case -1:
 234                         case 0:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == NULL)
 238                                 {
 239                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 240                                         Team = COLOR_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         if(Team == -1) // leave
 246         {
 247                 if(o.has_team)
 248                 {
 249                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 250                         tm = GetTeam(o.team, false);
 251                         tm.team_size -= 1;
 252                         o.has_team = 0;
 253                         return TRUE;
 254                 }
 255         }
 256         else
 257         {
 258                 if not(o.has_team)
 259                 {
 260                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         o.has_team = 1;
 265                         return TRUE;
 266                 }
 267                 else if(Team != o.team)
 268                 {
 269                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 270                         tm = GetTeam(o.team, false);
 271                         tm.team_size -= 1;
 272                         o.team = Team;
 273                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         return TRUE;
 277                 }
 278         }
 279         return FALSE;
 280 }
 281
 282 void Playerchecker_Think()
 283 {
 284         float i;
 285         entity e;
 286         for(i = 0; i < maxclients; ++i)
 287         {
 288                 e = playerslots[i];
 289                 if(GetPlayerName(i) == "")
 290                 {
 291                         if(e.sort_prev)
 292                         {
 293                                 //print("playerchecker: KILL KILL KILL\n");
 294                                 // player disconnected
 295                                 SetTeam(e, -1);
 296                                 RemovePlayer(e);
 297                                 e.sort_prev = world;
 298                                 //e.gotscores = 0;
 299                         }
 300                 }
 301                 else
 302                 {
 303                         if not(e.sort_prev)
 304                         {
 305                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 306                                 // player connected
 307                                 if not(e)
 308                                         playerslots[i] = e = spawn();
 309                                 e.sv_entnum = i;
 310                                 e.ping = 0;
 311                                 e.ping_packetloss = 0;
 312                                 e.ping_movementloss = 0;
 313                                 //e.gotscores = 0; // we might already have the scores...
 314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 315                                 RegisterPlayer(e);
 316                                 HUD_UpdatePlayerPos(e);
 317                         }
 318                 }
 319         }
 320         self.nextthink = time + 0.2;
 321 }
 322
 323 void Porto_Init();
 324 void TrueAim_Init();
 325 void PostInit(void)
 326 {
 327         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 328         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
 329
 330         entity playerchecker;
 331         playerchecker = spawn();
 332         playerchecker.think = Playerchecker_Think;
 333         playerchecker.nextthink = time + 0.2;
 334
 335         Porto_Init();
 336         TrueAim_Init();
 337
 338         postinit = true;
 339 }
 340
 341 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 342 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 343 float button_zoom;
 344 void Cmd_HUD_SetFields(float);
 345 void Cmd_HUD_Help(float);
 346 float CSQC_ConsoleCommand(string strMessage)
 347 {
 348         float argc;
 349         // Tokenize String
 350         //argc = tokenize(strMessage);
 351         argc = tokenize_console(strMessage);
 352
 353         // Acquire Command
 354         local string strCmd;
 355         strCmd = argv(0);
 356
 357         if(strCmd == "hud_configure") { // config hud
 358                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
 359                 return true;
 360         } else if(strCmd == "hud_save") { // save hud config
 361                 if(argv(1) == "" || argv(2)) {
 362                         print("Usage:\n");
 363                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 364                 }
 365                 else
 366                         HUD_Panel_ExportCfg(argv(1));
 367                 return true;
 368         } else if(strCmd == "+button4") { // zoom
 369                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 370                 if(ignore_plus_zoom)
 371                 {
 372                         --ignore_plus_zoom;
 373                         return false;
 374                 }
 375                 button_zoom = 1;
 376                 return true;
 377         } else if(strCmd == "-button4") { // zoom
 378                 if(ignore_minus_zoom)
 379                 {
 380                         --ignore_minus_zoom;
 381                         return false;
 382                 }
 383                 button_zoom = 0;
 384                 return true;
 385         } else if(strCmd == "+button3") { // secondary
 386                 button_attack2 = 1;
 387                 return false;
 388         } else if(strCmd == "-button3") { // secondary
 389                 button_attack2 = 0;
 390                 return false;
 391         } else if(strCmd == "+showscores") {
 392                 scoreboard_showscores = true;
 393                 return true;
 394         } else if(strCmd == "-showscores") {
 395                 scoreboard_showscores = false;
 396                 return true;
 397         } else if(strCmd == "+showaccuracy") {
 398                 scoreboard_showaccuracy = true;
 399                 return true;
 400         } else if(strCmd == "-showaccuracy") {
 401                 scoreboard_showaccuracy = false;
 402                 return true;
 403         }
 404
 405         if(camera_active)
 406         if(strCmd == "+forward" || strCmd == "-back") {
 407                 ++camera_direction_x;
 408                 return true;
 409         } else if(strCmd == "-forward" || strCmd == "+back") {
 410                 --camera_direction_x;
 411                 return true;
 412         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 413                 --camera_direction_y;
 414                 return true;
 415         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 416                 ++camera_direction_y;
 417                 return true;
 418         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 419                 ++camera_direction_z;
 420                 return true;
 421         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 422                 --camera_direction_z;
 423                 return true;
 424         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 425                 ++camera_roll;
 426                 return true;
 427         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 428                 --camera_roll;
 429                 return true;
 430         }
 431
 432         return false;
 433 }
 434
 435 .vector view_ofs;
 436 entity debug_shotorg;
 437 void ShotOrg_Draw()
 438 {
 439         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 440         self.angles = view_angles;
 441         self.angles_x = -self.angles_x;
 442         if not(self.cnt)
 443                 R_AddEntity(self);
 444 }
 445 void ShotOrg_Draw2D()
 446 {
 447         vector coord2d_topleft, coord2d_topright, coord2d;
 448         string s;
 449         vector fs;
 450
 451         s = vtos(self.view_ofs);
 452         s = substring(s, 1, strlen(s) - 2);
 453         if(tokenize_console(s) == 3)
 454                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 455
 456         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 457         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 458
 459         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 460
 461         coord2d = coord2d_topleft;
 462         if(fs_x < 8)
 463         {
 464                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 465                 fs = '8 8 0';
 466         }
 467         coord2d_y -= fs_y;
 468         coord2d_z = 0;
 469         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 470 }
 471
 472 void ShotOrg_Spawn()
 473 {
 474         debug_shotorg = spawn();
 475         debug_shotorg.draw = ShotOrg_Draw;
 476         debug_shotorg.draw2d = ShotOrg_Draw2D;
 477         debug_shotorg.renderflags = RF_VIEWMODEL;
 478         debug_shotorg.effects = EF_FULLBRIGHT;
 479         precache_model("models/shotorg_adjuster.md3");
 480         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 481         debug_shotorg.scale = 2;
 482         debug_shotorg.view_ofs = '25 8 -8';
 483 }
 484
 485 void DrawDebugModel()
 486 {
 487         if(time - floor(time) > 0.5)
 488         {
 489                 PolyDrawModel(self);
 490         }
 491         else
 492         {
 493                 self.renderflags = 0;
 494                 R_AddEntity(self);
 495         }
 496 }
 497
 498 void GameCommand(string msg)
 499 {
 500         string s;
 501         float argc;
 502         entity e;
 503         argc = tokenize_console(msg);
 504
 505         if(argv(0) == "help" || argc == 0)
 506         {
 507                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 508                 print("  settemp cvar value\n");
 509                 print("  scoreboard_columns_set ...\n");
 510                 print("  scoreboard_columns_help\n");
 511                 GameCommand_Generic("help");
 512                 return;
 513         }
 514
 515         if(GameCommand_Generic(msg))
 516                 return;
 517
 518         string cmd;
 519         cmd = argv(0);
 520         if(cmd == "mv_download") {
 521                 Cmd_MapVote_MapDownload(argc);
 522         }
 523         else if(cmd == "settemp") {
 524                 cvar_clientsettemp(argv(1), argv(2));
 525         }
 526         else if(cmd == "scoreboard_columns_set") {
 527                 Cmd_HUD_SetFields(argc);
 528         }
 529         else if(cmd == "scoreboard_columns_help") {
 530                 Cmd_HUD_Help(argc);
 531         }
 532 #ifdef BLURTEST
 533         else if(cmd == "blurtest") {
 534                 blurtest_time0 = time;
 535                 blurtest_time1 = time + stof(argv(1));
 536                 blurtest_radius = stof(argv(2));
 537                 blurtest_power = stof(argv(3));
 538         }
 539 #endif
 540         else if(cmd == "shotorg_move") {
 541                 if(!debug_shotorg)
 542                         ShotOrg_Spawn();
 543                 else
 544                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 545                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 546         }
 547         else if(cmd == "shotorg_movez") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_set") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = stov(argv(1));
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_setz") {
 562                 if(!debug_shotorg)
 563                         ShotOrg_Spawn();
 564                 else
 565                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 566                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 567         }
 568         else if(cmd == "shotorg_toggle_hide") {
 569                 if(debug_shotorg)
 570                 {
 571                         debug_shotorg.cnt = !debug_shotorg.cnt;
 572                 }
 573         }
 574         else if(cmd == "shotorg_end") {
 575                 if(debug_shotorg)
 576                 {
 577                         print(vtos(debug_shotorg.view_ofs), "\n");
 578                         remove(debug_shotorg);
 579                         debug_shotorg = world;
 580                 }
 581                 localcmd("sv_cmd debug_shotorg\n");
 582         }
 583         else if(cmd == "sendcvar") {
 584                 // W_FixWeaponOrder will trash argv, so save what we need.
 585                 string thiscvar;
 586                 thiscvar = strzone(argv(1));
 587                 s = cvar_string(thiscvar);
 588                 if(thiscvar == "cl_weaponpriority")
 589                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 590                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 591                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 592                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 593                 strunzone(thiscvar);
 594         }
 595         else if(cmd == "spawn") {
 596                 s = argv(1);
 597                 e = spawn();
 598                 precache_model(s);
 599                 setmodel(e, s);
 600                 setorigin(e, view_origin);
 601                 e.angles = view_angles;
 602                 e.draw = DrawDebugModel;
 603                 e.classname = "debugmodel";
 604         }
 605         else
 606         {
 607                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 608         }
 609
 610         return;
 611 }
 612
 613 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 614 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 615 // All keys are in ascii.
 616 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 617 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 618 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 619 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 620 {
 621         local float bSkipKey;
 622         bSkipKey = false;
 623
 624         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 625                 return true;
 626
 627         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 628                 return true;
 629
 630         if(menu_visible)
 631                 if(menu_action(bInputType, nPrimary, nSecondary))
 632                         return TRUE;
 633         return bSkipKey;
 634 }
 635
 636 // END REQUIRED CSQC FUNCTIONS
 637 // --------------------------------------------------------------------------
 638
 639 // --------------------------------------------------------------------------
 640 // BEGIN OPTIONAL CSQC FUNCTIONS
 641 void Ent_ReadEntCS()
 642 {
 643         InterpolateOrigin_Undo();
 644
 645         self.classname = "entcs_receiver";
 646         self.sv_entnum = ReadByte() - 1;
 647         self.origin_x = ReadShort();
 648         self.origin_y = ReadShort();
 649         self.origin_z = ReadShort();
 650         self.angles_y = ReadByte() * 360.0 / 256;
 651         self.origin_z = self.angles_x = self.angles_z = 0;
 652
 653         InterpolateOrigin_Note();
 654 }
 655
 656 void Ent_Remove();
 657
 658 void Ent_RemovePlayerScore()
 659 {
 660         float i;
 661
 662         if(self.owner)
 663         {
 664                 SetTeam(self.owner, -1);
 665                 self.owner.gotscores = 0;
 666                 for(i = 0; i < MAX_SCORE; ++i)
 667                         self.owner.(scores[i]) = 0; // clear all scores
 668         }
 669 }
 670
 671 void Ent_ReadPlayerScore()
 672 {
 673         float i, n;
 674         float isNew;
 675         entity o;
 676
 677         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 678         // (no I've never heard of M-x replace-string, sed, or anything like that)
 679         isNew = !self.owner; // workaround for DP bug
 680         n = ReadByte()-1;
 681
 682 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 683         if(!isNew && n != self.sv_entnum)
 684         {
 685                 print("A CSQC entity changed its owner!\n");
 686                 isNew = true;
 687                 Ent_Remove();
 688                 self.enttype = ENT_CLIENT_SCORES;
 689         }
 690 #endif
 691
 692         self.sv_entnum = n;
 693
 694         if not(playerslots[self.sv_entnum])
 695                 playerslots[self.sv_entnum] = spawn();
 696         o = self.owner = playerslots[self.sv_entnum];
 697         o.sv_entnum = self.sv_entnum;
 698         o.gotscores = 1;
 699
 700         //if not(o.sort_prev)
 701         //      RegisterPlayer(o);
 702         //playerchecker will do this for us later, if it has not already done so
 703
 704         float sf, lf;
 705 #if MAX_SCORE <= 8
 706         sf = ReadByte();
 707         lf = ReadByte();
 708 #else
 709         sf = ReadShort();
 710         lf = ReadShort();
 711 #endif
 712         float p;
 713         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 714                 if(sf & p)
 715                 {
 716                         if(lf & p)
 717                                 o.(scores[i]) = ReadInt24_t();
 718                         else
 719                                 o.(scores[i]) = ReadChar();
 720                 }
 721
 722         if(o.sort_prev)
 723                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 724
 725         self.entremove = Ent_RemovePlayerScore;
 726 }
 727
 728 void Ent_ReadTeamScore()
 729 {
 730         float i;
 731         entity o;
 732
 733         self.team = ReadByte();
 734         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 735
 736         float sf, lf;
 737 #if MAX_TEAMSCORE <= 8
 738         sf = ReadByte();
 739         lf = ReadByte();
 740 #else
 741         sf = ReadShort();
 742         lf = ReadShort();
 743 #endif
 744         float p;
 745         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 746                 if(sf & p)
 747                 {
 748                         if(lf & p)
 749                                 o.(teamscores[i]) = ReadInt24_t();
 750                         else
 751                                 o.(teamscores[i]) = ReadChar();
 752                 }
 753
 754         HUD_UpdateTeamPos(o);
 755 }
 756
 757 void Net_Reset()
 758 {
 759 }
 760
 761 void Ent_ClientData()
 762 {
 763         float f;
 764         float newspectatee_status;
 765
 766         f = ReadByte();
 767
 768         scoreboard_showscores_force = (f & 1);
 769
 770         if(f & 2)
 771         {
 772                 newspectatee_status = ReadByte();
 773                 if(newspectatee_status == player_localentnum)
 774                         newspectatee_status = -1; // observing
 775         }
 776         else
 777                 newspectatee_status = 0;
 778
 779         spectatorbutton_zoom = (f & 4);
 780
 781         if(f & 8)
 782         {
 783                 angles_held_status = 1;
 784                 angles_held_x = ReadAngle();
 785                 angles_held_y = ReadAngle();
 786                 angles_held_z = 0;
 787         }
 788         else
 789                 angles_held_status = 0;
 790
 791         if(newspectatee_status != spectatee_status)
 792         {
 793                 float i;
 794                 // clear the weapon accuracy stats
 795                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 796                         weapon_hits[i] = 0;
 797                         weapon_fired[i] = 0;
 798                 }
 799
 800                 // clear race stuff
 801                 race_laptime = 0;
 802                 race_checkpointtime = 0;
 803         }
 804         spectatee_status = newspectatee_status;
 805 }
 806
 807 void Ent_Nagger()
 808 {
 809         float nags, i, j, b, f;
 810
 811         nags = ReadByte();
 812
 813         if(nags & 128)
 814         {
 815                 if(vote_called_vote)
 816                         strunzone(vote_called_vote);
 817                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 818         }
 819
 820         if(nags & 1)
 821         {
 822                 for(j = 0; j < maxclients; ++j)
 823                         if(playerslots[j])
 824                                 playerslots[j].ready = 1;
 825                 for(i = 1; i <= maxclients; i += 8)
 826                 {
 827                         f = ReadByte();
 828                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 829                                 if not(f & b)
 830                                         if(playerslots[j])
 831                                                 playerslots[j].ready = 0;
 832                 }
 833         }
 834
 835         ready_waiting = (nags & 1);
 836         ready_waiting_for_me = (nags & 2);
 837         vote_waiting = (nags & 4);
 838         vote_waiting_for_me = (nags & 8);
 839         warmup_stage = (nags & 16);
 840 }
 841
 842 void Ent_RandomSeed()
 843 {
 844         float s;
 845         prandom_debug();
 846         s = ReadShort();
 847         psrandom(s);
 848 }
 849
 850 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 851 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 852 void Ent_RadarLink();
 853 void Ent_Init();
 854 void Ent_ScoresInfo();
 855 void(float bIsNewEntity) CSQC_Ent_Update =
 856 {
 857         float t;
 858         float savetime;
 859         t = ReadByte();
 860
 861         // set up the "time" global for received entities to be correct for interpolation purposes
 862         savetime = time;
 863         if(servertime)
 864         {
 865                 time = servertime;
 866         }
 867         else
 868         {
 869                 serverprevtime = time;
 870                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 871                 time = serverprevtime + serverdeltatime;
 872         }
 873
 874 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 875         if(self.enttype)
 876                 if(t != self.enttype)
 877                 {
 878                         print("A CSQC entity changed its type!\n");
 879                         Ent_Remove();
 880                         bIsNewEntity = 1;
 881                 }
 882 #endif
 883         self.enttype = t;
 884         switch(t)
 885         {
 886                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 887                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 888                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 889                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 890                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 891                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 892                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 893                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 894                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 895                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 896                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 897                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 898                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 899                 case ENT_CLIENT_INIT: Ent_Init(); break;
 900                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 901                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 902                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 903                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 904                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 905                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 906                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 907                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 908                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 909                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 910                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 911                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 912                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 913                 default:
 914                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 915                         break;
 916         }
 917
 918         time = savetime;
 919 };
 920 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 921 // used when an entity changes its type. For an entity that someone interacts
 922 // with others, make sure it can no longer do so.
 923 void Ent_Remove()
 924 {
 925         if(self.entremove)
 926                 self.entremove();
 927
 928         self.enttype = 0;
 929         self.classname = "";
 930         self.draw = menu_sub_null;
 931         self.entremove = menu_sub_null;
 932         // TODO possibly set more stuff to defaults
 933 }
 934 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 935 void CSQC_Ent_Remove()
 936 {
 937         if(self.enttype)
 938                 Ent_Remove();
 939         remove(self);
 940 }
 941
 942 void Gamemode_Init()
 943 {
 944         if(gametype == GAME_ONSLAUGHT) {
 945                 print(strcat("Using ", minimapname, " as minimap.\n"));
 946                 precache_pic("gfx/ons-cp-neutral.tga");
 947                 precache_pic("gfx/ons-cp-red.tga");
 948                 precache_pic("gfx/ons-cp-blue.tga");
 949                 precache_pic("gfx/ons-frame.tga");
 950                 precache_pic("gfx/ons-frame-team.tga");
 951         }
 952
 953         if not(isdemo())
 954         {
 955                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
 956                 calledhooks |= HOOK_START;
 957         }
 958 }
 959 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 960 void CSQC_Parse_StuffCmd(string strMessage)
 961 {
 962         localcmd(strMessage);
 963 }
 964 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 965 void CSQC_Parse_Print(string strMessage)
 966 {
 967         print(ColorTranslateRGB(strMessage));
 968 }
 969
 970 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 971 void CSQC_Parse_CenterPrint(string strMessage)
 972 {
 973         centerprint(strMessage);
 974 }
 975
 976 string notranslate_fogcmd1 = "\nfog ";
 977 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 978 void Fog_Force()
 979 {
 980         // TODO somehow thwart prvm_globalset client ...
 981
 982         if(forcefog != "")
 983                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 984 }
 985
 986 void Gamemode_Init();
 987 void Ent_ScoresInfo()
 988 {
 989         float i;
 990         self.classname = "ent_client_scores_info";
 991         gametype = ReadByte();
 992         for(i = 0; i < MAX_SCORE; ++i)
 993         {
 994                 scores_label[i] = strzone(ReadString());
 995                 scores_flags[i] = ReadByte();
 996         }
 997         for(i = 0; i < MAX_TEAMSCORE; ++i)
 998         {
 999                 teamscores_label[i] = strzone(ReadString());
1000                 teamscores_flags[i] = ReadByte();
1001         }
1002         HUD_InitScores();
1003         Gamemode_Init();
1004 }
1005
1006 void Ent_Init()
1007 {
1008         self.classname = "ent_client_init";
1009
1010         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1011
1012         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1013         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1014         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1015         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1016         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1017         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1018         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1019         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1020         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1021         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1022         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1023         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1024
1025         if(forcefog)
1026                 strunzone(forcefog);
1027         forcefog = strzone(ReadString());
1028
1029         armorblockpercent = ReadByte() / 255.0;
1030
1031         g_weaponswitchdelay = ReadByte() / 255.0;
1032
1033         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1034         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1035
1036         nex_scope = !ReadByte();
1037         campingrifle_scope = !ReadByte();
1038
1039         if(!postinit)
1040                 PostInit();
1041 }
1042
1043 void Net_ReadRace()
1044 {
1045         float b;
1046
1047         b = ReadByte();
1048
1049         switch(b)
1050         {
1051                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1052                         race_checkpoint = ReadByte();
1053                         race_time = ReadInt24_t();
1054                         race_previousbesttime = ReadInt24_t();
1055                         if(race_previousbestname)
1056                                 strunzone(race_previousbestname);
1057                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1058
1059                         race_checkpointtime = time;
1060
1061                         if(race_checkpoint == 0 || race_checkpoint == 254)
1062                         {
1063                                 race_penaltyaccumulator = 0;
1064                                 race_laptime = time; // valid
1065                         }
1066
1067                         break;
1068
1069                 case RACE_NET_CHECKPOINT_CLEAR:
1070                         race_laptime = 0;
1071                         race_checkpointtime = 0;
1072                         break;
1073
1074                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1075                         race_laptime = ReadCoord();
1076                         race_checkpointtime = -99999;
1077                         // fall through
1078                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1079                         race_nextcheckpoint = ReadByte();
1080
1081                         race_nextbesttime = ReadInt24_t();
1082                         if(race_nextbestname)
1083                                 strunzone(race_nextbestname);
1084                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_HIT_RACE:
1088                         race_mycheckpoint = ReadByte();
1089                         race_mycheckpointtime = time;
1090                         race_mycheckpointdelta = ReadInt24_t();
1091                         race_mycheckpointlapsdelta = ReadByte();
1092                         if(race_mycheckpointlapsdelta >= 128)
1093                                 race_mycheckpointlapsdelta -= 256;
1094                         if(race_mycheckpointenemy)
1095                                 strunzone(race_mycheckpointenemy);
1096                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1097                         break;
1098
1099                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1100                         race_othercheckpoint = ReadByte();
1101                         race_othercheckpointtime = time;
1102                         race_othercheckpointdelta = ReadInt24_t();
1103                         race_othercheckpointlapsdelta = ReadByte();
1104                         if(race_othercheckpointlapsdelta >= 128)
1105                                 race_othercheckpointlapsdelta -= 256;
1106                         if(race_othercheckpointenemy)
1107                                 strunzone(race_othercheckpointenemy);
1108                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1109                         break;
1110
1111                 case RACE_NET_PENALTY_RACE:
1112                         race_penaltyeventtime = time;
1113                         race_penaltytime = ReadShort();
1114                         //race_penaltyaccumulator += race_penaltytime;
1115                         if(race_penaltyreason)
1116                                 strunzone(race_penaltyreason);
1117                         race_penaltyreason = strzone(ReadString());
1118                         break;
1119
1120                 case RACE_NET_PENALTY_QUALIFYING:
1121                         race_penaltyeventtime = time;
1122                         race_penaltytime = ReadShort();
1123                         race_penaltyaccumulator += race_penaltytime;
1124                         if(race_penaltyreason)
1125                                 strunzone(race_penaltyreason);
1126                         race_penaltyreason = strzone(ReadString());
1127                         break;
1128
1129                 case RACE_NET_SERVER_RECORD:
1130                         race_server_record = ReadInt24_t();
1131                         break;
1132                 case RACE_NET_SPEED_AWARD:
1133                         race_speedaward = ReadInt24_t();
1134                         if(race_speedaward_holder)
1135                                 strunzone(race_speedaward_holder);
1136                         race_speedaward_holder = strzone(ReadString());
1137                         break;
1138                 case RACE_NET_SPEED_AWARD_BEST:
1139                         race_speedaward_alltimebest = ReadInt24_t();
1140                         if(race_speedaward_alltimebest_holder)
1141                                 strunzone(race_speedaward_alltimebest_holder);
1142                         race_speedaward_alltimebest_holder = strzone(ReadString());
1143                         break;
1144                 case RACE_NET_SERVER_RANKINGS:
1145                         float pos, prevpos, del;
1146                         pos = ReadShort();
1147                         prevpos = ReadShort();
1148                         del = ReadShort();
1149
1150                         // move other rankings out of the way
1151                         float i;
1152                         if (prevpos) {
1153                                 for (i=prevpos-1;i>pos-1;--i) {
1154                                         grecordtime[i] = grecordtime[i-1];
1155                                         if(grecordholder[i])
1156                                                 strunzone(grecordholder[i]);
1157                                         grecordholder[i] = strzone(grecordholder[i-1]);
1158                                 }
1159                         } else if (del) { // a record has been deleted by the admin
1160                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1161                                         if (i == RANKINGS_CNT-1) { // clear out last record
1162                                                 grecordtime[i] = 0;
1163                                                 if (grecordholder[i])
1164                                                         strunzone(grecordholder[i]);
1165                                                 grecordholder[i] = string_null;
1166                                         }
1167                                         else {
1168                                                 grecordtime[i] = grecordtime[i+1];
1169                                                 if (grecordholder[i])
1170                                                         strunzone(grecordholder[i]);
1171                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1172                                         }
1173                                 }
1174                         } else { // player has no ranked record yet
1175                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1176                                         grecordtime[i] = grecordtime[i-1];
1177                                         if(grecordholder[i])
1178                                                 strunzone(grecordholder[i]);
1179                                         grecordholder[i] = strzone(grecordholder[i-1]);
1180                                 }
1181                         }
1182
1183                         // store new ranking
1184                         if(grecordholder[pos-1] != "")
1185                                 strunzone(grecordholder[pos-1]);
1186                         grecordholder[pos-1] = strzone(ReadString());
1187                         grecordtime[pos-1] = ReadInt24_t();
1188                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1189                                 race_myrank = pos;
1190                         break;
1191                 case RACE_NET_SERVER_STATUS:
1192                         race_status = ReadShort();
1193                         if(race_status_name)
1194                                 strunzone(race_status_name);
1195                         race_status_name = strzone(ReadString());
1196         }
1197 }
1198
1199 void Net_ReadSpawn()
1200 {
1201         zoomin_effect = 1;
1202         current_viewzoom = 0.6;
1203 }
1204
1205 void Net_TeamNagger()
1206 {
1207         teamnagger = 1;
1208 }
1209
1210 void Net_ReadPingPLReport()
1211 {
1212         float e, pi, pl, ml;
1213         e = ReadByte();
1214         pi = ReadShort();
1215         pl = ReadByte();
1216         ml = ReadByte();
1217         if not(playerslots[e])
1218                 return;
1219         playerslots[e].ping = pi;
1220         playerslots[e].ping_packetloss = pl / 255.0;
1221         playerslots[e].ping_movementloss = ml / 255.0;
1222 }
1223
1224 void Net_VoteDialog(float highlight) {
1225         if(highlight) {
1226                 vote_highlighted = ReadByte();
1227                 return;
1228         }
1229
1230         vote_yescount = ReadByte();
1231         vote_nocount = ReadByte();
1232         vote_needed = ReadByte();
1233         vote_active = 1;
1234 }
1235
1236 void Net_VoteDialogReset() {
1237         vote_active = 0;
1238 }
1239
1240 void Net_Notify() {
1241         float type;
1242         type = ReadByte();
1243
1244         if(type == CSQC_KILLNOTIFY)
1245         {
1246                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1247         }
1248         else if(type == CSQC_CENTERPRINT)
1249         {
1250                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1251         }
1252 }
1253
1254 void Net_WeaponComplain() {
1255         complain_weapon = ReadByte();
1256
1257         if(complain_weapon_name)
1258                 strunzone(complain_weapon_name);
1259         complain_weapon_name = strzone(ReadString());
1260
1261         complain_weapon_type = ReadByte();
1262
1263         complain_weapon_time = time;
1264         weapontime = time; // ping the weapon panel
1265 }
1266
1267 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1268 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1269 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1270 float CSQC_Parse_TempEntity()
1271 {
1272         local float bHandled;
1273                 bHandled  = true;
1274         // Acquire TE ID
1275         local float nTEID;
1276                 nTEID = ReadByte();
1277
1278                 // NOTE: Could just do return instead of break...
1279         switch(nTEID)
1280         {
1281                 case TE_CSQC_TARGET_MUSIC:
1282                         Net_TargetMusic();
1283                         bHandled = true;
1284                         break;
1285                 case TE_CSQC_PICTURE:
1286                         Net_MapVote_Picture();
1287                         bHandled = true;
1288                         break;
1289                 case TE_CSQC_RACE:
1290                         Net_ReadRace();
1291                         bHandled = true;
1292                         break;
1293                 case TE_CSQC_SPAWN:
1294                         Net_ReadSpawn();
1295                         bHandled = true;
1296                         break;
1297                 case TE_CSQC_ZCURVEPARTICLES:
1298                         Net_ReadZCurveParticles();
1299                         bHandled = true;
1300                         break;
1301                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1302                         Net_ReadNexgunBeamParticle();
1303                         bHandled = true;
1304                         break;
1305                 case TE_CSQC_TEAMNAGGER:
1306                         Net_TeamNagger();
1307                         bHandled = true;
1308                         break;
1309                 case TE_CSQC_VOTE:
1310                         Net_VoteDialog(ReadByte());
1311                         bHandled = true;
1312                         break;
1313                 case TE_CSQC_VOTERESET:
1314                         Net_VoteDialogReset();
1315                         bHandled = true;
1316                         break;
1317                 case TE_CSQC_LIGHTNINGARC:
1318                         Net_ReadLightningarc();
1319                         bHandled = true;
1320                         break;
1321                 case TE_CSQC_PINGPLREPORT:
1322                         Net_ReadPingPLReport();
1323                         bHandled = true;
1324                         break;
1325                 case TE_CSQC_ANNOUNCE:
1326                         announce_snd = strzone(ReadString());
1327                         bHandled = true;
1328                         break;
1329                 case TE_CSQC_NOTIFY:
1330                         Net_Notify();
1331                         bHandled = true;
1332                         break;
1333                 case TE_CSQC_WEAPONCOMPLAIN:
1334                         Net_WeaponComplain();
1335                         bHandled = true;
1336                         break;
1337                 case TE_CSQC_NEX_VELOCITY:
1338                         nex_minvelocity = ReadShort();
1339                         nex_maxvelocity = ReadShort();
1340                         bHandled = true;
1341                         break;
1342                 default:
1343                         // No special logic for this temporary entity; return 0 so the engine can handle it
1344                         bHandled = false;
1345                         break;
1346         }
1347
1348         return bHandled;
1349 }
1350
1351 string getcommandkey(string text, string command)
1352 {
1353         string keys;
1354         float n, j, k, l;
1355
1356         if (!hud_showbinds)
1357                 return text;
1358
1359         keys = db_get(binddb, command);
1360         if (!keys)
1361         {
1362                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1363                 for(j = 0; j < n; ++j)
1364                 {
1365                         k = stof(argv(j));
1366                         if(k != -1)
1367                         {
1368                                 if ("" == keys)
1369                                         keys = keynumtostring(k);
1370                                 else
1371                                         keys = strcat(keys, ", ", keynumtostring(k));
1372
1373                                 ++l;
1374                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1375                         }
1376
1377                 }
1378                 db_put(binddb, command, keys);
1379         }
1380
1381         if ("" == keys) {
1382                 if (hud_showbinds > 1)
1383                         return strcat(text, " (not bound)");
1384                 else
1385                         return text;
1386         }
1387         else if (hud_showbinds > 1)
1388                 return strcat(text, " (", keys, ")");
1389         else
1390                 return keys;
1391 }