qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107         if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir) { zoomin_effect = 0; }
 127
 128         if(camera_active)
 129         {
 130                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 131         }
 132         else if(autocvar_cl_spawnzoom && zoomin_effect)
 133         {
 134                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 135
 136                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 137                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 138                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 139         }
 140         else
 141         {
 142                 if(zoomspeed < 0) // instant zoom
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / zoomfactor;
 146                         else
 147                                 current_viewzoom = 1;
 148                 }
 149                 else
 150                 {
 151                         if(zoomdir)
 152                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 153                         else
 154                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 155                 }
 156         }
 157
 158         if(almost_equals(current_viewzoom, 1))
 159                 current_zoomfraction = 0;
 160         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 161                 current_zoomfraction = 1;
 162         else
 163                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 164
 165         if(zoomsensitivity < 1)
 166                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 167         else
 168                 setsensitivityscale(1);
 169
 170         makevectors(view_angles);
 171
 172         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 173         {
 174                 v = pmove_vel;
 175                 if(csqcplayer)
 176                         v = csqcplayer.velocity;
 177
 178                 switch(autocvar_cl_velocityzoom_type)
 179                 {
 180                         case 3: curspeed = max(0, v_forward * v); break;
 181                         case 2: curspeed = (v_forward * v); break;
 182                         case 1: default: curspeed = vlen(v); break;
 183                 }
 184
 185                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 186                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 187                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 188
 189                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 190         }
 191         else
 192                 velocityzoom = 1;
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t, n;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_ent)
 241                 n = trace_ent.entnum;
 242         else
 243                 n = trace_networkentity;
 244         if(n < 1)
 245                 return SHOTTYPE_HITWORLD;
 246         if(n > maxclients)
 247                 return SHOTTYPE_HITWORLD;
 248         t = GetPlayerColor(n - 1);
 249         if(teamplay)
 250                 if(t == myteam)
 251                         return SHOTTYPE_HITTEAM;
 252         if(t == NUM_SPECTATOR)
 253                 return SHOTTYPE_HITWORLD;
 254         return SHOTTYPE_HITENEMY;
 255 }
 256
 257 float TrueAimCheck()
 258 {
 259         float nudge = 1; // added to traceline target and subtracted from result
 260         vector vecs, trueaimpoint, w_shotorg;
 261         vector mi, ma, dv;
 262         float shottype;
 263         entity ta;
 264         float mv;
 265
 266         mi = ma = '0 0 0';
 267         ta = trueaim;
 268         mv = MOVE_NOMONSTERS;
 269
 270         switch(activeweapon)
 271         {
 272                 case WEP_TUBA: // no aim
 273                 case WEP_PORTO: // shoots from eye
 274                 case WEP_HOOK: // no trueaim
 275                 case WEP_GRENADE_LAUNCHER: // toss curve
 276                         return SHOTTYPE_HITWORLD;
 277                 case WEP_NEX:
 278                 case WEP_MINSTANEX:
 279                         mv = MOVE_NORMAL;
 280                         break;
 281                 case WEP_RIFLE:
 282                         ta = trueaim_rifle;
 283                         mv = MOVE_NORMAL;
 284                         if(zoomscript_caught)
 285                         {
 286                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 287                                 return EnemyHitCheck();
 288                         }
 289                         break;
 290                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 291                         mi = '-3 -3 -3';
 292                         ma = '3 3 3';
 293                         break;
 294                 case WEP_FIREBALL: // projectile has a size!
 295                         mi = '-16 -16 -16';
 296                         ma = '16 16 16';
 297                         break;
 298                 case WEP_SEEKER: // projectile has a size!
 299                         mi = '-2 -2 -2';
 300                         ma = '2 2 2';
 301                         break;
 302                 case WEP_ELECTRO: // projectile has a size!
 303                         mi = '0 0 -3';
 304                         ma = '0 0 -3';
 305                         break;
 306         }
 307
 308         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 309
 310         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 311         trueaimpoint = trace_endpos;
 312
 313         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 314                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 315
 316         if(vecs_x > 0)
 317                 vecs_y = -vecs_y;
 318         else
 319                 vecs = '0 0 0';
 320
 321         dv = view_right * vecs_y + view_up * vecs_z;
 322         w_shotorg = view_origin + dv;
 323
 324         // now move the vecs forward as much as requested if possible
 325         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 326         w_shotorg = trace_endpos - view_forward * nudge;
 327
 328         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 329         shottype = EnemyHitCheck();
 330         if(shottype != SHOTTYPE_HITWORLD)
 331                 return shottype;
 332
 333 #if 0
 334         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 335         // or rather, I know why, but see no fix
 336         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 337                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 338                 return SHOTTYPE_HITOBSTRUCTION;
 339 #endif
 340
 341         return SHOTTYPE_HITWORLD;
 342 }
 343
 344 void CSQC_common_hud(void);
 345
 346 void PostInit(void);
 347 void CSQC_Demo_Camera();
 348 float HUD_WouldDrawScoreboard();
 349 float camera_mode;
 350 float CAMERA_FREE = 1;
 351 float CAMERA_CHASE = 2;
 352 float reticle_type;
 353 string NextFrameCommand;
 354 void CSQC_SPIDER_HUD();
 355 void CSQC_RAPTOR_HUD();
 356
 357 vector freeze_org, freeze_ang;
 358 entity nightvision_noise, nightvision_noise2;
 359
 360 #define MAX_TIME_DIFF 5
 361 float pickup_crosshair_time, pickup_crosshair_size;
 362 float hit_time, typehit_time;
 363 float nextsound_hit_time, nextsound_typehit_time;
 364 float hitindication_crosshair_time, hitindication_crosshair_size;
 365 float use_nex_chargepool;
 366
 367 float myhealth, myhealth_prev;
 368 float myhealth_flash;
 369
 370 float old_blurradius, old_bluralpha;
 371 float old_sharpen_intensity;
 372
 373 vector myhealth_gentlergb;
 374
 375 float contentavgalpha, liquidalpha_prev;
 376 vector liquidcolor_prev;
 377
 378 float eventchase_current_distance;
 379
 380 vector damage_blurpostprocess, content_blurpostprocess;
 381
 382 float checkfail[16];
 383
 384 #define BUTTON_3 4
 385 #define BUTTON_4 8
 386 float cl_notice_run();
 387 void CSQC_UpdateView(float w, float h)
 388 {
 389         entity e;
 390         float fov;
 391         float f, i, j;
 392         vector v;
 393         vector vf_size, vf_min;
 394         float a;
 395
 396         execute_next_frame();
 397
 398         ++framecount;
 399
 400         hud = getstati(STAT_HUD);
 401
 402         if(autocvar__hud_showbinds_reload) // menu can set this one
 403         {
 404                 db_close(binddb);
 405                 binddb = db_create();
 406                 cvar_set("_hud_showbinds_reload", "0");
 407         }
 408
 409         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 410                 view_quality = getproperty(VF_MINFPS_QUALITY);
 411         else
 412                 view_quality = 1;
 413
 414         button_attack2 = (input_buttons & BUTTON_3);
 415         button_zoom = (input_buttons & BUTTON_4);
 416
 417 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 418         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 419         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 420         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 421         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 422         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 423         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 424         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 425
 426         vf_size = getpropertyvec(VF_SIZE);
 427         vf_min = getpropertyvec(VF_MIN);
 428         vid_width = vf_size_x;
 429         vid_height = vf_size_y;
 430
 431         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 432         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 433
 434         WaypointSprite_Load();
 435
 436         CSQCPlayer_SetCamera();
 437
 438 #ifdef COMPAT_XON050_ENGINE
 439         if(spectatee_status)
 440                 myteam = GetPlayerColor(spectatee_status - 1);
 441         else
 442 #endif
 443                 myteam = GetPlayerColor(player_localentnum - 1);
 444
 445         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 446
 447         float is_dead = (getstati(STAT_HEALTH) <= 0);
 448
 449         // FIXME do we need this hack?
 450         if(isdemo())
 451         {
 452                 // in demos, input_buttons do not work
 453                 button_zoom = (autocvar__togglezoom == "-");
 454         }
 455         else if(button_zoom
 456                 && autocvar_cl_unpress_zoom_on_death
 457                 && (spectatee_status >= 0)
 458                 && (is_dead || intermission))
 459         {
 460                 // no zoom while dead or in intermission please
 461                 localcmd("-zoom\n");
 462                 button_zoom = FALSE;
 463         }
 464
 465         // event chase camera
 466         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 467         {
 468                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead) || intermission)
 469                 {
 470                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 471                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_cl_eventchase_viewoffset);
 472
 473                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 474                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 475                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 476                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 477
 478                         // make the camera smooth back
 479                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 480                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 481                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 482                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 483
 484                         makevectors(view_angles);
 485
 486                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 487                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 488
 489                         // If the boxtrace fails, revert back to line tracing.
 490                         if(trace_startsolid)
 491                         {
 492                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 493                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 494                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 495                         }
 496                         else { setproperty(VF_ORIGIN, trace_endpos); }
 497
 498                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 499                 }
 500                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 501                 {
 502                         cvar_set("chase_active", "0");
 503                         eventchase_current_distance = 0; // start from 0 next time
 504                 }
 505         }
 506         // workaround for camera stuck between player's legs when using chase_active 1
 507         // because the engine stops updating the chase_active camera when the game ends
 508         else if(intermission)
 509         {
 510                 cvar_settemp("chase_active", "-1");
 511                 eventchase_current_distance = 0;
 512         }
 513
 514         // do lockview after event chase camera so that it still applies whenever necessary.
 515         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 516         {
 517                 setproperty(VF_ORIGIN, freeze_org);
 518                 setproperty(VF_ANGLES, freeze_ang);
 519         }
 520         else
 521         {
 522                 freeze_org = getpropertyvec(VF_ORIGIN);
 523                 freeze_ang = getpropertyvec(VF_ANGLES);
 524         }
 525
 526         WarpZone_FixView();
 527         //WarpZone_FixPMove();
 528
 529         // Render the Scene
 530         view_origin = getpropertyvec(VF_ORIGIN);
 531         view_angles = getpropertyvec(VF_ANGLES);
 532         makevectors(view_angles);
 533         view_forward = v_forward;
 534         view_right = v_right;
 535         view_up = v_up;
 536
 537 #ifdef BLURTEST
 538         if(time > blurtest_time0 && time < blurtest_time1)
 539         {
 540                 float r, t;
 541
 542                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 543                 r = t * blurtest_radius;
 544                 f = 1 / pow(t, blurtest_power) - 1;
 545
 546                 cvar_set("r_glsl_postprocess", "1");
 547                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 548         }
 549         else
 550         {
 551                 cvar_set("r_glsl_postprocess", "0");
 552                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 553         }
 554 #endif
 555
 556         TargetMusic_Advance();
 557         Fog_Force();
 558
 559         if(drawtime == 0)
 560                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 561         else
 562                 drawframetime = bound(0.000001, time - drawtime, 1);
 563         drawtime = time;
 564
 565         // watch for gametype changes here...
 566         // in ParseStuffCMD the cmd isn't executed yet :/
 567         // might even be better to add the gametype to TE_CSQC_INIT...?
 568         if(!postinit)
 569                 PostInit();
 570
 571         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 572         {
 573                 if(calledhooks & HOOK_START)
 574                 {
 575                         localcmd("\ncl_hook_gameend\n");
 576                         calledhooks |= HOOK_END;
 577                 }
 578         }
 579
 580         Announcer();
 581
 582         fov = autocvar_fov;
 583         if(fov <= 59.5)
 584         {
 585                 if(!zoomscript_caught)
 586                 {
 587                         localcmd("+button9\n");
 588                         zoomscript_caught = 1;
 589                 }
 590         }
 591         else
 592         {
 593                 if(zoomscript_caught)
 594                 {
 595                         localcmd("-button9\n");
 596                         zoomscript_caught = 0;
 597                 }
 598         }
 599
 600         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 601
 602         // next WANTED weapon (for HUD)
 603         switchweapon = getstati(STAT_SWITCHWEAPON);
 604
 605         // currently switching-to weapon (for crosshair)
 606         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 607
 608         // actually active weapon (for zoom)
 609         activeweapon = getstati(STAT_ACTIVEWEAPON);
 610
 611         f = (serverflags & SERVERFLAG_TEAMPLAY);
 612         if(f != teamplay)
 613         {
 614                 teamplay = f;
 615                 HUD_InitScores();
 616         }
 617
 618         if(last_switchweapon != switchweapon)
 619         {
 620                 weapontime = time;
 621                 last_switchweapon = switchweapon;
 622                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 623                 {
 624                         localcmd("-zoom\n");
 625                         button_zoom = FALSE;
 626                 }
 627                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 628                 {
 629                         localcmd("-fire\n");
 630                         localcmd("-fire2\n");
 631                         button_attack2 = FALSE;
 632                 }
 633         }
 634         if(last_activeweapon != activeweapon)
 635         {
 636                 last_activeweapon = activeweapon;
 637
 638                 e = get_weaponinfo(activeweapon);
 639                 if(e.netname != "")
 640                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 641                 else
 642                         localcmd("\ncl_hook_activeweapon none\n");
 643         }
 644
 645         // ALWAYS Clear Current Scene First
 646         clearscene();
 647 #ifdef WORKAROUND_XON010
 648         if(checkextension("DP_CSQC_ROTATEMOVES"))
 649         {
 650 #endif
 651         setproperty(VF_ORIGIN, view_origin);
 652         setproperty(VF_ANGLES, view_angles);
 653 #ifdef WORKAROUND_XON010
 654         }
 655 #endif
 656
 657         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 658         setproperty(VF_SIZE, vf_size);
 659         setproperty(VF_MIN, vf_min);
 660
 661         // Assign Standard Viewflags
 662         // Draw the World (and sky)
 663         setproperty(VF_DRAWWORLD, 1);
 664
 665         // Set the console size vars
 666         vid_conwidth = autocvar_vid_conwidth;
 667         vid_conheight = autocvar_vid_conheight;
 668         vid_pixelheight = autocvar_vid_pixelheight;
 669
 670         setproperty(VF_FOV, GetCurrentFov(fov));
 671
 672         // Camera for demo playback
 673         if(camera_active)
 674         {
 675                 if(autocvar_camera_enable)
 676                         CSQC_Demo_Camera();
 677                 else
 678                 {
 679                         cvar_set("chase_active", ftos(chase_active_backup));
 680                         cvar_set("cl_demo_mousegrab", "0");
 681                         camera_active = FALSE;
 682                 }
 683         }
 684 #ifdef CAMERATEST
 685         else if(autocvar_camera_enable)
 686 #else
 687         else if(autocvar_camera_enable && isdemo())
 688 #endif
 689         {
 690                 // Enable required Darkplaces cvars
 691                 chase_active_backup = autocvar_chase_active;
 692                 cvar_set("chase_active", "2");
 693                 cvar_set("cl_demo_mousegrab", "1");
 694                 camera_active = TRUE;
 695                 camera_mode = FALSE;
 696         }
 697
 698         // Draw the Crosshair
 699         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 700
 701         // Draw the Engine Status Bar (the default Quake HUD)
 702         setproperty(VF_DRAWENGINESBAR, 0);
 703
 704         // Update the mouse position
 705         /*
 706            mousepos_x = vid_conwidth;
 707            mousepos_y = vid_conheight;
 708            mousepos = mousepos*0.5 + getmousepos();
 709          */
 710
 711         e = self;
 712         for(self = world; (self = nextent(self)); )
 713                 if(self.draw)
 714                         self.draw();
 715         self = e;
 716
 717         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 718         renderscene();
 719
 720         // now switch to 2D drawing mode by calling a 2D drawing function
 721         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 722         // next R_RenderScene call
 723         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 724
 725         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 726         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 727         {
 728                 // apply night vision effect
 729                 vector tc_00, tc_01, tc_10, tc_11;
 730                 vector rgb;
 731                 rgb_x = 0; // fteqcc sucks
 732                 rgb_y = 0; // fteqcc sucks
 733                 rgb_z = 0; // fteqcc sucks
 734
 735                 if(!nightvision_noise)
 736                 {
 737                         nightvision_noise = spawn();
 738                         nightvision_noise.classname = "nightvision_noise";
 739                 }
 740                 if(!nightvision_noise2)
 741                 {
 742                         nightvision_noise2 = spawn();
 743                         nightvision_noise2.classname = "nightvision_noise2";
 744                 }
 745
 746                 // color tint in yellow
 747                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 748
 749                 // draw BG
 750                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 751                 rgb = '1 1 1';
 752                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 753                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 754                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 755                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 756                 tc_11 = tc_01 + tc_10 - tc_00;
 757                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 758                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 759                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 760                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 761                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 762                 R_EndPolygon();
 763
 764                 // draw FG
 765                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 766                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 767                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 768                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 769                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 770                 tc_11 = tc_01 + tc_10 - tc_00;
 771                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 772                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 773                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 774                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 775                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 776                 R_EndPolygon();
 777         }
 778
 779         // Draw the aiming reticle for weapons that use it
 780         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 781         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 782         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 783         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 784                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 785         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 786                 reticle_type = 2; // nex zoom
 787         else if(button_zoom || zoomscript_caught)
 788                 reticle_type = 1; // normal zoom
 789         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 790                 reticle_type = 2; // nex zoom
 791
 792         if(reticle_type && autocvar_cl_reticle)
 793         {
 794                 if(autocvar_cl_reticle_stretch)
 795                 {
 796                         reticle_size_x = vid_conwidth;
 797                         reticle_size_y = vid_conheight;
 798                         reticle_pos_x = 0;
 799                         reticle_pos_y = 0;
 800                 }
 801                 else
 802                 {
 803                         reticle_size_x = max(vid_conwidth, vid_conheight);
 804                         reticle_size_y = max(vid_conwidth, vid_conheight);
 805                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 806                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 807                 }
 808
 809                 f = current_zoomfraction;
 810                 if(zoomscript_caught)
 811                         f = 1;
 812                 if(autocvar_cl_reticle_item_normal)
 813                 {
 814                         if(reticle_type == 1 && f)
 815                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 816                 }
 817                 if(autocvar_cl_reticle_item_nex)
 818                 {
 819                         if(reticle_type == 2 && f)
 820                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 821                 }
 822         }
 823
 824
 825         // improved polyblend
 826         if(autocvar_hud_contents)
 827         {
 828                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 829                 vector liquidcolor;
 830
 831                 switch(pointcontents(view_origin))
 832                 {
 833                         case CONTENT_WATER:
 834                                 liquidalpha = autocvar_hud_contents_water_alpha;
 835                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 836                                 incontent = 1;
 837                                 break;
 838
 839                         case CONTENT_LAVA:
 840                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 841                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 842                                 incontent = 1;
 843                                 break;
 844
 845                         case CONTENT_SLIME:
 846                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 847                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 848                                 incontent = 1;
 849                                 break;
 850
 851                         default:
 852                                 liquidalpha = 0;
 853                                 liquidcolor = '0 0 0';
 854                                 incontent = 0;
 855                                 break;
 856                 }
 857
 858                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 859                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 860                         contentfadetime = autocvar_hud_contents_fadeintime;
 861                         liquidalpha_prev = liquidalpha;
 862                         liquidcolor_prev = liquidcolor;
 863                 }
 864                 else
 865                         contentfadetime = autocvar_hud_contents_fadeouttime;
 866
 867                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 868                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 869
 870                 if(contentavgalpha)
 871                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 872
 873                 if(autocvar_hud_postprocessing)
 874                 {
 875                         if(autocvar_hud_contents_blur && contentavgalpha)
 876                         {
 877                                 content_blurpostprocess_x = 1;
 878                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 879                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 880                         }
 881                         else
 882                         {
 883                                 content_blurpostprocess_x = 0;
 884                                 content_blurpostprocess_y = 0;
 885                                 content_blurpostprocess_z = 0;
 886                         }
 887                 }
 888         }
 889
 890         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 891         {
 892                 splash_size_x = max(vid_conwidth, vid_conheight);
 893                 splash_size_y = max(vid_conwidth, vid_conheight);
 894                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 895                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 896
 897                 float myhealth_flash_temp;
 898                 myhealth = getstati(STAT_HEALTH);
 899
 900                 // fade out
 901                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 902                 // add new damage
 903                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 904
 905                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 906                 pain_threshold = autocvar_hud_damage_pain_threshold;
 907                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 908                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 909
 910                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 911                 {
 912                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 913                 }
 914
 915                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 916
 917                 if(myhealth_prev < 1)
 918                 {
 919                         if(myhealth >= 1)
 920                         {
 921                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 922                                 myhealth_flash_temp = 0;
 923                         }
 924                         else
 925                         {
 926                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 927                         }
 928                 }
 929
 930                 if(spectatee_status == -1 || intermission)
 931                 {
 932                         myhealth_flash = 0; // observing, or match ended
 933                         myhealth_flash_temp = 0;
 934                 }
 935
 936                 myhealth_prev = myhealth;
 937
 938                 // IDEA: change damage color/picture based on player model for robot/alien species?
 939                 // pro: matches model better
 940                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 941                 // maybe different reddish pics?
 942                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 943                 {
 944                         if(autocvar_cl_gentle_damage == 2)
 945                         {
 946                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 947                                 {
 948                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 949                                 }
 950                         }
 951                         else
 952                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 953
 954                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 955                 }
 956                 else
 957                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 958
 959                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 960                 {
 961                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 962                         {
 963                                 damage_blurpostprocess_x = 1;
 964                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 965                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 966                         }
 967                         else
 968                         {
 969                                 damage_blurpostprocess_x = 0;
 970                                 damage_blurpostprocess_y = 0;
 971                                 damage_blurpostprocess_z = 0;
 972                         }
 973                 }
 974         }
 975
 976         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 977         float e2 = (autocvar_hud_powerup != 0);
 978         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 979         {
 980                 // enable or disable rendering types if they are used or not
 981                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 982                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 983
 984                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 985                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
 986                 {
 987                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 988                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 989                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 990                         {
 991                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 992                                 old_blurradius = blurradius;
 993                                 old_bluralpha = bluralpha;
 994                         }
 995                 }
 996                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 997                 {
 998                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 999                         old_blurradius = 0;
1000                         old_bluralpha = 0;
1001                 }
1002
1003                 // edge detection postprocess handling done second (used by hud_powerup)
1004                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1005                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1006                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1007
1008                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1009
1010                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1011                 {
1012                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1013                         {
1014                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1015                                 old_sharpen_intensity = sharpen_intensity;
1016                         }
1017                 }
1018                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1019                 {
1020                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1021                         old_sharpen_intensity = 0;
1022                 }
1023
1024                 if(cvar("r_glsl_postprocess") == 0)
1025                         cvar_set("r_glsl_postprocess", "2");
1026         }
1027         else if(cvar("r_glsl_postprocess") == 2)
1028                 cvar_set("r_glsl_postprocess", "0");
1029
1030         if(menu_visible)
1031                 menu_show();
1032
1033         /*if(gametype == MAPINFO_TYPE_CTF)
1034           {
1035           ctf_view();
1036           } else */
1037
1038         // draw 2D entities
1039         e = self;
1040         for(self = world; (self = nextent(self)); )
1041                 if(self.draw2d)
1042                         self.draw2d();
1043         self = e;
1044         Draw_ShowNames_All();
1045
1046         scoreboard_active = HUD_WouldDrawScoreboard();
1047
1048         hit_time = getstatf(STAT_HIT_TIME);
1049         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1050         {
1051                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1052                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1053
1054                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1055         }
1056         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1057         if(typehit_time > nextsound_typehit_time)
1058         {
1059                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1060                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1061
1062                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1063         }
1064
1065         //else
1066         {
1067                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1068                 {
1069                         if(getstati(STAT_FROZEN))
1070                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1071                         if(getstatf(STAT_REVIVE_PROGRESS))
1072                         {
1073                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1074                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1075                         }
1076                 }
1077
1078                 if(autocvar_r_letterbox == 0)
1079                         if(autocvar_viewsize < 120)
1080                                 CSQC_common_hud();
1081
1082                 // crosshair goes VERY LAST
1083                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1084                 {
1085                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1086                                 return;
1087
1088                         string wcross_style;
1089                         float wcross_alpha, wcross_resolution;
1090                         wcross_style = autocvar_crosshair;
1091                         if (wcross_style == "0")
1092                                 return;
1093                         wcross_resolution = autocvar_crosshair_size;
1094                         if (wcross_resolution == 0)
1095                                 return;
1096                         wcross_alpha = autocvar_crosshair_alpha;
1097                         if (wcross_alpha == 0)
1098                                 return;
1099
1100                         // TrueAim check
1101                         float shottype;
1102
1103                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1104                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1105                         wcross_origin_z = 0;
1106                         if(autocvar_crosshair_hittest)
1107                         {
1108                                 vector wcross_oldorigin;
1109                                 wcross_oldorigin = wcross_origin;
1110                                 shottype = TrueAimCheck();
1111                                 if(shottype == SHOTTYPE_HITWORLD)
1112                                 {
1113                                         v = wcross_origin - wcross_oldorigin;
1114                                         v_x /= vid_conwidth;
1115                                         v_y /= vid_conheight;
1116                                         if(vlen(v) > 0.01)
1117                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1118                                 }
1119                                 if(!autocvar_crosshair_hittest_showimpact)
1120                                         wcross_origin = wcross_oldorigin;
1121                         }
1122                         else
1123                                 shottype = SHOTTYPE_HITWORLD;
1124
1125                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1126                         string wcross_wep = "", wcross_name;
1127                         float wcross_scale, wcross_blur;
1128
1129                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1130                                 e = get_weaponinfo(switchingweapon);
1131                                 if (e && e.netname != "")
1132                                 {
1133                                         wcross_wep = e.netname;
1134                                         if(autocvar_crosshair_per_weapon)
1135                                         {
1136                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1137                                                 if (wcross_resolution == 0)
1138                                                         return;
1139                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1140                                                 if (wcross_alpha == 0)
1141                                                         return;
1142
1143                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1144                                                 if(wcross_style == "" || wcross_style == "0")
1145                                                         wcross_style = wcross_wep;
1146                                         }
1147                                 }
1148                         }
1149                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1150                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1151                         else if(autocvar_crosshair_color_by_health)
1152                         {
1153                                 float x = getstati(STAT_HEALTH);
1154
1155                                 //x = red
1156                                 //y = green
1157                                 //z = blue
1158
1159                                 wcross_color_z = 0;
1160
1161                                 if(x > 200)
1162                                 {
1163                                         wcross_color_x = 0;
1164                                         wcross_color_y = 1;
1165                                 }
1166                                 else if(x > 150)
1167                                 {
1168                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1169                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1170                                 }
1171                                 else if(x > 100)
1172                                 {
1173                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1174                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1175                                         wcross_color_z = 1 - (x-100)*0.02;
1176                                 }
1177                                 else if(x > 50)
1178                                 {
1179                                         wcross_color_x = 1;
1180                                         wcross_color_y = 1;
1181                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1182                                 }
1183                                 else if(x > 20)
1184                                 {
1185                                         wcross_color_x = 1;
1186                                         wcross_color_y = (x-20)*90/27/100;
1187                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1188                                 }
1189                                 else
1190                                 {
1191                                         wcross_color_x = 1;
1192                                         wcross_color_y = 0;
1193                                 }
1194                         }
1195                         else
1196                                 wcross_color = stov(autocvar_crosshair_color);
1197
1198                         wcross_name = strcat("gfx/crosshair", wcross_style);
1199
1200                         if(autocvar_crosshair_effect_scalefade)
1201                         {
1202                                 wcross_scale = wcross_resolution;
1203                                 wcross_resolution = 1;
1204                         }
1205                         else
1206                         {
1207                                 wcross_scale = 1;
1208                         }
1209
1210                         if(autocvar_crosshair_pickup)
1211                         {
1212                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1213
1214                                 if(pickup_crosshair_time < stat_pickup_time)
1215                                 {
1216                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1217                                                 pickup_crosshair_size = 1;
1218
1219                                         pickup_crosshair_time = stat_pickup_time;
1220                                 }
1221
1222                                 if(pickup_crosshair_size > 0)
1223                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1224                                 else
1225                                         pickup_crosshair_size = 0;
1226
1227                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1228                         }
1229
1230                         if(autocvar_crosshair_hitindication)
1231                         {
1232                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1233
1234                                 if(hitindication_crosshair_time < hit_time)
1235                                 {
1236                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1237                                                 hitindication_crosshair_size = 1;
1238
1239                                         hitindication_crosshair_time = hit_time;
1240                                 }
1241
1242                                 if(hitindication_crosshair_size > 0)
1243                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1244                                 else
1245                                         hitindication_crosshair_size = 0;
1246
1247                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1248                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1249                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1250                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1251                         }
1252
1253                         if(shottype == SHOTTYPE_HITENEMY)
1254                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1255                         if(shottype == SHOTTYPE_HITTEAM)
1256                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1257
1258                         f = autocvar_crosshair_effect_speed;
1259                         if(f < 0)
1260                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1261                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1262                         {
1263                                 wcross_changedonetime = time + f;
1264                         }
1265                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1266                         {
1267                                 wcross_name_changestarttime = time;
1268                                 wcross_name_changedonetime = time + f;
1269                                 if(wcross_name_goal_prev_prev)
1270                                         strunzone(wcross_name_goal_prev_prev);
1271                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1272                                 wcross_name_goal_prev = strzone(wcross_name);
1273                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1274                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1275                                 wcross_resolution_goal_prev = wcross_resolution;
1276                         }
1277
1278                         wcross_scale_goal_prev = wcross_scale;
1279                         wcross_alpha_goal_prev = wcross_alpha;
1280                         wcross_color_goal_prev = wcross_color;
1281
1282                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1283                         {
1284                                 wcross_blur = 1;
1285                                 wcross_alpha *= 0.75;
1286                         }
1287                         else
1288                                 wcross_blur = 0;
1289                         // *_prev is at time-frametime
1290                         // * is at wcross_changedonetime+f
1291                         // what do we have at time?
1292                         if(time < wcross_changedonetime)
1293                         {
1294                                 f = frametime / (wcross_changedonetime - time + frametime);
1295                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1296                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1297                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1298                         }
1299
1300                         wcross_scale_prev = wcross_scale;
1301                         wcross_alpha_prev = wcross_alpha;
1302                         wcross_color_prev = wcross_color;
1303
1304                         wcross_scale *= 1 - autocvar__menu_alpha;
1305                         wcross_alpha *= 1 - autocvar__menu_alpha;
1306                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1307
1308                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1309                         {
1310                                 // crosshair rings for weapon stats
1311                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1312                                 {
1313                                         // declarations and stats
1314                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1315                                         string ring_image = string_null, ring_inner_image = string_null;
1316                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1317
1318                                         ring_scale = autocvar_crosshair_ring_size;
1319
1320                                         float weapon_clipload, weapon_clipsize;
1321                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1322                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1323
1324                                         float nex_charge, nex_chargepool;
1325                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1326                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1327
1328                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1329                                                 nex_charge_movingavg = nex_charge;
1330
1331
1332                                         // handle the values
1333                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1334                                         {
1335                                                 if (nex_chargepool || use_nex_chargepool) {
1336                                                         use_nex_chargepool = 1;
1337                                                         ring_inner_value = nex_chargepool;
1338                                                 } else {
1339                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1340                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1341                                                 }
1342
1343                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1344                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1345                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1346
1347                                                 // draw the outer ring to show the current charge of the weapon
1348                                                 ring_value = nex_charge;
1349                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1350                                                 ring_rgb = wcross_color;
1351                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1352                                         }
1353                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1354                                         {
1355                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1356                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1357                                                 ring_rgb = wcross_color;
1358                                                 ring_image = "gfx/crosshair_ring.tga";
1359                                         }
1360                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1361                                         {
1362                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1363                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1364                                                 ring_rgb = wcross_color;
1365                                                 ring_image = "gfx/crosshair_ring.tga";
1366                                         }
1367
1368                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1369                                         {
1370                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1371                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1372                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1373                                                 ring_rgb = wcross_color;
1374
1375                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1376                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1377                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1378                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1379                                                 else
1380                                                         ring_image = "gfx/crosshair_ring.tga";
1381                                         }
1382
1383                                         // if in weapon switch animation, fade ring out/in
1384                                         if(g_weaponswitchdelay > 0)
1385                                         {
1386                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1387                                                 if(f > 0 && f < 2)
1388                                                         ring_alpha *= fabs(1 - f);
1389                                         }
1390
1391                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1392                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1393
1394                                         if (ring_value)
1395                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1396                                 }
1397
1398 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1399                                 do \
1400                                 { \
1401                                         if(wcross_blur > 0) \
1402                                         { \
1403                                                 for(i = -2; i <= 2; ++i) \
1404                                                 for(j = -2; j <= 2; ++j) \
1405                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1406                                         } \
1407                                         else \
1408                                         { \
1409                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1410                                         } \
1411                                 } \
1412                                 while(0)
1413
1414 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1415                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1416
1417 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1418                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1419
1420                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1421                                 {
1422                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1423                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1424                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1425                                         f = 1 - f;
1426                                 }
1427                                 else
1428                                 {
1429                                         f = 1;
1430                                 }
1431                                 wcross_name_alpha_goal_prev = f;
1432
1433                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1434                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1435
1436                                 if(autocvar_crosshair_dot)
1437                                 {
1438                                         vector wcross_color_old;
1439                                         wcross_color_old = wcross_color;
1440
1441                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1442                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1443
1444                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1445                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1446                                         wcross_color = wcross_color_old;
1447                                 }
1448                         }
1449                 }
1450                 else
1451                 {
1452                         wcross_scale_prev = 0;
1453                         wcross_alpha_prev = 0;
1454                         wcross_scale_goal_prev = 0;
1455                         wcross_alpha_goal_prev = 0;
1456                         wcross_changedonetime = 0;
1457                         if(wcross_name_goal_prev)
1458                                 strunzone(wcross_name_goal_prev);
1459                         wcross_name_goal_prev = string_null;
1460                         if(wcross_name_goal_prev_prev)
1461                                 strunzone(wcross_name_goal_prev_prev);
1462                         wcross_name_goal_prev_prev = string_null;
1463                         wcross_name_changestarttime = 0;
1464                         wcross_name_changedonetime = 0;
1465                         wcross_name_alpha_goal_prev = 0;
1466                         wcross_name_alpha_goal_prev_prev = 0;
1467                         wcross_resolution_goal_prev = 0;
1468                         wcross_resolution_goal_prev_prev = 0;
1469                 }
1470         }
1471
1472         if(NextFrameCommand)
1473         {
1474                 localcmd("\n", NextFrameCommand, "\n");
1475                 NextFrameCommand = string_null;
1476         }
1477
1478         // we must do this check AFTER a frame was rendered, or it won't work
1479         if(cs_project_is_b0rked == 0)
1480         {
1481                 string w0, h0;
1482                 w0 = ftos(autocvar_vid_conwidth);
1483                 h0 = ftos(autocvar_vid_conheight);
1484                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1485                 //setproperty(VF_FOV, '90 90 0');
1486                 setproperty(VF_ORIGIN, '0 0 0');
1487                 setproperty(VF_ANGLES, '0 0 0');
1488                 setproperty(VF_PERSPECTIVE, 1);
1489                 makevectors('0 0 0');
1490                 vector v1, v2;
1491                 cvar_set("vid_conwidth", "800");
1492                 cvar_set("vid_conheight", "600");
1493                 v1 = cs_project(v_forward);
1494                 cvar_set("vid_conwidth", "640");
1495                 cvar_set("vid_conheight", "480");
1496                 v2 = cs_project(v_forward);
1497                 if(v1 == v2)
1498                         cs_project_is_b0rked = 1;
1499                 else
1500                         cs_project_is_b0rked = -1;
1501                 cvar_set("vid_conwidth", w0);
1502                 cvar_set("vid_conheight", h0);
1503         }
1504
1505         if(autocvar__hud_configure)
1506                 HUD_Panel_Mouse();
1507
1508     if(hud && !intermission)
1509     {
1510         if(hud == HUD_SPIDERBOT)
1511             CSQC_SPIDER_HUD();
1512         else if(hud == HUD_WAKIZASHI)
1513             CSQC_WAKIZASHI_HUD();
1514         else if(hud == HUD_RAPTOR)
1515             CSQC_RAPTOR_HUD();
1516         else if(hud == HUD_BUMBLEBEE)
1517             CSQC_BUMBLE_HUD();
1518         else if(hud == HUD_BUMBLEBEE_GUN)
1519             CSQC_BUMBLE_GUN_HUD();
1520     }
1521
1522         cl_notice_run();
1523
1524         // let's reset the view back to normal for the end
1525         setproperty(VF_MIN, '0 0 0');
1526         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1527 }
1528
1529
1530 void CSQC_common_hud(void)
1531 {
1532         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1533                 Accuracy_LoadLevels();
1534
1535     HUD_Main(); // always run these functions for alpha checks
1536     HUD_DrawScoreboard();
1537
1538     if (scoreboard_active) // scoreboard/accuracy
1539         HUD_Reset();
1540     else if (intermission == 2) // map voting screen
1541     {
1542         HUD_FinaleOverlay();
1543         HUD_Reset();
1544     }
1545         /*
1546         switch(hud)
1547         {
1548                 case HUD_SPIDERBOT:
1549                         CSQC_SPIDER_HUD();
1550                         break;
1551
1552                 case HUD_WAKIZASHI:
1553                         CSQC_WAKIZASHI_HUD();
1554                         break;
1555
1556         case HUD_BUMBLEBEE:
1557             CSQC_BUMBLE_HUD();
1558             break;
1559         }
1560         */
1561 }
1562
1563
1564 // following vectors must be global to allow seamless switching between camera modes
1565 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1566 void CSQC_Demo_Camera()
1567 {
1568         float speed, attenuation, dimensions;
1569         vector tmp, delta;
1570
1571         if( autocvar_camera_reset || !camera_mode )
1572         {
1573                 camera_offset = '0 0 0';
1574                 current_angles = '0 0 0';
1575                 camera_direction = '0 0 0';
1576                 camera_offset_z += 30;
1577                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1578                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1579                 current_origin = view_origin;
1580                 current_camera_offset  = camera_offset;
1581                 cvar_set("camera_reset", "0");
1582                 camera_mode = CAMERA_CHASE;
1583         }
1584
1585         // Camera angles
1586         if( camera_roll )
1587                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1588
1589         if(autocvar_camera_look_player)
1590         {
1591                 vector dir;
1592                 float n;
1593
1594                 dir = normalize(view_origin - current_position);
1595                 n = mouse_angles_z;
1596                 mouse_angles = vectoangles(dir);
1597                 mouse_angles_x = mouse_angles_x * -1;
1598                 mouse_angles_z = n;
1599         }
1600         else
1601         {
1602                 tmp = getmousepos() * 0.1;
1603                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1604                 {
1605                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1606                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1607                 }
1608         }
1609
1610         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1611         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1612         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1613         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1614
1615         // Fix difference when angles don't have the same sign
1616         delta = '0 0 0';
1617         if(mouse_angles_y < -60 && current_angles_y > 60)
1618                 delta = '0 360 0';
1619         if(mouse_angles_y > 60 && current_angles_y < -60)
1620                 delta = '0 -360 0';
1621
1622         if(autocvar_camera_look_player)
1623                 attenuation = autocvar_camera_look_attenuation;
1624         else
1625                 attenuation = autocvar_camera_speed_attenuation;
1626
1627         attenuation = 1 / max(1, attenuation);
1628         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1629
1630         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1631         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1632         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1633         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1634
1635         // Camera position
1636         tmp = '0 0 0';
1637         dimensions = 0;
1638
1639         if( camera_direction_x )
1640         {
1641                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1642                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1643                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1644                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1645                 ++dimensions;
1646         }
1647
1648         if( camera_direction_y )
1649         {
1650                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1651                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1652                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1653                 ++dimensions;
1654         }
1655
1656         if( camera_direction_z )
1657         {
1658                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1659                 ++dimensions;
1660         }
1661
1662         if(autocvar_camera_free)
1663                 speed = autocvar_camera_speed_free;
1664         else
1665                 speed = autocvar_camera_speed_chase;
1666
1667         if(dimensions)
1668         {
1669                 speed = speed * sqrt(1 / dimensions);
1670                 camera_offset += tmp * speed;
1671         }
1672
1673         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1674
1675         // Camera modes
1676         if( autocvar_camera_free )
1677         {
1678                 if ( camera_mode == CAMERA_CHASE )
1679                 {
1680                         current_camera_offset = current_origin + current_camera_offset;
1681                         camera_offset = current_origin + camera_offset;
1682                 }
1683
1684                 camera_mode = CAMERA_FREE;
1685                 current_position = current_camera_offset;
1686         }
1687         else
1688         {
1689                 if ( camera_mode == CAMERA_FREE )
1690                 {
1691                         current_origin = view_origin;
1692                         camera_offset = camera_offset - current_origin;
1693                         current_camera_offset = current_camera_offset - current_origin;
1694                 }
1695
1696                 camera_mode = CAMERA_CHASE;
1697
1698                 if(autocvar_camera_chase_smoothly)
1699                         current_origin += (view_origin - current_origin) * attenuation;
1700                 else
1701                         current_origin = view_origin;
1702
1703                 current_position = current_origin + current_camera_offset;
1704         }
1705
1706         setproperty(VF_ANGLES, current_angles);
1707         setproperty(VF_ORIGIN, current_position);
1708 }