Don't let eventchase put the view into the ceiling when you die
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 entity porto;
2 vector polyline[16];
3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
4 float DPCONTENTS_SOLID = 1; // blocks player movement
5 float DPCONTENTS_BODY = 32; // blocks player movement
6 float DPCONTENTS_CORPSE = 64; // blocks player movement
7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
8 void Porto_Draw()
9 {
10         vector p, dir, ang, q, nextdir;
11         float idx, portal_number, portal1_idx;
12
13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
14                 return;
15         if(g_balance_porto_secondary)
16                 return;
17         if(intermission == 1)
18                 return;
19         if(intermission == 2)
20                 return;
21         if (getstati(STAT_HEALTH) <= 0)
22                 return;
23
24         dir = view_forward;
25
26         if(angles_held_status)
27         {
28                 makevectors(angles_held);
29                 dir = v_forward;
30         }
31
32         p = view_origin;
33
34         polyline[0] = p;
35         idx = 1;
36         portal_number = 0;
37         nextdir = dir;
38
39         for(;;)
40         {
41                 dir = nextdir;
42                 traceline(p, p + 65536 * dir, TRUE, porto);
43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
44                         return;
45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
46                 p = trace_endpos;
47                 polyline[idx] = p;
48                 ++idx;
49                 if(idx >= 16)
50                         return;
51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
52                         continue;
53                 ++portal_number;
54                 ang = vectoangles2(trace_plane_normal, dir);
55                 ang_x = -ang_x;
56                 makevectors(ang);
57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
58                         return;
59                 if(portal_number == 1)
60                 {
61                         portal1_idx = idx;
62                         if(portal_number >= 2)
63                                 break;
64                 }
65         }
66
67         while(idx >= 2)
68         {
69                 p = polyline[idx-2];
70                 q = polyline[idx-1];
71                 if(idx == 2)
72                         p = p - view_up * 16;
73                 if(idx-1 >= portal1_idx)
74                 {
75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
76                 }
77                 else
78                 {
79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
80                 }
81                 --idx;
82         }
83 }
84
85 void Porto_Init()
86 {
87         porto = spawn();
88         porto.classname = "porto";
89         porto.draw = Porto_Draw;
90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
91 }
92
93 float drawtime;
94 float avgspeed;
95 vector GetCurrentFov(float fov)
96 {
97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
98         float velocityzoom, curspeed;
99         vector v;
100
101         zoomsensitivity = autocvar_cl_zoomsensitivity;
102         zoomfactor = autocvar_cl_zoomfactor;
103         if(zoomfactor < 1 || zoomfactor > 16)
104                 zoomfactor = 2.5;
105         zoomspeed = autocvar_cl_zoomspeed;
106         if(zoomspeed >= 0)
107         if(zoomspeed < 0.5 || zoomspeed > 16)
108                         zoomspeed = 3.5;
109
110         zoomdir = button_zoom;
111         if(hud == HUD_NORMAL)
112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
113                 zoomdir += button_attack2;
114         if(spectatee_status > 0 || isdemo())
115         {
116                 if(spectatorbutton_zoom)
117                 {
118                         if(zoomdir)
119                                 zoomdir = 0;
120                         else
121                                 zoomdir = 1;
122                 }
123                 // fteqcc failed twice here already, don't optimize this
124         }
125
126         if(zoomdir) { zoomin_effect = 0; }
127
128         if(camera_active)
129         {
130                 current_viewzoom = min(1, current_viewzoom + drawframetime);
131         }
132         else if(autocvar_cl_spawnzoom && zoomin_effect)
133         {
134                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
135                 
136                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime); 
137                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
138                 if(current_viewzoom == 1) { zoomin_effect = 0; }
139         }
140         else
141         {
142                 if(zoomspeed < 0) // instant zoom
143                 {
144                         if(zoomdir)
145                                 current_viewzoom = 1 / zoomfactor;
146                         else
147                                 current_viewzoom = 1;
148                 }
149                 else
150                 {
151                         if(zoomdir)
152                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
153                         else
154                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
155                 }
156         }
157
158         if(almost_equals(current_viewzoom, 1))
159                 current_zoomfraction = 0;
160         else if(almost_equals(current_viewzoom, 1/zoomfactor))
161                 current_zoomfraction = 1;
162         else
163                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
164
165         if(zoomsensitivity < 1)
166                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
167         else
168                 setsensitivityscale(1);
169                 
170         makevectors(view_angles);
171
172         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
173         {
174                 v = pmove_vel;
175                 if(csqcplayer)
176                         v = csqcplayer.velocity;
177
178                 switch(autocvar_cl_velocityzoom_type)
179                 {
180                         case 3: curspeed = max(0, v_forward * v); break;
181                         case 2: curspeed = (v_forward * v); break;
182                         case 1: default: curspeed = vlen(v); break;
183                 }
184                 
185                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
186                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
187                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
188                 
189                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
190         }
191         else
192                 velocityzoom = 1;
193
194         float frustumx, frustumy, fovx, fovy;
195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
199
200         return '1 0 0' * fovx + '0 1 0' * fovy;
201 }
202
203 // this function must match W_SetupShot!
204 float zoomscript_caught;
205
206 vector wcross_origin;
207 float wcross_scale_prev, wcross_alpha_prev;
208 vector wcross_color_prev;
209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
210 vector wcross_color_goal_prev;
211 float wcross_changedonetime;
212
213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
215 float wcross_name_changestarttime, wcross_name_changedonetime;
216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
217
218 float wcross_ring_prev;
219
220 entity trueaim;
221 entity trueaim_rifle;
222
223 #define SHOTTYPE_HITTEAM 1
224 #define SHOTTYPE_HITOBSTRUCTION 2
225 #define SHOTTYPE_HITWORLD 3
226 #define SHOTTYPE_HITENEMY 4
227
228 void TrueAim_Init()
229 {
230         trueaim = spawn();
231         trueaim.classname = "trueaim";
232         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
233         trueaim_rifle = spawn();
234         trueaim_rifle.classname = "trueaim_rifle";
235         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
236 }
237
238 float EnemyHitCheck()
239 {
240         float t, n;
241         wcross_origin = project_3d_to_2d(trace_endpos);
242         wcross_origin_z = 0;
243         if(trace_ent)
244                 n = trace_ent.entnum;
245         else
246                 n = trace_networkentity;
247         if(n < 1)
248                 return SHOTTYPE_HITWORLD;
249         if(n > maxclients)
250                 return SHOTTYPE_HITWORLD;
251         t = GetPlayerColor(n - 1);
252         if(teamplay)
253                 if(t == myteam)
254                         return SHOTTYPE_HITTEAM;
255         if(t == NUM_SPECTATOR)
256                 return SHOTTYPE_HITWORLD;
257         return SHOTTYPE_HITENEMY;
258 }
259
260 float TrueAimCheck()
261 {
262         float nudge = 1; // added to traceline target and subtracted from result
263         vector vecs, trueaimpoint, w_shotorg;
264         vector mi, ma, dv;
265         float shottype;
266         entity ta;
267         float mv;
268
269         mi = ma = '0 0 0';
270         ta = trueaim;
271         mv = MOVE_NOMONSTERS;
272
273         switch(activeweapon)
274         {
275                 case WEP_TUBA: // no aim
276                 case WEP_PORTO: // shoots from eye
277                 case WEP_HOOK: // no trueaim
278                 case WEP_GRENADE_LAUNCHER: // toss curve
279                         return SHOTTYPE_HITWORLD;
280                 case WEP_NEX:
281                 case WEP_MINSTANEX:
282                         mv = MOVE_NORMAL;
283                         break;
284                 case WEP_RIFLE:
285                         ta = trueaim_rifle;
286                         mv = MOVE_NORMAL;
287                         if(zoomscript_caught)
288                         {
289                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
290                                 return EnemyHitCheck();
291                         }
292                         break;
293                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
294                         mi = '-3 -3 -3';
295                         ma = '3 3 3';
296                         break;
297                 case WEP_FIREBALL: // projectile has a size!
298                         mi = '-16 -16 -16';
299                         ma = '16 16 16';
300                         break;
301                 case WEP_SEEKER: // projectile has a size!
302                         mi = '-2 -2 -2';
303                         ma = '2 2 2';
304                         break;
305                 case WEP_ELECTRO: // projectile has a size!
306                         mi = '0 0 -3';
307                         ma = '0 0 -3';
308                         break;
309         }
310
311         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
312
313         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
314         trueaimpoint = trace_endpos;
315
316         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
317                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
318
319         if(vecs_x > 0)
320                 vecs_y = -vecs_y;
321         else
322                 vecs = '0 0 0';
323
324         dv = view_right * vecs_y + view_up * vecs_z;
325         w_shotorg = view_origin + dv;
326
327         // now move the vecs forward as much as requested if possible
328         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
329         w_shotorg = trace_endpos - view_forward * nudge;
330
331         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
332         shottype = EnemyHitCheck();
333         if(shottype != SHOTTYPE_HITWORLD)
334                 return shottype;
335
336 #if 0
337         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
338         // or rather, I know why, but see no fix
339         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
340                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
341                 return SHOTTYPE_HITOBSTRUCTION;
342 #endif
343
344         return SHOTTYPE_HITWORLD;
345 }
346
347 void CSQC_common_hud(void);
348
349 void PostInit(void);
350 void CSQC_Demo_Camera();
351 float HUD_WouldDrawScoreboard();
352 float camera_mode;
353 float CAMERA_FREE = 1;
354 float CAMERA_CHASE = 2;
355 float reticle_type;
356 string NextFrameCommand;
357 void CSQC_SPIDER_HUD();
358 void CSQC_RAPTOR_HUD();
359
360 vector freeze_org, freeze_ang;
361 entity nightvision_noise, nightvision_noise2;
362
363 #define MAX_TIME_DIFF 5
364 float pickup_crosshair_time, pickup_crosshair_size;
365 float hit_time, typehit_time;
366 float nextsound_hit_time, nextsound_typehit_time;
367 float hitindication_crosshair_time, hitindication_crosshair_size;
368 float use_nex_chargepool;
369
370 float myhealth, myhealth_prev;
371 float myhealth_flash;
372
373 float old_blurradius, old_bluralpha;
374 float old_sharpen_intensity;
375
376 vector myhealth_gentlergb;
377
378 float contentavgalpha, liquidalpha_prev;
379 vector liquidcolor_prev;
380
381 float eventchase_current_distance;
382
383 vector damage_blurpostprocess, content_blurpostprocess;
384
385 float checkfail[16];
386
387 float rainbow_last_flicker;
388 vector rainbow_prev_color;
389
390 #define BUTTON_3 4
391 #define BUTTON_4 8
392 float cl_notice_run();
393 float prev_myteam;
394 void CSQC_UpdateView(float w, float h)
395 {
396         entity e;
397         float fov;
398         float f, i, j;
399         vector v;
400         vector vf_size, vf_min;
401         float a;
402
403         execute_next_frame();
404
405         ++framecount;
406
407         hud = getstati(STAT_HUD);
408
409         if(autocvar__hud_showbinds_reload) // menu can set this one
410         {
411                 db_close(binddb);
412                 binddb = db_create();
413                 cvar_set("_hud_showbinds_reload", "0");
414         }
415
416         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
417                 view_quality = getproperty(VF_MINFPS_QUALITY);
418         else
419                 view_quality = 1;
420
421         button_attack2 = (input_buttons & BUTTON_3);
422         button_zoom = (input_buttons & BUTTON_4);
423
424 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
425         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
426         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
427         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
428         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
429         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
430         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
431         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
432
433         vf_size = getpropertyvec(VF_SIZE);
434         vf_min = getpropertyvec(VF_MIN);
435         vid_width = vf_size_x;
436         vid_height = vf_size_y;
437
438         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
439         vector splash_pos = '0 0 0', splash_size = '0 0 0';
440
441         WaypointSprite_Load();
442
443         CSQCPlayer_SetCamera();
444
445 #ifdef COMPAT_XON050_ENGINE
446         if(spectatee_status)
447                 myteam = GetPlayerColor(spectatee_status - 1);
448         else
449 #endif
450                 myteam = GetPlayerColor(player_localentnum - 1);
451
452         if(myteam != prev_myteam)
453         {
454                 myteamcolors = colormapPaletteColor(myteam, 1);
455                 for(i = 0; i < HUD_PANEL_NUM; ++i)
456                         hud_panel[i].update_time = time;
457                 prev_myteam = myteam;
458         }
459
460         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
461
462         float is_dead = (getstati(STAT_HEALTH) <= 0);
463
464         // FIXME do we need this hack?
465         if(isdemo())
466         {
467                 // in demos, input_buttons do not work
468                 button_zoom = (autocvar__togglezoom == "-");
469         }
470         else if(button_zoom
471                 && autocvar_cl_unpress_zoom_on_death
472                 && (spectatee_status >= 0)
473                 && (is_dead || intermission))
474         {
475                 // no zoom while dead or in intermission please
476                 localcmd("-zoom\n");
477                 button_zoom = FALSE;
478         }
479
480         // event chase camera
481         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
482         {
483                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead) || intermission)
484                 {
485                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
486                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
487
488                         // detect maximum viewoffset and use it
489                         WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
490                         current_view_origin_z +=
491                                 max(0,
492                                         (trace_fraction * autocvar_cl_eventchase_viewoffset_z)
493                                         -
494                                         autocvar_cl_eventchase_maxs_z
495                                 );
496
497                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
498                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
499                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
500                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
501
502                         // make the camera smooth back
503                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
504                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
505                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
506                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
507
508                         makevectors(view_angles);
509
510                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
511                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
512
513                         // If the boxtrace fails, revert back to line tracing.
514                         if(trace_startsolid)
515                         {
516                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
517                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
518                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
519                         }
520                         else { setproperty(VF_ORIGIN, trace_endpos); }
521
522                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
523                 }
524                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
525                 {
526                         cvar_set("chase_active", "0");
527                         eventchase_current_distance = 0; // start from 0 next time
528                 }
529         }
530         // workaround for camera stuck between player's legs when using chase_active 1
531         // because the engine stops updating the chase_active camera when the game ends
532         else if(intermission)
533         {
534                 cvar_settemp("chase_active", "-1");
535                 eventchase_current_distance = 0;
536         }
537
538         // do lockview after event chase camera so that it still applies whenever necessary.
539         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
540         {
541                 setproperty(VF_ORIGIN, freeze_org);
542                 setproperty(VF_ANGLES, freeze_ang);
543         }
544         else
545         {
546                 freeze_org = getpropertyvec(VF_ORIGIN);
547                 freeze_ang = getpropertyvec(VF_ANGLES);
548         }
549
550         WarpZone_FixView();
551         //WarpZone_FixPMove();
552
553         // Render the Scene
554         view_origin = getpropertyvec(VF_ORIGIN);
555         view_angles = getpropertyvec(VF_ANGLES);
556         makevectors(view_angles);
557         view_forward = v_forward;
558         view_right = v_right;
559         view_up = v_up;
560
561 #ifdef BLURTEST
562         if(time > blurtest_time0 && time < blurtest_time1)
563         {
564                 float r, t;
565
566                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
567                 r = t * blurtest_radius;
568                 f = 1 / pow(t, blurtest_power) - 1;
569
570                 cvar_set("r_glsl_postprocess", "1");
571                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
572         }
573         else
574         {
575                 cvar_set("r_glsl_postprocess", "0");
576                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
577         }
578 #endif
579
580         TargetMusic_Advance();
581         Fog_Force();
582
583         if(drawtime == 0)
584                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
585         else
586                 drawframetime = bound(0.000001, time - drawtime, 1);
587         drawtime = time;
588
589         // watch for gametype changes here...
590         // in ParseStuffCMD the cmd isn't executed yet :/
591         // might even be better to add the gametype to TE_CSQC_INIT...?
592         if(!postinit)
593                 PostInit();
594
595         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
596         {
597                 if(calledhooks & HOOK_START)
598                 {
599                         localcmd("\ncl_hook_gameend\n");
600                         calledhooks |= HOOK_END;
601                 }
602         }
603
604         Announcer();
605
606         fov = autocvar_fov;
607         if(fov <= 59.5)
608         {
609                 if(!zoomscript_caught)
610                 {
611                         localcmd("+button9\n");
612                         zoomscript_caught = 1;
613                 }
614         }
615         else
616         {
617                 if(zoomscript_caught)
618                 {
619                         localcmd("-button9\n");
620                         zoomscript_caught = 0;
621                 }
622         }
623
624         ColorTranslateMode = autocvar_cl_stripcolorcodes;
625
626         // next WANTED weapon (for HUD)
627         switchweapon = getstati(STAT_SWITCHWEAPON);
628
629         // currently switching-to weapon (for crosshair)
630         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
631
632         // actually active weapon (for zoom)
633         activeweapon = getstati(STAT_ACTIVEWEAPON);
634
635         f = (serverflags & SERVERFLAG_TEAMPLAY);
636         if(f != teamplay)
637         {
638                 teamplay = f;
639                 HUD_InitScores();
640         }
641
642         if(last_switchweapon != switchweapon)
643         {
644                 weapontime = time;
645                 last_switchweapon = switchweapon;
646                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
647                 {
648                         localcmd("-zoom\n");
649                         button_zoom = FALSE;
650                 }
651                 if(autocvar_cl_unpress_attack_on_weapon_switch)
652                 {
653                         localcmd("-fire\n");
654                         localcmd("-fire2\n");
655                         button_attack2 = FALSE;
656                 }
657         }
658         if(last_activeweapon != activeweapon)
659         {
660                 last_activeweapon = activeweapon;
661
662                 e = get_weaponinfo(activeweapon);
663                 if(e.netname != "")
664                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
665                 else
666                         localcmd("\ncl_hook_activeweapon none\n");
667         }
668
669         // ALWAYS Clear Current Scene First
670         clearscene();
671 #ifdef WORKAROUND_XON010
672         if(checkextension("DP_CSQC_ROTATEMOVES"))
673         {
674 #endif
675         setproperty(VF_ORIGIN, view_origin);
676         setproperty(VF_ANGLES, view_angles);
677 #ifdef WORKAROUND_XON010
678         }
679 #endif
680
681         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
682         setproperty(VF_SIZE, vf_size);
683         setproperty(VF_MIN, vf_min);
684
685         // Assign Standard Viewflags
686         // Draw the World (and sky)
687         setproperty(VF_DRAWWORLD, 1);
688
689         // Set the console size vars
690         vid_conwidth = autocvar_vid_conwidth;
691         vid_conheight = autocvar_vid_conheight;
692         vid_pixelheight = autocvar_vid_pixelheight;
693
694         setproperty(VF_FOV, GetCurrentFov(fov));
695
696         // Camera for demo playback
697         if(camera_active)
698         {
699                 if(autocvar_camera_enable)
700                         CSQC_Demo_Camera();
701                 else
702                 {
703                         cvar_set("chase_active", ftos(chase_active_backup));
704                         cvar_set("cl_demo_mousegrab", "0");
705                         camera_active = FALSE;
706                 }
707         }
708 #ifdef CAMERATEST
709         else if(autocvar_camera_enable)
710 #else
711         else if(autocvar_camera_enable && isdemo())
712 #endif
713         {
714                 // Enable required Darkplaces cvars
715                 chase_active_backup = autocvar_chase_active;
716                 cvar_set("chase_active", "2");
717                 cvar_set("cl_demo_mousegrab", "1");
718                 camera_active = TRUE;
719                 camera_mode = FALSE;
720         }
721
722         // Draw the Crosshair
723         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
724
725         // Draw the Engine Status Bar (the default Quake HUD)
726         setproperty(VF_DRAWENGINESBAR, 0);
727
728         // Update the mouse position
729         /*
730            mousepos_x = vid_conwidth;
731            mousepos_y = vid_conheight;
732            mousepos = mousepos*0.5 + getmousepos();
733          */
734
735         e = self;
736         for(self = world; (self = nextent(self)); )
737                 if(self.draw)
738                         self.draw();
739         self = e;
740
741         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
742         renderscene();
743
744         // now switch to 2D drawing mode by calling a 2D drawing function
745         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
746         // next R_RenderScene call
747         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
748
749         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
750         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
751         {
752                 // apply night vision effect
753                 vector tc_00, tc_01, tc_10, tc_11;
754                 vector rgb;
755                 rgb_x = 0; // fteqcc sucks
756                 rgb_y = 0; // fteqcc sucks
757                 rgb_z = 0; // fteqcc sucks
758
759                 if(!nightvision_noise)
760                 {
761                         nightvision_noise = spawn();
762                         nightvision_noise.classname = "nightvision_noise";
763                 }
764                 if(!nightvision_noise2)
765                 {
766                         nightvision_noise2 = spawn();
767                         nightvision_noise2.classname = "nightvision_noise2";
768                 }
769
770                 // color tint in yellow
771                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
772
773                 // draw BG
774                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
775                 rgb = '1 1 1';
776                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
777                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
778                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
779                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
780                 tc_11 = tc_01 + tc_10 - tc_00;
781                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
782                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
783                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
784                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
785                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
786                 R_EndPolygon();
787
788                 // draw FG
789                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
790                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
791                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
792                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
793                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
794                 tc_11 = tc_01 + tc_10 - tc_00;
795                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
796                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
797                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
798                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
799                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
800                 R_EndPolygon();
801         }
802         
803         // Draw the aiming reticle for weapons that use it
804         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
805         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
806         // the view to go back to normal, so reticle_type would become 0 as we fade out)
807         if(spectatee_status || is_dead || hud != HUD_NORMAL)
808                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
809         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
810                 reticle_type = 2; // nex zoom
811         else if(button_zoom || zoomscript_caught)
812                 reticle_type = 1; // normal zoom
813         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
814                 reticle_type = 2; // nex zoom
815     
816         if(reticle_type && autocvar_cl_reticle)
817         {
818                 if(autocvar_cl_reticle_stretch)
819                 {
820                         reticle_size_x = vid_conwidth;
821                         reticle_size_y = vid_conheight;
822                         reticle_pos_x = 0;
823                         reticle_pos_y = 0;
824                 }
825                 else
826                 {
827                         reticle_size_x = max(vid_conwidth, vid_conheight);
828                         reticle_size_y = max(vid_conwidth, vid_conheight);
829                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
830                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
831                 }
832
833                 f = current_zoomfraction;
834                 if(zoomscript_caught)
835                         f = 1;
836                 if(autocvar_cl_reticle_item_normal)
837                 {
838                         if(reticle_type == 1 && f)
839                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
840                 }
841                 if(autocvar_cl_reticle_item_nex)
842                 {
843                         if(reticle_type == 2 && f)
844                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
845                 }
846         }
847
848
849         // improved polyblend
850         if(autocvar_hud_contents)
851         {
852                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
853                 vector liquidcolor;
854
855                 switch(pointcontents(view_origin))
856                 {
857                         case CONTENT_WATER:
858                                 liquidalpha = autocvar_hud_contents_water_alpha;
859                                 liquidcolor = stov(autocvar_hud_contents_water_color);
860                                 incontent = 1;
861                                 break;
862
863                         case CONTENT_LAVA:
864                                 liquidalpha = autocvar_hud_contents_lava_alpha;
865                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
866                                 incontent = 1;
867                                 break;
868
869                         case CONTENT_SLIME:
870                                 liquidalpha = autocvar_hud_contents_slime_alpha;
871                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
872                                 incontent = 1;
873                                 break;
874
875                         default:
876                                 liquidalpha = 0;
877                                 liquidcolor = '0 0 0';
878                                 incontent = 0;
879                                 break;
880                 }
881
882                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
883                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
884                         contentfadetime = autocvar_hud_contents_fadeintime;
885                         liquidalpha_prev = liquidalpha;
886                         liquidcolor_prev = liquidcolor;
887                 }
888                 else
889                         contentfadetime = autocvar_hud_contents_fadeouttime;
890
891                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
892                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
893
894                 if(contentavgalpha)
895                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
896
897                 if(autocvar_hud_postprocessing)
898                 {
899                         if(autocvar_hud_contents_blur && contentavgalpha)
900                         {
901                                 content_blurpostprocess_x = 1;
902                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
903                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
904                         }
905                         else
906                         {
907                                 content_blurpostprocess_x = 0;
908                                 content_blurpostprocess_y = 0;
909                                 content_blurpostprocess_z = 0;
910                         }
911                 }
912         }
913
914         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
915         {
916                 splash_size_x = max(vid_conwidth, vid_conheight);
917                 splash_size_y = max(vid_conwidth, vid_conheight);
918                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
919                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
920
921                 float myhealth_flash_temp;
922                 myhealth = getstati(STAT_HEALTH);
923
924                 // fade out
925                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
926                 // add new damage
927                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
928
929                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
930                 pain_threshold = autocvar_hud_damage_pain_threshold;
931                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
932                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
933
934                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
935                 {
936                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
937                 }
938
939                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
940
941                 if(myhealth_prev < 1)
942                 {
943                         if(myhealth >= 1)
944                         {
945                                 myhealth_flash = 0; // just spawned, clear the flash immediately
946                                 myhealth_flash_temp = 0;
947                         }
948                         else
949                         {
950                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
951                         }
952                 }
953
954                 if(spectatee_status == -1 || intermission)
955                 {
956                         myhealth_flash = 0; // observing, or match ended
957                         myhealth_flash_temp = 0;
958                 }
959
960                 myhealth_prev = myhealth;
961
962                 // IDEA: change damage color/picture based on player model for robot/alien species?
963                 // pro: matches model better
964                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
965                 // maybe different reddish pics?
966                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
967                 {
968                         if(autocvar_cl_gentle_damage == 2)
969                         {
970                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
971                                 {
972                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
973                                 }
974                         }
975                         else
976                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
977
978                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
979                 }
980                 else
981                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
982
983                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
984                 {
985                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
986                         {
987                                 damage_blurpostprocess_x = 1;
988                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
989                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
990                         }
991                         else
992                         {
993                                 damage_blurpostprocess_x = 0;
994                                 damage_blurpostprocess_y = 0;
995                                 damage_blurpostprocess_z = 0;
996                         }
997                 }
998         }
999
1000         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1001         float e2 = (autocvar_hud_powerup != 0);
1002         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1003         {
1004                 // enable or disable rendering types if they are used or not
1005                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1006                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1007
1008                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1009                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1010                 {
1011                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1012                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1013                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1014                         {
1015                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1016                                 old_blurradius = blurradius;
1017                                 old_bluralpha = bluralpha;
1018                         }
1019                 }
1020                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1021                 {
1022                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1023                         old_blurradius = 0;
1024                         old_bluralpha = 0;
1025                 }
1026
1027                 // edge detection postprocess handling done second (used by hud_powerup) 
1028                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1029                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1030                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1031                 
1032                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1033                 
1034                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1035                 {
1036                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1037                         {
1038                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1039                                 old_sharpen_intensity = sharpen_intensity;
1040                         }
1041                 }
1042                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1043                 {
1044                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1045                         old_sharpen_intensity = 0;
1046                 }
1047
1048                 if(cvar("r_glsl_postprocess") == 0)
1049                         cvar_set("r_glsl_postprocess", "2");
1050         }
1051         else if(cvar("r_glsl_postprocess") == 2)
1052                 cvar_set("r_glsl_postprocess", "0");
1053
1054         if(menu_visible)
1055                 menu_show();
1056
1057         /*if(gametype == MAPINFO_TYPE_CTF)
1058           {
1059           ctf_view();
1060           } else */
1061
1062         // draw 2D entities
1063         e = self;
1064         for(self = world; (self = nextent(self)); )
1065                 if(self.draw2d)
1066                         self.draw2d();
1067         self = e;
1068         Draw_ShowNames_All();
1069
1070         scoreboard_active = HUD_WouldDrawScoreboard();
1071
1072         hit_time = getstatf(STAT_HIT_TIME);
1073         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1074         {
1075                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1076                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1077                         
1078                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1079         }
1080         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1081         if(typehit_time > nextsound_typehit_time) 
1082         {
1083                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1084                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1085                         
1086                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1087         }
1088
1089         //else
1090         {
1091                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1092                 {
1093                         if(getstati(STAT_FROZEN))
1094                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1095                         if(getstatf(STAT_REVIVE_PROGRESS))
1096                         {
1097                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1098                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1099                         }
1100                 }
1101
1102                 if(autocvar_r_letterbox == 0)
1103                         if(autocvar_viewsize < 120)
1104                                 CSQC_common_hud();
1105
1106                 // crosshair goes VERY LAST
1107                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) 
1108                 {
1109                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1110                                 return;
1111                                 
1112                         string wcross_style;
1113                         float wcross_alpha, wcross_resolution;
1114                         wcross_style = autocvar_crosshair;
1115                         if (wcross_style == "0")
1116                                 return;
1117                         wcross_resolution = autocvar_crosshair_size;
1118                         if (wcross_resolution == 0)
1119                                 return;
1120                         wcross_alpha = autocvar_crosshair_alpha;
1121                         if (wcross_alpha == 0)
1122                                 return;
1123
1124                         // TrueAim check
1125                         float shottype;
1126
1127                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1128                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1129                         wcross_origin_z = 0;
1130                         if(autocvar_crosshair_hittest)
1131                         {
1132                                 vector wcross_oldorigin;
1133                                 wcross_oldorigin = wcross_origin;
1134                                 shottype = TrueAimCheck();
1135                                 if(shottype == SHOTTYPE_HITWORLD)
1136                                 {
1137                                         v = wcross_origin - wcross_oldorigin;
1138                                         v_x /= vid_conwidth;
1139                                         v_y /= vid_conheight;
1140                                         if(vlen(v) > 0.01)
1141                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1142                                 }
1143                                 if(!autocvar_crosshair_hittest_showimpact)
1144                                         wcross_origin = wcross_oldorigin;
1145                         }
1146                         else
1147                                 shottype = SHOTTYPE_HITWORLD;
1148
1149                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1150                         string wcross_wep = "", wcross_name;
1151                         float wcross_scale, wcross_blur;
1152
1153                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1154                         {
1155                                 e = get_weaponinfo(switchingweapon);
1156                                 if (e && e.netname != "")
1157                                 {
1158                                         wcross_wep = e.netname;
1159                                         if(autocvar_crosshair_per_weapon)
1160                                         {
1161                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1162                                                 if (wcross_resolution == 0)
1163                                                         return;
1164                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1165                                                 if (wcross_alpha == 0)
1166                                                         return;
1167
1168                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1169                                                 if(wcross_style == "" || wcross_style == "0")
1170                                                         wcross_style = wcross_wep;
1171                                         }
1172                                 }
1173                         }
1174
1175                         //print(sprintf("crosshair style: %s\n", wcross_style));
1176                         wcross_name = strcat("gfx/crosshair", wcross_style);
1177
1178                         // MAIN CROSSHAIR COLOR DECISION
1179                         switch(autocvar_crosshair_color_special)
1180                         {
1181                                 case 1: // crosshair_color_per_weapon
1182                                 {
1183                                         if(wcross_wep != "")
1184                                         {
1185                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1186                                                 break;
1187                                         }
1188                                         else { goto normalcolor; }
1189                                 }
1190
1191                                 case 2: // crosshair_color_by_health
1192                                 {
1193                                         float x = getstati(STAT_HEALTH);
1194
1195                                         //x = red
1196                                         //y = green
1197                                         //z = blue
1198
1199                                         wcross_color_z = 0;
1200
1201                                         if(x > 200)
1202                                         {
1203                                                 wcross_color_x = 0;
1204                                                 wcross_color_y = 1;
1205                                         }
1206                                         else if(x > 150)
1207                                         {
1208                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1209                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1210                                         }
1211                                         else if(x > 100)
1212                                         {
1213                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1214                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1215                                                 wcross_color_z = 1 - (x-100)*0.02;
1216                                         }
1217                                         else if(x > 50)
1218                                         {
1219                                                 wcross_color_x = 1;
1220                                                 wcross_color_y = 1;
1221                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1222                                         }
1223                                         else if(x > 20)
1224                                         {
1225                                                 wcross_color_x = 1;
1226                                                 wcross_color_y = (x-20)*90/27/100;
1227                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1228                                         }
1229                                         else
1230                                         {
1231                                                 wcross_color_x = 1;
1232                                                 wcross_color_y = 0;
1233                                         }
1234                                         break;
1235                                 }
1236
1237                                 case 3: // crosshair_color_rainbow
1238                                 {
1239                                         if(time >= rainbow_last_flicker)
1240                                         {
1241                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1242                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1243                                         }
1244                                         wcross_color = rainbow_prev_color;
1245                                         break;
1246                                 }
1247                                 :normalcolor
1248                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1249                         }
1250
1251                         if(autocvar_crosshair_effect_scalefade)
1252                         {
1253                                 wcross_scale = wcross_resolution;
1254                                 wcross_resolution = 1;
1255                         }
1256                         else
1257                         {
1258                                 wcross_scale = 1;
1259                         }
1260
1261                         if(autocvar_crosshair_pickup)
1262                         {
1263                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1264                                 
1265                                 if(pickup_crosshair_time < stat_pickup_time)
1266                                 {
1267                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1268                                                 pickup_crosshair_size = 1;
1269                                                 
1270                                         pickup_crosshair_time = stat_pickup_time;
1271                                 }
1272
1273                                 if(pickup_crosshair_size > 0)
1274                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1275                                 else
1276                                         pickup_crosshair_size = 0;
1277
1278                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1279                         }
1280
1281                         if(autocvar_crosshair_hitindication)
1282                         {
1283                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1284                                 
1285                                 if(hitindication_crosshair_time < hit_time)
1286                                 {
1287                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1288                                                 hitindication_crosshair_size = 1;
1289                                                 
1290                                         hitindication_crosshair_time = hit_time;
1291                                 }
1292
1293                                 if(hitindication_crosshair_size > 0)
1294                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1295                                 else
1296                                         hitindication_crosshair_size = 0;
1297
1298                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1299                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1300                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1301                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1302                         }
1303
1304                         if(shottype == SHOTTYPE_HITENEMY)
1305                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1306                         if(shottype == SHOTTYPE_HITTEAM)
1307                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1308
1309                         f = fabs(autocvar_crosshair_effect_time);
1310                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1311                         {
1312                                 wcross_changedonetime = time + f;
1313                         }
1314                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1315                         {
1316                                 wcross_name_changestarttime = time;
1317                                 wcross_name_changedonetime = time + f;
1318                                 if(wcross_name_goal_prev_prev)
1319                                         strunzone(wcross_name_goal_prev_prev);
1320                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1321                                 wcross_name_goal_prev = strzone(wcross_name);
1322                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1323                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1324                                 wcross_resolution_goal_prev = wcross_resolution;
1325                         }
1326
1327                         wcross_scale_goal_prev = wcross_scale;
1328                         wcross_alpha_goal_prev = wcross_alpha;
1329                         wcross_color_goal_prev = wcross_color;
1330
1331                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1332                         {
1333                                 wcross_blur = 1;
1334                                 wcross_alpha *= 0.75;
1335                         }
1336                         else
1337                                 wcross_blur = 0;
1338                         // *_prev is at time-frametime
1339                         // * is at wcross_changedonetime+f
1340                         // what do we have at time?
1341                         if(time < wcross_changedonetime)
1342                         {
1343                                 f = frametime / (wcross_changedonetime - time + frametime);
1344                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1345                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1346                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1347                         }
1348
1349                         wcross_scale_prev = wcross_scale;
1350                         wcross_alpha_prev = wcross_alpha;
1351                         wcross_color_prev = wcross_color;
1352
1353                         wcross_scale *= 1 - autocvar__menu_alpha;
1354                         wcross_alpha *= 1 - autocvar__menu_alpha;
1355                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1356
1357                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1358                         {
1359                                 // crosshair rings for weapon stats
1360                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1361                                 {
1362                                         // declarations and stats
1363                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1364                                         string ring_image = string_null, ring_inner_image = string_null;
1365                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1366
1367                                         ring_scale = autocvar_crosshair_ring_size;
1368
1369                                         float weapon_clipload, weapon_clipsize;
1370                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1371                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1372
1373                                         float nex_charge, nex_chargepool;
1374                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1375                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1376
1377                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1378                                                 nex_charge_movingavg = nex_charge;
1379
1380
1381                                         // handle the values
1382                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1383                                         {
1384                                                 if (nex_chargepool || use_nex_chargepool) { 
1385                                                         use_nex_chargepool = 1; 
1386                                                         ring_inner_value = nex_chargepool;
1387                                                 } else { 
1388                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1389                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1); 
1390                                                 }
1391
1392                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1393                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1394                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1395
1396                                                 // draw the outer ring to show the current charge of the weapon
1397                                                 ring_value = nex_charge;
1398                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1399                                                 ring_rgb = wcross_color;
1400                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1401                                         }
1402                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer) 
1403                                         {
1404                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1405                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1406                                                 ring_rgb = wcross_color;
1407                                                 ring_image = "gfx/crosshair_ring.tga";
1408                                         }
1409                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1410                                         {
1411                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1412                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1413                                                 ring_rgb = wcross_color;
1414                                                 ring_image = "gfx/crosshair_ring.tga";
1415                                         }
1416
1417                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring 
1418                                         {
1419                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1420                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1421                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1422                                                 ring_rgb = wcross_color;
1423
1424                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1425                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1426                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1427                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1428                                                 else
1429                                                         ring_image = "gfx/crosshair_ring.tga";
1430                                         }
1431
1432                                         // if in weapon switch animation, fade ring out/in
1433                                         if(autocvar_crosshair_effect_time > 0)
1434                                         {
1435                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1436                                                 if not(f < 1)
1437                                                 {
1438                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1439                                                 }
1440                                                 
1441                                                 if(wcross_ring_prev)
1442                                                 {
1443                                                         if(f < 1)
1444                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1445                                                 }
1446                                                 else
1447                                                 {
1448                                                         if(f < 1)
1449                                                                 ring_alpha *= bound(0, f, 1);
1450                                                 }
1451                                         }
1452
1453                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1454                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1455
1456                                         if (ring_value)
1457                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1458                                 }
1459
1460 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1461                                 do \
1462                                 { \
1463                                         if(wcross_blur > 0) \
1464                                         { \
1465                                                 for(i = -2; i <= 2; ++i) \
1466                                                 for(j = -2; j <= 2; ++j) \
1467                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1468                                         } \
1469                                         else \
1470                                         { \
1471                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1472                                         } \
1473                                 } \
1474                                 while(0)
1475
1476 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1477                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1478
1479 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1480                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1481
1482                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1483                                 {
1484                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1485                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1486                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1487                                         f = 1 - f;
1488                                 }
1489                                 else
1490                                 {
1491                                         f = 1;
1492                                 }
1493                                 wcross_name_alpha_goal_prev = f;
1494
1495                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1496                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1497
1498                                 if(autocvar_crosshair_dot)
1499                                 {
1500                                         vector wcross_color_old;
1501                                         wcross_color_old = wcross_color;
1502                                         
1503                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1504                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1505                                                 
1506                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1507                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1508                                         wcross_color = wcross_color_old;
1509                                 }
1510                         }
1511                 }
1512                 else
1513                 {
1514                         wcross_scale_prev = 0;
1515                         wcross_alpha_prev = 0;
1516                         wcross_scale_goal_prev = 0;
1517                         wcross_alpha_goal_prev = 0;
1518                         wcross_changedonetime = 0;
1519                         if(wcross_name_goal_prev)
1520                                 strunzone(wcross_name_goal_prev);
1521                         wcross_name_goal_prev = string_null;
1522                         if(wcross_name_goal_prev_prev)
1523                                 strunzone(wcross_name_goal_prev_prev);
1524                         wcross_name_goal_prev_prev = string_null;
1525                         wcross_name_changestarttime = 0;
1526                         wcross_name_changedonetime = 0;
1527                         wcross_name_alpha_goal_prev = 0;
1528                         wcross_name_alpha_goal_prev_prev = 0;
1529                         wcross_resolution_goal_prev = 0;
1530                         wcross_resolution_goal_prev_prev = 0;
1531                 }
1532         }
1533
1534         if(NextFrameCommand)
1535         {
1536                 localcmd("\n", NextFrameCommand, "\n");
1537                 NextFrameCommand = string_null;
1538         }
1539
1540         // we must do this check AFTER a frame was rendered, or it won't work
1541         if(cs_project_is_b0rked == 0)
1542         {
1543                 string w0, h0;
1544                 w0 = ftos(autocvar_vid_conwidth);
1545                 h0 = ftos(autocvar_vid_conheight);
1546                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1547                 //setproperty(VF_FOV, '90 90 0');
1548                 setproperty(VF_ORIGIN, '0 0 0');
1549                 setproperty(VF_ANGLES, '0 0 0');
1550                 setproperty(VF_PERSPECTIVE, 1);
1551                 makevectors('0 0 0');
1552                 vector v1, v2;
1553                 cvar_set("vid_conwidth", "800");
1554                 cvar_set("vid_conheight", "600");
1555                 v1 = cs_project(v_forward);
1556                 cvar_set("vid_conwidth", "640");
1557                 cvar_set("vid_conheight", "480");
1558                 v2 = cs_project(v_forward);
1559                 if(v1 == v2)
1560                         cs_project_is_b0rked = 1;
1561                 else
1562                         cs_project_is_b0rked = -1;
1563                 cvar_set("vid_conwidth", w0);
1564                 cvar_set("vid_conheight", h0);
1565         }
1566
1567         if(autocvar__hud_configure)
1568                 HUD_Panel_Mouse();
1569     
1570     if(hud && !intermission)
1571     {        
1572         if(hud == HUD_SPIDERBOT)
1573             CSQC_SPIDER_HUD();
1574         else if(hud == HUD_WAKIZASHI)
1575             CSQC_WAKIZASHI_HUD();
1576         else if(hud == HUD_RAPTOR)
1577             CSQC_RAPTOR_HUD();
1578         else if(hud == HUD_BUMBLEBEE)
1579             CSQC_BUMBLE_HUD();
1580         else if(hud == HUD_BUMBLEBEE_GUN)
1581             CSQC_BUMBLE_GUN_HUD();
1582     }
1583         
1584         cl_notice_run();
1585         
1586         // let's reset the view back to normal for the end
1587         setproperty(VF_MIN, '0 0 0');
1588         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1589 }
1590
1591
1592 void CSQC_common_hud(void)
1593 {
1594         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1595                 Accuracy_LoadLevels();
1596
1597     HUD_Main(); // always run these functions for alpha checks
1598     HUD_DrawScoreboard();
1599
1600     if (scoreboard_active) // scoreboard/accuracy
1601         HUD_Reset();
1602     else if (intermission == 2) // map voting screen
1603     {
1604         HUD_FinaleOverlay();
1605         HUD_Reset();
1606     }
1607         /*
1608         switch(hud)
1609         {
1610                 case HUD_SPIDERBOT:
1611                         CSQC_SPIDER_HUD();
1612                         break;
1613
1614                 case HUD_WAKIZASHI:
1615                         CSQC_WAKIZASHI_HUD();
1616                         break;
1617
1618         case HUD_BUMBLEBEE:
1619             CSQC_BUMBLE_HUD();
1620             break;
1621         }
1622         */
1623 }
1624
1625
1626 // following vectors must be global to allow seamless switching between camera modes
1627 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1628 void CSQC_Demo_Camera()
1629 {
1630         float speed, attenuation, dimensions;
1631         vector tmp, delta;
1632
1633         if( autocvar_camera_reset || !camera_mode )
1634         {
1635                 camera_offset = '0 0 0';
1636                 current_angles = '0 0 0';
1637                 camera_direction = '0 0 0';
1638                 camera_offset_z += 30;
1639                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1640                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1641                 current_origin = view_origin;
1642                 current_camera_offset  = camera_offset;
1643                 cvar_set("camera_reset", "0");
1644                 camera_mode = CAMERA_CHASE;
1645         }
1646
1647         // Camera angles
1648         if( camera_roll )
1649                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1650
1651         if(autocvar_camera_look_player)
1652         {
1653                 vector dir;
1654                 float n;
1655
1656                 dir = normalize(view_origin - current_position);
1657                 n = mouse_angles_z;
1658                 mouse_angles = vectoangles(dir);
1659                 mouse_angles_x = mouse_angles_x * -1;
1660                 mouse_angles_z = n;
1661         }
1662         else
1663         {
1664                 tmp = getmousepos() * 0.1;
1665                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1666                 {
1667                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1668                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1669                 }
1670         }
1671
1672         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1673         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1674         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1675         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1676
1677         // Fix difference when angles don't have the same sign
1678         delta = '0 0 0';
1679         if(mouse_angles_y < -60 && current_angles_y > 60)
1680                 delta = '0 360 0';
1681         if(mouse_angles_y > 60 && current_angles_y < -60)
1682                 delta = '0 -360 0';
1683
1684         if(autocvar_camera_look_player)
1685                 attenuation = autocvar_camera_look_attenuation;
1686         else
1687                 attenuation = autocvar_camera_speed_attenuation;
1688
1689         attenuation = 1 / max(1, attenuation);
1690         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1691
1692         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1693         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1694         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1695         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1696
1697         // Camera position
1698         tmp = '0 0 0';
1699         dimensions = 0;
1700
1701         if( camera_direction_x )
1702         {
1703                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1704                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1705                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1706                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1707                 ++dimensions;
1708         }
1709
1710         if( camera_direction_y )
1711         {
1712                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1713                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1714                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1715                 ++dimensions;
1716         }
1717
1718         if( camera_direction_z )
1719         {
1720                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1721                 ++dimensions;
1722         }
1723
1724         if(autocvar_camera_free)
1725                 speed = autocvar_camera_speed_free;
1726         else
1727                 speed = autocvar_camera_speed_chase;
1728
1729         if(dimensions)
1730         {
1731                 speed = speed * sqrt(1 / dimensions);
1732                 camera_offset += tmp * speed;
1733         }
1734
1735         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1736
1737         // Camera modes
1738         if( autocvar_camera_free )
1739         {
1740                 if ( camera_mode == CAMERA_CHASE )
1741                 {
1742                         current_camera_offset = current_origin + current_camera_offset;
1743                         camera_offset = current_origin + camera_offset;
1744                 }
1745
1746                 camera_mode = CAMERA_FREE;
1747                 current_position = current_camera_offset;
1748         }
1749         else
1750         {
1751                 if ( camera_mode == CAMERA_FREE )
1752                 {
1753                         current_origin = view_origin;
1754                         camera_offset = camera_offset - current_origin;
1755                         current_camera_offset = current_camera_offset - current_origin;
1756                 }
1757
1758                 camera_mode = CAMERA_CHASE;
1759
1760                 if(autocvar_camera_chase_smoothly)
1761                         current_origin += (view_origin - current_origin) * attenuation;
1762                 else
1763                         current_origin = view_origin;
1764
1765                 current_position = current_origin + current_camera_offset;
1766         }
1767
1768         setproperty(VF_ANGLES, current_angles);
1769         setproperty(VF_ORIGIN, current_position);
1770 }