qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 void Porto_Init()
  84 {
  85         porto = spawn();
  86         porto.classname = "porto";
  87         porto.draw = Porto_Draw;
  88         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  89 }
  90
  91 float drawtime;
  92 float avgspeed;
  93 vector GetCurrentFov(float fov)
  94 {
  95         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  96         float velocityzoom, curspeed;
  97         vector v;
  98
  99         zoomsensitivity = autocvar_cl_zoomsensitivity;
 100         zoomfactor = autocvar_cl_zoomfactor;
 101         if(zoomfactor < 1 || zoomfactor > 16)
 102                 zoomfactor = 2.5;
 103         zoomspeed = autocvar_cl_zoomspeed;
 104         if(zoomspeed >= 0)
 105                 if(zoomspeed < 0.5 || zoomspeed > 16)
 106                         zoomspeed = 3.5;
 107
 108         zoomdir = button_zoom;
 109         if(hud == HUD_NORMAL)
 110         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 111                 zoomdir += button_attack2;
 112         if(spectatee_status > 0 || isdemo())
 113         {
 114                 if(spectatorbutton_zoom)
 115                 {
 116                         if(zoomdir)
 117                                 zoomdir = 0;
 118                         else
 119                                 zoomdir = 1;
 120                 }
 121                 // fteqcc failed twice here already, don't optimize this
 122         }
 123
 124         if(zoomdir)
 125                 zoomin_effect = 0;
 126
 127         if(zoomin_effect || camera_active)
 128         {
 129                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 130         }
 131         else
 132         {
 133                 if(zoomspeed < 0) // instant zoom
 134                 {
 135                         if(zoomdir)
 136                                 current_viewzoom = 1 / zoomfactor;
 137                         else
 138                                 current_viewzoom = 1;
 139                 }
 140                 else
 141                 {
 142                         if(zoomdir)
 143                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 144                         else
 145                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 146                 }
 147         }
 148
 149         if(almost_equals(current_viewzoom, 1))
 150                 current_zoomfraction = 0;
 151         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 152                 current_zoomfraction = 1;
 153         else
 154                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 155
 156         if(zoomsensitivity < 1)
 157                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 158         else
 159                 setsensitivityscale(1);
 160
 161         makevectors(view_angles);
 162
 163         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 164         {
 165                 v = pmove_vel;
 166                 if(csqcplayer)
 167                         v = csqcplayer.velocity;
 168
 169                 switch(autocvar_cl_velocityzoom_type)
 170                 {
 171                         case 3: curspeed = max(0, v_forward * v); break;
 172                         case 2: curspeed = (v_forward * v); break;
 173                         case 1: default: curspeed = vlen(v); break;
 174                 }
 175
 176                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 177                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 178                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 179
 180                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 181         }
 182         else
 183                 velocityzoom = 1;
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t, n;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_ent)
 232                 n = trace_ent.entnum;
 233         else
 234                 n = trace_networkentity;
 235         if(n < 1)
 236                 return SHOTTYPE_HITWORLD;
 237         if(n > maxclients)
 238                 return SHOTTYPE_HITWORLD;
 239         t = GetPlayerColor(n - 1);
 240         if(teamplay)
 241                 if(t == myteam)
 242                         return SHOTTYPE_HITTEAM;
 243         if(t == COLOR_SPECTATOR)
 244                 return SHOTTYPE_HITWORLD;
 245         return SHOTTYPE_HITENEMY;
 246 }
 247
 248 float TrueAimCheck()
 249 {
 250         float nudge = 1; // added to traceline target and subtracted from result
 251         vector vecs, trueaimpoint, w_shotorg;
 252         vector mi, ma, dv;
 253         float shottype;
 254         entity ta;
 255         float mv;
 256
 257         mi = ma = '0 0 0';
 258         ta = trueaim;
 259         mv = MOVE_NOMONSTERS;
 260
 261         switch(activeweapon)
 262         {
 263                 case WEP_TUBA: // no aim
 264                 case WEP_PORTO: // shoots from eye
 265                 case WEP_HOOK: // no trueaim
 266                 case WEP_GRENADE_LAUNCHER: // toss curve
 267                         return SHOTTYPE_HITWORLD;
 268                 case WEP_NEX:
 269                 case WEP_MINSTANEX:
 270                         mv = MOVE_NORMAL;
 271                         break;
 272                 case WEP_RIFLE:
 273                         ta = trueaim_rifle;
 274                         mv = MOVE_NORMAL;
 275                         if(zoomscript_caught)
 276                         {
 277                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 278                                 return EnemyHitCheck();
 279                         }
 280                         break;
 281                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 282                         mi = '-3 -3 -3';
 283                         ma = '3 3 3';
 284                         break;
 285                 case WEP_FIREBALL: // projectile has a size!
 286                         mi = '-16 -16 -16';
 287                         ma = '16 16 16';
 288                         break;
 289                 case WEP_SEEKER: // projectile has a size!
 290                         mi = '-2 -2 -2';
 291                         ma = '2 2 2';
 292                         break;
 293                 case WEP_ELECTRO: // projectile has a size!
 294                         mi = '0 0 -3';
 295                         ma = '0 0 -3';
 296                         break;
 297         }
 298
 299         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 300
 301         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 302         trueaimpoint = trace_endpos;
 303
 304         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 305                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 306
 307         if(vecs_x > 0)
 308                 vecs_y = -vecs_y;
 309         else
 310                 vecs = '0 0 0';
 311
 312         dv = view_right * vecs_y + view_up * vecs_z;
 313         w_shotorg = view_origin + dv;
 314
 315         // now move the vecs forward as much as requested if possible
 316         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 317         w_shotorg = trace_endpos - view_forward * nudge;
 318
 319         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 320         shottype = EnemyHitCheck();
 321         if(shottype != SHOTTYPE_HITWORLD)
 322                 return shottype;
 323
 324 #if 0
 325         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 326         // or rather, I know why, but see no fix
 327         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 328                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 329                 return SHOTTYPE_HITOBSTRUCTION;
 330 #endif
 331
 332         return SHOTTYPE_HITWORLD;
 333 }
 334
 335 void CSQC_common_hud(void);
 336
 337 void PostInit(void);
 338 void CSQC_Demo_Camera();
 339 float HUD_WouldDrawScoreboard();
 340 float camera_mode;
 341 float CAMERA_FREE = 1;
 342 float CAMERA_CHASE = 2;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 #define MAX_TIME_DIFF 5
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float hit_time, typehit_time;
 354 float nextsound_hit_time, nextsound_typehit_time;
 355 float hitindication_crosshair_time, hitindication_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 float old_blurradius, old_bluralpha;
 362 float old_sharpen_intensity;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 vector damage_blurpostprocess, content_blurpostprocess;
 372
 373 float checkfail[16];
 374
 375 #define BUTTON_3 4
 376 #define BUTTON_4 8
 377 float cl_notice_run();
 378 void CSQC_UpdateView(float w, float h)
 379 {
 380         entity e;
 381         float fov;
 382         float f, i, j;
 383         vector v;
 384         vector vf_size, vf_min;
 385         float a;
 386
 387         execute_next_frame();
 388
 389         ++framecount;
 390
 391         hud = getstati(STAT_HUD);
 392
 393         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 394                 view_quality = getproperty(VF_MINFPS_QUALITY);
 395         else
 396                 view_quality = 1;
 397
 398         button_attack2 = (input_buttons & BUTTON_3);
 399         button_zoom = (input_buttons & BUTTON_4);
 400
 401         // FIXME do we need this hack?
 402         if(isdemo())
 403         {
 404                 // in demos, input_buttons do not work
 405                 button_zoom = (autocvar__togglezoom == "-");
 406         }
 407
 408 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 409         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 410         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 411         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 412         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 413         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 414         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 415         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 416
 417         vf_size = getpropertyvec(VF_SIZE);
 418         vf_min = getpropertyvec(VF_MIN);
 419         vid_width = vf_size_x;
 420         vid_height = vf_size_y;
 421
 422         vector reticle_pos, reticle_size;
 423         vector splash_pos, splash_size;
 424
 425         WaypointSprite_Load();
 426
 427         CSQCPlayer_SetCamera();
 428
 429 #ifdef COMPAT_XON050_ENGINE
 430         if(spectatee_status)
 431                 myteam = GetPlayerColor(spectatee_status - 1);
 432         else
 433 #endif
 434                 myteam = GetPlayerColor(player_localentnum - 1);
 435
 436         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 437
 438         // event chase camera
 439         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 440         {
 441                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 442                 {
 443                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 444                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 445
 446                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 447                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 448                         if(!autocvar_chase_active)
 449                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 450
 451                         // make the camera smooth back
 452                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 453                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 454                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 455                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 456
 457                         vector eventchase_target_origin;
 458                         makevectors(view_angles);
 459                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 460                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 461                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 462                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 463                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 464                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 465                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 466
 467                         setproperty(VF_ORIGIN, trace_endpos);
 468                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 469                 }
 470                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 471                 {
 472                         cvar_set("chase_active", "0");
 473                         eventchase_current_distance = 0; // start from 0 next time
 474                 }
 475         }
 476
 477         // do lockview after event chase camera so that it still applies whenever necessary.
 478         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 479         {
 480                 setproperty(VF_ORIGIN, freeze_org);
 481                 setproperty(VF_ANGLES, freeze_ang);
 482         }
 483         else
 484         {
 485                 freeze_org = getpropertyvec(VF_ORIGIN);
 486                 freeze_ang = getpropertyvec(VF_ANGLES);
 487         }
 488
 489         WarpZone_FixView();
 490         //WarpZone_FixPMove();
 491
 492         // Render the Scene
 493         view_origin = getpropertyvec(VF_ORIGIN);
 494         view_angles = getpropertyvec(VF_ANGLES);
 495         makevectors(view_angles);
 496         view_forward = v_forward;
 497         view_right = v_right;
 498         view_up = v_up;
 499
 500 #ifdef BLURTEST
 501         if(time > blurtest_time0 && time < blurtest_time1)
 502         {
 503                 float r, t;
 504
 505                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 506                 r = t * blurtest_radius;
 507                 f = 1 / pow(t, blurtest_power) - 1;
 508
 509                 cvar_set("r_glsl_postprocess", "1");
 510                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 511         }
 512         else
 513         {
 514                 cvar_set("r_glsl_postprocess", "0");
 515                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 516         }
 517 #endif
 518
 519         TargetMusic_Advance();
 520         Fog_Force();
 521
 522         if(drawtime == 0)
 523                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 524         else
 525                 drawframetime = bound(0.000001, time - drawtime, 1);
 526         drawtime = time;
 527
 528         // watch for gametype changes here...
 529         // in ParseStuffCMD the cmd isn't executed yet :/
 530         // might even be better to add the gametype to TE_CSQC_INIT...?
 531         if(!postinit)
 532                 PostInit();
 533
 534         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 535         {
 536                 if(calledhooks & HOOK_START)
 537                 {
 538                         localcmd("\ncl_hook_gameend\n");
 539                         calledhooks |= HOOK_END;
 540                 }
 541         }
 542
 543   Announcer();
 544
 545         fov = autocvar_fov;
 546         if(fov <= 59.5)
 547         {
 548                 if(!zoomscript_caught)
 549                 {
 550                         localcmd("+button9\n");
 551                         zoomscript_caught = 1;
 552                 }
 553         }
 554         else
 555         {
 556                 if(zoomscript_caught)
 557                 {
 558                         localcmd("-button9\n");
 559                         zoomscript_caught = 0;
 560                 }
 561         }
 562
 563         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 564
 565         // next WANTED weapon (for HUD)
 566         switchweapon = getstati(STAT_SWITCHWEAPON);
 567
 568         // currently switching-to weapon (for crosshair)
 569         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 570
 571         // actually active weapon (for zoom)
 572         activeweapon = getstati(STAT_ACTIVEWEAPON);
 573
 574         f = (serverflags & SERVERFLAG_TEAMPLAY);
 575         if(f != teamplay)
 576         {
 577                 teamplay = f;
 578                 HUD_InitScores();
 579         }
 580
 581         if(last_switchweapon != switchweapon) {
 582                 weapontime = time;
 583                 last_switchweapon = switchweapon;
 584         }
 585         if(last_activeweapon != activeweapon) {
 586                 last_activeweapon = activeweapon;
 587
 588                 e = get_weaponinfo(activeweapon);
 589                 if(e.netname != "")
 590                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 591                 else
 592                         localcmd("\ncl_hook_activeweapon none\n");
 593         }
 594
 595         // ALWAYS Clear Current Scene First
 596         clearscene();
 597 #ifdef WORKAROUND_XON010
 598         if(checkextension("DP_CSQC_ROTATEMOVES"))
 599         {
 600 #endif
 601         setproperty(VF_ORIGIN, view_origin);
 602         setproperty(VF_ANGLES, view_angles);
 603 #ifdef WORKAROUND_XON010
 604         }
 605 #endif
 606
 607         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 608         setproperty(VF_SIZE, vf_size);
 609         setproperty(VF_MIN, vf_min);
 610
 611         // Assign Standard Viewflags
 612         // Draw the World (and sky)
 613         setproperty(VF_DRAWWORLD, 1);
 614
 615         // Set the console size vars
 616         vid_conwidth = autocvar_vid_conwidth;
 617         vid_conheight = autocvar_vid_conheight;
 618         vid_pixelheight = autocvar_vid_pixelheight;
 619
 620         setproperty(VF_FOV, GetCurrentFov(fov));
 621
 622         // Camera for demo playback
 623         if(camera_active)
 624         {
 625                 if(autocvar_camera_enable)
 626                         CSQC_Demo_Camera();
 627                 else
 628                 {
 629                         cvar_set("chase_active", ftos(chase_active_backup));
 630                         cvar_set("cl_demo_mousegrab", "0");
 631                         camera_active = FALSE;
 632                 }
 633         }
 634 #ifdef CAMERATEST
 635         else if(autocvar_camera_enable)
 636 #else
 637         else if(autocvar_camera_enable && isdemo())
 638 #endif
 639         {
 640                 // Enable required Darkplaces cvars
 641                 chase_active_backup = autocvar_chase_active;
 642                 cvar_set("chase_active", "2");
 643                 cvar_set("cl_demo_mousegrab", "1");
 644                 camera_active = TRUE;
 645                 camera_mode = FALSE;
 646         }
 647
 648         // Draw the Crosshair
 649         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 650
 651         // Draw the Engine Status Bar (the default Quake HUD)
 652         setproperty(VF_DRAWENGINESBAR, 0);
 653
 654         // Update the mouse position
 655         /*
 656            mousepos_x = vid_conwidth;
 657            mousepos_y = vid_conheight;
 658            mousepos = mousepos*0.5 + getmousepos();
 659          */
 660
 661         e = self;
 662         for(self = world; (self = nextent(self)); )
 663                 if(self.draw)
 664                         self.draw();
 665         self = e;
 666
 667         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 668         renderscene();
 669
 670         // now switch to 2D drawing mode by calling a 2D drawing function
 671         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 672         // next R_RenderScene call
 673         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 674
 675         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 676         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 677         {
 678                 // apply night vision effect
 679                 vector tc_00, tc_01, tc_10, tc_11;
 680                 vector rgb;
 681                 rgb_x = 0; // fteqcc sucks
 682                 rgb_y = 0; // fteqcc sucks
 683                 rgb_z = 0; // fteqcc sucks
 684
 685                 if(!nightvision_noise)
 686                 {
 687                         nightvision_noise = spawn();
 688                         nightvision_noise.classname = "nightvision_noise";
 689                 }
 690                 if(!nightvision_noise2)
 691                 {
 692                         nightvision_noise2 = spawn();
 693                         nightvision_noise2.classname = "nightvision_noise2";
 694                 }
 695
 696                 // color tint in yellow
 697                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 698
 699                 // draw BG
 700                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 701                 rgb = '1 1 1';
 702                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 703                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 704                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 705                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 706                 tc_11 = tc_01 + tc_10 - tc_00;
 707                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 708                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 709                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 710                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 711                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 712                 R_EndPolygon();
 713
 714                 // draw FG
 715                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 716                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 717                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 718                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 719                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 720                 tc_11 = tc_01 + tc_10 - tc_00;
 721                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 722                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 723                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 724                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 725                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 726                 R_EndPolygon();
 727         }
 728
 729         // Draw the aiming reticle for weapons that use it
 730         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 731         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 732         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 733         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 734                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 735         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 736                 reticle_type = 2; // nex zoom
 737         else if(button_zoom || zoomscript_caught)
 738                 reticle_type = 1; // normal zoom
 739         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 740                 reticle_type = 2; // nex zoom
 741
 742         if(reticle_type && autocvar_cl_reticle)
 743         {
 744                 if(autocvar_cl_reticle_stretch)
 745                 {
 746                         reticle_size_x = vid_conwidth;
 747                         reticle_size_y = vid_conheight;
 748                         reticle_pos_x = 0;
 749                         reticle_pos_y = 0;
 750                 }
 751                 else
 752                 {
 753                         reticle_size_x = max(vid_conwidth, vid_conheight);
 754                         reticle_size_y = max(vid_conwidth, vid_conheight);
 755                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 756                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 757                 }
 758
 759                 f = current_zoomfraction;
 760                 if(zoomscript_caught)
 761                         f = 1;
 762                 if(autocvar_cl_reticle_item_normal)
 763                 {
 764                         if(reticle_type == 1 && f)
 765                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 766                 }
 767                 if(autocvar_cl_reticle_item_nex)
 768                 {
 769                         if(reticle_type == 2 && f)
 770                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 771                 }
 772         }
 773
 774
 775         // improved polyblend
 776         vector rgb;
 777         if(autocvar_hud_contents)
 778         {
 779                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 780                 vector liquidcolor;
 781
 782                 switch(pointcontents(view_origin))
 783                 {
 784                         case CONTENT_WATER:
 785                                 liquidalpha = autocvar_hud_contents_water_alpha;
 786                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 787                                 incontent = 1;
 788                                 break;
 789
 790                         case CONTENT_LAVA:
 791                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 792                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 793                                 incontent = 1;
 794                                 break;
 795
 796                         case CONTENT_SLIME:
 797                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 798                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 799                                 incontent = 1;
 800                                 break;
 801
 802                         default:
 803                                 liquidalpha = 0;
 804                                 liquidcolor = '0 0 0';
 805                                 incontent = 0;
 806                                 break;
 807                 }
 808
 809                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 810                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 811                         contentfadetime = autocvar_hud_contents_fadeintime;
 812                         liquidalpha_prev = liquidalpha;
 813                         liquidcolor_prev = liquidcolor;
 814                 }
 815                 else
 816                         contentfadetime = autocvar_hud_contents_fadeouttime;
 817
 818                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 819                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 820
 821                 if(contentavgalpha)
 822                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 823
 824                 if(autocvar_hud_postprocessing)
 825                 {
 826                         if(autocvar_hud_contents_blur && contentavgalpha)
 827                         {
 828                                 content_blurpostprocess_x = 1;
 829                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 830                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 831                         }
 832                         else
 833                         {
 834                                 content_blurpostprocess_x = 0;
 835                                 content_blurpostprocess_y = 0;
 836                                 content_blurpostprocess_z = 0;
 837                         }
 838                 }
 839         }
 840
 841         if(autocvar_hud_damage)
 842         {
 843                 splash_size_x = max(vid_conwidth, vid_conheight);
 844                 splash_size_y = max(vid_conwidth, vid_conheight);
 845                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 846                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 847
 848                 float myhealth_flash_temp;
 849                 myhealth = getstati(STAT_HEALTH);
 850
 851                 // fade out
 852                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 853                 // add new damage
 854                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 855
 856                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 857                 pain_threshold = autocvar_hud_damage_pain_threshold;
 858                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 859                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 860
 861                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 862                 {
 863                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 864                 }
 865
 866                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 867
 868                 if(myhealth_prev < 1)
 869                 {
 870                         if(myhealth >= 1)
 871                         {
 872                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 873                                 myhealth_flash_temp = 0;
 874                         }
 875                         else
 876                         {
 877                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 878                         }
 879                 }
 880
 881                 if(spectatee_status == -1 || intermission)
 882                 {
 883                         myhealth_flash = 0; // observing, or match ended
 884                         myhealth_flash_temp = 0;
 885                 }
 886
 887                 myhealth_prev = myhealth;
 888
 889                 // IDEA: change damage color/picture based on player model for robot/alien species?
 890                 // pro: matches model better
 891                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 892                 // maybe different reddish pics?
 893                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 894                 {
 895                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 896                         {
 897                                 if(autocvar_cl_gentle_damage == 2)
 898                                 {
 899                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 900                                         {
 901                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 902                                         }
 903                                 }
 904                                 else
 905                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 906
 907                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 908                         }
 909                         else
 910                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 911                 }
 912
 913                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 914                 {
 915                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 916                         {
 917                                 damage_blurpostprocess_x = 1;
 918                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 919                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 920                         }
 921                         else
 922                         {
 923                                 damage_blurpostprocess_x = 0;
 924                                 damage_blurpostprocess_y = 0;
 925                                 damage_blurpostprocess_z = 0;
 926                         }
 927                 }
 928         }
 929
 930         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 931         float e2 = (autocvar_hud_powerup != 0);
 932         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 933         {
 934                 // enable or disable rendering types if they are used or not
 935                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 936                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 937
 938                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 939                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 940                 {
 941                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 942                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 943                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 944                         {
 945                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 946                                 old_blurradius = blurradius;
 947                                 old_bluralpha = bluralpha;
 948                         }
 949                 }
 950                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 951                 {
 952                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 953                         old_blurradius = 0;
 954                         old_bluralpha = 0;
 955                 }
 956
 957                 // edge detection postprocess handling done second (used by hud_powerup)
 958                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 959                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 960                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 961
 962                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 963
 964                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 965                 {
 966                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 967                         {
 968                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 969                                 old_sharpen_intensity = sharpen_intensity;
 970                         }
 971                 }
 972                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 973                 {
 974                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 975                         old_sharpen_intensity = 0;
 976                 }
 977
 978                 if(cvar("r_glsl_postprocess") == 0)
 979                         cvar_set("r_glsl_postprocess", "2");
 980         }
 981         else if(cvar("r_glsl_postprocess") == 2)
 982                 cvar_set("r_glsl_postprocess", "0");
 983
 984         if(menu_visible)
 985                 menu_show();
 986
 987         /*if(gametype == MAPINFO_TYPE_CTF)
 988           {
 989           ctf_view();
 990           } else */
 991
 992         // draw 2D entities
 993         e = self;
 994         for(self = world; (self = nextent(self)); )
 995                 if(self.draw2d)
 996                         self.draw2d();
 997         self = e;
 998         Draw_ShowNames_All();
 999
