qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125                 if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir)
 145                 zoomin_effect = 0;
 146
 147         if(zoomin_effect || camera_active)
 148         {
 149                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 150         }
 151         else
 152         {
 153                 if(zoomspeed < 0) // instant zoom
 154                 {
 155                         if(zoomdir)
 156                                 current_viewzoom = 1 / zoomfactor;
 157                         else
 158                                 current_viewzoom = 1;
 159                 }
 160                 else
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 164                         else
 165                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 166                 }
 167         }
 168
 169         if(almost_equals(current_viewzoom, 1))
 170                 current_zoomfraction = 0;
 171         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 172                 current_zoomfraction = 1;
 173         else
 174                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 175
 176         if(zoomsensitivity < 1)
 177                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 178         else
 179                 setsensitivityscale(1);
 180
 181         if (autocvar_cl_velocityzoom)
 182         {
 183                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 184                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 185                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 186                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 187         }
 188         else
 189                 velocityzoom = 1;
 190
 191         float frustumx, frustumy, fovx, fovy;
 192         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 193         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 194         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 195         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 196
 197         return '1 0 0' * fovx + '0 1 0' * fovy;
 198 }
 199
 200 // this function must match W_SetupShot!
 201 float zoomscript_caught;
 202
 203 vector wcross_origin;
 204 float wcross_scale_prev, wcross_alpha_prev;
 205 vector wcross_color_prev;
 206 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 207 vector wcross_color_goal_prev;
 208 float wcross_changedonetime;
 209
 210 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 211 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 212 float wcross_name_changestarttime, wcross_name_changedonetime;
 213 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 214 entity trueaim;
 215 entity trueaim_rifle;
 216
 217 #define SHOTTYPE_HITTEAM 1
 218 #define SHOTTYPE_HITOBSTRUCTION 2
 219 #define SHOTTYPE_HITWORLD 3
 220 #define SHOTTYPE_HITENEMY 4
 221
 222 void TrueAim_Init()
 223 {
 224         trueaim = spawn();
 225         trueaim.classname = "trueaim";
 226         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 227         trueaim_rifle = spawn();
 228         trueaim_rifle.classname = "trueaim_rifle";
 229         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230 }
 231
 232 float EnemyHitCheck()
 233 {
 234         float t;
 235         wcross_origin = project_3d_to_2d(trace_endpos);
 236         wcross_origin_z = 0;
 237         if(trace_networkentity < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(trace_networkentity > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(trace_networkentity - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 float pickup_crosshair_time, pickup_crosshair_size;
 352 float hit_time, typehit_time;
 353 float nextsound_hit_time, nextsound_typehit_time;
 354 float hitindication_crosshair_time, hitindication_crosshair_size;
 355 float use_nex_chargepool;
 356
 357 float myhealth, myhealth_prev;
 358 float myhealth_flash;
 359
 360 float old_blurradius, old_bluralpha;
 361 float old_sharpen_intensity;
 362
 363 vector myhealth_gentlergb;
 364
 365 float contentavgalpha, liquidalpha_prev;
 366 vector liquidcolor_prev;
 367
 368 float eventchase_current_distance;
 369
 370 vector damage_blurpostprocess, content_blurpostprocess;
 371
 372 float checkfail[16];
 373
 374 void CSQC_UpdateView(float w, float h)
 375 {
 376         entity e;
 377         float fov;
 378         float f, i, j;
 379         vector v;
 380         vector vf_size, vf_min;
 381         float a;
 382         hud = getstati(STAT_HUD);
 383
 384         button_attack2 = (input_buttons & BUTTON_3);
 385         button_zoom = (input_buttons & BUTTON_4);
 386
 387         // FIXME do we need this hack?
 388         if(isdemo())
 389         {
 390                 // in demos, input_buttons do not work
 391                 button_zoom = (autocvar__togglezoom == "-");
 392         }
 393
 394 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 395         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 396         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 397         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 398         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 399         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 400         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 401
 402         vf_size = R_SetView3fv(VF_SIZE);
 403         vf_min = R_SetView3fv(VF_MIN);
 404         vid_width = vf_size_x;
 405         vid_height = vf_size_y;
 406
 407         vector reticle_pos, reticle_size;
 408         vector splash_pos, splash_size;
 409
 410         WaypointSprite_Load();
 411
 412         if(spectatee_status)
 413                 myteam = GetPlayerColor(spectatee_status - 1);
 414         else
 415                 myteam = GetPlayerColor(player_localentnum - 1);
 416
 417         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 418
 419         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 420         {
 421                 R_SetView(VF_ORIGIN, freeze_org);
 422                 R_SetView(VF_ANGLES, freeze_ang);
 423         }
 424         else
 425         {
 426                 freeze_org = R_SetView3fv(VF_ORIGIN);
 427                 freeze_ang = R_SetView3fv(VF_ANGLES);
 428         }
 429
 430         // event chase camera
 431         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 432         {
 433                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 434                 {
 435                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 436                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 437                         if(!autocvar_chase_active)
 438                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 439
 440                         // make the camera smooth back
 441                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 442                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 443                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 444                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 445
 446                         vector eventchase_target_origin;
 447                         makevectors(view_angles);
 448                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 449                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 450
 451                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 452                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 453                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 454                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 455                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 456
 457                         R_SetView(VF_ORIGIN, trace_endpos);
 458                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 459                 }
 460                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 461                 {
 462                         cvar_set("chase_active", "0");
 463                         eventchase_current_distance = 0; // start from 0 next time
 464                 }
 465         }
 466
 467         WarpZone_FixView();
 468         //WarpZone_FixPMove();
 469
 470         // Render the Scene
 471         view_origin = R_SetView3fv(VF_ORIGIN);
 472         view_angles = R_SetView3fv(VF_ANGLES);
 473         makevectors(view_angles);
 474         view_forward = v_forward;
 475         view_right = v_right;
 476         view_up = v_up;
 477
 478 #ifdef BLURTEST
 479         if(time > blurtest_time0 && time < blurtest_time1)
 480         {
 481                 float r, t;
 482
 483                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 484                 r = t * blurtest_radius;
 485                 f = 1 / pow(t, blurtest_power) - 1;
 486
 487                 cvar_set("r_glsl_postprocess", "1");
 488                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 489         }
 490         else
 491         {
 492                 cvar_set("r_glsl_postprocess", "0");
 493                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 494         }
 495 #endif
 496
 497         TargetMusic_Advance();
 498         Fog_Force();
 499
 500         if(drawtime == 0)
 501                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 502         else
 503                 drawframetime = bound(0.000001, time - drawtime, 1);
 504         drawtime = time;
 505
 506         // watch for gametype changes here...
 507         // in ParseStuffCMD the cmd isn't executed yet :/
 508         // might even be better to add the gametype to TE_CSQC_INIT...?
 509         if(!postinit)
 510                 PostInit();
 511
 512         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 513                 if(calledhooks & HOOK_START)
 514                 {
 515                         localcmd("\ncl_hook_gameend\n");
 516                         calledhooks |= HOOK_END;
 517                 }
 518
 519         CheckForGamestartChange();
 520         serverAnnouncer();
 521         maptimeAnnouncer();
 522         carrierAnnouncer();
 523
 524         fov = autocvar_fov;
 525         if(fov <= 59.5)
 526         {
 527                 if(!zoomscript_caught)
 528                 {
 529                         localcmd("+button9\n");
 530                         zoomscript_caught = 1;
 531                 }
 532         }
 533         else
 534         {
 535                 if(zoomscript_caught)
 536                 {
 537                         localcmd("-button9\n");
 538                         zoomscript_caught = 0;
 539                 }
 540         }
 541
 542         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 543         activeweapon = getstati(STAT_SWITCHWEAPON);
 544         f = (serverflags & SERVERFLAG_TEAMPLAY);
 545         if(f != teamplay)
 546         {
 547                 teamplay = f;
 548                 HUD_InitScores();
 549         }
 550
 551         if(last_weapon != activeweapon) {
 552                 weapontime = time;
 553                 last_weapon = activeweapon;
 554
 555                 e = get_weaponinfo(activeweapon);
 556                 if(e.netname != "")
 557                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 558                 else
 559                         localcmd("\ncl_hook_activeweapon none\n");
 560         }
 561
 562         // ALWAYS Clear Current Scene First
 563         R_ClearScene();
 564 #ifdef WORKAROUND_XON010
 565         if(checkextension("DP_CSQC_ROTATEMOVES"))
 566         {
 567 #endif
 568         R_SetView(VF_ORIGIN, view_origin);
 569         R_SetView(VF_ANGLES, view_angles);
 570 #ifdef WORKAROUND_XON010
 571         }
 572 #endif
 573
 574         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 575         R_SetView(VF_SIZE, vf_size);
 576         R_SetView(VF_MIN, vf_min);
 577
 578         // Assign Standard Viewflags
 579         // Draw the World (and sky)
 580         R_SetView(VF_DRAWWORLD, 1);
 581
 582         // Set the console size vars
 583         vid_conwidth = autocvar_vid_conwidth;
 584         vid_conheight = autocvar_vid_conheight;
 585         vid_pixelheight = autocvar_vid_pixelheight;
 586
 587         R_SetView(VF_FOV, GetCurrentFov(fov));
 588
 589         // Camera for demo playback
 590         if(camera_active)
 591         {
 592                 if(autocvar_camera_enable)
 593                         CSQC_Demo_Camera();
 594                 else
 595                 {
 596                         cvar_set("chase_active", ftos(chase_active_backup));
 597                         cvar_set("cl_demo_mousegrab", "0");
 598                         camera_active = FALSE;
 599                 }
 600         }
 601 #ifdef CAMERATEST
 602         else if(autocvar_camera_enable)
 603 #else
 604         else if(autocvar_camera_enable && isdemo())
 605 #endif
 606         {
 607                 // Enable required Darkplaces cvars
 608                 chase_active_backup = autocvar_chase_active;
 609                 cvar_set("chase_active", "2");
 610                 cvar_set("cl_demo_mousegrab", "1");
 611                 camera_active = TRUE;
 612                 camera_mode = FALSE;
 613         }
 614
 615         // Draw the Crosshair
 616         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 617
 618         // Draw the Engine Status Bar (the default Quake HUD)
 619         R_SetView(VF_DRAWENGINEHUD, 0);
 620
 621         // Update the mouse position
 622         /*
 623            mousepos_x = vid_conwidth;
 624            mousepos_y = vid_conheight;
 625            mousepos = mousepos*0.5 + getmousepos();
 626          */
 627
 628         e = self;
 629         for(self = world; (self = nextent(self)); )
 630                 if(self.draw)
 631                         self.draw();
 632         self = e;
 633
 634         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 635         R_RenderScene();
 636
 637         // now switch to 2D drawing mode by calling a 2D drawing function
 638         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 639         // next R_RenderScene call
 640         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 641
 642         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 643         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 644         {
 645                 // apply night vision effect
 646                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 647
 648                 if(!nightvision_noise)
 649                 {
 650                         nightvision_noise = spawn();
 651                         nightvision_noise.classname = "nightvision_noise";
 652                 }
 653                 if(!nightvision_noise2)
 654                 {
 655                         nightvision_noise2 = spawn();
 656                         nightvision_noise2.classname = "nightvision_noise2";
 657                 }
 658
 659                 // color tint in yellow
 660                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 661
 662                 // draw BG
 663                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 664                 rgb = '1 1 1';
 665                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 666                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 667                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 668                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 669                 tc_11 = tc_01 + tc_10 - tc_00;
 670                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 671                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 672                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 673                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 674                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 675                 R_EndPolygon();
 676
 677                 // draw FG
 678                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 679                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 680                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 681                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 682                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 683                 tc_11 = tc_01 + tc_10 - tc_00;
 684                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 685                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 686                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 687                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 688                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 689                 R_EndPolygon();
 690         }
 691
 692         // Draw the aiming reticle for weapons that use it
 693         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 694         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 695         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 696         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 697                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 698         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 699                 reticle_type = 2; // nex zoom
 700         else if(button_zoom || zoomscript_caught)
 701                 reticle_type = 1; // normal zoom
 702         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 703                 reticle_type = 2; // nex zoom
 704
 705         if (reticle_type)
 706         {
 707                 if(autocvar_cl_reticle_stretch)
 708                 {
 709                         reticle_size_x = vid_conwidth;
 710                         reticle_size_y = vid_conheight;
 711                         reticle_pos_x = 0;
 712                         reticle_pos_y = 0;
 713                 }
 714                 else
 715                 {
 716                         reticle_size_x = max(vid_conwidth, vid_conheight);
 717                         reticle_size_y = max(vid_conwidth, vid_conheight);
 718                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 719                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 720                 }
 721
 722                 f = current_zoomfraction;
 723                 if(zoomscript_caught)
 724                         f = 1;
 725                 if(autocvar_cl_reticle_item_normal)
 726                 {
 727                         if(reticle_type == 1 && f)
 728                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 729                 }
 730                 if(autocvar_cl_reticle_item_nex)
 731                 {
 732                         if(reticle_type == 2 && f)
 733                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 734                 }
 735         }
 736
 737
 738         // improved polyblend
 739         vector rgb;
 740         if(autocvar_hud_contents)
 741         {
 742                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 743                 vector liquidcolor;
 744
 745                 switch(pointcontents(view_origin))
 746                 {
 747                         case CONTENT_WATER:
 748                                 liquidalpha = autocvar_hud_contents_water_alpha;
 749                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 750                                 incontent = 1;
 751                                 break;
 752
 753                         case CONTENT_LAVA:
 754                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 755                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 756                                 incontent = 1;
 757                                 break;
 758
 759                         case CONTENT_SLIME:
 760                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 761                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 762                                 incontent = 1;
 763                                 break;
 764
 765                         default:
 766                                 liquidalpha = 0;
 767                                 liquidcolor = '0 0 0';
 768                                 incontent = 0;
 769                                 break;
 770                 }
 771
 772                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 773                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 774                         contentfadetime = autocvar_hud_contents_fadeintime;
 775                         liquidalpha_prev = liquidalpha;
 776                         liquidcolor_prev = liquidcolor;
 777                 }
 778                 else
 779                         contentfadetime = autocvar_hud_contents_fadeouttime;
 780
 781                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 782                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 783
 784                 if(contentavgalpha)
 785                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 786
 787                 if(autocvar_hud_postprocessing)
 788                 {
 789                         if(autocvar_hud_contents_blur && contentavgalpha)
 790                         {
 791                                 content_blurpostprocess_x = 1;
 792                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 793                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 794                         }
 795                         else
 796                         {
 797                                 content_blurpostprocess_x = 0;
 798                                 content_blurpostprocess_y = 0;
 799                                 content_blurpostprocess_z = 0;
 800                         }
 801                 }
 802         }
 803
 804         if(autocvar_hud_damage && !autocvar_chase_active)
 805
 806         {
 807                 splash_size_x = max(vid_conwidth, vid_conheight);
 808                 splash_size_y = max(vid_conwidth, vid_conheight);
 809                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 810                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 811
 812                 float myhealth_flash_temp;
 813                 myhealth = getstati(STAT_HEALTH);
 814
 815                 // fade out
 816                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 817                 // add new damage
 818                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 819
 820                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 821                 pain_threshold = autocvar_hud_damage_pain_threshold;
 822                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 823                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 824
 825                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 826                 {
 827                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 828                 }
 829
 830                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 831
 832                 if(myhealth_prev < 1)
 833                 {
 834                         if(myhealth >= 1)
 835                         {
 836                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 837                                 myhealth_flash_temp = 0;
 838                         }
 839                         else
 840                         {
 841                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 842                         }
 843                 }
 844
 845                 if(spectatee_status == -1 || intermission)
 846                 {
 847                         myhealth_flash = 0; // observing, or match ended
 848                         myhealth_flash_temp = 0;
 849                 }
 850
 851                 myhealth_prev = myhealth;
 852
 853                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 854                 {
 855                         if(autocvar_cl_gentle_damage == 2)
 856                         {
 857                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 858                                 {
 859                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 860                                 }
 861                         }
 862                         else
 863                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 864
 865                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 866                 }
 867                 else
 868                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 869
 870                 if(autocvar_hud_postprocessing)
 871                 {
 872                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 873                         {
 874                                 damage_blurpostprocess_x = 1;
 875                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 876                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 877                         }
 878                         else
 879                         {
 880                                 damage_blurpostprocess_x = 0;
 881                                 damage_blurpostprocess_y = 0;
 882                                 damage_blurpostprocess_z = 0;
 883                         }
 884                 }
 885         }
 886
 887         if(autocvar_hud_postprocessing)
 888         {
 889                 // all of this should be done in the engine eventually
 890
 891                 // enable or disable rendering types if they are used or not
 892                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
 893                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
 894                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
 895                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
 896
 897                 // lets apply the postprocess effects from the previous two functions if needed
 898                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 899                 {
 900                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 901                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 902                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 903                         {
 904                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 905                                 old_blurradius = blurradius;
 906                                 old_bluralpha = bluralpha;
 907                         }
 908                 }
 909                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 910                 {
 911                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 912                         old_blurradius = 0;
 913                         old_bluralpha = 0;
 914                 }
 915
 916                 float sharpen_intensity;
 917                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 918                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 919                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 920                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 921
 922                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 923                 {
 924                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 925
 926                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 927                         {
 928                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 929                                 old_sharpen_intensity = sharpen_intensity;
 930                         }
 931                 }
 932                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 933                 {
 934                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 935                         old_sharpen_intensity = 0;
 936                 }
 937         }
 938
 939         if(menu_visible)
 940                 menu_show();
 941
 942         /*if(gametype == GAME_CTF)
 943           {
 944           ctf_view();
 945           } else */
 946
 947         // draw 2D entities
 948         e = self;
 949         for(self = world; (self = nextent(self)); )
 950                 if(self.draw2d)
 951                         self.draw2d();
 952         self = e;
 953         Draw_ShowNames_All();
 954
 955         scoreboard_active = HUD_WouldDrawScoreboard();
 956
 957         hit_time = getstatf(STAT_HIT_TIME);
 958         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 959         {
 960                 sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 961                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 962         }
 963         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 964         if(typehit_time > nextsound_typehit_time)
 965         {
 966                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 967                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 968         }
 969
 970         //else
 971         {
 972                 if(gametype == GAME_FREEZETAG)
 973                 {
 974                         if(getstati(STAT_FROZEN))
 975                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 976                         if(getstatf(STAT_REVIVE_PROGRESS))
 977                         {
 978                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 979                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 980                         }
 981                 }
 982
 983                 if(autocvar_r_letterbox == 0)
 984                         if(autocvar_viewsize < 120)
 985                                 CSQC_common_hud();
 986
 987                 // crosshair goes VERY LAST
 988                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 989                         string wcross_style;
 990                         float wcross_alpha, wcross_resolution;
 991                         wcross_style = autocvar_crosshair;
 992                         if (wcross_style == "0")
 993                                 return;
 994                         wcross_resolution = autocvar_crosshair_size;
 995                         if (wcross_resolution == 0)
 996                                 return;
 997                         wcross_alpha = autocvar_crosshair_alpha;
 998                         if (wcross_alpha == 0)
 999                                 return;
1000
1001                         // TrueAim check
1002                         float shottype;
1003
1004                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1005                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1006                         wcross_origin_z = 0;
1007                         if(autocvar_crosshair_hittest)
1008                         {
1009                                 vector wcross_oldorigin;
1010                                 wcross_oldorigin = wcross_origin;
1011                                 shottype = TrueAimCheck();
1012                                 if(shottype == SHOTTYPE_HITWORLD)
1013                                 {
1014                                         v = wcross_origin - wcross_oldorigin;
1015                                         v_x /= vid_conwidth;
1016                                         v_y /= vid_conheight;
1017                                         if(vlen(v) > 0.01)
1018                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1019                                 }
1020                                 if(!autocvar_crosshair_hittest_showimpact)
1021                                         wcross_origin = wcross_oldorigin;
1022                         }
1023                         else
1024                                 shottype = SHOTTYPE_HITWORLD;
1025
1026                         vector wcross_color, wcross_size;
1027                         string wcross_wep, wcross_name;
1028                         float wcross_scale, wcross_blur;
1029
1030                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1031                                 e = get_weaponinfo(activeweapon);
1032                                 if (e && e.netname != "")
1033                                 {
1034                                         wcross_wep = e.netname;
1035                                         if(autocvar_crosshair_per_weapon)
1036                                         {
1037                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1038                                                 if (wcross_resolution == 0)
1039                                                         return;
1040                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1041                                                 if (wcross_alpha == 0)
1042                                                         return;
1043
1044                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1045                                                 if(wcross_style == "" || wcross_style == "0")
1046                                                         wcross_style = wcross_wep;
1047                                         }
1048                                 }
1049                         }
1050                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1051                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1052                         else if(autocvar_crosshair_color_by_health)
1053                         {
1054                                 local float x = getstati(STAT_HEALTH);
1055
1056                                 //x = red
1057                                 //y = green
1058                                 //z = blue
1059
1060                                 wcross_color_z = 0;
1061
1062                                 if(x > 200)
1063                                 {
1064                                         wcross_color_x = 0;
1065                                         wcross_color_y = 1;
1066                                 }
1067                                 else if(x > 150)
1068                                 {
1069                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1070                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1071                                 }
1072                                 else if(x > 100)
1073                                 {
1074                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1075                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1076                                         wcross_color_z = 1 - (x-100)*0.02;
1077                                 }
1078                                 else if(x > 50)
1079                                 {
1080                                         wcross_color_x = 1;
1081                                         wcross_color_y = 1;
1082                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1083                                 }
1084                                 else if(x > 20)
1085                                 {
1086                                         wcross_color_x = 1;
1087                                         wcross_color_y = (x-20)*90/27/100;
1088                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1089                                 }
1090                                 else
1091                                 {
1092                                         wcross_color_x = 1;
1093                                         wcross_color_y = 0;
1094                                 }
1095                         }
1096                         else
1097                                 wcross_color = stov(autocvar_crosshair_color);
1098
1099                         wcross_name = strcat("gfx/crosshair", wcross_style);
1100
1101                         if(autocvar_crosshair_effect_scalefade)
1102                         {
1103                                 wcross_scale = wcross_resolution;
1104                                 wcross_resolution = 1;
1105                         }
1106                         else
1107                         {
1108                                 wcross_scale = 1;
1109                         }
1110
1111                         if(autocvar_crosshair_pickup)
1112                         {
1113                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1114                                 {
1115                                         pickup_crosshair_size = 1;
1116                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1117                                 }
1118
1119                                 if(pickup_crosshair_size > 0)
1120                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1121                                 else
1122                                         pickup_crosshair_size = 0;
1123
1124                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1125                         }
1126
1127                         vector hitindication_color;
1128                         if(autocvar_crosshair_hitindication)
1129                         {
1130                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1131                                 if(hitindication_crosshair_time < hit_time)
1132                                 {
1133                                         hitindication_crosshair_size = 1;
1134                                         hitindication_crosshair_time = hit_time;
1135                                 }
1136
1137                                 if(hitindication_crosshair_size > 0)
1138                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1139                                 else
1140                                         hitindication_crosshair_size = 0;
1141
1142                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1143                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1144                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1145                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1146                         }
1147
1148                         if(shottype == SHOTTYPE_HITENEMY)
1149                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1150                         if(shottype == SHOTTYPE_HITTEAM)
1151                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1152
1153                         f = autocvar_crosshair_effect_speed;
1154                         if(f < 0)
1155                                 f *= -2 * g_weaponswitchdelay;
1156                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1157                         {
1158                                 wcross_changedonetime = time + f;
1159                         }
1160                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1161                         {
1162                                 wcross_name_changestarttime = time;
1163                                 wcross_name_changedonetime = time + f;
1164                                 if(wcross_name_goal_prev_prev)
1165                                         strunzone(wcross_name_goal_prev_prev);
1166                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1167                                 wcross_name_goal_prev = strzone(wcross_name);
1168                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1169                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1170                                 wcross_resolution_goal_prev = wcross_resolution;
1171                         }
1172
1173                         wcross_scale_goal_prev = wcross_scale;
1174                         wcross_alpha_goal_prev = wcross_alpha;
1175                         wcross_color_goal_prev = wcross_color;
1176
1177                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1178                         {
1179                                 wcross_blur = 1;
1180                                 wcross_alpha *= 0.75;
1181                         }
1182                         else
1183                                 wcross_blur = 0;
1184                         // *_prev is at time-frametime
1185                         // * is at wcross_changedonetime+f
1186                         // what do we have at time?
1187                         if(time < wcross_changedonetime)
1188                         {
1189                                 f = frametime / (wcross_changedonetime - time + frametime);
1190                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1191                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1192                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1193                         }
1194
1195                         wcross_scale_prev = wcross_scale;
1196                         wcross_alpha_prev = wcross_alpha;
1197                         wcross_color_prev = wcross_color;
1198
1199                         wcross_scale *= 1 - autocvar__menu_alpha;
1200                         wcross_alpha *= 1 - autocvar__menu_alpha;
1201                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1202
1203                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1204                         {
1205                                 // crosshair rings for weapon stats
1206                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1207                                 {
1208                                         // declarations and stats
1209                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1210                                         string ring_image, ring_inner_image;
1211                                         vector ring_rgb, ring_inner_rgb;
1212
1213                                         ring_scale = autocvar_crosshair_ring_size;
1214
1215                                         float weapon_clipload, weapon_clipsize;
1216                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1217                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1218
1219                                         float nex_charge, nex_chargepool;
1220                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1221                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1222
1223                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1224                                                 nex_charge_movingavg = nex_charge;
1225
1226
1227                                         // handle the values
1228                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1229                                         {
1230                                                 if (nex_chargepool || use_nex_chargepool) {
1231                                                         use_nex_chargepool = 1;
1232                                                         ring_inner_value = nex_chargepool;
1233                                                 } else {
1234                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1235                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1236                                                 }
1237
1238                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1239                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1240                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1241
1242                                                 // draw the outer ring to show the current charge of the weapon
1243                                                 ring_value = nex_charge;
1244                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1245                                                 ring_rgb = wcross_color;
1246                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1247                                         }
1248                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1249                                         {
1250                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1251                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1252                                                 ring_rgb = wcross_color;
1253                                                 ring_image = "gfx/crosshair_ring.tga";
1254                                         }
1255                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1256                                         {
1257                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1258                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1259                                                 ring_rgb = wcross_color;
1260                                                 ring_image = "gfx/crosshair_ring.tga";
1261                                         }
1262
1263                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1264                                         {
1265                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1266                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1267                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1268                                                 ring_rgb = wcross_color;
1269
1270                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1271                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1272                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1273                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1274                                                 else
1275                                                         ring_image = "gfx/crosshair_ring.tga";
1276                                         }
1277
1278                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1279                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1280
1281                                         if (ring_value)
1282                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1283                                 }
1284
1285 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1286                                 do \
1287                                 { \
1288                                         if(wcross_blur > 0) \
1289                                         { \
1290                                                 for(i = -2; i <= 2; ++i) \
1291                                                 for(j = -2; j <= 2; ++j) \
1292                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1293                                         } \
1294                                         else \
1295                                         { \
1296                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1297                                         } \
1298                                 } \
1299                                 while(0)
1300
1301 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1302                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1303
1304 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1305                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1306
1307                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1308                                 {
1309                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1310                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1311                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1312                                         f = 1 - f;
1313                                 }
1314                                 else
1315                                 {
1316                                         f = 1;
1317                                 }
1318                                 wcross_name_alpha_goal_prev = f;
1319
1320                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1321                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1322
1323                                 if(autocvar_crosshair_dot)
1324                                 {
1325                                         vector wcross_color_old;
1326                                         wcross_color_old = wcross_color;
1327                                         if(autocvar_crosshair_dot_color != "0")
1328                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1329                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1330                                         // FIXME why don't we use wcross_alpha here?
1331                                         wcross_color = wcross_color_old;
1332                                 }
1333                         }
1334                 }
1335                 else
1336                 {
1337                         wcross_scale_prev = 0;
1338                         wcross_alpha_prev = 0;
1339                         wcross_scale_goal_prev = 0;
1340                         wcross_alpha_goal_prev = 0;
1341                         wcross_changedonetime = 0;
1342                         if(wcross_name_goal_prev)
1343                                 strunzone(wcross_name_goal_prev);
1344                         wcross_name_goal_prev = string_null;
1345                         if(wcross_name_goal_prev_prev)
1346                                 strunzone(wcross_name_goal_prev_prev);
1347                         wcross_name_goal_prev_prev = string_null;
1348                         wcross_name_changestarttime = 0;
1349                         wcross_name_changedonetime = 0;
1350                         wcross_name_alpha_goal_prev = 0;
1351                         wcross_name_alpha_goal_prev_prev = 0;
1352                         wcross_resolution_goal_prev = 0;
1353                         wcross_resolution_goal_prev_prev = 0;
1354                 }
1355         }
1356
1357         if(NextFrameCommand)
1358         {
1359                 localcmd("\n", NextFrameCommand, "\n");
1360                 NextFrameCommand = string_null;
1361         }
1362
1363         // we must do this check AFTER a frame was rendered, or it won't work
1364         if(cs_project_is_b0rked == 0)
1365         {
1366                 string w0, h0;
1367                 w0 = ftos(autocvar_vid_conwidth);
1368                 h0 = ftos(autocvar_vid_conheight);
1369                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1370                 //R_SetView(VF_FOV, '90 90 0');
1371                 R_SetView(VF_ORIGIN, '0 0 0');
1372                 R_SetView(VF_ANGLES, '0 0 0');
1373                 R_SetView(VF_PERSPECTIVE, 1);
1374                 makevectors('0 0 0');
1375                 vector v1, v2;
1376                 cvar_set("vid_conwidth", "800");
1377                 cvar_set("vid_conheight", "600");
1378                 v1 = cs_project(v_forward);
1379                 cvar_set("vid_conwidth", "640");
1380                 cvar_set("vid_conheight", "480");
1381                 v2 = cs_project(v_forward);
1382                 if(v1 == v2)
1383                         cs_project_is_b0rked = 1;
1384                 else
1385                         cs_project_is_b0rked = -1;
1386                 cvar_set("vid_conwidth", w0);
1387                 cvar_set("vid_conheight", h0);
1388         }
1389
1390         if(autocvar__hud_configure)
1391                 HUD_Panel_Mouse();
1392
1393     if(hud && !intermission)
1394     {
1395         if(hud == HUD_SPIDERBOT)
1396             CSQC_SPIDER_HUD();
1397         else if(hud == HUD_WAKIZASHI)
1398             CSQC_WAKIZASHI_HUD();
1399         else if(hud == HUD_RAPTOR)
1400             CSQC_RAPTOR_HUD();
1401         else if(hud == HUD_BUMBLEBEE)
1402             CSQC_BUMBLE_HUD();
1403     }
1404         // let's reset the view back to normal for the end
1405         R_SetView(VF_MIN, '0 0 0');
1406         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1407 }
1408
1409
1410 void CSQC_common_hud(void)
1411 {
1412     // do some accuracy var caching
1413     float i;
1414     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1415     {
1416         if(autocvar_accuracy_color_levels != acc_color_levels)
1417         {
1418             if(acc_color_levels)
1419                 strunzone(acc_color_levels);
1420             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1421             acc_levels = tokenize(acc_color_levels);
1422             if (acc_levels > MAX_ACCURACY_LEVELS)
1423                 acc_levels = MAX_ACCURACY_LEVELS;
1424
1425             for (i = 0; i < acc_levels; ++i)
1426                 acc_lev[i] = stof(argv(i)) / 100.0;
1427         }
1428         // let know that acc_col[] needs to be loaded
1429         acc_col_x[0] = -1;
1430     }
1431
1432     HUD_Main(); // always run these functions for alpha checks
1433     HUD_DrawScoreboard();
1434
1435     if (scoreboard_active) // scoreboard/accuracy
1436         HUD_Reset();
1437     else if (intermission == 2) // map voting screen
1438     {
1439         HUD_FinaleOverlay();
1440         HUD_Reset();
1441     }
1442         /*
1443         switch(hud)
1444         {
1445                 case HUD_SPIDERBOT:
1446                         CSQC_SPIDER_HUD();
1447                         break;
1448
1449                 case HUD_WAKIZASHI:
1450                         CSQC_WAKIZASHI_HUD();
1451                         break;
1452
1453         case HUD_BUMBLEBEE:
1454             CSQC_BUMBLE_HUD();
1455             break;
1456         }
1457         */
1458 }
1459
1460
1461 // following vectors must be global to allow seamless switching between camera modes
1462 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1463 void CSQC_Demo_Camera()
1464 {
1465         float speed, attenuation, dimensions;
1466         vector tmp, delta;
1467
1468         if( autocvar_camera_reset || !camera_mode )
1469         {
1470                 camera_offset = '0 0 0';
1471                 current_angles = '0 0 0';
1472                 camera_direction = '0 0 0';
1473                 camera_offset_z += 30;
1474                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1475                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1476                 current_origin = view_origin;
1477                 current_camera_offset  = camera_offset;
1478                 cvar_set("camera_reset", "0");
1479                 camera_mode = CAMERA_CHASE;
1480         }
1481
1482         // Camera angles
1483         if( camera_roll )
1484                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1485
1486         if(autocvar_camera_look_player)
1487         {
1488                 local vector dir;
1489                 local float n;
1490
1491                 dir = normalize(view_origin - current_position);
1492                 n = mouse_angles_z;
1493                 mouse_angles = vectoangles(dir);
1494                 mouse_angles_x = mouse_angles_x * -1;
1495                 mouse_angles_z = n;
1496         }
1497         else
1498         {
1499                 tmp = getmousepos() * 0.1;
1500                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1501                 {
1502                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1503                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1504                 }
1505         }
1506
1507         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1508         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1509         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1510         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1511
1512         // Fix difference when angles don't have the same sign
1513         delta = '0 0 0';
1514         if(mouse_angles_y < -60 && current_angles_y > 60)
1515                 delta = '0 360 0';
1516         if(mouse_angles_y > 60 && current_angles_y < -60)
1517                 delta = '0 -360 0';
1518
1519         if(autocvar_camera_look_player)
1520                 attenuation = autocvar_camera_look_attenuation;
1521         else
1522                 attenuation = autocvar_camera_speed_attenuation;
1523
1524         attenuation = 1 / max(1, attenuation);
1525         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1526
1527         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1528         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1529         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1530         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1531
1532         // Camera position
1533         tmp = '0 0 0';
1534         dimensions = 0;
1535
1536         if( camera_direction_x )
1537         {
1538                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1539                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1540                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1541                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1542                 ++dimensions;
1543         }
1544
1545         if( camera_direction_y )
1546         {
1547                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1548                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1549                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1550                 ++dimensions;
1551         }
1552
1553         if( camera_direction_z )
1554         {
1555                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1556                 ++dimensions;
1557         }
1558
1559         if(autocvar_camera_free)
1560                 speed = autocvar_camera_speed_free;
1561         else
1562                 speed = autocvar_camera_speed_chase;
1563
1564         if(dimensions)
1565         {
1566                 speed = speed * sqrt(1 / dimensions);
1567                 camera_offset += tmp * speed;
1568         }
1569
1570         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1571
1572         // Camera modes
1573         if( autocvar_camera_free )
1574         {
1575                 if ( camera_mode == CAMERA_CHASE )
1576                 {
1577                         current_camera_offset = current_origin + current_camera_offset;
1578                         camera_offset = current_origin + camera_offset;
1579                 }
1580
1581                 camera_mode = CAMERA_FREE;
1582                 current_position = current_camera_offset;
1583         }
1584         else
1585         {
1586                 if ( camera_mode == CAMERA_FREE )
1587                 {
1588                         current_origin = view_origin;
1589                         camera_offset = camera_offset - current_origin;
1590                         current_camera_offset = current_camera_offset - current_origin;
1591                 }
1592
1593                 camera_mode = CAMERA_CHASE;
1594
1595                 if(autocvar_camera_chase_smoothly)
1596                         current_origin += (view_origin - current_origin) * attenuation;
1597                 else
1598                         current_origin = view_origin;
1599
1600                 current_position = current_origin + current_camera_offset;
1601         }
1602
1603         R_SetView(VF_ANGLES, current_angles);
1604         R_SetView(VF_ORIGIN, current_position);
1605 }