qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 void CSQC_UpdateView(float w, float h)
 353 {
 354         entity e;
 355         float fov;
 356         float f, i, j;
 357         vector v, vo;
 358         vector vf_size, vf_min;
 359
 360         vf_size = R_SetView3fv(VF_SIZE);
 361         vf_min = R_SetView3fv(VF_MIN);
 362         vid_width = vf_size_x;
 363         vid_height = vf_size_y;
 364
 365         vector reticle_pos, reticle_size;
 366
 367         WaypointSprite_Load();
 368
 369         if(spectatee_status)
 370                 myteam = GetPlayerColor(spectatee_status - 1);
 371         else
 372                 myteam = GetPlayerColor(player_localentnum - 1);
 373
 374         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 375         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 376
 377         warpzone_fixview_origin = pmove_org + vo;
 378         warpzone_fixview_cl_viewangles = input_angles;
 379         warpzone_fixview_angles = view_angles;
 380         WarpZone_FixView();
 381         pmove_org = warpzone_fixview_origin - vo;
 382         input_angles = warpzone_fixview_cl_viewangles;
 383         view_angles = warpzone_fixview_angles;
 384
 385         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
 386         {
 387                 pmove_org = freeze_pmove_org;
 388                 input_angles = view_angles = freeze_input_angles;
 389                 R_SetView(VF_ORIGIN, pmove_org + vo);
 390                 R_SetView(VF_ANGLES, view_angles);
 391                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 392         }
 393         freeze_pmove_org = pmove_org;
 394         freeze_input_angles = input_angles;
 395
 396         // Render the Scene
 397         if(!intermission || !view_set)
 398         {
 399                 view_origin = pmove_org + vo;
 400                 view_angles = input_angles;
 401                 makevectors(view_angles);
 402                 view_forward = v_forward;
 403                 view_right = v_right;
 404                 view_up = v_up;
 405                 view_set = 1;
 406         }
 407
 408 #ifdef BLURTEST
 409         if(time > blurtest_time0 && time < blurtest_time1)
 410         {
 411                 float r, t;
 412
 413                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 414                 r = t * blurtest_radius;
 415                 f = 1 / pow(t, blurtest_power) - 1;
 416
 417                 cvar_set("r_glsl_postprocess", "1");
 418                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 419         }
 420         else
 421         {
 422                 cvar_set("r_glsl_postprocess", "0");
 423                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 424         }
 425 #endif
 426
 427         TargetMusic_Advance();
 428         Fog_Force();
 429
 430         drawframetime = max(0.000001, time - drawtime);
 431         drawtime = time;
 432
 433         // watch for gametype changes here...
 434         // in ParseStuffCMD the cmd isn't executed yet :/
 435         // might even be better to add the gametype to TE_CSQC_INIT...?
 436         if(!postinit)
 437                 PostInit();
 438
 439         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 440                 if(calledhooks & HOOK_START)
 441                 {
 442                         localcmd("\ncl_hook_gameend\n");
 443                         calledhooks |= HOOK_END;
 444                 }
 445
 446         CheckForGamestartChange();
 447         serverAnnouncer();
 448         maptimeAnnouncer();
 449         carrierAnnouncer();
 450
 451         fov = cvar("fov");
 452         if(button_zoom || fov <= 59.5)
 453         {
 454                 if(!zoomscript_caught)
 455                 {
 456                         localcmd("+button4\n");
 457                         zoomscript_caught = 1;
 458                         ignore_plus_zoom += 1;
 459                 }
 460         }
 461         else
 462         {
 463                 if(zoomscript_caught)
 464                 {
 465                         localcmd("-button4\n");
 466                         zoomscript_caught = 0;
 467                         ignore_minus_zoom += 1;
 468                 }
 469         }
 470
 471         ColorTranslateMode = cvar("cl_stripcolorcodes");
 472         activeweapon = getstati(STAT_SWITCHWEAPON);
 473         f = cvar("teamplay");
 474         if(f != teamplay)
 475         {
 476                 teamplay = f;
 477                 HUD_InitScores();
 478         }
 479
 480         if(last_weapon != activeweapon) {
 481                 weapontime = time;
 482                 last_weapon = activeweapon;
 483
 484                 e = get_weaponinfo(activeweapon);
 485                 if(e.netname != "")
 486                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 487                 else
 488                         localcmd("\ncl_hook_activeweapon none\n");
 489         }
 490
 491         // ALWAYS Clear Current Scene First
 492         R_ClearScene();
 493
 494         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 495         R_SetView(VF_SIZE, vf_size);
 496         R_SetView(VF_MIN, vf_min);
 497
 498         // Assign Standard Viewflags
 499         // Draw the World (and sky)
 500         R_SetView(VF_DRAWWORLD, 1);
 501
 502         // Set the console size vars
 503         vid_conwidth = cvar("vid_conwidth");
 504         vid_conheight = cvar("vid_conheight");
 505         vid_pixelheight = cvar("vid_pixelheight");
 506
 507         R_SetView(VF_FOV, GetCurrentFov(fov));
 508
 509         // Camera for demo playback
 510         if(camera_active)
 511         {
 512                 if(cvar("camera_enable"))
 513                         CSQC_Demo_Camera();
 514                 else
 515                 {
 516                         cvar_set("chase_active", ftos(chase_active_backup));
 517                         cvar_set("cl_demo_mousegrab", "0");
 518                         camera_active = FALSE;
 519                 }
 520         }
 521 #ifdef CAMERATEST
 522         else if(cvar("camera_enable"))
 523 #else
 524         else if(cvar("camera_enable") && isdemo())
 525 #endif
 526         {
 527                 // Enable required Darkplaces cvars
 528                 chase_active_backup = cvar("chase_active");
 529                 cvar_set("chase_active", "2");
 530                 cvar_set("cl_demo_mousegrab", "1");
 531                 camera_active = TRUE;
 532                 camera_mode = FALSE;
 533         }
 534
 535         // Draw the Crosshair
 536         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 537
 538         // Draw the Engine Status Bar (the default Quake HUD)
 539         R_SetView(VF_DRAWENGINEHUD, 0);
 540
 541         // fetch this one only once per frame
 542         hud_showbinds = cvar("hud_showbinds");
 543         hud_showbinds_limit = cvar("hud_showbinds_limit");
 544
 545         // Update the mouse position
 546         /*
 547            mousepos_x = vid_conwidth;
 548            mousepos_y = vid_conheight;
 549            mousepos = mousepos*0.5 + getmousepos();
 550          */
 551
 552         e = self;
 553         for(self = world; (self = nextent(self)); )
 554                 if(self.draw)
 555                         self.draw();
 556         self = e;
 557
 558         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 559         R_RenderScene();
 560
 561         // now switch to 2D drawing mode by calling a 2D drawing function
 562         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 563         // next R_RenderScene call
 564         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 565
 566         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright"))
 567         {
 568                 // apply night vision effect
 569                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 570                 float a;
 571
 572                 if(!nightvision_noise)
 573                 {
 574                         nightvision_noise = spawn();
 575                         nightvision_noise.classname = "nightvision_noise";
 576                 }
 577                 if(!nightvision_noise2)
 578                 {
 579                         nightvision_noise2 = spawn();
 580                         nightvision_noise2.classname = "nightvision_noise2";
 581                 }
 582
 583                 // color tint in yellow
 584                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 585
 586                 // draw BG
 587                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 588                 rgb = '1 1 1';
 589                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 590                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 591                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 592                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 593                 tc_11 = tc_01 + tc_10 - tc_00;
 594                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 595                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 596                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 597                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 598                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 599                 R_EndPolygon();
 600
 601                 // draw FG
 602                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 603                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 604                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 605                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 606                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 607                 tc_11 = tc_01 + tc_10 - tc_00;
 608                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 609                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 610                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 611                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 612                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 613                 R_EndPolygon();
 614         }
 615
 616         // Draw the aiming reticle for weapons that use it
 617         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 618         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 619         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 620         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 621                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 622         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 623                 reticle_type = 2; // nex zoom
 624         else if(button_zoom || zoomscript_caught)
 625                 reticle_type = 1; // normal zoom
 626         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 627                 reticle_type = 2; // nex zoom
 628
 629         if(cvar("cl_reticle_stretch"))
 630         {
 631                 reticle_size_x = vid_conwidth;
 632                 reticle_size_y = vid_conheight;
 633                 reticle_pos_x = 0;
 634                 reticle_pos_y = 0;
 635         }
 636         else
 637         {
 638                 reticle_size_x = max(vid_conwidth, vid_conheight);
 639                 reticle_size_y = max(vid_conwidth, vid_conheight);
 640                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 641                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 642         }
 643
 644         f = current_zoomfraction;
 645         if(zoomscript_caught)
 646                 f = 1;
 647         if(cvar("cl_reticle_item_normal"))
 648         {
 649                 precache_pic("gfx/reticle_normal");
 650                 if(reticle_type == 1 && f)
 651                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 652         }
 653         if(cvar("cl_reticle_item_nex"))
 654         {
 655                 precache_pic("gfx/reticle_nex");
 656                 if(reticle_type == 2 && f)
 657                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 658         }
 659
 660         // Draw the mouse cursor
 661         // NOTE: drawpic must happen after R_RenderScene for some reason
 662         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 663         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 664         //self = edict_num(player_localnum);
 665         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 666         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 667         // as long as the ctf part isn't in, this is useless
 668         if(menu_visible)
 669                 menu_show();
 670
 671         /*if(gametype == GAME_CTF)
 672           {
 673           ctf_view();
 674           } else */
 675
 676         // draw 2D entities
 677         e = self;
 678         for(self = world; (self = nextent(self)); )
 679                 if(self.draw2d)
 680                         self.draw2d();
 681         self = e;
 682
 683         scoreboard_active = HUD_WouldDrawScoreboard();
 684
 685         float hud;
 686         hud = getstati(STAT_HUD);
 687         if(hud == HUD_SPIDERBOT)
 688                 CSQC_SPIDER_HUD();
 689         else if(hud == HUD_WAKIZASHI)
 690         CSQC_WAKIZASHI_HUD();
 691     else if(hud == HUD_RAPTOR)
 692         CSQC_RAPTOR_HUD();
 693         else
 694         {
 695                 if(cvar("r_letterbox") == 0)
 696                         if(cvar("viewsize") < 120)
 697                                 CSQC_common_hud();
 698
 699                 // crosshair goes VERY LAST
 700                 if(!scoreboard_active && !camera_active && intermission != 2) {
 701                         string wcross_style;
 702                         float wcross_alpha, wcross_resolution;
 703                         wcross_style = cvar_string("crosshair");
 704                         if (wcross_style == "0")
 705                                 return;
 706                         wcross_resolution = cvar("crosshair_size");
 707                         if (wcross_resolution == 0)
 708                                 return;
 709                         wcross_alpha = cvar("crosshair_color_alpha");
 710                         if (wcross_alpha == 0)
 711                                 return;
 712
 713                         // TrueAim check
 714                         float shottype;
 715                         float bullets, ring_scale;
 716                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 717                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 718                         wcross_origin_z = 0;
 719                         if(cvar("crosshair_hittest"))
 720                         {
 721                                 vector wcross_oldorigin;
 722                                 wcross_oldorigin = wcross_origin;
 723                                 shottype = TrueAimCheck();
 724                                 if(shottype == SHOTTYPE_HITWORLD)
 725                                 {
 726                                         v = wcross_origin - wcross_oldorigin;
 727                                         v_x /= vid_conwidth;
 728                                         v_y /= vid_conheight;
 729                                         if(vlen(v) > 0.01)
 730                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 731                                 }
 732                                 if(!cvar("crosshair_hittest_showimpact"))
 733                                         wcross_origin = wcross_oldorigin;
 734                         }
 735                         else
 736                                 shottype = SHOTTYPE_HITWORLD;
 737
 738                         vector wcross_color, wcross_size;
 739                         string wcross_wep, wcross_name;
 740                         float wcross_scale, wcross_blur;
 741
 742                         wcross_color_x = cvar("crosshair_color_red");
 743                         wcross_color_y = cvar("crosshair_color_green");
 744                         wcross_color_z = cvar("crosshair_color_blue");
 745                         if (cvar("crosshair_per_weapon")) {
 746                                 e = get_weaponinfo(activeweapon);
 747                                 if (e && e.netname != "")
 748                                 {
 749                                         wcross_wep = e.netname;
 750                                         wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 751                                         if (wcross_resolution == 0)
 752                                                 return;
 753                                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 754                                         if (wcross_alpha == 0)
 755                                                 return;
 756
 757                                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 758                                         if(wcross_style == "")
 759                                                 wcross_style = e.netname;
 760
 761                                         if(!cvar("crosshair_color_override"))
 762                                         {
 763                                                 wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 764                                                 wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 765                                                 wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 766                                         }
 767                                 }
 768                         }
 769
 770                         wcross_name = strcat("gfx/crosshair", wcross_style);
 771
 772                         if(cvar("crosshair_effect_scalefade"))
 773                         {
 774                                 wcross_scale = wcross_resolution;
 775                                 wcross_resolution = 1;
 776                         }
 777                         else
 778                         {
 779                                 wcross_scale = 1;
 780                         }
 781
 782                         if(shottype == SHOTTYPE_HITENEMY)
 783                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 784                         else if(shottype == SHOTTYPE_HITTEAM)
 785                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 786
 787                         f = cvar("crosshair_effect_speed");
 788                         if(f < 0)
 789                                 f *= -2 * g_weaponswitchdelay;
 790                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 791                         {
 792                                 wcross_changedonetime = time + f;
 793                         }
 794                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 795                         {
 796                                 wcross_name_changestarttime = time;
 797                                 wcross_name_changedonetime = time + f;
 798                                 if(wcross_name_goal_prev_prev)
 799                                         strunzone(wcross_name_goal_prev_prev);
 800                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 801                                 wcross_name_goal_prev = strzone(wcross_name);
 802                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 803                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 804                                 wcross_resolution_goal_prev = wcross_resolution;
 805                         }
 806
 807                         wcross_scale_goal_prev = wcross_scale;
 808                         wcross_alpha_goal_prev = wcross_alpha;
 809                         wcross_color_goal_prev = wcross_color;
 810
 811                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 812                         {
 813                                 wcross_blur = 1;
 814                                 wcross_alpha *= 0.75;
 815                         }
 816                         else
 817                                 wcross_blur = 0;
 818                         // *_prev is at time-frametime
 819                         // * is at wcross_changedonetime+f
 820                         // what do we have at time?
 821                         if(time < wcross_changedonetime)
 822                         {
 823                                 f = frametime / (wcross_changedonetime - time + frametime);
 824                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 825                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 826                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 827                         }
 828
 829                         wcross_scale_prev = wcross_scale;
 830                         wcross_alpha_prev = wcross_alpha;
 831                         wcross_color_prev = wcross_color;
 832
 833                         wcross_scale *= 1 - cvar("_menu_alpha");
 834                         wcross_alpha *= 1 - cvar("_menu_alpha");
 835
 836                         ring_scale = cvar("crosshair_ring_size");
 837
 838                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 839
 840                         float nex_charge;
 841                         nex_charge = getstatf(STAT_NEX_CHARGE);
 842
 843                         // ring around crosshair representing bullets left in camping rifle clip
 844                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
 845                         {
 846                                 bullets = getstati(STAT_BULLETS_LOADED);
 847                                 f = bound(0, bullets / cr_maxbullets, 1);
 848
 849                                 a = cvar("crosshair_campingrifle_bulletcounter_alpha");
 850                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 851                         }
 852                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
 853                         {
 854                                 a = cvar("crosshair_nexvelocity_alpha");
 855                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 856                         }
 857
 858 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 859                         do \
 860                         { \
 861                                 if(wcross_blur > 0) \
 862                                 { \
 863                                         for(i = -2; i <= 2; ++i) \
 864                                                 for(j = -2; j <= 2; ++j) \
 865                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 866                                 } \
 867                                 else \
 868                                 { \
 869                                         M(0,0,sz,wcross_name,wcross_alpha); \
 870                                 } \
 871                         } \
 872                         while(0)
 873
 874 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 875                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 876
 877 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 878                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 879
 880                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 881                         {
 882                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 883                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 884                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 885                                 f = 1 - f;
 886                         }
 887                         else
 888                         {
 889                                 f = 1;
 890                         }
 891
 892                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 893                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 894
 895                         if(cvar("crosshair_dot"))
 896                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
 897
 898                         wcross_name_alpha_goal_prev = f;
 899                 }
 900                 else
 901                 {
 902                         wcross_scale_prev = 0;
 903                         wcross_alpha_prev = 0;
 904                         wcross_scale_goal_prev = 0;
 905                         wcross_alpha_goal_prev = 0;
 906                         wcross_changedonetime = 0;
 907                         if(wcross_name_goal_prev)
 908                                 strunzone(wcross_name_goal_prev);
 909                         wcross_name_goal_prev = string_null;
 910                         if(wcross_name_goal_prev_prev)
 911                                 strunzone(wcross_name_goal_prev_prev);
 912                         wcross_name_goal_prev_prev = string_null;
 913                         wcross_name_changestarttime = 0;
 914                         wcross_name_changedonetime = 0;
 915                         wcross_name_alpha_goal_prev = 0;
 916                         wcross_name_alpha_goal_prev_prev = 0;
 917                         wcross_resolution_goal_prev = 0;
 918                         wcross_resolution_goal_prev_prev = 0;
 919                 }
 920         }
 921
 922         if(NextFrameCommand)
 923         {
 924                 localcmd("\n", NextFrameCommand, "\n");
 925                 NextFrameCommand = string_null;
 926         }
 927
 928         // we must do this check AFTER a frame was rendered, or it won't work
 929         if(cs_project_is_b0rked == 0)
 930         {
 931                 string w0, h0;
 932                 w0 = cvar_string("vid_conwidth");
 933                 h0 = cvar_string("vid_conheight");
 934                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 935                 //R_SetView(VF_FOV, '90 90 0');
 936                 R_SetView(VF_ORIGIN, '0 0 0');
 937                 R_SetView(VF_ANGLES, '0 0 0');
 938                 R_SetView(VF_PERSPECTIVE, 1);
 939                 makevectors('0 0 0');
 940                 vector v1, v2;
 941                 cvar_set("vid_conwidth", "800");
 942                 cvar_set("vid_conheight", "600");
 943                 v1 = cs_project(v_forward);
 944                 cvar_set("vid_conwidth", "640");
 945                 cvar_set("vid_conheight", "480");
 946                 v2 = cs_project(v_forward);
 947                 if(v1 == v2)
 948                         cs_project_is_b0rked = 1;
 949                 else
 950                         cs_project_is_b0rked = -1;
 951                 cvar_set("vid_conwidth", w0);
 952                 cvar_set("vid_conheight", h0);
 953         }
 954
 955         if(autocvar__hud_configure)
 956                 HUD_Panel_Mouse();
 957
 958         // let's reset the view back to normal for the end
 959         R_SetView(VF_MIN, '0 0 0');
 960         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
 961 }
 962
 963 #define spider_h "gfx/vehicles/hud_bg.tga"
 964 #define spider_b "gfx/vehicles/sbot.tga"
 965 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 966 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 967 #define spider_s "gfx/vehicles/shiled.tga"
 968 #define spider_a1 "gfx/hud/sb_rocket.tga"
 969 #define spider_a2 "gfx/sb_bullets.tga"
 970
 971 void CSQC_SPIDER_HUD()
 972 {
 973         float rockets, reload, heat, hp, shield;
 974         vector picsize, hudloc;
 975
 976     // Fetch health & ammo stats
 977     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 978         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 979         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 980         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 981         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 982
 983     // Draw the crosshairs
 984     picsize = drawgetimagesize(SPIDER_CROSS);
 985     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 986     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 987     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 988
 989     hudloc_y =  4;
 990     hudloc_x = 4;
 991
 992     picsize = drawgetimagesize(spider_h) * 0.5;
 993     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 994
 995     picsize = drawgetimagesize(spider_a2) * 0.5;
 996     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 997
 998     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
 999     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1000     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1001
1002     picsize = drawgetimagesize(spider_a1) * 0.85;
1003     if(rockets == 9)
1004     {
1005         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1006         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1007     }
1008     else
1009     {
1010         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1011         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1012     }
1013
1014     picsize = drawgetimagesize(spider_b) * 0.5;
1015     hudloc_y = 10.5;
1016     hudloc_x = 10.5;
1017
1018     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1019     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1020     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1021     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1022
1023
1024         /*
1025         // Draw health bar
1026         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1027         p = p + '0 1 0' * vid_conheight - '0 32 0';
1028         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1029         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1030         p_y += 8;
1031         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1032         p_x += 256 * hp;
1033         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1034
1035         // Draw minigun heat indicator
1036         p = '0.5 0 0' * (vid_conwidth - 256);
1037         p = p + '0 1 0' * vid_conheight - '0 34  0';
1038         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1039         p_x += 256 * (1-heat);
1040         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1041
1042
1043         // Draw rocket icons for loaded/empty tubes.
1044         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1045         pp += '0 1 0' * vid_conheight - '0 64 0';
1046         for(i = 0; i < 8; ++i)
1047         {
1048                 p = pp + '1 0 0' * (rkt_size * i);
1049                 if(rockets == 8)
1050                 {
1051                         if(floor(reload * 8) == i)
1052                         {
1053                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1054                         }
1055                         else if(i < reload * 8)
1056                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1057                         else
1058                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1059                 }
1060                 else
1061                 {
1062                         if(i < rockets)
1063                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1064                         else
1065                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1066                 }
1067         }
1068         */
1069
1070         if (scoreboard_showscores)
1071         {
1072                 HUD_DrawScoreboard();
1073                 HUD_DrawCenterPrint();
1074         }
1075
1076 }
1077
1078 #define raptor_h "gfx/vehicles/hud_bg.tga"
1079 #define raptor_b "gfx/vehicles/raptor.tga"
1080 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1081 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1082 #define raptor_s "gfx/vehicles/shiled.tga"
1083
1084 void CSQC_RAPTOR_HUD()
1085 {
1086         float rockets, reload, heat, hp, shield, energy;
1087         vector picsize, hudloc;
1088
1089     // Fetch health & ammo stats
1090     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1091         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1092         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1093         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1094
1095     // Draw the crosshairs
1096     picsize = drawgetimagesize(SPIDER_CROSS);
1097     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1098     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1099     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1100
1101     hudloc_y =  4;
1102     hudloc_x = 4;
1103
1104     picsize = drawgetimagesize(raptor_h) * 0.5;
1105     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1106
1107     picsize = drawgetimagesize(spider_a2) * 0.5;
1108     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1109
1110     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1111     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1112     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1113
1114
1115     picsize = drawgetimagesize(spider_a1) * 0.85;
1116     if(reload == 1)
1117     {
1118         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1119         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1120     }
1121     else
1122     {
1123         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1124         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1125     }
1126
1127     picsize = drawgetimagesize(raptor_b) * 0.5;
1128     hudloc_y = 10.5;
1129     hudloc_x = 10.5;
1130
1131     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1132     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1133     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1134     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1135
1136
1137         if (scoreboard_showscores)
1138         {
1139                 HUD_DrawScoreboard();
1140                 HUD_DrawCenterPrint();
1141         }
1142
1143 }
1144
1145 #define waki_h "gfx/vehicles/hud_bg.tga"
1146 #define waki_b "gfx/vehicles/waki.tga"
1147 #define waki_e "gfx/vehicles/waki_e.tga"
1148 #define waki_g "gfx/vehicles/waki_guns.tga"
1149 #define waki_r "gfx/vehicles/waki_rockets.tga"
1150 #define waki_s "gfx/vehicles/shiled.tga"
1151
1152 #define waki_a1 "gfx/hud/sb_rocket.tga"
1153 #define waki_a2 "gfx/sb_cells.tga"
1154
1155 void CSQC_WAKIZASHI_HUD()
1156 {
1157         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1158         float health, shield, energy, rockets;
1159         vector picsize, hudloc;
1160
1161     picsize = drawgetimagesize(SPIDER_CROSS);
1162     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1163     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1164     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1165
1166 /*
1167 const float STAT_VEHICLESTAT_HEALTH  = 60;
1168 const float STAT_VEHICLESTAT_SHIELD  = 61;
1169 const float STAT_VEHICLESTAT_ENERGY  = 62;
1170 const float STAT_VEHICLESTAT_AMMO1   = 63;
1171 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1172 const float STAT_VEHICLESTAT_AMMO2   = 65;
1173 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1174 */
1175     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1176         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1177         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1178         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1179
1180     hudloc_y =  4;
1181     hudloc_x = 4;
1182
1183     picsize = drawgetimagesize(waki_h) * 0.5;
1184     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1185
1186     picsize = drawgetimagesize(waki_a2) * 0.7;
1187     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1188
1189
1190     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1191     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1192
1193     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1194
1195     picsize = drawgetimagesize(waki_a1) * 0.75;
1196     if(rockets == 1)
1197     {
1198         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1199         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1200     }
1201     else
1202     {
1203         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1204         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1205         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1206     }
1207
1208     picsize = drawgetimagesize(waki_b) * 0.5;
1209     hudloc_y = 10.5;
1210     hudloc_x = 10.5;
1211
1212     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1213     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1214     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1215     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1216
1217
1218
1219         /*
1220         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1221         p = p + '0 1 0' * vid_conheight - '0 32 0';
1222
1223         // Draw health bar
1224         p_y += 8;
1225         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1226         p_x += 256 * health;
1227         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1228
1229         // Draw shiled bar
1230         p_x -= 256 * health;
1231         p_y += 4;
1232         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1233
1234         // Draw energy
1235         //p_x -= 256 * health;
1236         p_y -= 8;
1237         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1238
1239         // Draw rockets bar
1240         p_y += 12;
1241         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1242         */
1243
1244
1245
1246
1247         if (scoreboard_showscores)
1248         {
1249                 HUD_DrawScoreboard();
1250                 HUD_DrawCenterPrint();
1251         }
1252
1253 }
1254
1255
1256 void CSQC_common_hud(void)
1257 {
1258         // HUD_SortFrags(); done in HUD_Draw
1259         float hud;
1260         hud = getstati(STAT_HUD);
1261
1262         //hud = 10;
1263         switch(hud)
1264         {
1265                 case HUD_NORMAL:
1266                         // do some accuracy var caching
1267                         float i;
1268                         if(cvar_string("hud_panel_weapons_accuracy_color_levels") != acc_color_levels)
1269                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1270                         {
1271                                 if(acc_color_levels)
1272                                         strunzone(acc_color_levels);
1273                                 acc_color_levels = strzone(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1274                                 acc_levels = tokenize(acc_color_levels);
1275                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1276                                         acc_levels = MAX_ACCURACY_LEVELS;
1277
1278                                 for (i = 0; i < acc_levels; ++i)
1279                                         acc_lev[i] = stof(argv(i));
1280                         }
1281
1282                         HUD_Main(); // always run these functions for alpha checks
1283                         HUD_DrawScoreboard();
1284
1285                         if (scoreboard_active) // scoreboard/accuracy
1286                         {
1287                                 HUD_Reset();
1288                                 // HUD_DrawScoreboard takes care of centerprint_start
1289                         }
1290                         else if (intermission == 2) // map voting screen
1291                         {
1292                                 HUD_FinaleOverlay();
1293                                 HUD_Reset();
1294
1295                                 centerprint_start_x = 0;
1296                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1297                         }
1298                         else // hud
1299                         {
1300                                 centerprint_start_x = 0;
1301                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1302                         }
1303
1304                         HUD_DrawCenterPrint();
1305                         break;
1306
1307                 case HUD_SPIDERBOT:
1308                         CSQC_SPIDER_HUD();
1309                         break;
1310
1311                 case HUD_WAKIZASHI:
1312                         CSQC_WAKIZASHI_HUD();
1313                         break;
1314         }
1315 }
1316
1317
1318 // following vectors must be global to allow seamless switching between camera modes
1319 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1320 void CSQC_Demo_Camera()
1321 {
1322         float speed, attenuation, dimensions;
1323         vector tmp, delta;
1324
1325         if( cvar("camera_reset") || !camera_mode )
1326         {
1327                 camera_offset = '0 0 0';
1328                 current_angles = '0 0 0';
1329                 camera_direction = '0 0 0';
1330                 camera_offset_z += 30;
1331                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1332                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1333                 current_origin = view_origin;
1334                 current_camera_offset  = camera_offset;
1335                 cvar_set("camera_reset", "0");
1336                 camera_mode = CAMERA_CHASE;
1337         }
1338
1339         // Camera angles
1340         if( camera_roll )
1341                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1342
1343         if(cvar("camera_look_player"))
1344         {
1345                 local vector dir;
1346                 local float n;
1347
1348                 dir = normalize(view_origin - current_position);
1349                 n = mouse_angles_z;
1350                 mouse_angles = vectoangles(dir);
1351                 mouse_angles_x = mouse_angles_x * -1;
1352                 mouse_angles_z = n;
1353         }
1354         else
1355         {
1356                 tmp = getmousepos() * 0.1;
1357                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1358                 {
1359                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1360                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1361                 }
1362         }
1363
1364         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1365         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1366         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1367         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1368
1369         // Fix difference when angles don't have the same sign
1370         delta = '0 0 0';
1371         if(mouse_angles_y < -60 && current_angles_y > 60)
1372                 delta = '0 360 0';
1373         if(mouse_angles_y > 60 && current_angles_y < -60)
1374                 delta = '0 -360 0';
1375
1376         if(cvar("camera_look_player"))
1377                 attenuation = cvar("camera_look_attenuation");
1378         else
1379                 attenuation = cvar("camera_speed_attenuation");
1380
1381         attenuation = 1 / max(1, attenuation);
1382         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1383
1384         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1385         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1386         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1387         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1388
1389         // Camera position
1390         tmp = '0 0 0';
1391         dimensions = 0;
1392
1393         if( camera_direction_x )
1394         {
1395                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1396                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1397                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1398                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1399                 ++dimensions;
1400         }
1401
1402         if( camera_direction_y )
1403         {
1404                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1405                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1406                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1407                 ++dimensions;
1408         }
1409
1410         if( camera_direction_z )
1411         {
1412                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1413                 ++dimensions;
1414         }
1415
1416         if(cvar("camera_free"))
1417                 speed = cvar("camera_speed_free");
1418         else
1419                 speed = cvar("camera_speed_chase");
1420
1421         if(dimensions)
1422         {
1423                 speed = speed * sqrt(1 / dimensions);
1424                 camera_offset += tmp * speed;
1425         }
1426
1427         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1428
1429         // Camera modes
1430         if( cvar("camera_free") )
1431         {
1432                 if ( camera_mode == CAMERA_CHASE )
1433                 {
1434                         current_camera_offset = current_origin + current_camera_offset;
1435                         camera_offset = current_origin + camera_offset;
1436                 }
1437
1438                 camera_mode = CAMERA_FREE;
1439                 current_position = current_camera_offset;
1440         }
1441         else
1442         {
1443                 if ( camera_mode == CAMERA_FREE )
1444                 {
1445                         current_origin = view_origin;
1446                         camera_offset = camera_offset - current_origin;
1447                         current_camera_offset = current_camera_offset - current_origin;
1448                 }
1449
1450                 camera_mode = CAMERA_CHASE;
1451
1452                 if(cvar("camera_chase_smoothly"))
1453                         current_origin += (view_origin - current_origin) * attenuation;
1454                 else
1455                         current_origin = view_origin;
1456
1457                 current_position = current_origin + current_camera_offset;
1458         }
1459
1460         R_SetView(VF_ANGLES, current_angles);
1461         R_SetView(VF_ORIGIN, current_position);
1462 }