1000         scoreboard_active = HUD_WouldDrawScoreboard();
1001
1002         hit_time = getstatf(STAT_HIT_TIME);
1003         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1004         {
1005                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1006                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1007
1008                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1009         }
1010         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1011         if(typehit_time > nextsound_typehit_time)
1012         {
1013                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1014                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1015
1016                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1017         }
1018
1019         //else
1020         {
1021                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1022                 {
1023                         if(getstati(STAT_FROZEN))
1024                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1025                         if(getstatf(STAT_REVIVE_PROGRESS))
1026                         {
1027                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1028                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1029                         }
1030                 }
1031
1032                 if(autocvar_r_letterbox == 0)
1033                         if(autocvar_viewsize < 120)
1034                                 CSQC_common_hud();
1035
1036                 // crosshair goes VERY LAST
1037                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1038                 {
1039                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1040                                 return;
1041
1042                         string wcross_style;
1043                         float wcross_alpha, wcross_resolution;
1044                         wcross_style = autocvar_crosshair;
1045                         if (wcross_style == "0")
1046                                 return;
1047                         wcross_resolution = autocvar_crosshair_size;
1048                         if (wcross_resolution == 0)
1049                                 return;
1050                         wcross_alpha = autocvar_crosshair_alpha;
1051                         if (wcross_alpha == 0)
1052                                 return;
1053
1054                         // TrueAim check
1055                         float shottype;
1056
1057                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1058                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1059                         wcross_origin_z = 0;
1060                         if(autocvar_crosshair_hittest)
1061                         {
1062                                 vector wcross_oldorigin;
1063                                 wcross_oldorigin = wcross_origin;
1064                                 shottype = TrueAimCheck();
1065                                 if(shottype == SHOTTYPE_HITWORLD)
1066                                 {
1067                                         v = wcross_origin - wcross_oldorigin;
1068                                         v_x /= vid_conwidth;
1069                                         v_y /= vid_conheight;
1070                                         if(vlen(v) > 0.01)
1071                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1072                                 }
1073                                 if(!autocvar_crosshair_hittest_showimpact)
1074                                         wcross_origin = wcross_oldorigin;
1075                         }
1076                         else
1077                                 shottype = SHOTTYPE_HITWORLD;
1078
1079                         vector wcross_color, wcross_size;
1080                         string wcross_wep, wcross_name;
1081                         float wcross_scale, wcross_blur;
1082
1083                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1084                                 e = get_weaponinfo(switchingweapon);
1085                                 if (e && e.netname != "")
1086                                 {
1087                                         wcross_wep = e.netname;
1088                                         if(autocvar_crosshair_per_weapon)
1089                                         {
1090                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1091                                                 if (wcross_resolution == 0)
1092                                                         return;
1093                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1094                                                 if (wcross_alpha == 0)
1095                                                         return;
1096
1097                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1098                                                 if(wcross_style == "" || wcross_style == "0")
1099                                                         wcross_style = wcross_wep;
1100                                         }
1101                                 }
1102                         }
1103                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1104                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1105                         else if(autocvar_crosshair_color_by_health)
1106                         {
1107                                 float x = getstati(STAT_HEALTH);
1108
1109                                 //x = red
1110                                 //y = green
1111                                 //z = blue
1112
1113                                 wcross_color_z = 0;
1114
1115                                 if(x > 200)
1116                                 {
1117                                         wcross_color_x = 0;
1118                                         wcross_color_y = 1;
1119                                 }
1120                                 else if(x > 150)
1121                                 {
1122                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1123                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1124                                 }
1125                                 else if(x > 100)
1126                                 {
1127                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1128                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1129                                         wcross_color_z = 1 - (x-100)*0.02;
1130                                 }
1131                                 else if(x > 50)
1132                                 {
1133                                         wcross_color_x = 1;
1134                                         wcross_color_y = 1;
1135                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1136                                 }
1137                                 else if(x > 20)
1138                                 {
1139                                         wcross_color_x = 1;
1140                                         wcross_color_y = (x-20)*90/27/100;
1141                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1142                                 }
1143                                 else
1144                                 {
1145                                         wcross_color_x = 1;
1146                                         wcross_color_y = 0;
1147                                 }
1148                         }
1149                         else
1150                                 wcross_color = stov(autocvar_crosshair_color);
1151
1152                         wcross_name = strcat("gfx/crosshair", wcross_style);
1153
1154                         if(autocvar_crosshair_effect_scalefade)
1155                         {
1156                                 wcross_scale = wcross_resolution;
1157                                 wcross_resolution = 1;
1158                         }
1159                         else
1160                         {
1161                                 wcross_scale = 1;
1162                         }
1163
1164                         if(autocvar_crosshair_pickup)
1165                         {
1166                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1167
1168                                 if(pickup_crosshair_time < stat_pickup_time)
1169                                 {
1170                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1171                                                 pickup_crosshair_size = 1;
1172
1173                                         pickup_crosshair_time = stat_pickup_time;
1174                                 }
1175
1176                                 if(pickup_crosshair_size > 0)
1177                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1178                                 else
1179                                         pickup_crosshair_size = 0;
1180
1181                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1182                         }
1183
1184                         if(autocvar_crosshair_hitindication)
1185                         {
1186                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1187                                 if(hitindication_crosshair_time < hit_time)
1188                                 {
1189                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1190                                                 hitindication_crosshair_size = 1;
1191
1192                                         hitindication_crosshair_time = hit_time;
1193                                 }
1194
1195                                 if(hitindication_crosshair_size > 0)
1196                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1197                                 else
1198                                         hitindication_crosshair_size = 0;
1199
1200                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1201                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1202                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1203                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1204                         }
1205
1206                         if(shottype == SHOTTYPE_HITENEMY)
1207                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1208                         if(shottype == SHOTTYPE_HITTEAM)
1209                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1210
1211                         f = autocvar_crosshair_effect_speed;
1212                         if(f < 0)
1213                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1214                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1215                         {
1216                                 wcross_changedonetime = time + f;
1217                         }
1218                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1219                         {
1220                                 wcross_name_changestarttime = time;
1221                                 wcross_name_changedonetime = time + f;
1222                                 if(wcross_name_goal_prev_prev)
1223                                         strunzone(wcross_name_goal_prev_prev);
1224                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1225                                 wcross_name_goal_prev = strzone(wcross_name);
1226                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1227                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1228                                 wcross_resolution_goal_prev = wcross_resolution;
1229                         }
1230
1231                         wcross_scale_goal_prev = wcross_scale;
1232                         wcross_alpha_goal_prev = wcross_alpha;
1233                         wcross_color_goal_prev = wcross_color;
1234
1235                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1236                         {
1237                                 wcross_blur = 1;
1238                                 wcross_alpha *= 0.75;
1239                         }
1240                         else
1241                                 wcross_blur = 0;
1242                         // *_prev is at time-frametime
1243                         // * is at wcross_changedonetime+f
1244                         // what do we have at time?
1245                         if(time < wcross_changedonetime)
1246                         {
1247                                 f = frametime / (wcross_changedonetime - time + frametime);
1248                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1249                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1250                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1251                         }
1252
1253                         wcross_scale_prev = wcross_scale;
1254                         wcross_alpha_prev = wcross_alpha;
1255                         wcross_color_prev = wcross_color;
1256
1257                         wcross_scale *= 1 - autocvar__menu_alpha;
1258                         wcross_alpha *= 1 - autocvar__menu_alpha;
1259                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1260
1261                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1262                         {
1263                                 // crosshair rings for weapon stats
1264                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1265                                 {
1266                                         // declarations and stats
1267                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1268                                         string ring_image, ring_inner_image;
1269                                         vector ring_rgb, ring_inner_rgb;
1270
1271                                         ring_scale = autocvar_crosshair_ring_size;
1272
1273                                         float weapon_clipload, weapon_clipsize;
1274                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1275                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1276
1277                                         float nex_charge, nex_chargepool;
1278                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1279                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1280
1281                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1282                                                 nex_charge_movingavg = nex_charge;
1283
1284
1285                                         // handle the values
1286                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1287                                         {
1288                                                 if (nex_chargepool || use_nex_chargepool) {
1289                                                         use_nex_chargepool = 1;
1290                                                         ring_inner_value = nex_chargepool;
1291                                                 } else {
1292                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1293                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1294                                                 }
1295
1296                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1297                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1298                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1299
1300                                                 // draw the outer ring to show the current charge of the weapon
1301                                                 ring_value = nex_charge;
1302                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1303                                                 ring_rgb = wcross_color;
1304                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1305                                         }
1306                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1307                                         {
1308                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1309                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1310                                                 ring_rgb = wcross_color;
1311                                                 ring_image = "gfx/crosshair_ring.tga";
1312                                         }
1313                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1314                                         {
1315                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1316                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1317                                                 ring_rgb = wcross_color;
1318                                                 ring_image = "gfx/crosshair_ring.tga";
1319                                         }
1320
1321                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1322                                         {
1323                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1324                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1325                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1326                                                 ring_rgb = wcross_color;
1327
1328                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1329                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1330                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1331                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1332                                                 else
1333                                                         ring_image = "gfx/crosshair_ring.tga";
1334                                         }
1335
1336                                         // if in weapon switch animation, fade ring out/in
1337                                         if(g_weaponswitchdelay > 0)
1338                                         {
1339                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1340                                                 if(f > 0 && f < 2)
1341                                                         ring_alpha *= fabs(1 - f);
1342                                         }
1343
1344                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1345                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1346
1347                                         if (ring_value)
1348                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1349                                 }
1350
1351 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1352                                 do \
1353                                 { \
1354                                         if(wcross_blur > 0) \
1355                                         { \
1356                                                 for(i = -2; i <= 2; ++i) \
1357                                                 for(j = -2; j <= 2; ++j) \
1358                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1359                                         } \
1360                                         else \
1361                                         { \
1362                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1363                                         } \
1364                                 } \
1365                                 while(0)
1366
1367 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1368                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1369
1370 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1371                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1372
1373                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1374                                 {
1375                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1376                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1377                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1378                                         f = 1 - f;
1379                                 }
1380                                 else
1381                                 {
1382                                         f = 1;
1383                                 }
1384                                 wcross_name_alpha_goal_prev = f;
1385
1386                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1387                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1388
1389                                 if(autocvar_crosshair_dot)
1390                                 {
1391                                         vector wcross_color_old;
1392                                         wcross_color_old = wcross_color;
1393
1394                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1395                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1396
1397                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1398                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1399                                         wcross_color = wcross_color_old;
1400                                 }
1401                         }
1402                 }
1403                 else
1404                 {
1405                         wcross_scale_prev = 0;
1406                         wcross_alpha_prev = 0;
1407                         wcross_scale_goal_prev = 0;
1408                         wcross_alpha_goal_prev = 0;
1409                         wcross_changedonetime = 0;
1410                         if(wcross_name_goal_prev)
1411                                 strunzone(wcross_name_goal_prev);
1412                         wcross_name_goal_prev = string_null;
1413                         if(wcross_name_goal_prev_prev)
1414                                 strunzone(wcross_name_goal_prev_prev);
1415                         wcross_name_goal_prev_prev = string_null;
1416                         wcross_name_changestarttime = 0;
1417                         wcross_name_changedonetime = 0;
1418                         wcross_name_alpha_goal_prev = 0;
1419                         wcross_name_alpha_goal_prev_prev = 0;
1420                         wcross_resolution_goal_prev = 0;
1421                         wcross_resolution_goal_prev_prev = 0;
1422                 }
1423         }
1424
1425         if(NextFrameCommand)
1426         {
1427                 localcmd("\n", NextFrameCommand, "\n");
1428                 NextFrameCommand = string_null;
1429         }
1430
1431         // we must do this check AFTER a frame was rendered, or it won't work
1432         if(cs_project_is_b0rked == 0)
1433         {
1434                 string w0, h0;
1435                 w0 = ftos(autocvar_vid_conwidth);
1436                 h0 = ftos(autocvar_vid_conheight);
1437                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1438                 //setproperty(VF_FOV, '90 90 0');
1439                 setproperty(VF_ORIGIN, '0 0 0');
1440                 setproperty(VF_ANGLES, '0 0 0');
1441                 setproperty(VF_PERSPECTIVE, 1);
1442                 makevectors('0 0 0');
1443                 vector v1, v2;
1444                 cvar_set("vid_conwidth", "800");
1445                 cvar_set("vid_conheight", "600");
1446                 v1 = cs_project(v_forward);
1447                 cvar_set("vid_conwidth", "640");
1448                 cvar_set("vid_conheight", "480");
1449                 v2 = cs_project(v_forward);
1450                 if(v1 == v2)
1451                         cs_project_is_b0rked = 1;
1452                 else
1453                         cs_project_is_b0rked = -1;
1454                 cvar_set("vid_conwidth", w0);
1455                 cvar_set("vid_conheight", h0);
1456         }
1457
1458         if(autocvar__hud_configure)
1459                 HUD_Panel_Mouse();
1460
1461     if(hud && !intermission)
1462     {
1463         if(hud == HUD_SPIDERBOT)
1464             CSQC_SPIDER_HUD();
1465         else if(hud == HUD_WAKIZASHI)
1466             CSQC_WAKIZASHI_HUD();
1467         else if(hud == HUD_RAPTOR)
1468             CSQC_RAPTOR_HUD();
1469         else if(hud == HUD_BUMBLEBEE)
1470             CSQC_BUMBLE_HUD();
1471     }
1472
1473         cl_notice_run();
1474
1475         // let's reset the view back to normal for the end
1476         setproperty(VF_MIN, '0 0 0');
1477         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1478 }
1479
1480
1481 void CSQC_common_hud(void)
1482 {
1483     // do some accuracy var caching
1484     float i;
1485     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1486     {
1487         if(autocvar_accuracy_color_levels != acc_color_levels)
1488         {
1489             if(acc_color_levels)
1490                 strunzone(acc_color_levels);
1491             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1492             acc_levels = tokenize_console(acc_color_levels);
1493             if (acc_levels > MAX_ACCURACY_LEVELS)
1494                 acc_levels = MAX_ACCURACY_LEVELS;
1495
1496             for (i = 0; i < acc_levels; ++i)
1497                 acc_lev[i] = stof(argv(i)) / 100.0;
1498         }
1499         // let know that acc_col[] needs to be loaded
1500         acc_col[0] = '-1 0 0';
1501     }
1502
1503     HUD_Main(); // always run these functions for alpha checks
1504     HUD_DrawScoreboard();
1505
1506     if (scoreboard_active) // scoreboard/accuracy
1507         HUD_Reset();
1508     else if (intermission == 2) // map voting screen
1509     {
1510         HUD_FinaleOverlay();
1511         HUD_Reset();
1512     }
1513         /*
1514         switch(hud)
1515         {
1516                 case HUD_SPIDERBOT:
1517                         CSQC_SPIDER_HUD();
1518                         break;
1519
1520                 case HUD_WAKIZASHI:
1521                         CSQC_WAKIZASHI_HUD();
1522                         break;
1523
1524         case HUD_BUMBLEBEE:
1525             CSQC_BUMBLE_HUD();
1526             break;
1527         }
1528         */
1529 }
1530
1531
1532 // following vectors must be global to allow seamless switching between camera modes
1533 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1534 void CSQC_Demo_Camera()
1535 {
1536         float speed, attenuation, dimensions;
1537         vector tmp, delta;
1538
1539         if( autocvar_camera_reset || !camera_mode )
1540         {
1541                 camera_offset = '0 0 0';
1542                 current_angles = '0 0 0';
1543                 camera_direction = '0 0 0';
1544                 camera_offset_z += 30;
1545                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1546                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1547                 current_origin = view_origin;
1548                 current_camera_offset  = camera_offset;
1549                 cvar_set("camera_reset", "0");
1550                 camera_mode = CAMERA_CHASE;
1551         }
1552
1553         // Camera angles
1554         if( camera_roll )
1555                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1556
1557         if(autocvar_camera_look_player)
1558         {
1559                 vector dir;
1560                 float n;
1561
1562                 dir = normalize(view_origin - current_position);
1563                 n = mouse_angles_z;
1564                 mouse_angles = vectoangles(dir);
1565                 mouse_angles_x = mouse_angles_x * -1;
1566                 mouse_angles_z = n;
1567         }
1568         else
1569         {
1570                 tmp = getmousepos() * 0.1;
1571                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1572                 {
1573                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1574                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1575                 }
1576         }
1577
1578         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1579         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1580         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1581         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1582
1583         // Fix difference when angles don't have the same sign
1584         delta = '0 0 0';
1585         if(mouse_angles_y < -60 && current_angles_y > 60)
1586                 delta = '0 360 0';
1587         if(mouse_angles_y > 60 && current_angles_y < -60)
1588                 delta = '0 -360 0';
1589
1590         if(autocvar_camera_look_player)
1591                 attenuation = autocvar_camera_look_attenuation;
1592         else
1593                 attenuation = autocvar_camera_speed_attenuation;
1594
1595         attenuation = 1 / max(1, attenuation);
1596         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1597
1598         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1599         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1600         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1601         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1602
1603         // Camera position
1604         tmp = '0 0 0';
1605         dimensions = 0;
1606
1607         if( camera_direction_x )
1608         {
1609                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1610                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1611                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1612                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1613                 ++dimensions;
1614         }
1615
1616         if( camera_direction_y )
1617         {
1618                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1619                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1620                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1621                 ++dimensions;
1622         }
1623
1624         if( camera_direction_z )
1625         {
1626                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1627                 ++dimensions;
1628         }
1629
1630         if(autocvar_camera_free)
1631                 speed = autocvar_camera_speed_free;
1632         else
1633                 speed = autocvar_camera_speed_chase;
1634
1635         if(dimensions)
1636         {
1637                 speed = speed * sqrt(1 / dimensions);
1638                 camera_offset += tmp * speed;
1639         }
1640
1641         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1642
1643         // Camera modes
1644         if( autocvar_camera_free )
1645         {
1646                 if ( camera_mode == CAMERA_CHASE )
1647                 {
1648                         current_camera_offset = current_origin + current_camera_offset;
1649                         camera_offset = current_origin + camera_offset;
1650                 }
1651
1652                 camera_mode = CAMERA_FREE;
1653                 current_position = current_camera_offset;
1654         }
1655         else
1656         {
1657                 if ( camera_mode == CAMERA_FREE )
1658                 {
1659                         current_origin = view_origin;
1660                         camera_offset = camera_offset - current_origin;
1661                         current_camera_offset = current_camera_offset - current_origin;
1662                 }
1663
1664                 camera_mode = CAMERA_CHASE;
1665
1666                 if(autocvar_camera_chase_smoothly)
1667                         current_origin += (view_origin - current_origin) * attenuation;
1668                 else
1669                         current_origin = view_origin;
1670
1671                 current_position = current_origin + current_camera_offset;
1672         }
1673
1674         setproperty(VF_ANGLES, current_angles);
1675         setproperty(VF_ORIGIN, current_position);
1676 }