qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 float pickup_crosshair_time, pickup_crosshair_fade;
 353
 354 void CSQC_UpdateView(float w, float h)
 355 {
 356         entity e;
 357         float fov;
 358         float f, i, j;
 359         vector v, vo;
 360         vector vf_size, vf_min;
 361
 362         vf_size = R_SetView3fv(VF_SIZE);
 363         vf_min = R_SetView3fv(VF_MIN);
 364         vid_width = vf_size_x;
 365         vid_height = vf_size_y;
 366
 367         vector reticle_pos, reticle_size;
 368
 369         WaypointSprite_Load();
 370
 371         if(spectatee_status)
 372                 myteam = GetPlayerColor(spectatee_status - 1);
 373         else
 374                 myteam = GetPlayerColor(player_localentnum - 1);
 375
 376         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 377         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 378
 379         warpzone_fixview_origin = pmove_org + vo;
 380         warpzone_fixview_cl_viewangles = input_angles;
 381         warpzone_fixview_angles = view_angles;
 382         WarpZone_FixView();
 383         pmove_org = warpzone_fixview_origin - vo;
 384         input_angles = warpzone_fixview_cl_viewangles;
 385         view_angles = warpzone_fixview_angles;
 386
 387         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
 388         {
 389                 pmove_org = freeze_pmove_org;
 390                 input_angles = view_angles = freeze_input_angles;
 391                 R_SetView(VF_ORIGIN, pmove_org + vo);
 392                 R_SetView(VF_ANGLES, view_angles);
 393                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 394         }
 395         freeze_pmove_org = pmove_org;
 396         freeze_input_angles = input_angles;
 397
 398         // Render the Scene
 399         if(!intermission || !view_set)
 400         {
 401                 view_origin = pmove_org + vo;
 402                 view_angles = input_angles;
 403                 makevectors(view_angles);
 404                 view_forward = v_forward;
 405                 view_right = v_right;
 406                 view_up = v_up;
 407                 view_set = 1;
 408         }
 409
 410 #ifdef BLURTEST
 411         if(time > blurtest_time0 && time < blurtest_time1)
 412         {
 413                 float r, t;
 414
 415                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 416                 r = t * blurtest_radius;
 417                 f = 1 / pow(t, blurtest_power) - 1;
 418
 419                 cvar_set("r_glsl_postprocess", "1");
 420                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 421         }
 422         else
 423         {
 424                 cvar_set("r_glsl_postprocess", "0");
 425                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 426         }
 427 #endif
 428
 429         TargetMusic_Advance();
 430         Fog_Force();
 431
 432         drawframetime = max(0.000001, time - drawtime);
 433         drawtime = time;
 434
 435         // watch for gametype changes here...
 436         // in ParseStuffCMD the cmd isn't executed yet :/
 437         // might even be better to add the gametype to TE_CSQC_INIT...?
 438         if(!postinit)
 439                 PostInit();
 440
 441         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 442                 if(calledhooks & HOOK_START)
 443                 {
 444                         localcmd("\ncl_hook_gameend\n");
 445                         calledhooks |= HOOK_END;
 446                 }
 447
 448         CheckForGamestartChange();
 449         serverAnnouncer();
 450         maptimeAnnouncer();
 451         carrierAnnouncer();
 452
 453         fov = cvar("fov");
 454         if(button_zoom || fov <= 59.5)
 455         {
 456                 if(!zoomscript_caught)
 457                 {
 458                         localcmd("+button4\n");
 459                         zoomscript_caught = 1;
 460                         ignore_plus_zoom += 1;
 461                 }
 462         }
 463         else
 464         {
 465                 if(zoomscript_caught)
 466                 {
 467                         localcmd("-button4\n");
 468                         zoomscript_caught = 0;
 469                         ignore_minus_zoom += 1;
 470                 }
 471         }
 472
 473         ColorTranslateMode = cvar("cl_stripcolorcodes");
 474         activeweapon = getstati(STAT_SWITCHWEAPON);
 475         f = cvar("teamplay");
 476         if(f != teamplay)
 477         {
 478                 teamplay = f;
 479                 HUD_InitScores();
 480         }
 481
 482         if(last_weapon != activeweapon) {
 483                 weapontime = time;
 484                 last_weapon = activeweapon;
 485
 486                 e = get_weaponinfo(activeweapon);
 487                 if(e.netname != "")
 488                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 489                 else
 490                         localcmd("\ncl_hook_activeweapon none\n");
 491         }
 492
 493         // ALWAYS Clear Current Scene First
 494         R_ClearScene();
 495
 496         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 497         R_SetView(VF_SIZE, vf_size);
 498         R_SetView(VF_MIN, vf_min);
 499
 500         // Assign Standard Viewflags
 501         // Draw the World (and sky)
 502         R_SetView(VF_DRAWWORLD, 1);
 503
 504         // Set the console size vars
 505         vid_conwidth = cvar("vid_conwidth");
 506         vid_conheight = cvar("vid_conheight");
 507         vid_pixelheight = cvar("vid_pixelheight");
 508
 509         R_SetView(VF_FOV, GetCurrentFov(fov));
 510
 511         // Camera for demo playback
 512         if(camera_active)
 513         {
 514                 if(cvar("camera_enable"))
 515                         CSQC_Demo_Camera();
 516                 else
 517                 {
 518                         cvar_set("chase_active", ftos(chase_active_backup));
 519                         cvar_set("cl_demo_mousegrab", "0");
 520                         camera_active = FALSE;
 521                 }
 522         }
 523 #ifdef CAMERATEST
 524         else if(cvar("camera_enable"))
 525 #else
 526         else if(cvar("camera_enable") && isdemo())
 527 #endif
 528         {
 529                 // Enable required Darkplaces cvars
 530                 chase_active_backup = cvar("chase_active");
 531                 cvar_set("chase_active", "2");
 532                 cvar_set("cl_demo_mousegrab", "1");
 533                 camera_active = TRUE;
 534                 camera_mode = FALSE;
 535         }
 536
 537         // Draw the Crosshair
 538         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 539
 540         // Draw the Engine Status Bar (the default Quake HUD)
 541         R_SetView(VF_DRAWENGINEHUD, 0);
 542
 543         // fetch this one only once per frame
 544         hud_showbinds = cvar("hud_showbinds");
 545         hud_showbinds_limit = cvar("hud_showbinds_limit");
 546
 547         // Update the mouse position
 548         /*
 549            mousepos_x = vid_conwidth;
 550            mousepos_y = vid_conheight;
 551            mousepos = mousepos*0.5 + getmousepos();
 552          */
 553
 554         e = self;
 555         for(self = world; (self = nextent(self)); )
 556                 if(self.draw)
 557                         self.draw();
 558         self = e;
 559
 560         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 561         R_RenderScene();
 562
 563         // now switch to 2D drawing mode by calling a 2D drawing function
 564         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 565         // next R_RenderScene call
 566         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 567
 568         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright"))
 569         {
 570                 // apply night vision effect
 571                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 572                 float a;
 573
 574                 if(!nightvision_noise)
 575                 {
 576                         nightvision_noise = spawn();
 577                         nightvision_noise.classname = "nightvision_noise";
 578                 }
 579                 if(!nightvision_noise2)
 580                 {
 581                         nightvision_noise2 = spawn();
 582                         nightvision_noise2.classname = "nightvision_noise2";
 583                 }
 584
 585                 // color tint in yellow
 586                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 587
 588                 // draw BG
 589                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 590                 rgb = '1 1 1';
 591                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 592                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 593                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 594                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 595                 tc_11 = tc_01 + tc_10 - tc_00;
 596                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 597                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 598                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 599                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 600                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 601                 R_EndPolygon();
 602
 603                 // draw FG
 604                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 605                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 606                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 607                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 608                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 609                 tc_11 = tc_01 + tc_10 - tc_00;
 610                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 611                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 612                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 613                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 614                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 615                 R_EndPolygon();
 616         }
 617
 618         // Draw the aiming reticle for weapons that use it
 619         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 620         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 621         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 622         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 623                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 624         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 625                 reticle_type = 2; // nex zoom
 626         else if(button_zoom || zoomscript_caught)
 627                 reticle_type = 1; // normal zoom
 628         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 629                 reticle_type = 2; // nex zoom
 630
 631         if(cvar("cl_reticle_stretch"))
 632         {
 633                 reticle_size_x = vid_conwidth;
 634                 reticle_size_y = vid_conheight;
 635                 reticle_pos_x = 0;
 636                 reticle_pos_y = 0;
 637         }
 638         else
 639         {
 640                 reticle_size_x = max(vid_conwidth, vid_conheight);
 641                 reticle_size_y = max(vid_conwidth, vid_conheight);
 642                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 643                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 644         }
 645
 646         f = current_zoomfraction;
 647         if(zoomscript_caught)
 648                 f = 1;
 649         if(cvar("cl_reticle_item_normal"))
 650         {
 651                 precache_pic("gfx/reticle_normal");
 652                 if(reticle_type == 1 && f)
 653                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 654         }
 655         if(cvar("cl_reticle_item_nex"))
 656         {
 657                 precache_pic("gfx/reticle_nex");
 658                 if(reticle_type == 2 && f)
 659                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 660         }
 661
 662         // Draw the mouse cursor
 663         // NOTE: drawpic must happen after R_RenderScene for some reason
 664         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 665         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 666         //self = edict_num(player_localnum);
 667         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 668         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 669         // as long as the ctf part isn't in, this is useless
 670         if(menu_visible)
 671                 menu_show();
 672
 673         /*if(gametype == GAME_CTF)
 674           {
 675           ctf_view();
 676           } else */
 677
 678         // draw 2D entities
 679         e = self;
 680         for(self = world; (self = nextent(self)); )
 681                 if(self.draw2d)
 682                         self.draw2d();
 683         self = e;
 684
 685         scoreboard_active = HUD_WouldDrawScoreboard();
 686
 687         float hud;
 688         hud = getstati(STAT_HUD);
 689         if(hud == HUD_SPIDERBOT)
 690                 CSQC_SPIDER_HUD();
 691         else if(hud == HUD_WAKIZASHI)
 692         CSQC_WAKIZASHI_HUD();
 693     else if(hud == HUD_RAPTOR)
 694         CSQC_RAPTOR_HUD();
 695         else
 696         {
 697                 if(cvar("r_letterbox") == 0)
 698                         if(cvar("viewsize") < 120)
 699                                 CSQC_common_hud();
 700
 701                 // crosshair goes VERY LAST
 702                 if(!scoreboard_active && !camera_active && intermission != 2) {
 703                         // TrueAim check
 704                         float shottype;
 705                         float bullets, ring_scale;
 706                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 707                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 708                         wcross_origin_z = 0;
 709                         if(cvar("crosshair_hittest"))
 710                         {
 711                                 vector wcross_oldorigin;
 712                                 wcross_oldorigin = wcross_origin;
 713                                 shottype = TrueAimCheck();
 714                                 if(shottype == SHOTTYPE_HITWORLD)
 715                                 {
 716                                         v = wcross_origin - wcross_oldorigin;
 717                                         v_x /= vid_conwidth;
 718                                         v_y /= vid_conheight;
 719                                         if(vlen(v) > 0.01)
 720                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 721                                 }
 722                                 if(!cvar("crosshair_hittest_showimpact"))
 723                                         wcross_origin = wcross_oldorigin;
 724                         }
 725                         else
 726                                 shottype = SHOTTYPE_HITWORLD;
 727
 728                         string wcross_style;
 729                         wcross_style = cvar_string("crosshair");
 730
 731                         if (wcross_style != "0") {
 732                                 vector wcross_color, wcross_size;
 733                                 string wcross_wep, wcross_name;
 734                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 735
 736                                 wcross_color_x = cvar("crosshair_color_red");
 737                                 wcross_color_y = cvar("crosshair_color_green");
 738                                 wcross_color_z = cvar("crosshair_color_blue");
 739                                 wcross_alpha = cvar("crosshair_color_alpha");
 740                                 wcross_resolution = cvar("crosshair_size");
 741                                 if (cvar("crosshair_per_weapon")) {
 742                                         e = get_weaponinfo(activeweapon);
 743                                         if (e && e.netname != "")
 744                                         {
 745                                                 wcross_wep = e.netname;
 746                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 747                                                 if(wcross_style == "")
 748                                                         wcross_style = e.netname;
 749
 750                                                 if(!cvar("crosshair_color_override"))
 751                                                 {
 752                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 753                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 754                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 755                                                 }
 756
 757                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 758                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 759                                         }
 760                                 }
 761
 762                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 763
 764                                 if(cvar("crosshair_effect_scalefade"))
 765                                 {
 766                                         wcross_scale = wcross_resolution;
 767                                         wcross_resolution = 1;
 768                                 }
 769                                 else
 770                                 {
 771                                         wcross_scale = 1;
 772                                 }
 773
 774                                 if(cvar("crosshair_pickup"))
 775                                 {
 776                                         if(pickup_crosshair_time < getstatf(STAT_PICKUP_CROSSHAIR))
 777                                         {
 778                                                 pickup_crosshair_fade = 1;
 779                                                 pickup_crosshair_time = getstatf(STAT_PICKUP_CROSSHAIR);
 780                                         }
 781                                         if(pickup_crosshair_fade > 0)
 782                                                 pickup_crosshair_fade -= cvar("crosshair_pickup_speed");
 783                                         else
 784                                                 pickup_crosshair_fade = 0;
 785                                         wcross_scale += sin(pickup_crosshair_fade) * cvar("crosshair_pickup");
 786                                 }
 787
 788                                 if(shottype == SHOTTYPE_HITENEMY)
 789                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 790                                 if(shottype == SHOTTYPE_HITTEAM)
 791                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 792
 793                                 f = cvar("crosshair_effect_speed");
 794                                 if(f < 0)
 795                                         f *= -2 * g_weaponswitchdelay;
 796                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 797                                 {
 798                                         wcross_changedonetime = time + f;
 799                                 }
 800                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 801                                 {
 802                                         wcross_name_changestarttime = time;
 803                                         wcross_name_changedonetime = time + f;
 804                                         if(wcross_name_goal_prev_prev)
 805                                                 strunzone(wcross_name_goal_prev_prev);
 806                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 807                                         wcross_name_goal_prev = strzone(wcross_name);
 808                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 809                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 810                                         wcross_resolution_goal_prev = wcross_resolution;
 811                                 }
 812
 813                                 wcross_scale_goal_prev = wcross_scale;
 814                                 wcross_alpha_goal_prev = wcross_alpha;
 815                                 wcross_color_goal_prev = wcross_color;
 816
 817                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 818                                 {
 819                                         wcross_blur = 1;
 820                                         wcross_alpha *= 0.75;
 821                                 }
 822                                 else
 823                                         wcross_blur = 0;
 824                                 // *_prev is at time-frametime
 825                                 // * is at wcross_changedonetime+f
 826                                 // what do we have at time?
 827                                 if(time < wcross_changedonetime)
 828                                 {
 829                                         f = frametime / (wcross_changedonetime - time + frametime);
 830                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 831                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 832                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 833                                 }
 834
 835                                 wcross_scale_prev = wcross_scale;
 836                                 wcross_alpha_prev = wcross_alpha;
 837                                 wcross_color_prev = wcross_color;
 838
 839                                 wcross_scale *= 1 - cvar("_menu_alpha");
 840                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 841
 842                                 ring_scale = cvar("crosshair_ring_size");
 843
 844                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 845
 846                                 float nex_charge;
 847                                 nex_charge = getstatf(STAT_NEX_CHARGE);
 848
 849                                 // ring around crosshair representing bullets left in camping rifle clip
 850                                 if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
 851                                 {
 852                                         bullets = getstati(STAT_BULLETS_LOADED);
 853                                         f = bound(0, bullets / cr_maxbullets, 1);
 854
 855                                         a = cvar("crosshair_campingrifle_bulletcounter_alpha");
 856                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 857                                 }
 858                                 else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
 859                                 {
 860                                         a = cvar("crosshair_nexvelocity_alpha");
 861                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 862                                 }
 863
 864 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 865                                 do \
 866                                 { \
 867                                         if(wcross_blur > 0) \
 868                                         { \
 869                                                 for(i = -2; i <= 2; ++i) \
 870                                                         for(j = -2; j <= 2; ++j) \
 871                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 872                                         } \
 873                                         else \
 874                                         { \
 875                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 876                                         } \
 877                                 } \
 878                                 while(0)
 879
 880 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 881                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 882
 883 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 884                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 885
 886                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 887                                 {
 888                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 889                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 890                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 891                                         f = 1 - f;
 892                                 }
 893                                 else
 894                                 {
 895                                         f = 1;
 896                                 }
 897
 898                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 899                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 900
 901                                 if(cvar("crosshair_dot"))
 902                                         CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
 903
 904                                 wcross_name_alpha_goal_prev = f;
 905                         }
 906                 }
 907                 else
 908                 {
 909                         wcross_scale_prev = 0;
 910                         wcross_alpha_prev = 0;
 911                         wcross_scale_goal_prev = 0;
 912                         wcross_alpha_goal_prev = 0;
 913                         wcross_changedonetime = 0;
 914                         if(wcross_name_goal_prev)
 915                                 strunzone(wcross_name_goal_prev);
 916                         wcross_name_goal_prev = string_null;
 917                         if(wcross_name_goal_prev_prev)
 918                                 strunzone(wcross_name_goal_prev_prev);
 919                         wcross_name_goal_prev_prev = string_null;
 920                         wcross_name_changestarttime = 0;
 921                         wcross_name_changedonetime = 0;
 922                         wcross_name_alpha_goal_prev = 0;
 923                         wcross_name_alpha_goal_prev_prev = 0;
 924                         wcross_resolution_goal_prev = 0;
 925                         wcross_resolution_goal_prev_prev = 0;
 926                 }
 927         }
 928
 929         if(NextFrameCommand)
 930         {
 931                 localcmd("\n", NextFrameCommand, "\n");
 932                 NextFrameCommand = string_null;
 933         }
 934
 935         // we must do this check AFTER a frame was rendered, or it won't work
 936         if(cs_project_is_b0rked == 0)
 937         {
 938                 string w0, h0;
 939                 w0 = cvar_string("vid_conwidth");
 940                 h0 = cvar_string("vid_conheight");
 941                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 942                 //R_SetView(VF_FOV, '90 90 0');
 943                 R_SetView(VF_ORIGIN, '0 0 0');
 944                 R_SetView(VF_ANGLES, '0 0 0');
 945                 R_SetView(VF_PERSPECTIVE, 1);
 946                 makevectors('0 0 0');
 947                 vector v1, v2;
 948                 cvar_set("vid_conwidth", "800");
 949                 cvar_set("vid_conheight", "600");
 950                 v1 = cs_project(v_forward);
 951                 cvar_set("vid_conwidth", "640");
 952                 cvar_set("vid_conheight", "480");
 953                 v2 = cs_project(v_forward);
 954                 if(v1 == v2)
 955                         cs_project_is_b0rked = 1;
 956                 else
 957                         cs_project_is_b0rked = -1;
 958                 cvar_set("vid_conwidth", w0);
 959                 cvar_set("vid_conheight", h0);
 960         }
 961
 962         if(autocvar__hud_configure)
 963                 HUD_Panel_Mouse();
 964
 965         // let's reset the view back to normal for the end
 966         R_SetView(VF_MIN, '0 0 0');
 967         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
 968 }
 969
 970 #define spider_h "gfx/vehicles/hud_bg.tga"
 971 #define spider_b "gfx/vehicles/sbot.tga"
 972 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 973 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 974 #define spider_s "gfx/vehicles/shiled.tga"
 975 #define spider_a1 "gfx/hud/sb_rocket.tga"
 976 #define spider_a2 "gfx/sb_bullets.tga"
 977
 978 void CSQC_SPIDER_HUD()
 979 {
 980         float rockets, reload, heat, hp, shield;
 981         vector picsize, hudloc;
 982
 983     // Fetch health & ammo stats
 984     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 985         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 986         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 987         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 988         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 989
 990     // Draw the crosshairs
 991     picsize = drawgetimagesize(SPIDER_CROSS);
 992     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 993     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 994     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 995
 996     hudloc_y =  4;
 997     hudloc_x = 4;
 998
 999     picsize = drawgetimagesize(spider_h) * 0.5;
1000     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1001
1002     picsize = drawgetimagesize(spider_a2) * 0.5;
1003     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1004
1005     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1006     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1007     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1008
1009     picsize = drawgetimagesize(spider_a1) * 0.85;
1010     if(rockets == 9)
1011     {
1012         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1013         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1014     }
1015     else
1016     {
1017         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1018         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1019     }
1020
1021     picsize = drawgetimagesize(spider_b) * 0.5;
1022     hudloc_y = 10.5;
1023     hudloc_x = 10.5;
1024
1025     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1026     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1027     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1028     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1029
1030
1031         /*
1032         // Draw health bar
1033         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1034         p = p + '0 1 0' * vid_conheight - '0 32 0';
1035         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1036         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1037         p_y += 8;
1038         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1039         p_x += 256 * hp;
1040         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1041
1042         // Draw minigun heat indicator
1043         p = '0.5 0 0' * (vid_conwidth - 256);
1044         p = p + '0 1 0' * vid_conheight - '0 34  0';
1045         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1046         p_x += 256 * (1-heat);
1047         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1048
1049
1050         // Draw rocket icons for loaded/empty tubes.
1051         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1052         pp += '0 1 0' * vid_conheight - '0 64 0';
1053         for(i = 0; i < 8; ++i)
1054         {
1055                 p = pp + '1 0 0' * (rkt_size * i);
1056                 if(rockets == 8)
1057                 {
1058                         if(floor(reload * 8) == i)
1059                         {
1060                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1061                         }
1062                         else if(i < reload * 8)
1063                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1064                         else
1065                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1066                 }
1067                 else
1068                 {
1069                         if(i < rockets)
1070                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1071                         else
1072                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1073                 }
1074         }
1075         */
1076
1077         if (scoreboard_showscores)
1078         {
1079                 HUD_DrawScoreboard();
1080                 HUD_DrawCenterPrint();
1081         }
1082
1083 }
1084
1085 #define raptor_h "gfx/vehicles/hud_bg.tga"
1086 #define raptor_b "gfx/vehicles/raptor.tga"
1087 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1088 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1089 #define raptor_s "gfx/vehicles/shiled.tga"
1090
1091 void CSQC_RAPTOR_HUD()
1092 {
1093         float reload, hp, shield, energy;
1094         vector picsize, hudloc;
1095
1096     // Fetch health & ammo stats
1097     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1098         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1099         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1100         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1101
1102     // Draw the crosshairs
1103     picsize = drawgetimagesize(SPIDER_CROSS);
1104     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1105     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1106     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1107
1108     hudloc_y =  4;
1109     hudloc_x = 4;
1110
1111     picsize = drawgetimagesize(raptor_h) * 0.5;
1112     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1113
1114     picsize = drawgetimagesize(spider_a2) * 0.5;
1115     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1116
1117     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1118     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1119     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1120
1121
1122     picsize = drawgetimagesize(spider_a1) * 0.85;
1123     if(reload == 1)
1124     {
1125         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1126         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1127     }
1128     else
1129     {
1130         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1131         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1132     }
1133
1134     picsize = drawgetimagesize(raptor_b) * 0.5;
1135     hudloc_y = 10.5;
1136     hudloc_x = 10.5;
1137
1138     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1139     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1140     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1141     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1142
1143
1144         if (scoreboard_showscores)
1145         {
1146                 HUD_DrawScoreboard();
1147                 HUD_DrawCenterPrint();
1148         }
1149
1150 }
1151
1152 #define waki_h "gfx/vehicles/hud_bg.tga"
1153 #define waki_b "gfx/vehicles/waki.tga"
1154 #define waki_e "gfx/vehicles/waki_e.tga"
1155 #define waki_g "gfx/vehicles/waki_guns.tga"
1156 #define waki_r "gfx/vehicles/waki_rockets.tga"
1157 #define waki_s "gfx/vehicles/shiled.tga"
1158
1159 #define waki_a1 "gfx/hud/sb_rocket.tga"
1160 #define waki_a2 "gfx/sb_cells.tga"
1161
1162 void CSQC_WAKIZASHI_HUD()
1163 {
1164         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1165         float health, shield, energy, rockets;
1166         vector picsize, hudloc;
1167
1168     picsize = drawgetimagesize(SPIDER_CROSS);
1169     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1170     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1171     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1172
1173 /*
1174 const float STAT_VEHICLESTAT_HEALTH  = 60;
1175 const float STAT_VEHICLESTAT_SHIELD  = 61;
1176 const float STAT_VEHICLESTAT_ENERGY  = 62;
1177 const float STAT_VEHICLESTAT_AMMO1   = 63;
1178 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1179 const float STAT_VEHICLESTAT_AMMO2   = 65;
1180 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1181 */
1182     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1183         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1184         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1185         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1186
1187     hudloc_y =  4;
1188     hudloc_x = 4;
1189
1190     picsize = drawgetimagesize(waki_h) * 0.5;
1191     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1192
1193     picsize = drawgetimagesize(waki_a2) * 0.7;
1194     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1195
1196
1197     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1198     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1199
1200     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1201
1202     picsize = drawgetimagesize(waki_a1) * 0.75;
1203     if(rockets == 1)
1204     {
1205         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1206         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1207     }
1208     else
1209     {
1210         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1211         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1212         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1213     }
1214
1215     picsize = drawgetimagesize(waki_b) * 0.5;
1216     hudloc_y = 10.5;
1217     hudloc_x = 10.5;
1218
1219     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1220     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1221     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1222     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1223
1224
1225
1226         /*
1227         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1228         p = p + '0 1 0' * vid_conheight - '0 32 0';
1229
1230         // Draw health bar
1231         p_y += 8;
1232         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1233         p_x += 256 * health;
1234         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1235
1236         // Draw shiled bar
1237         p_x -= 256 * health;
1238         p_y += 4;
1239         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1240
1241         // Draw energy
1242         //p_x -= 256 * health;
1243         p_y -= 8;
1244         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1245
1246         // Draw rockets bar
1247         p_y += 12;
1248         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1249         */
1250
1251
1252
1253
1254         if (scoreboard_showscores)
1255         {
1256                 HUD_DrawScoreboard();
1257                 HUD_DrawCenterPrint();
1258         }
1259
1260 }
1261
1262
1263 void CSQC_common_hud(void)
1264 {
1265         // HUD_SortFrags(); done in HUD_Draw
1266         float hud;
1267         hud = getstati(STAT_HUD);
1268
1269         //hud = 10;
1270         switch(hud)
1271         {
1272                 case HUD_NORMAL:
1273                         // do some accuracy var caching
1274                         float i;
1275                         if(cvar_string("hud_panel_weapons_accuracy_color_levels") != acc_color_levels)
1276                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1277                         {
1278                                 if(acc_color_levels)
1279                                         strunzone(acc_color_levels);
1280                                 acc_color_levels = strzone(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1281                                 acc_levels = tokenize(acc_color_levels);
1282                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1283                                         acc_levels = MAX_ACCURACY_LEVELS;
1284
1285                                 for (i = 0; i < acc_levels; ++i)
1286                                         acc_lev[i] = stof(argv(i));
1287                         }
1288
1289                         HUD_Main(); // always run these functions for alpha checks
1290                         HUD_DrawScoreboard();
1291
1292                         if (scoreboard_active) // scoreboard/accuracy
1293                         {
1294                                 HUD_Reset();
1295                                 // HUD_DrawScoreboard takes care of centerprint_start
1296                         }
1297                         else if (intermission == 2) // map voting screen
1298                         {
1299                                 HUD_FinaleOverlay();
1300                                 HUD_Reset();
1301
1302                                 centerprint_start_x = 0;
1303                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1304                         }
1305                         else // hud
1306                         {
1307                                 centerprint_start_x = 0;
1308                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1309                         }
1310
1311                         HUD_DrawCenterPrint();
1312                         break;
1313
1314                 case HUD_SPIDERBOT:
1315                         CSQC_SPIDER_HUD();
1316                         break;
1317
1318                 case HUD_WAKIZASHI:
1319                         CSQC_WAKIZASHI_HUD();
1320                         break;
1321         }
1322 }
1323
1324
1325 // following vectors must be global to allow seamless switching between camera modes
1326 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1327 void CSQC_Demo_Camera()
1328 {
1329         float speed, attenuation, dimensions;
1330         vector tmp, delta;
1331
1332         if( cvar("camera_reset") || !camera_mode )
1333         {
1334                 camera_offset = '0 0 0';
1335                 current_angles = '0 0 0';
1336                 camera_direction = '0 0 0';
1337                 camera_offset_z += 30;
1338                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1339                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1340                 current_origin = view_origin;
1341                 current_camera_offset  = camera_offset;
1342                 cvar_set("camera_reset", "0");
1343                 camera_mode = CAMERA_CHASE;
1344         }
1345
1346         // Camera angles
1347         if( camera_roll )
1348                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1349
1350         if(cvar("camera_look_player"))
1351         {
1352                 local vector dir;
1353                 local float n;
1354
1355                 dir = normalize(view_origin - current_position);
1356                 n = mouse_angles_z;
1357                 mouse_angles = vectoangles(dir);
1358                 mouse_angles_x = mouse_angles_x * -1;
1359                 mouse_angles_z = n;
1360         }
1361         else
1362         {
1363                 tmp = getmousepos() * 0.1;
1364                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1365                 {
1366                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1367                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1368                 }
1369         }
1370
1371         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1372         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1373         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1374         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1375
1376         // Fix difference when angles don't have the same sign
1377         delta = '0 0 0';
1378         if(mouse_angles_y < -60 && current_angles_y > 60)
1379                 delta = '0 360 0';
1380         if(mouse_angles_y > 60 && current_angles_y < -60)
1381                 delta = '0 -360 0';
1382
1383         if(cvar("camera_look_player"))
1384                 attenuation = cvar("camera_look_attenuation");
1385         else
1386                 attenuation = cvar("camera_speed_attenuation");
1387
1388         attenuation = 1 / max(1, attenuation);
1389         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1390
1391         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1392         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1393         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1394         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1395
1396         // Camera position
1397         tmp = '0 0 0';
1398         dimensions = 0;
1399
1400         if( camera_direction_x )
1401         {
1402                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1403                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1404                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1405                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1406                 ++dimensions;
1407         }
1408
1409         if( camera_direction_y )
1410         {
1411                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1412                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1413                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1414                 ++dimensions;
1415         }
1416
1417         if( camera_direction_z )
1418         {
1419                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1420                 ++dimensions;
1421         }
1422
1423         if(cvar("camera_free"))
1424                 speed = cvar("camera_speed_free");
1425         else
1426                 speed = cvar("camera_speed_chase");
1427
1428         if(dimensions)
1429         {
1430                 speed = speed * sqrt(1 / dimensions);
1431                 camera_offset += tmp * speed;
1432         }
1433
1434         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1435
1436         // Camera modes
1437         if( cvar("camera_free") )
1438         {
1439                 if ( camera_mode == CAMERA_CHASE )
1440                 {
1441                         current_camera_offset = current_origin + current_camera_offset;
1442                         camera_offset = current_origin + camera_offset;
1443                 }
1444
1445                 camera_mode = CAMERA_FREE;
1446                 current_position = current_camera_offset;
1447         }
1448         else
1449         {
1450                 if ( camera_mode == CAMERA_FREE )
1451                 {
1452                         current_origin = view_origin;
1453                         camera_offset = camera_offset - current_origin;
1454                         current_camera_offset = current_camera_offset - current_origin;
1455                 }
1456
1457                 camera_mode = CAMERA_CHASE;
1458
1459                 if(cvar("camera_chase_smoothly"))
1460                         current_origin += (view_origin - current_origin) * attenuation;
1461                 else
1462                         current_origin = view_origin;
1463
1464                 current_position = current_origin + current_camera_offset;
1465         }
1466
1467         R_SetView(VF_ANGLES, current_angles);
1468         R_SetView(VF_ORIGIN, current_position);
1469 }