986a338e402368268c5edb8cfe406013f8f1be8e
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 entity porto;
2 vector polyline[16];
3 float trace_dphitcontents;
4 float trace_networkentity;
5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
6 float DPCONTENTS_SOLID = 1; // blocks player movement
7 float DPCONTENTS_BODY = 32; // blocks player movement
8 float DPCONTENTS_CORPSE = 64; // blocks player movement
9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
10 void Porto_Draw()
11 {
12         vector p, dir, ang, q, nextdir;
13         float idx, portal_number, portal1_idx;
14
15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
16                 return;
17         if(intermission == 1)
18                 return;
19         if(intermission == 2)
20                 return;
21         if (getstati(STAT_HEALTH) <= 0)
22                 return;
23
24         dir = view_forward;
25
26         if(angles_held_status)
27         {
28                 makevectors(angles_held);
29                 dir = v_forward;
30         }
31
32         p = view_origin;
33
34         polyline[0] = p;
35         idx = 1;
36         portal_number = 0;
37         nextdir = dir;
38
39         for(;;)
40         {
41                 dir = nextdir;
42                 traceline(p, p + 65536 * dir, TRUE, porto);
43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
44                         return;
45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
46                 p = trace_endpos;
47                 polyline[idx] = p;
48                 ++idx;
49                 if(idx >= 16)
50                         return;
51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
52                         continue;
53                 ++portal_number;
54                 ang = vectoangles2(trace_plane_normal, dir);
55                 ang_x = -ang_x;
56                 makevectors(ang);
57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
58                         return;
59                 if(portal_number == 1)
60                         portal1_idx = idx;
61                 if(portal_number >= 2)
62                         break;
63         }
64
65         while(idx >= 2)
66         {
67                 p = polyline[idx-2];
68                 q = polyline[idx-1];
69                 if(idx == 2)
70                         p = p - view_up * 16;
71                 if(idx-1 >= portal1_idx)
72                 {
73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
74                 }
75                 else
76                 {
77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
78                 }
79                 --idx;
80         }
81 }
82
83 /**
84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
85  *
86  * TODO: Use a better solution where a common shared entitiy is used that contains
87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
88  * and STAT_FRAGLIMIT to be auto-sent)
89  */
90 void CheckForGamestartChange() {
91         float startTime;
92         startTime = getstatf(STAT_GAMESTARTTIME);
93         if (previous_game_starttime != startTime) {
94                 if ((time + 5.0) < startTime) {
95                         //if connecting to server while restart was active don't always play prepareforbattle
96                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
97                 }
98                 if (time < startTime) {
99                         restartAnnouncer = spawn();
100                         restartAnnouncer.think = restartAnnouncer_Think;
101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
102                 }
103         }
104         previous_game_starttime = startTime;
105 }
106
107 void Porto_Init()
108 {
109         porto = spawn();
110         porto.classname = "porto";
111         porto.draw = Porto_Draw;
112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
113 }
114
115 float drawtime;
116 float avgspeed;
117 vector GetCurrentFov(float fov)
118 {
119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
120
121         zoomsensitivity = autocvar_cl_zoomsensitivity;
122         zoomfactor = autocvar_cl_zoomfactor;
123         if(zoomfactor < 1 || zoomfactor > 16)
124                 zoomfactor = 2.5;
125         zoomspeed = autocvar_cl_zoomspeed;
126         if(zoomspeed >= 0)
127                 if(zoomspeed < 0.5 || zoomspeed > 16)
128                         zoomspeed = 3.5;
129
130         zoomdir = button_zoom;
131         if(hud == HUD_NORMAL)
132         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
133                 zoomdir += button_attack2;
134         if(spectatee_status > 0 || isdemo())
135         {
136                 if(spectatorbutton_zoom)
137                         zoomdir = 0 + !zoomdir;
138                 // do not even THINK about removing this 0
139                 // _I_ know what I am doing
140                 // fteqcc does not
141         }
142
143         if(zoomdir)
144                 zoomin_effect = 0;
145
146         if(zoomin_effect || camera_active)
147         {
148                 current_viewzoom = min(1, current_viewzoom + drawframetime);
149         }
150         else
151         {
152                 if(zoomspeed < 0) // instant zoom
153                 {
154                         if(zoomdir)
155                                 current_viewzoom = 1 / zoomfactor;
156                         else
157                                 current_viewzoom = 1;
158                 }
159                 else
160                 {
161                         if(zoomdir)
162                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
163                         else
164                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
165                 }
166         }
167
168         if(almost_equals(current_viewzoom, 1))
169                 current_zoomfraction = 0;
170         else if(almost_equals(current_viewzoom, 1/zoomfactor))
171                 current_zoomfraction = 1;
172         else
173                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
174
175         if(zoomsensitivity < 1)
176                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
177         else
178                 setsensitivityscale(1);
179
180         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
181         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
182         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
183
184         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
185
186         float frustumx, frustumy, fovx, fovy;
187         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
188         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
189         fovx = atan2(frustumx, 1) / M_PI * 360.0;
190         fovy = atan2(frustumy, 1) / M_PI * 360.0;
191
192         return '1 0 0' * fovx + '0 1 0' * fovy;
193 }
194
195 // this function must match W_SetupShot!
196 float zoomscript_caught;
197
198 vector wcross_origin;
199 float wcross_scale_prev, wcross_alpha_prev;
200 vector wcross_color_prev;
201 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
202 vector wcross_color_goal_prev;
203 float wcross_changedonetime;
204
205 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
206 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
207 float wcross_name_changestarttime, wcross_name_changedonetime;
208 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
209 entity trueaim;
210 entity trueaim_rifle;
211
212 #define SHOTTYPE_HITTEAM 1
213 #define SHOTTYPE_HITOBSTRUCTION 2
214 #define SHOTTYPE_HITWORLD 3
215 #define SHOTTYPE_HITENEMY 4
216
217 void TrueAim_Init()
218 {
219         trueaim = spawn();
220         trueaim.classname = "trueaim";
221         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
222         trueaim_rifle = spawn();
223         trueaim_rifle.classname = "trueaim_rifle";
224         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
225 }
226
227 float EnemyHitCheck()
228 {
229         float t;
230         wcross_origin = project_3d_to_2d(trace_endpos);
231         wcross_origin_z = 0;
232         if(trace_networkentity < 1)
233                 return SHOTTYPE_HITWORLD;
234         if(trace_networkentity > maxclients)
235                 return SHOTTYPE_HITWORLD;
236         t = GetPlayerColor(trace_networkentity - 1);
237         if(teamplay)
238                 if(t == myteam)
239                         return SHOTTYPE_HITTEAM;
240         if(t == COLOR_SPECTATOR)
241                 return SHOTTYPE_HITWORLD;
242         return SHOTTYPE_HITENEMY;
243 }
244
245 float TrueAimCheck()
246 {
247         float nudge = 1; // added to traceline target and subtracted from result
248         vector vecs, trueaimpoint, w_shotorg;
249         vector mi, ma, dv;
250         float shottype;
251         entity ta;
252         float mv;
253
254         mi = ma = '0 0 0';
255         ta = trueaim;
256         mv = MOVE_NOMONSTERS;
257
258         switch(activeweapon)
259         {
260                 case WEP_TUBA: // no aim
261                 case WEP_PORTO: // shoots from eye
262                 case WEP_HOOK: // no trueaim
263                 case WEP_GRENADE_LAUNCHER: // toss curve
264                         return SHOTTYPE_HITWORLD;
265                 case WEP_NEX:
266                 case WEP_MINSTANEX:
267                         mv = MOVE_NORMAL;
268                         break;
269                 case WEP_RIFLE:
270                         ta = trueaim_rifle;
271                         mv = MOVE_NORMAL;
272                         if(zoomscript_caught)
273                         {
274                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
275                                 return EnemyHitCheck();
276                         }
277                         break;
278                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
279                         mi = '-3 -3 -3';
280                         ma = '3 3 3';
281                         break;
282                 case WEP_FIREBALL: // projectile has a size!
283                         mi = '-16 -16 -16';
284                         ma = '16 16 16';
285                         break;
286                 case WEP_SEEKER: // projectile has a size!
287                         mi = '-2 -2 -2';
288                         ma = '2 2 2';
289                         break;
290                 case WEP_ELECTRO: // projectile has a size!
291                         mi = '0 0 -3';
292                         ma = '0 0 -3';
293                         break;
294         }
295
296         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
297
298         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
299         trueaimpoint = trace_endpos;
300
301         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
302                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
303
304         if(vecs_x > 0)
305                 vecs_y = -vecs_y;
306         else
307                 vecs = '0 0 0';
308
309         dv = view_right * vecs_y + view_up * vecs_z;
310         w_shotorg = view_origin + dv;
311
312         // now move the vecs forward as much as requested if possible
313         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
314         w_shotorg = trace_endpos - view_forward * nudge;
315
316         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
317         shottype = EnemyHitCheck();
318         if(shottype != SHOTTYPE_HITWORLD)
319                 return shottype;
320
321 #if 0
322         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
323         // or rather, I know why, but see no fix
324         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
325                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
326                 return SHOTTYPE_HITOBSTRUCTION;
327 #endif
328
329         return SHOTTYPE_HITWORLD;
330 }
331
332 void CSQC_common_hud(void);
333
334 void PostInit(void);
335 void CSQC_Demo_Camera();
336 float HUD_WouldDrawScoreboard();
337 float camera_mode;
338 float reticle_type;
339 string NextFrameCommand;
340 void CSQC_SPIDER_HUD();
341 void CSQC_RAPTOR_HUD();
342
343 vector freeze_org, freeze_ang;
344 entity nightvision_noise, nightvision_noise2;
345
346 float pickup_crosshair_time, pickup_crosshair_size;
347 float hit_time, typehit_time;
348 float nextsound_hit_time, nextsound_typehit_time;
349 float hitindication_crosshair_time, hitindication_crosshair_size;
350 float use_nex_chargepool;
351
352 float myhealth, myhealth_prev;
353 float myhealth_flash;
354
355 float old_blurradius, old_bluralpha;
356 float old_sharpen_intensity;
357
358 vector myhealth_gentlergb;
359
360 float contentavgalpha, liquidalpha_prev;
361 vector liquidcolor_prev;
362
363 float eventchase_current_distance;
364
365 vector damage_blurpostprocess, content_blurpostprocess;
366
367 float checkfail[16];
368
369 void CSQC_UpdateView(float w, float h)
370 {
371         entity e;
372         float fov;
373         float f, i, j;
374         vector v;
375         vector vf_size, vf_min;
376         float a;
377         hud = getstati(STAT_HUD);
378
379         button_attack2 = (input_buttons & BUTTON_3);
380         button_zoom = (input_buttons & BUTTON_4);
381
382 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
383         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
384         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
385         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
386         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
387         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
388         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
389
390         vf_size = R_SetView3fv(VF_SIZE);
391         vf_min = R_SetView3fv(VF_MIN);
392         vid_width = vf_size_x;
393         vid_height = vf_size_y;
394
395         vector reticle_pos, reticle_size;
396         vector splash_pos, splash_size;
397
398         WaypointSprite_Load();
399
400         if(spectatee_status)
401                 myteam = GetPlayerColor(spectatee_status - 1);
402         else
403                 myteam = GetPlayerColor(player_localentnum - 1);
404
405         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
406
407         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
408         {
409                 R_SetView(VF_ORIGIN, freeze_org);
410                 R_SetView(VF_ANGLES, freeze_ang);
411         }
412         else
413         {
414                 freeze_org = R_SetView3fv(VF_ORIGIN);
415                 freeze_ang = R_SetView3fv(VF_ANGLES);
416         }
417
418         // event chase camera
419         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
420         {
421                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
422                 {
423                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
424                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
425                         if(!autocvar_chase_active)
426                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
427
428                         // make the camera smooth back
429                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
430                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
431                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
432                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
433
434                         vector eventchase_target_origin;
435                         makevectors(view_angles);
436                         // pass 1, used to check where the camera would go and obtain the trace_fraction
437                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
438
439                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
440                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
441                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
442                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
443                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
444
445                         R_SetView(VF_ORIGIN, trace_endpos);
446                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
447                 }
448                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
449                 {
450                         cvar_set("chase_active", "0");
451                         eventchase_current_distance = 0; // start from 0 next time
452                 }
453         }
454
455         WarpZone_FixView();
456         //WarpZone_FixPMove();
457
458         // Render the Scene
459         view_origin = R_SetView3fv(VF_ORIGIN);
460         view_angles = R_SetView3fv(VF_ANGLES);
461         makevectors(view_angles);
462         view_forward = v_forward;
463         view_right = v_right;
464         view_up = v_up;
465
466 #ifdef BLURTEST
467         if(time > blurtest_time0 && time < blurtest_time1)
468         {
469                 float r, t;
470
471                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
472                 r = t * blurtest_radius;
473                 f = 1 / pow(t, blurtest_power) - 1;
474
475                 cvar_set("r_glsl_postprocess", "1");
476                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
477         }
478         else
479         {
480                 cvar_set("r_glsl_postprocess", "0");
481                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
482         }
483 #endif
484
485         TargetMusic_Advance();
486         Fog_Force();
487
488         if(drawtime == 0)
489                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
490         else
491                 drawframetime = bound(0.000001, time - drawtime, 1);
492         drawtime = time;
493
494         // watch for gametype changes here...
495         // in ParseStuffCMD the cmd isn't executed yet :/
496         // might even be better to add the gametype to TE_CSQC_INIT...?
497         if(!postinit)
498                 PostInit();
499
500         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
501                 if(calledhooks & HOOK_START)
502                 {
503                         localcmd("\ncl_hook_gameend\n");
504                         calledhooks |= HOOK_END;
505                 }
506
507         CheckForGamestartChange();
508         serverAnnouncer();
509         maptimeAnnouncer();
510         carrierAnnouncer();
511
512         fov = autocvar_fov;
513         if(fov <= 59.5)
514         {
515                 if(!zoomscript_caught)
516                 {
517                         localcmd("+button9\n");
518                         zoomscript_caught = 1;
519                 }
520         }
521         else
522         {
523                 if(zoomscript_caught)
524                 {
525                         localcmd("-button9\n");
526                         zoomscript_caught = 0;
527                 }
528         }
529
530         ColorTranslateMode = autocvar_cl_stripcolorcodes;
531         activeweapon = getstati(STAT_SWITCHWEAPON);
532         f = (serverflags & SERVERFLAG_TEAMPLAY);
533         if(f != teamplay)
534         {
535                 teamplay = f;
536                 HUD_InitScores();
537         }
538
539         if(last_weapon != activeweapon) {
540                 weapontime = time;
541                 last_weapon = activeweapon;
542
543                 e = get_weaponinfo(activeweapon);
544                 if(e.netname != "")
545                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
546                 else
547                         localcmd("\ncl_hook_activeweapon none\n");
548         }
549
550         // ALWAYS Clear Current Scene First
551         R_ClearScene();
552 #ifdef WORKAROUND_XON010
553         if(checkextension("DP_CSQC_ROTATEMOVES"))
554         {
555 #endif
556         R_SetView(VF_ORIGIN, view_origin);
557         R_SetView(VF_ANGLES, view_angles);
558 #ifdef WORKAROUND_XON010
559         }
560 #endif
561
562         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
563         R_SetView(VF_SIZE, vf_size);
564         R_SetView(VF_MIN, vf_min);
565
566         // Assign Standard Viewflags
567         // Draw the World (and sky)
568         R_SetView(VF_DRAWWORLD, 1);
569
570         // Set the console size vars
571         vid_conwidth = autocvar_vid_conwidth;
572         vid_conheight = autocvar_vid_conheight;
573         vid_pixelheight = autocvar_vid_pixelheight;
574
575         R_SetView(VF_FOV, GetCurrentFov(fov));
576
577         // Camera for demo playback
578         if(camera_active)
579         {
580                 if(autocvar_camera_enable)
581                         CSQC_Demo_Camera();
582                 else
583                 {
584                         cvar_set("chase_active", ftos(chase_active_backup));
585                         cvar_set("cl_demo_mousegrab", "0");
586                         camera_active = FALSE;
587                 }
588         }
589 #ifdef CAMERATEST
590         else if(autocvar_camera_enable)
591 #else
592         else if(autocvar_camera_enable && isdemo())
593 #endif
594         {
595                 // Enable required Darkplaces cvars
596                 chase_active_backup = autocvar_chase_active;
597                 cvar_set("chase_active", "2");
598                 cvar_set("cl_demo_mousegrab", "1");
599                 camera_active = TRUE;
600                 camera_mode = FALSE;
601         }
602
603         // Draw the Crosshair
604         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
605
606         // Draw the Engine Status Bar (the default Quake HUD)
607         R_SetView(VF_DRAWENGINEHUD, 0);
608
609         // Update the mouse position
610         /*
611            mousepos_x = vid_conwidth;
612            mousepos_y = vid_conheight;
613            mousepos = mousepos*0.5 + getmousepos();
614          */
615
616         e = self;
617         for(self = world; (self = nextent(self)); )
618                 if(self.draw)
619                         self.draw();
620         self = e;
621
622         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
623         R_RenderScene();
624
625         // now switch to 2D drawing mode by calling a 2D drawing function
626         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
627         // next R_RenderScene call
628         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
629
630         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
631         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
632         {
633                 // apply night vision effect
634                 vector rgb, tc_00, tc_01, tc_10, tc_11;
635
636                 if(!nightvision_noise)
637                 {
638                         nightvision_noise = spawn();
639                         nightvision_noise.classname = "nightvision_noise";
640                 }
641                 if(!nightvision_noise2)
642                 {
643                         nightvision_noise2 = spawn();
644                         nightvision_noise2.classname = "nightvision_noise2";
645                 }
646
647                 // color tint in yellow
648                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
649
650                 // draw BG
651                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
652                 rgb = '1 1 1';
653                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
654                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
655                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
656                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
657                 tc_11 = tc_01 + tc_10 - tc_00;
658                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
659                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
660                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
661                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
662                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
663                 R_EndPolygon();
664
665                 // draw FG
666                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
667                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
668                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
669                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
670                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
671                 tc_11 = tc_01 + tc_10 - tc_00;
672                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
673                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
674                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
675                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
676                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
677                 R_EndPolygon();
678         }
679         
680         // Draw the aiming reticle for weapons that use it
681         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
682         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
683         // the view to go back to normal, so reticle_type would become 0 as we fade out)
684         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
685                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
686         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
687                 reticle_type = 2; // nex zoom
688         else if(button_zoom || zoomscript_caught)
689                 reticle_type = 1; // normal zoom
690         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
691                 reticle_type = 2; // nex zoom
692     
693         if (reticle_type)
694         {
695                 if(autocvar_cl_reticle_stretch)
696                 {
697                         reticle_size_x = vid_conwidth;
698                         reticle_size_y = vid_conheight;
699                         reticle_pos_x = 0;
700                         reticle_pos_y = 0;
701                 }
702                 else
703                 {
704                         reticle_size_x = max(vid_conwidth, vid_conheight);
705                         reticle_size_y = max(vid_conwidth, vid_conheight);
706                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
707                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
708                 }
709
710                 f = current_zoomfraction;
711                 if(zoomscript_caught)
712                         f = 1;
713                 if(autocvar_cl_reticle_item_normal)
714                 {
715                         if(reticle_type == 1 && f)
716                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
717                 }
718                 if(autocvar_cl_reticle_item_nex)
719                 {
720                         if(reticle_type == 2 && f)
721                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
722                 }
723         }
724
725
726         // improved polyblend
727         vector rgb;
728         if(autocvar_hud_contents)
729         {
730                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
731                 vector liquidcolor;
732
733                 switch(pointcontents(view_origin))
734                 {
735                         case CONTENT_WATER:
736                                 liquidalpha = autocvar_hud_contents_water_alpha;
737                                 liquidcolor = stov(autocvar_hud_contents_water_color);
738                                 incontent = 1;
739                                 break;
740
741                         case CONTENT_LAVA:
742                                 liquidalpha = autocvar_hud_contents_lava_alpha;
743                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
744                                 incontent = 1;
745                                 break;
746
747                         case CONTENT_SLIME:
748                                 liquidalpha = autocvar_hud_contents_slime_alpha;
749                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
750                                 incontent = 1;
751                                 break;
752
753                         default:
754                                 liquidalpha = 0;
755                                 liquidcolor = '0 0 0';
756                                 incontent = 0;
757                                 break;
758                 }
759
760                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
761                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
762                         contentfadetime = autocvar_hud_contents_fadeintime;
763                         liquidalpha_prev = liquidalpha;
764                         liquidcolor_prev = liquidcolor;
765                 }
766                 else
767                         contentfadetime = autocvar_hud_contents_fadeouttime;
768
769                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
770                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
771
772                 if(contentavgalpha)
773                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
774
775                 if(autocvar_hud_postprocessing)
776                 {
777                         if(autocvar_hud_contents_blur && contentavgalpha)
778                         {
779                                 content_blurpostprocess_x = 1;
780                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
781                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
782                         }
783                         else
784                         {
785                                 content_blurpostprocess_x = 0;
786                                 content_blurpostprocess_y = 0;
787                                 content_blurpostprocess_z = 0;
788                         }
789                 }
790         }
791         
792         if(autocvar_hud_damage && !autocvar_chase_active)
793
794         {
795                 splash_size_x = max(vid_conwidth, vid_conheight);
796                 splash_size_y = max(vid_conwidth, vid_conheight);
797                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
798                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
799
800                 float myhealth_flash_temp;
801                 myhealth = getstati(STAT_HEALTH);
802
803                 // fade out
804                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
805                 // add new damage
806                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
807
808                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
809                 pain_threshold = autocvar_hud_damage_pain_threshold;
810                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
811                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
812
813                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
814                 {
815                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
816                 }
817
818                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
819
820                 if(myhealth_prev < 1)
821                 {
822                         if(myhealth >= 1)
823                         {
824                                 myhealth_flash = 0; // just spawned, clear the flash immediately
825                                 myhealth_flash_temp = 0;
826                         }
827                         else
828                         {
829                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
830                         }
831                 }
832
833                 if(spectatee_status == -1 || intermission)
834                 {
835                         myhealth_flash = 0; // observing, or match ended
836                         myhealth_flash_temp = 0;
837                 }
838
839                 myhealth_prev = myhealth;
840
841                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
842                 {
843                         if(autocvar_cl_gentle_damage == 2)
844                         {
845                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
846                                 {
847                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
848                                 }
849                         }
850                         else
851                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
852
853                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
854                 }
855                 else
856                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
857
858                 if(autocvar_hud_postprocessing)
859                 {
860                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
861                         {
862                                 damage_blurpostprocess_x = 1;
863                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
864                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
865                         }
866                         else
867                         {
868                                 damage_blurpostprocess_x = 0;
869                                 damage_blurpostprocess_y = 0;
870                                 damage_blurpostprocess_z = 0;
871                         }
872                 }
873         }
874
875         if(autocvar_hud_postprocessing)
876         {
877                 // all of this should be done in the engine eventually
878
879                 // enable or disable rendering types if they are used or not
880                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
881                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
882                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
883                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
884
885                 // lets apply the postprocess effects from the previous two functions if needed
886                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
887                 {
888                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
889                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
890                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
891                         {
892                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
893                                 old_blurradius = blurradius;
894                                 old_bluralpha = bluralpha;
895                         }
896                 }
897                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
898                 {
899                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
900                         old_blurradius = 0;
901                         old_bluralpha = 0;
902                 }
903
904                 float sharpen_intensity;
905                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
906                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
907                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
908                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
909
910                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
911                 {
912                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
913
914                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
915                         {
916                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
917                                 old_sharpen_intensity = sharpen_intensity;
918                         }
919                 }
920                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
921                 {
922                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
923                         old_sharpen_intensity = 0;
924                 }
925         }
926
927         if(menu_visible)
928                 menu_show();
929
930         /*if(gametype == GAME_CTF)
931           {
932           ctf_view();
933           } else */
934
935         // draw 2D entities
936         e = self;
937         for(self = world; (self = nextent(self)); )
938                 if(self.draw2d)
939                         self.draw2d();
940         self = e;
941         Draw_ShowNames_All();
942
943         scoreboard_active = HUD_WouldDrawScoreboard();
944
945         hit_time = getstatf(STAT_HIT_TIME);
946         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
947         {
948                 sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
949                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
950         }
951         typehit_time = getstatf(STAT_TYPEHIT_TIME);
952         if(typehit_time > nextsound_typehit_time)
953         {
954                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
955                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
956         }
957
958         //else
959         {
960                 if(gametype == GAME_FREEZETAG)
961                 {
962                         if(getstati(STAT_FROZEN))
963                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
964                         if(getstatf(STAT_REVIVE_PROGRESS))
965                         {
966                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
967                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
968                         }
969                 }
970
971                 if(autocvar_r_letterbox == 0)
972                         if(autocvar_viewsize < 120)
973                                 CSQC_common_hud();
974
975                 // crosshair goes VERY LAST
976                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
977                         string wcross_style;
978                         float wcross_alpha, wcross_resolution;
979                         wcross_style = autocvar_crosshair;
980                         if (wcross_style == "0")
981                                 return;
982                         wcross_resolution = autocvar_crosshair_size;
983                         if (wcross_resolution == 0)
984                                 return;
985                         wcross_alpha = autocvar_crosshair_alpha;
986                         if (wcross_alpha == 0)
987                                 return;
988
989                         // TrueAim check
990                         float shottype;
991
992                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
993                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
994                         wcross_origin_z = 0;
995                         if(autocvar_crosshair_hittest)
996                         {
997                                 vector wcross_oldorigin;
998                                 wcross_oldorigin = wcross_origin;
999                                 shottype = TrueAimCheck();
1000                                 if(shottype == SHOTTYPE_HITWORLD)
1001                                 {
1002                                         v = wcross_origin - wcross_oldorigin;
1003                                         v_x /= vid_conwidth;
1004                                         v_y /= vid_conheight;
1005                                         if(vlen(v) > 0.01)
1006                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1007                                 }
1008                                 if(!autocvar_crosshair_hittest_showimpact)
1009                                         wcross_origin = wcross_oldorigin;
1010                         }
1011                         else
1012                                 shottype = SHOTTYPE_HITWORLD;
1013
1014                         vector wcross_color, wcross_size;
1015                         string wcross_wep, wcross_name;
1016                         float wcross_scale, wcross_blur;
1017
1018                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1019                                 e = get_weaponinfo(activeweapon);
1020                                 if (e && e.netname != "")
1021                                 {
1022                                         wcross_wep = e.netname;
1023                                         if(autocvar_crosshair_per_weapon)
1024                                         {
1025                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1026                                                 if (wcross_resolution == 0)
1027                                                         return;
1028                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1029                                                 if (wcross_alpha == 0)
1030                                                         return;
1031
1032                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1033                                                 if(wcross_style == "" || wcross_style == "0")
1034                                                         wcross_style = wcross_wep;
1035                                         }
1036                                 }
1037                         }
1038                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1039                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1040                         else if(autocvar_crosshair_color_by_health)
1041                         {
1042                                 local float x = getstati(STAT_HEALTH);
1043
1044                                 //x = red
1045                                 //y = green
1046                                 //z = blue
1047
1048                                 wcross_color_z = 0;
1049
1050                                 if(x > 200)
1051                                 {
1052                                         wcross_color_x = 0;
1053                                         wcross_color_y = 1;
1054                                 }
1055                                 else if(x > 150)
1056                                 {
1057                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1058                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1059                                 }
1060                                 else if(x > 100)
1061                                 {
1062                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1063                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1064                                         wcross_color_z = 1 - (x-100)*0.02;
1065                                 }
1066                                 else if(x > 50)
1067                                 {
1068                                         wcross_color_x = 1;
1069                                         wcross_color_y = 1;
1070                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1071                                 }
1072                                 else if(x > 20)
1073                                 {
1074                                         wcross_color_x = 1;
1075                                         wcross_color_y = (x-20)*90/27/100;
1076                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1077                                 }
1078                                 else
1079                                 {
1080                                         wcross_color_x = 1;
1081                                         wcross_color_y = 0;
1082                                 }
1083                         }
1084                         else
1085                                 wcross_color = stov(autocvar_crosshair_color);
1086
1087                         wcross_name = strcat("gfx/crosshair", wcross_style);
1088
1089                         if(autocvar_crosshair_effect_scalefade)
1090                         {
1091                                 wcross_scale = wcross_resolution;
1092                                 wcross_resolution = 1;
1093                         }
1094                         else
1095                         {
1096                                 wcross_scale = 1;
1097                         }
1098
1099                         if(autocvar_crosshair_pickup)
1100                         {
1101                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1102                                 {
1103                                         pickup_crosshair_size = 1;
1104                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1105                                 }
1106
1107                                 if(pickup_crosshair_size > 0)
1108                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1109                                 else
1110                                         pickup_crosshair_size = 0;
1111
1112                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1113                         }
1114
1115                         vector hitindication_color;
1116                         if(autocvar_crosshair_hitindication)
1117                         {
1118                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1119                                 if(hitindication_crosshair_time < hit_time)
1120                                 {
1121                                         hitindication_crosshair_size = 1;
1122                                         hitindication_crosshair_time = hit_time;
1123                                 }
1124
1125                                 if(hitindication_crosshair_size > 0)
1126                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1127                                 else
1128                                         hitindication_crosshair_size = 0;
1129
1130                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1131                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1132                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1133                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1134                         }
1135
1136                         if(shottype == SHOTTYPE_HITENEMY)
1137                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1138                         if(shottype == SHOTTYPE_HITTEAM)
1139                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1140
1141                         f = autocvar_crosshair_effect_speed;
1142                         if(f < 0)
1143                                 f *= -2 * g_weaponswitchdelay;
1144                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1145                         {
1146                                 wcross_changedonetime = time + f;
1147                         }
1148                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1149                         {
1150                                 wcross_name_changestarttime = time;
1151                                 wcross_name_changedonetime = time + f;
1152                                 if(wcross_name_goal_prev_prev)
1153                                         strunzone(wcross_name_goal_prev_prev);
1154                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1155                                 wcross_name_goal_prev = strzone(wcross_name);
1156                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1157                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1158                                 wcross_resolution_goal_prev = wcross_resolution;
1159                         }
1160
1161                         wcross_scale_goal_prev = wcross_scale;
1162                         wcross_alpha_goal_prev = wcross_alpha;
1163                         wcross_color_goal_prev = wcross_color;
1164
1165                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1166                         {
1167                                 wcross_blur = 1;
1168                                 wcross_alpha *= 0.75;
1169                         }
1170                         else
1171                                 wcross_blur = 0;
1172                         // *_prev is at time-frametime
1173                         // * is at wcross_changedonetime+f
1174                         // what do we have at time?
1175                         if(time < wcross_changedonetime)
1176                         {
1177                                 f = frametime / (wcross_changedonetime - time + frametime);
1178                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1179                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1180                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1181                         }
1182
1183                         wcross_scale_prev = wcross_scale;
1184                         wcross_alpha_prev = wcross_alpha;
1185                         wcross_color_prev = wcross_color;
1186
1187                         wcross_scale *= 1 - autocvar__menu_alpha;
1188                         wcross_alpha *= 1 - autocvar__menu_alpha;
1189                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1190
1191                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1192                         {
1193                                 // crosshair rings for weapon stats
1194                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1195                                 {
1196                                         // declarations and stats
1197                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1198                                         string ring_image, ring_inner_image;
1199                                         vector ring_rgb, ring_inner_rgb;
1200
1201                                         ring_scale = autocvar_crosshair_ring_size;
1202
1203                                         float weapon_clipload, weapon_clipsize;
1204                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1205                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1206
1207                                         float nex_charge, nex_chargepool;
1208                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1209                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1210
1211                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1212                                                 nex_charge_movingavg = nex_charge;
1213
1214
1215                                         // handle the values
1216                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1217                                         {
1218                                                 if (nex_chargepool || use_nex_chargepool) { 
1219                                                         use_nex_chargepool = 1; 
1220                                                         ring_inner_value = nex_chargepool;
1221                                                 } else { 
1222                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1223                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1); 
1224                                                 }
1225
1226                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1227                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1228                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1229
1230                                                 // draw the outer ring to show the current charge of the weapon
1231                                                 ring_value = nex_charge;
1232                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1233                                                 ring_rgb = wcross_color;
1234                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1235                                         }
1236                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer) 
1237                                         {
1238                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1239                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1240                                                 ring_rgb = wcross_color;
1241                                                 ring_image = "gfx/crosshair_ring.tga";
1242                                         }
1243                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1244                                         {
1245                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1246                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1247                                                 ring_rgb = wcross_color;
1248                                                 ring_image = "gfx/crosshair_ring.tga";
1249                                         }
1250
1251                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring 
1252                                         {
1253                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1254                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1255                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1256                                                 ring_rgb = wcross_color;
1257
1258                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1259                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1260                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1261                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1262                                                 else
1263                                                         ring_image = "gfx/crosshair_ring.tga";
1264                                         }
1265
1266                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1267                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1268
1269                                         if (ring_value)
1270                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1271                                 }
1272
1273 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1274                                 do \
1275                                 { \
1276                                         if(wcross_blur > 0) \
1277                                         { \
1278                                                 for(i = -2; i <= 2; ++i) \
1279                                                 for(j = -2; j <= 2; ++j) \
1280                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1281                                         } \
1282                                         else \
1283                                         { \
1284                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1285                                         } \
1286                                 } \
1287                                 while(0)
1288
1289 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1290                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1291
1292 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1293                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1294
1295                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1296                                 {
1297                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1298                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1299                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1300                                         f = 1 - f;
1301                                 }
1302                                 else
1303                                 {
1304                                         f = 1;
1305                                 }
1306                                 wcross_name_alpha_goal_prev = f;
1307
1308                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1309                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1310
1311                                 if(autocvar_crosshair_dot)
1312                                 {
1313                                         vector wcross_color_old;
1314                                         wcross_color_old = wcross_color;
1315                                         if(autocvar_crosshair_dot_color != "0")
1316                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1317                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1318                                         // FIXME why don't we use wcross_alpha here?
1319                                         wcross_color = wcross_color_old;
1320                                 }
1321                         }
1322                 }
1323                 else
1324                 {
1325                         wcross_scale_prev = 0;
1326                         wcross_alpha_prev = 0;
1327                         wcross_scale_goal_prev = 0;
1328                         wcross_alpha_goal_prev = 0;
1329                         wcross_changedonetime = 0;
1330                         if(wcross_name_goal_prev)
1331                                 strunzone(wcross_name_goal_prev);
1332                         wcross_name_goal_prev = string_null;
1333                         if(wcross_name_goal_prev_prev)
1334                                 strunzone(wcross_name_goal_prev_prev);
1335                         wcross_name_goal_prev_prev = string_null;
1336                         wcross_name_changestarttime = 0;
1337                         wcross_name_changedonetime = 0;
1338                         wcross_name_alpha_goal_prev = 0;
1339                         wcross_name_alpha_goal_prev_prev = 0;
1340                         wcross_resolution_goal_prev = 0;
1341                         wcross_resolution_goal_prev_prev = 0;
1342                 }
1343         }
1344
1345         if(NextFrameCommand)
1346         {
1347                 localcmd("\n", NextFrameCommand, "\n");
1348                 NextFrameCommand = string_null;
1349         }
1350
1351         // we must do this check AFTER a frame was rendered, or it won't work
1352         if(cs_project_is_b0rked == 0)
1353         {
1354                 string w0, h0;
1355                 w0 = ftos(autocvar_vid_conwidth);
1356                 h0 = ftos(autocvar_vid_conheight);
1357                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1358                 //R_SetView(VF_FOV, '90 90 0');
1359                 R_SetView(VF_ORIGIN, '0 0 0');
1360                 R_SetView(VF_ANGLES, '0 0 0');
1361                 R_SetView(VF_PERSPECTIVE, 1);
1362                 makevectors('0 0 0');
1363                 vector v1, v2;
1364                 cvar_set("vid_conwidth", "800");
1365                 cvar_set("vid_conheight", "600");
1366                 v1 = cs_project(v_forward);
1367                 cvar_set("vid_conwidth", "640");
1368                 cvar_set("vid_conheight", "480");
1369                 v2 = cs_project(v_forward);
1370                 if(v1 == v2)
1371                         cs_project_is_b0rked = 1;
1372                 else
1373                         cs_project_is_b0rked = -1;
1374                 cvar_set("vid_conwidth", w0);
1375                 cvar_set("vid_conheight", h0);
1376         }
1377
1378         if(autocvar__hud_configure)
1379                 HUD_Panel_Mouse();
1380     
1381     if(hud && !intermission)
1382     {        
1383         if(hud == HUD_SPIDERBOT)
1384             CSQC_SPIDER_HUD();
1385         else if(hud == HUD_WAKIZASHI)
1386             CSQC_WAKIZASHI_HUD();
1387         else if(hud == HUD_RAPTOR)
1388             CSQC_RAPTOR_HUD();
1389         else if(hud == HUD_BUMBLEBEE)
1390             CSQC_BUMBLE_HUD();
1391     }
1392         // let's reset the view back to normal for the end
1393         R_SetView(VF_MIN, '0 0 0');
1394         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1395 }
1396
1397
1398 void CSQC_common_hud(void)
1399 {
1400     // do some accuracy var caching
1401     float i;
1402     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1403     {
1404         if(autocvar_accuracy_color_levels != acc_color_levels)
1405         {
1406             if(acc_color_levels)
1407                 strunzone(acc_color_levels);
1408             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1409             acc_levels = tokenize(acc_color_levels);
1410             if (acc_levels > MAX_ACCURACY_LEVELS)
1411                 acc_levels = MAX_ACCURACY_LEVELS;
1412
1413             for (i = 0; i < acc_levels; ++i)
1414                 acc_lev[i] = stof(argv(i)) / 100.0;
1415         }
1416         // let know that acc_col[] needs to be loaded
1417         acc_col_x[0] = -1;
1418     }
1419
1420     HUD_Main(); // always run these functions for alpha checks
1421     HUD_DrawScoreboard();
1422
1423     if (scoreboard_active) // scoreboard/accuracy
1424         HUD_Reset();
1425     else if (intermission == 2) // map voting screen
1426     {
1427         HUD_FinaleOverlay();
1428         HUD_Reset();
1429     }
1430         /*
1431         switch(hud)
1432         {
1433                 case HUD_SPIDERBOT:
1434                         CSQC_SPIDER_HUD();
1435                         break;
1436
1437                 case HUD_WAKIZASHI:
1438                         CSQC_WAKIZASHI_HUD();
1439                         break;
1440
1441         case HUD_BUMBLEBEE:
1442             CSQC_BUMBLE_HUD();
1443             break;
1444         }
1445         */
1446 }
1447
1448
1449 // following vectors must be global to allow seamless switching between camera modes
1450 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1451 void CSQC_Demo_Camera()
1452 {
1453         float speed, attenuation, dimensions;
1454         vector tmp, delta;
1455
1456         if( autocvar_camera_reset || !camera_mode )
1457         {
1458                 camera_offset = '0 0 0';
1459                 current_angles = '0 0 0';
1460                 camera_direction = '0 0 0';
1461                 camera_offset_z += 30;
1462                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1463                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1464                 current_origin = view_origin;
1465                 current_camera_offset  = camera_offset;
1466                 cvar_set("camera_reset", "0");
1467                 camera_mode = CAMERA_CHASE;
1468         }
1469
1470         // Camera angles
1471         if( camera_roll )
1472                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1473
1474         if(autocvar_camera_look_player)
1475         {
1476                 local vector dir;
1477                 local float n;
1478
1479                 dir = normalize(view_origin - current_position);
1480                 n = mouse_angles_z;
1481                 mouse_angles = vectoangles(dir);
1482                 mouse_angles_x = mouse_angles_x * -1;
1483                 mouse_angles_z = n;
1484         }
1485         else
1486         {
1487                 tmp = getmousepos() * 0.1;
1488                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1489                 {
1490                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1491                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1492                 }
1493         }
1494
1495         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1496         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1497         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1498         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1499
1500         // Fix difference when angles don't have the same sign
1501         delta = '0 0 0';
1502         if(mouse_angles_y < -60 && current_angles_y > 60)
1503                 delta = '0 360 0';
1504         if(mouse_angles_y > 60 && current_angles_y < -60)
1505                 delta = '0 -360 0';
1506
1507         if(autocvar_camera_look_player)
1508                 attenuation = autocvar_camera_look_attenuation;
1509         else
1510                 attenuation = autocvar_camera_speed_attenuation;
1511
1512         attenuation = 1 / max(1, attenuation);
1513         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1514
1515         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1516         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1517         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1518         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1519
1520         // Camera position
1521         tmp = '0 0 0';
1522         dimensions = 0;
1523
1524         if( camera_direction_x )
1525         {
1526                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1527                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1528                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1529                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1530                 ++dimensions;
1531         }
1532
1533         if( camera_direction_y )
1534         {
1535                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1536                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1537                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1538                 ++dimensions;
1539         }
1540
1541         if( camera_direction_z )
1542         {
1543                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1544                 ++dimensions;
1545         }
1546
1547         if(autocvar_camera_free)
1548                 speed = autocvar_camera_speed_free;
1549         else
1550                 speed = autocvar_camera_speed_chase;
1551
1552         if(dimensions)
1553         {
1554                 speed = speed * sqrt(1 / dimensions);
1555                 camera_offset += tmp * speed;
1556         }
1557
1558         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1559
1560         // Camera modes
1561         if( autocvar_camera_free )
1562         {
1563                 if ( camera_mode == CAMERA_CHASE )
1564                 {
1565                         current_camera_offset = current_origin + current_camera_offset;
1566                         camera_offset = current_origin + camera_offset;
1567                 }
1568
1569                 camera_mode = CAMERA_FREE;
1570                 current_position = current_camera_offset;
1571         }
1572         else
1573         {
1574                 if ( camera_mode == CAMERA_FREE )
1575                 {
1576                         current_origin = view_origin;
1577                         camera_offset = camera_offset - current_origin;
1578                         current_camera_offset = current_camera_offset - current_origin;
1579                 }
1580
1581                 camera_mode = CAMERA_CHASE;
1582
1583                 if(autocvar_camera_chase_smoothly)
1584                         current_origin += (view_origin - current_origin) * attenuation;
1585                 else
1586                         current_origin = view_origin;
1587
1588                 current_position = current_origin + current_camera_offset;
1589         }
1590
1591         R_SetView(VF_ANGLES, current_angles);
1592         R_SetView(VF_ORIGIN, current_position);
1593 }