qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 151         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 152
 153         get_mi_min_max_texcoords(1); // try the CLEVER way first
 154         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 155         shortmapname = mi_shortname;
 156
 157         if(precache_pic(minimapname) == "")
 158         {
 159                 // but maybe we have a non-clever minimap
 160                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 161                 if(precache_pic(minimapname) == "")
 162                         minimapname = ""; // FAIL
 163                 else
 164                         get_mi_min_max_texcoords(0); // load new texcoords
 165         }
 166
 167         mi_center = (mi_min + mi_max) * 0.5;
 168         mi_scale = mi_max - mi_min;
 169         minimapname = strzone(minimapname);
 170
 171         WarpZone_Init();
 172
 173         hud_configure_prev = -1;
 174         tab_panel = -1;
 175 }
 176
 177 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 178 void CSQC_Shutdown(void)
 179 {
 180 #ifdef USE_FTE
 181 #pragma TARGET id
 182         if(!__engine_check)
 183                 return 0;
 184 #pragma TARGET fte
 185 #endif
 186
 187         WarpZone_Shutdown();
 188
 189         remove(teams);
 190         remove(players);
 191         db_close(binddb);
 192         db_close(tempdb);
 193         if(autocvar_cl_db_saveasdump)
 194                 db_dump(ClientProgsDB, "client.db");
 195         else
 196                 db_save(ClientProgsDB, "client.db");
 197         db_close(ClientProgsDB);
 198
 199         cvar_clientsettemp_restore();
 200
 201         if(camera_active)
 202                 cvar_set("chase_active",ftos(chase_active_backup));
 203
 204         // unset the event chasecam's chase_active
 205         if(autocvar_chase_active < 0)
 206                 cvar_set("chase_active", "0");
 207
 208         if not(isdemo())
 209         {
 210                 if not(calledhooks & HOOK_START)
 211                         localcmd("\n_cl_hook_gamestart nop\n");
 212                 if not(calledhooks & HOOK_END)
 213                         localcmd("\ncl_hook_gameend\n");
 214         }
 215 }
 216
 217 .float has_team;
 218 float SetTeam(entity o, float Team)
 219 {
 220         entity tm;
 221         if(teamplay)
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case COLOR_TEAM1:
 227                         case COLOR_TEAM2:
 228                         case COLOR_TEAM3:
 229                         case COLOR_TEAM4:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == NULL)
 233                                 {
 234                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 235                                         Team = COLOR_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         else
 241         {
 242                 switch(Team)
 243                 {
 244                         case -1:
 245                         case 0:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == NULL)
 249                                 {
 250                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 251                                         Team = COLOR_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         if(Team == -1) // leave
 257         {
 258                 if(o.has_team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         o.team = Team;
 271                         tm = GetTeam(Team, true);
 272                         tm.team_size += 1;
 273                         o.has_team = 1;
 274                         return TRUE;
 275                 }
 276                 else if(Team != o.team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         return TRUE;
 284                 }
 285         }
 286         return FALSE;
 287 }
 288
 289 void Playerchecker_Think()
 290 {
 291         float i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(GetPlayerName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 333
 334         entity playerchecker;
 335         playerchecker = spawn();
 336         playerchecker.think = Playerchecker_Think;
 337         playerchecker.nextthink = time + 0.2;
 338
 339         Porto_Init();
 340         TrueAim_Init();
 341
 342         postinit = true;
 343 }
 344
 345 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 346 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 347 float button_zoom;
 348 void Cmd_HUD_SetFields(float);
 349 void Cmd_HUD_Help(float);
 350 float CSQC_ConsoleCommand(string strMessage)
 351 {
 352         float argc;
 353         // Tokenize String
 354         //argc = tokenize(strMessage);
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         local string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+showscores") {
 373                 scoreboard_showscores = true;
 374                 return true;
 375         } else if(strCmd == "-showscores") {
 376                 scoreboard_showscores = false;
 377                 return true;
 378         } else if(strCmd == "+showaccuracy") {
 379                 scoreboard_showaccuracy = true;
 380                 return true;
 381         } else if(strCmd == "-showaccuracy") {
 382                 scoreboard_showaccuracy = false;
 383                 return true;
 384         }
 385
 386         if(camera_active)
 387         if(strCmd == "+forward" || strCmd == "-back") {
 388                 ++camera_direction_x;
 389                 return true;
 390         } else if(strCmd == "-forward" || strCmd == "+back") {
 391                 --camera_direction_x;
 392                 return true;
 393         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 394                 --camera_direction_y;
 395                 return true;
 396         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 397                 ++camera_direction_y;
 398                 return true;
 399         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 400                 ++camera_direction_z;
 401                 return true;
 402         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 403                 --camera_direction_z;
 404                 return true;
 405         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 406                 ++camera_roll;
 407                 return true;
 408         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 409                 --camera_roll;
 410                 return true;
 411         }
 412
 413         return false;
 414 }
 415
 416 .vector view_ofs;
 417 entity debug_shotorg;
 418 void ShotOrg_Draw()
 419 {
 420         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 421         self.angles = view_angles;
 422         self.angles_x = -self.angles_x;
 423         if not(self.cnt)
 424                 self.drawmask = MASK_NORMAL;
 425         else
 426                 self.drawmask = 0;
 427 }
 428 void ShotOrg_Draw2D()
 429 {
 430         vector coord2d_topleft, coord2d_topright, coord2d;
 431         string s;
 432         vector fs;
 433
 434         s = vtos(self.view_ofs);
 435         s = substring(s, 1, strlen(s) - 2);
 436         if(tokenize_console(s) == 3)
 437                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 438
 439         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 440         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 441
 442         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 443
 444         coord2d = coord2d_topleft;
 445         if(fs_x < 8)
 446         {
 447                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 448                 fs = '8 8 0';
 449         }
 450         coord2d_y -= fs_y;
 451         coord2d_z = 0;
 452         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 453 }
 454
 455 void ShotOrg_Spawn()
 456 {
 457         debug_shotorg = spawn();
 458         debug_shotorg.draw = ShotOrg_Draw;
 459         debug_shotorg.draw2d = ShotOrg_Draw2D;
 460         debug_shotorg.renderflags = RF_VIEWMODEL;
 461         debug_shotorg.effects = EF_FULLBRIGHT;
 462         precache_model("models/shotorg_adjuster.md3");
 463         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 464         debug_shotorg.scale = 2;
 465         debug_shotorg.view_ofs = '25 8 -8';
 466 }
 467
 468 void DrawDebugModel()
 469 {
 470         if(time - floor(time) > 0.5)
 471         {
 472                 PolyDrawModel(self);
 473                 self.drawmask = 0;
 474         }
 475         else
 476         {
 477                 self.renderflags = 0;
 478                 self.drawmask = MASK_NORMAL;
 479         }
 480 }
 481
 482 void GameCommand(string msg)
 483 {
 484         string s;
 485         float argc;
 486         entity e;
 487         argc = tokenize_console(msg);
 488
 489         if(argv(0) == "help" || argc == 0)
 490         {
 491                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 492                 print(_("  settemp cvar value\n"));
 493                 print(_("  scoreboard_columns_set ...\n"));
 494                 print(_("  scoreboard_columns_help\n"));
 495                 GameCommand_Generic("help");
 496                 return;
 497         }
 498
 499         if(GameCommand_Generic(msg))
 500                 return;
 501
 502         string cmd;
 503         cmd = argv(0);
 504         if(cmd == "mv_download") {
 505                 Cmd_MapVote_MapDownload(argc);
 506         }
 507         else if(cmd == "settemp") {
 508                 cvar_clientsettemp(argv(1), argv(2));
 509         }
 510         else if(cmd == "scoreboard_columns_set") {
 511                 Cmd_HUD_SetFields(argc);
 512         }
 513         else if(cmd == "scoreboard_columns_help") {
 514                 Cmd_HUD_Help(argc);
 515         }
 516 #ifdef BLURTEST
 517         else if(cmd == "blurtest") {
 518                 blurtest_time0 = time;
 519                 blurtest_time1 = time + stof(argv(1));
 520                 blurtest_radius = stof(argv(2));
 521                 blurtest_power = stof(argv(3));
 522         }
 523 #endif
 524         else if(cmd == "shotorg_move") {
 525                 if(!debug_shotorg)
 526                         ShotOrg_Spawn();
 527                 else
 528                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 529                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 530         }
 531         else if(cmd == "shotorg_movez") {
 532                 if(!debug_shotorg)
 533                         ShotOrg_Spawn();
 534                 else
 535                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 536                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 537         }
 538         else if(cmd == "shotorg_set") {
 539                 if(!debug_shotorg)
 540                         ShotOrg_Spawn();
 541                 else
 542                         debug_shotorg.view_ofs = stov(argv(1));
 543                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 544         }
 545         else if(cmd == "shotorg_setz") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_toggle_hide") {
 553                 if(debug_shotorg)
 554                 {
 555                         debug_shotorg.cnt = !debug_shotorg.cnt;
 556                 }
 557         }
 558         else if(cmd == "shotorg_end") {
 559                 if(debug_shotorg)
 560                 {
 561                         print(vtos(debug_shotorg.view_ofs), "\n");
 562                         remove(debug_shotorg);
 563                         debug_shotorg = world;
 564                 }
 565                 localcmd("sv_cmd debug_shotorg\n");
 566         }
 567         else if(cmd == "sendcvar") {
 568                 // W_FixWeaponOrder will trash argv, so save what we need.
 569                 string thiscvar;
 570                 thiscvar = strzone(argv(1));
 571                 s = cvar_string(thiscvar);
 572                 if(thiscvar == "cl_weaponpriority")
 573                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 574                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 575                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 576                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 577                 strunzone(thiscvar);
 578         }
 579         else if(cmd == "spawn") {
 580                 s = argv(1);
 581                 e = spawn();
 582                 precache_model(s);
 583                 setmodel(e, s);
 584                 setorigin(e, view_origin);
 585                 e.angles = view_angles;
 586                 e.draw = DrawDebugModel;
 587                 e.classname = "debugmodel";
 588         }
 589     else if(cmd == "vyes")
 590     {
 591         if(uid2name_dialog)
 592         {
 593             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 594             vote_prev = 0;
 595             cvar_set("cl_allow_uid2name", "1");
 596             vote_change = -9999;
 597                         uid2name_dialog = 0;
 598         }
 599         else
 600         {
 601             localcmd("cmd vote yes\n");
 602         }
 603     }
 604     else if(cmd == "vno")
 605     {
 606         if(uid2name_dialog)
 607         {
 608             vote_active = 0;
 609             vote_prev = 0;
 610             cvar_set("cl_allow_uid2name", "0");
 611             vote_change = -9999;
 612                         uid2name_dialog = 0;
 613         }
 614         else
 615         {
 616             localcmd("cmd vote no\n");
 617         }
 618     }
 619
 620         else
 621         {
 622                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 623         }
 624
 625         return;
 626 }
 627
 628 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 629 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 630 // All keys are in ascii.
 631 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 632 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 633 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 634 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 635 {
 636         local float bSkipKey;
 637         bSkipKey = false;
 638
 639         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 640                 return true;
 641
 642         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 643                 return true;
 644
 645         if(menu_visible)
 646                 if(menu_action(bInputType, nPrimary, nSecondary))
 647                         return TRUE;
 648
 649         return bSkipKey;
 650 }
 651
 652 // END REQUIRED CSQC FUNCTIONS
 653 // --------------------------------------------------------------------------
 654
 655 // --------------------------------------------------------------------------
 656 // BEGIN OPTIONAL CSQC FUNCTIONS
 657 void Ent_ReadEntCS()
 658 {
 659         InterpolateOrigin_Undo();
 660
 661         self.classname = "entcs_receiver";
 662         self.sv_entnum = ReadByte() - 1;
 663         self.origin_x = ReadShort();
 664         self.origin_y = ReadShort();
 665         self.origin_z = ReadShort();
 666         self.angles_y = ReadByte() * 360.0 / 256;
 667         self.origin_z = self.angles_x = self.angles_z = 0;
 668
 669         InterpolateOrigin_Note();
 670 }
 671
 672 void Ent_Remove();
 673
 674 void Ent_RemovePlayerScore()
 675 {
 676         float i;
 677
 678         if(self.owner)
 679         {
 680                 SetTeam(self.owner, -1);
 681                 self.owner.gotscores = 0;
 682                 for(i = 0; i < MAX_SCORE; ++i)
 683                         self.owner.(scores[i]) = 0; // clear all scores
 684         }
 685 }
 686
 687 void Ent_ReadPlayerScore()
 688 {
 689         float i, n;
 690         float isNew;
 691         entity o;
 692
 693         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 694         // (no I've never heard of M-x replace-string, sed, or anything like that)
 695         isNew = !self.owner; // workaround for DP bug
 696         n = ReadByte()-1;
 697
 698 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 699         if(!isNew && n != self.sv_entnum)
 700         {
 701                 //print(_("A CSQC entity changed its owner!\n"));
 702                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 703                 isNew = true;
 704                 Ent_Remove();
 705                 self.enttype = ENT_CLIENT_SCORES;
 706         }
 707 #endif
 708
 709         self.sv_entnum = n;
 710
 711         if not(playerslots[self.sv_entnum])
 712                 playerslots[self.sv_entnum] = spawn();
 713         o = self.owner = playerslots[self.sv_entnum];
 714         o.sv_entnum = self.sv_entnum;
 715         o.gotscores = 1;
 716
 717         //if not(o.sort_prev)
 718         //      RegisterPlayer(o);
 719         //playerchecker will do this for us later, if it has not already done so
 720
 721         float sf, lf;
 722 #if MAX_SCORE <= 8
 723         sf = ReadByte();
 724         lf = ReadByte();
 725 #else
 726         sf = ReadShort();
 727         lf = ReadShort();
 728 #endif
 729         float p;
 730         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 731                 if(sf & p)
 732                 {
 733                         if(lf & p)
 734                                 o.(scores[i]) = ReadInt24_t();
 735                         else
 736                                 o.(scores[i]) = ReadChar();
 737                 }
 738
 739         if(o.sort_prev)
 740                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 741
 742         self.entremove = Ent_RemovePlayerScore;
 743 }
 744
 745 void Ent_ReadTeamScore()
 746 {
 747         float i;
 748         entity o;
 749
 750         self.team = ReadByte();
 751         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 752
 753         float sf, lf;
 754 #if MAX_TEAMSCORE <= 8
 755         sf = ReadByte();
 756         lf = ReadByte();
 757 #else
 758         sf = ReadShort();
 759         lf = ReadShort();
 760 #endif
 761         float p;
 762         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 763                 if(sf & p)
 764                 {
 765                         if(lf & p)
 766                                 o.(teamscores[i]) = ReadInt24_t();
 767                         else
 768                                 o.(teamscores[i]) = ReadChar();
 769                 }
 770
 771         HUD_UpdateTeamPos(o);
 772 }
 773
 774 void Ent_ClientData()
 775 {
 776         float f;
 777         float newspectatee_status;
 778
 779         f = ReadByte();
 780
 781         scoreboard_showscores_force = (f & 1);
 782
 783         if(f & 2)
 784         {
 785                 newspectatee_status = ReadByte();
 786                 if(newspectatee_status == player_localentnum)
 787                         newspectatee_status = -1; // observing
 788         }
 789         else
 790                 newspectatee_status = 0;
 791
 792         spectatorbutton_zoom = (f & 4);
 793
 794         if(f & 8)
 795         {
 796                 angles_held_status = 1;
 797                 angles_held_x = ReadAngle();
 798                 angles_held_y = ReadAngle();
 799                 angles_held_z = 0;
 800         }
 801         else
 802                 angles_held_status = 0;
 803
 804         if(newspectatee_status != spectatee_status)
 805         {
 806                 float i;
 807
 808                 // clear race stuff
 809                 race_laptime = 0;
 810                 race_checkpointtime = 0;
 811         }
 812         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 813         {
 814                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 815                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 816                 )
 817                         prev_p_health = -1;
 818                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 819                         prev_health = -1;
 820         }
 821         spectatee_status = newspectatee_status;
 822 }
 823
 824 void Ent_Nagger()
 825 {
 826         float nags, i, j, b, f;
 827
 828         nags = ReadByte();
 829
 830         if(nags & 128)
 831         {
 832                 if(vote_called_vote)
 833                         strunzone(vote_called_vote);
 834                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 835         }
 836
 837         if(nags & 1)
 838         {
 839                 for(j = 0; j < maxclients; ++j)
 840                         if(playerslots[j])
 841                                 playerslots[j].ready = 1;
 842                 for(i = 1; i <= maxclients; i += 8)
 843                 {
 844                         f = ReadByte();
 845                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 846                                 if not(f & b)
 847                                         if(playerslots[j])
 848                                                 playerslots[j].ready = 0;
 849                 }
 850         }
 851
 852         ready_waiting = (nags & 1);
 853         ready_waiting_for_me = (nags & 2);
 854         vote_waiting = (nags & 4);
 855         vote_waiting_for_me = (nags & 8);
 856         warmup_stage = (nags & 16);
 857 }
 858
 859 void Ent_RandomSeed()
 860 {
 861         float s;
 862         prandom_debug();
 863         s = ReadShort();
 864         psrandom(s);
 865 }
 866
 867 void Ent_ReadAccuracy(void)
 868 {
 869         float sf, f, w, b;
 870         sf = ReadInt24_t();
 871         if(sf == 0)
 872         {
 873                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 874                         weapon_accuracy[w] = -1;
 875                 return;
 876         }
 877
 878         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 879         {
 880                 if(sf & f)
 881                 {
 882                         b = ReadByte();
 883                         if(b == 0)
 884                                 weapon_accuracy[w] = -1;
 885                         else if(b == 255)
 886                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 887                         else
 888                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 889                 }
 890         }
 891 }
 892
 893 void Ent_ShowNames()
 894 {
 895     float sf;
 896
 897     // entity init, TODO can this be done only once somehow?
 898     self.the_entnum = ReadByte(); // TODO: fixme to only send once somehow
 899     self.draw2d = Draw_ShowNames;
 900     //self.movetype = MOVETYPE_FLY; // movetype needed so we can traceline?
 901     self.mins = '-20 -20 -24';
 902     self.maxs = '20 20 45';
 903     self.classname = "shownames_tag";
 904
 905     sf = ReadByte();
 906
 907     if(sf & 1)
 908     {
 909         self.origin_x = ReadShort();
 910         self.origin_y = ReadShort();
 911         self.origin_z = ReadShort();
 912     }
 913     if(sf & 2)
 914     {
 915         self.healthvalue = ReadByte();
 916     }
 917     if(sf & 4)
 918     {
 919         self.armorvalue = ReadByte();
 920     }
 921
 922     if(sf & 128) // same team
 923         self.sameteam = TRUE;
 924     else
 925         self.sameteam = FALSE;
 926 }
 927
 928 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 929 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 930 void Ent_RadarLink();
 931 void Ent_Init();
 932 void Ent_ScoresInfo();
 933 void(float bIsNewEntity) CSQC_Ent_Update =
 934 {
 935         float t;
 936         float savetime;
 937         t = ReadByte();
 938
 939         // set up the "time" global for received entities to be correct for interpolation purposes
 940         savetime = time;
 941         if(servertime)
 942         {
 943                 time = servertime;
 944         }
 945         else
 946         {
 947                 serverprevtime = time;
 948                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 949                 time = serverprevtime + serverdeltatime;
 950         }
 951
 952 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 953         if(self.enttype)
 954                 if(t != self.enttype)
 955                 {
 956                         //print(_("A CSQC entity changed its type!\n"));
 957                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 958                         Ent_Remove();
 959                         bIsNewEntity = 1;
 960                 }
 961 #endif
 962         self.enttype = t;
 963         switch(t)
 964         {
 965                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 966                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 967                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 968                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 969                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 970                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 971                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 972                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 973                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 974                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 975                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 976                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 977                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 978                 case ENT_CLIENT_INIT: Ent_Init(); break;
 979                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 980                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 981                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 982                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 983                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 984                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 985                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 986                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 987                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 988                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 989                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 990                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 991                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 992                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 993                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 994                 case ENT_CLIENT_SHOWNAMES: Ent_ShowNames(); break;
 995                 default:
 996                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 997                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 998                         break;
 999         }
1000
1001         time = savetime;
1002 };
1003 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1004 // used when an entity changes its type. For an entity that someone interacts
1005 // with others, make sure it can no longer do so.
1006 void Ent_Remove()
1007 {
1008         if(self.entremove)
1009                 self.entremove();
1010
1011         self.enttype = 0;
1012         self.classname = "";
1013         self.draw = menu_sub_null;
1014         self.entremove = menu_sub_null;
1015         // TODO possibly set more stuff to defaults
1016 }
1017 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1018 void CSQC_Ent_Remove()
1019 {
1020         if(self.enttype)
1021                 Ent_Remove();
1022         remove(self);
1023 }
1024
1025 void Gamemode_Init()
1026 {
1027         if not(isdemo())
1028         {
1029                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1030                 calledhooks |= HOOK_START;
1031         }
1032 }
1033 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1034 void CSQC_Parse_StuffCmd(string strMessage)
1035 {
1036         localcmd(strMessage);
1037 }
1038 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1039 void CSQC_Parse_Print(string strMessage)
1040 {
1041         print(ColorTranslateRGB(strMessage));
1042 }
1043
1044 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1045 void CSQC_Parse_CenterPrint(string strMessage)
1046 {
1047         centerprint(strMessage);
1048 }
1049
1050 string notranslate_fogcmd1 = "\nfog ";
1051 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1052 void Fog_Force()
1053 {
1054         // TODO somehow thwart prvm_globalset client ...
1055
1056         if(forcefog != "")
1057                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1058 }
1059
1060 void Gamemode_Init();
1061 void Ent_ScoresInfo()
1062 {
1063         float i;
1064         self.classname = "ent_client_scores_info";
1065         gametype = ReadByte();
1066         for(i = 0; i < MAX_SCORE; ++i)
1067         {
1068                 scores_label[i] = strzone(ReadString());
1069                 scores_flags[i] = ReadByte();
1070         }
1071         for(i = 0; i < MAX_TEAMSCORE; ++i)
1072         {
1073                 teamscores_label[i] = strzone(ReadString());
1074                 teamscores_flags[i] = ReadByte();
1075         }
1076         HUD_InitScores();
1077         Gamemode_Init();
1078 }
1079
1080 void Ent_Init()
1081 {
1082         self.classname = "ent_client_init";
1083
1084         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1085
1086         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1087         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1088         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1089         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1090         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1091         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1092         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1093         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1094         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1095         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1096         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1097         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1098
1099         if(forcefog)
1100                 strunzone(forcefog);
1101         forcefog = strzone(ReadString());
1102
1103         armorblockpercent = ReadByte() / 255.0;
1104
1105         g_weaponswitchdelay = ReadByte() / 255.0;
1106
1107         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1108         g_balance_grenadelauncher_bouncestop = ReadCoord();
1109         g_balance_electro_secondary_bouncefactor = ReadCoord();
1110         g_balance_electro_secondary_bouncestop = ReadCoord();
1111
1112         nex_scope = !ReadByte();
1113         sniperrifle_scope = !ReadByte();
1114
1115         serverflags = ReadByte();
1116
1117         minelayer_maxmines = ReadByte();
1118
1119         hagar_maxrockets = ReadByte();
1120
1121         g_trueaim_minrange = ReadCoord();
1122
1123         if(!postinit)
1124                 PostInit();
1125 }
1126
1127 void Net_ReadRace()
1128 {
1129         float b;
1130
1131         b = ReadByte();
1132
1133         switch(b)
1134         {
1135                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1136                         race_checkpoint = ReadByte();
1137                         race_time = ReadInt24_t();
1138                         race_previousbesttime = ReadInt24_t();
1139                         if(race_previousbestname)
1140                                 strunzone(race_previousbestname);
1141                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1142
1143                         race_checkpointtime = time;
1144
1145                         if(race_checkpoint == 0 || race_checkpoint == 254)
1146                         {
1147                                 race_penaltyaccumulator = 0;
1148                                 race_laptime = time; // valid
1149                         }
1150
1151                         break;
1152
1153                 case RACE_NET_CHECKPOINT_CLEAR:
1154                         race_laptime = 0;
1155                         race_checkpointtime = 0;
1156                         break;
1157
1158                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1159                         race_laptime = ReadCoord();
1160                         race_checkpointtime = -99999;
1161                         // fall through
1162                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1163                         race_nextcheckpoint = ReadByte();
1164
1165                         race_nextbesttime = ReadInt24_t();
1166                         if(race_nextbestname)
1167                                 strunzone(race_nextbestname);
1168                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1169                         break;
1170
1171                 case RACE_NET_CHECKPOINT_HIT_RACE:
1172                         race_mycheckpoint = ReadByte();
1173                         race_mycheckpointtime = time;
1174                         race_mycheckpointdelta = ReadInt24_t();
1175                         race_mycheckpointlapsdelta = ReadByte();
1176                         if(race_mycheckpointlapsdelta >= 128)
1177                                 race_mycheckpointlapsdelta -= 256;
1178                         if(race_mycheckpointenemy)
1179                                 strunzone(race_mycheckpointenemy);
1180                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1181                         break;
1182
1183                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1184                         race_othercheckpoint = ReadByte();
1185                         race_othercheckpointtime = time;
1186                         race_othercheckpointdelta = ReadInt24_t();
1187                         race_othercheckpointlapsdelta = ReadByte();
1188                         if(race_othercheckpointlapsdelta >= 128)
1189                                 race_othercheckpointlapsdelta -= 256;
1190                         if(race_othercheckpointenemy)
1191                                 strunzone(race_othercheckpointenemy);
1192                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1193                         break;
1194
1195                 case RACE_NET_PENALTY_RACE:
1196                         race_penaltyeventtime = time;
1197                         race_penaltytime = ReadShort();
1198                         //race_penaltyaccumulator += race_penaltytime;
1199                         if(race_penaltyreason)
1200                                 strunzone(race_penaltyreason);
1201                         race_penaltyreason = strzone(ReadString());
1202                         break;
1203
1204                 case RACE_NET_PENALTY_QUALIFYING:
1205                         race_penaltyeventtime = time;
1206                         race_penaltytime = ReadShort();
1207                         race_penaltyaccumulator += race_penaltytime;
1208                         if(race_penaltyreason)
1209                                 strunzone(race_penaltyreason);
1210                         race_penaltyreason = strzone(ReadString());
1211                         break;
1212
1213                 case RACE_NET_SERVER_RECORD:
1214                         race_server_record = ReadInt24_t();
1215                         break;
1216                 case RACE_NET_SPEED_AWARD:
1217                         race_speedaward = ReadInt24_t();
1218                         if(race_speedaward_holder)
1219                                 strunzone(race_speedaward_holder);
1220                         race_speedaward_holder = strzone(ReadString());
1221                         break;
1222                 case RACE_NET_SPEED_AWARD_BEST:
1223                         race_speedaward_alltimebest = ReadInt24_t();
1224                         if(race_speedaward_alltimebest_holder)
1225                                 strunzone(race_speedaward_alltimebest_holder);
1226                         race_speedaward_alltimebest_holder = strzone(ReadString());
1227                         break;
1228                 case RACE_NET_SERVER_RANKINGS:
1229                         float pos, prevpos, del;
1230                         pos = ReadShort();
1231                         prevpos = ReadShort();
1232                         del = ReadShort();
1233
1234                         // move other rankings out of the way
1235                         float i;
1236                         if (prevpos) {
1237                                 for (i=prevpos-1;i>pos-1;--i) {
1238                                         grecordtime[i] = grecordtime[i-1];
1239                                         if(grecordholder[i])
1240                                                 strunzone(grecordholder[i]);
1241                                         grecordholder[i] = strzone(grecordholder[i-1]);
1242                                 }
1243                         } else if (del) { // a record has been deleted by the admin
1244                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1245                                         if (i == RANKINGS_CNT-1) { // clear out last record
1246                                                 grecordtime[i] = 0;
1247                                                 if (grecordholder[i])
1248                                                         strunzone(grecordholder[i]);
1249                                                 grecordholder[i] = string_null;
1250                                         }
1251                                         else {
1252                                                 grecordtime[i] = grecordtime[i+1];
1253                                                 if (grecordholder[i])
1254                                                         strunzone(grecordholder[i]);
1255                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1256                                         }
1257                                 }
1258                         } else { // player has no ranked record yet
1259                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1260                                         grecordtime[i] = grecordtime[i-1];
1261                                         if(grecordholder[i])
1262                                                 strunzone(grecordholder[i]);
1263                                         grecordholder[i] = strzone(grecordholder[i-1]);
1264                                 }
1265                         }
1266
1267                         // store new ranking
1268                         if(grecordholder[pos-1] != "")
1269                                 strunzone(grecordholder[pos-1]);
1270                         grecordholder[pos-1] = strzone(ReadString());
1271                         grecordtime[pos-1] = ReadInt24_t();
1272                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1273                                 race_myrank = pos;
1274                         break;
1275                 case RACE_NET_SERVER_STATUS:
1276                         race_status = ReadShort();
1277                         if(race_status_name)
1278                                 strunzone(race_status_name);
1279                         race_status_name = strzone(ReadString());
1280         }
1281 }
1282
1283 void Net_ReadSpawn()
1284 {
1285         zoomin_effect = 1;
1286         current_viewzoom = 0.6;
1287 }
1288
1289 void Net_TeamNagger()
1290 {
1291         teamnagger = 1;
1292 }
1293
1294 void Net_ReadPingPLReport()
1295 {
1296         float e, pi, pl, ml;
1297         e = ReadByte();
1298         pi = ReadShort();
1299         pl = ReadByte();
1300         ml = ReadByte();
1301         if not(playerslots[e])
1302                 return;
1303         playerslots[e].ping = pi;
1304         playerslots[e].ping_packetloss = pl / 255.0;
1305         playerslots[e].ping_movementloss = ml / 255.0;
1306 }
1307
1308 void Net_VoteDialog(float highlight) {
1309         if(highlight) {
1310                 vote_highlighted = ReadByte();
1311                 return;
1312         }
1313
1314         vote_yescount = ReadByte();
1315         vote_nocount = ReadByte();
1316         vote_needed = ReadByte();
1317         vote_active = 1;
1318 }
1319
1320 void Net_VoteDialogReset() {
1321         vote_active = 0;
1322 }
1323
1324 void Net_Notify() {
1325         float type;
1326         type = ReadByte();
1327
1328         if(type == CSQC_KILLNOTIFY)
1329         {
1330                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1331         }
1332         else if(type == CSQC_CENTERPRINT)
1333         {
1334                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1335         }
1336 }
1337
1338 void Net_WeaponComplain() {
1339         complain_weapon = ReadByte();
1340
1341         if(complain_weapon_name)
1342                 strunzone(complain_weapon_name);
1343         complain_weapon_name = strzone(ReadString());
1344
1345         complain_weapon_type = ReadByte();
1346
1347         complain_weapon_time = time;
1348         weapontime = time; // ping the weapon panel
1349 }
1350
1351 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1352 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1353 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1354 float CSQC_Parse_TempEntity()
1355 {
1356         local float bHandled;
1357                 bHandled  = true;
1358         // Acquire TE ID
1359         local float nTEID;
1360                 nTEID = ReadByte();
1361
1362                 // NOTE: Could just do return instead of break...
1363         switch(nTEID)
1364         {
1365                 case TE_CSQC_TARGET_MUSIC:
1366                         Net_TargetMusic();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_PICTURE:
1370                         Net_MapVote_Picture();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_RACE:
1374                         Net_ReadRace();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_SPAWN:
1378                         Net_ReadSpawn();
1379                         bHandled = true;
1380                         break;
1381                 case TE_CSQC_ZCURVEPARTICLES:
1382                         Net_ReadZCurveParticles();
1383                         bHandled = true;
1384                         break;
1385                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1386                         Net_ReadNexgunBeamParticle();
1387                         bHandled = true;
1388                         break;
1389                 case TE_CSQC_TEAMNAGGER:
1390                         Net_TeamNagger();
1391                         bHandled = true;
1392                         break;
1393                 case TE_CSQC_VOTE:
1394                         Net_VoteDialog(ReadByte());
1395                         bHandled = true;
1396                         break;
1397                 case TE_CSQC_VOTERESET:
1398                         Net_VoteDialogReset();
1399                         bHandled = true;
1400                         break;
1401                 case TE_CSQC_LIGHTNINGARC:
1402                         Net_ReadLightningarc();
1403                         bHandled = true;
1404                         break;
1405                 case TE_CSQC_PINGPLREPORT:
1406                         Net_ReadPingPLReport();
1407                         bHandled = true;
1408                         break;
1409                 case TE_CSQC_ANNOUNCE:
1410                         announce_snd = strzone(ReadString());
1411                         bHandled = true;
1412                         break;
1413                 case TE_CSQC_NOTIFY:
1414                         Net_Notify();
1415                         bHandled = true;
1416                         break;
1417                 case TE_CSQC_WEAPONCOMPLAIN:
1418                         Net_WeaponComplain();
1419                         bHandled = true;
1420                         break;
1421                 default:
1422                         // No special logic for this temporary entity; return 0 so the engine can handle it
1423                         bHandled = false;
1424                         break;
1425         }
1426
1427         return bHandled;
1428 }
1429
1430 string getcommandkey(string text, string command)
1431 {
1432         string keys;
1433         float n, j, k, l;
1434
1435         if (!autocvar_hud_showbinds)
1436                 return text;
1437
1438         keys = db_get(binddb, command);
1439         if (!keys)
1440         {
1441                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1442                 for(j = 0; j < n; ++j)
1443                 {
1444                         k = stof(argv(j));
1445                         if(k != -1)
1446                         {
1447                                 if ("" == keys)
1448                                         keys = keynumtostring(k);
1449                                 else
1450                                         keys = strcat(keys, ", ", keynumtostring(k));
1451
1452                                 ++l;
1453                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1454                         }
1455
1456                 }
1457                 db_put(binddb, command, keys);
1458         }
1459
1460         if ("" == keys) {
1461                 if (autocvar_hud_showbinds > 1)
1462                         return sprintf(_("%s (not bound)"), text);
1463                 else
1464                         return text;
1465         }
1466         else if (autocvar_hud_showbinds > 1)
1467                 return sprintf(_("%s (%s)"), text, keys);
1468         else
1469                 return keys;
1470 }