qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(void)
 203 {
 204         float fovx, fovy;
 205         float width = (mi_picmax_x - mi_picmin_x);
 206         float height = (mi_picmax_y - mi_picmin_y);
 207         float distance_to_middle_of_world = vlen(view_origin);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 322
 323         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 324         trueaimpoint = trace_endpos;
 325
 326         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 327                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 328
 329         if(vecs_x > 0)
 330                 vecs_y = -vecs_y;
 331         else
 332                 vecs = '0 0 0';
 333
 334         dv = view_right * vecs_y + view_up * vecs_z;
 335         w_shotorg = view_origin + dv;
 336
 337         // now move the vecs forward as much as requested if possible
 338         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 339         w_shotorg = trace_endpos - view_forward * nudge;
 340
 341         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 342         shottype = EnemyHitCheck();
 343         if(shottype != SHOTTYPE_HITWORLD)
 344                 return shottype;
 345
 346 #if 0
 347         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 348         // or rather, I know why, but see no fix
 349         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 350                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 351                 return SHOTTYPE_HITOBSTRUCTION;
 352 #endif
 353
 354         return SHOTTYPE_HITWORLD;
 355 }
 356
 357 void CSQC_common_hud(void);
 358
 359 void PostInit(void);
 360 void CSQC_Demo_Camera();
 361 float HUD_WouldDrawScoreboard();
 362 float camera_mode;
 363 const float CAMERA_FREE = 1;
 364 const float CAMERA_CHASE = 2;
 365 float reticle_type;
 366 string NextFrameCommand;
 367 void CSQC_SPIDER_HUD();
 368 void CSQC_RAPTOR_HUD();
 369
 370 vector freeze_org, freeze_ang;
 371 entity nightvision_noise, nightvision_noise2;
 372
 373 #define MAX_TIME_DIFF 5
 374 float pickup_crosshair_time, pickup_crosshair_size;
 375 float hit_time, typehit_time;
 376 float nextsound_hit_time, nextsound_typehit_time;
 377 float hitindication_crosshair_time, hitindication_crosshair_size;
 378 float use_nex_chargepool;
 379
 380 float myhealth, myhealth_prev;
 381 float myhealth_flash;
 382
 383 float old_blurradius, old_bluralpha;
 384 float old_sharpen_intensity;
 385
 386 vector myhealth_gentlergb;
 387
 388 float contentavgalpha, liquidalpha_prev;
 389 vector liquidcolor_prev;
 390
 391 float eventchase_current_distance;
 392
 393 vector damage_blurpostprocess, content_blurpostprocess;
 394
 395 float checkfail[16];
 396
 397 float rainbow_last_flicker;
 398 vector rainbow_prev_color;
 399
 400 #define BUTTON_3 4
 401 #define BUTTON_4 8
 402 float cl_notice_run();
 403 float prev_myteam;
 404 void CSQC_UpdateView(float w, float h)
 405 {
 406         entity e;
 407         float fov;
 408         float f, i, j;
 409         vector v;
 410         vector vf_size, vf_min;
 411         float a;
 412
 413         execute_next_frame();
 414
 415         ++framecount;
 416
 417         hud = getstati(STAT_HUD);
 418
 419         if(autocvar__hud_showbinds_reload) // menu can set this one
 420         {
 421                 db_close(binddb);
 422                 binddb = db_create();
 423                 cvar_set("_hud_showbinds_reload", "0");
 424         }
 425
 426         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 427                 view_quality = getproperty(VF_MINFPS_QUALITY);
 428         else
 429                 view_quality = 1;
 430
 431         button_attack2 = (input_buttons & BUTTON_3);
 432         button_zoom = (input_buttons & BUTTON_4);
 433
 434 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 435         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 436         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 437         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 438         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 439         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 440         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 441         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442
 443         vf_size = getpropertyvec(VF_SIZE);
 444         vf_min = getpropertyvec(VF_MIN);
 445         vid_width = vf_size_x;
 446         vid_height = vf_size_y;
 447
 448         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 449         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 450
 451         WaypointSprite_Load();
 452
 453         CSQCPlayer_SetCamera();
 454
 455 #ifdef COMPAT_XON050_ENGINE
 456         if(spectatee_status)
 457                 myteam = GetPlayerColor(spectatee_status - 1);
 458         else
 459 #endif
 460                 myteam = GetPlayerColor(player_localentnum - 1);
 461
 462         if(myteam != prev_myteam)
 463         {
 464                 myteamcolors = colormapPaletteColor(myteam, 1);
 465                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 466                         hud_panel[i].update_time = time;
 467                 prev_myteam = myteam;
 468         }
 469
 470         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 471
 472         float is_dead = (getstati(STAT_HEALTH) <= 0);
 473
 474         // FIXME do we need this hack?
 475         if(isdemo())
 476         {
 477                 // in demos, input_buttons do not work
 478                 button_zoom = (autocvar__togglezoom == "-");
 479         }
 480         else if(button_zoom
 481                 && autocvar_cl_unpress_zoom_on_death
 482                 && (spectatee_status >= 0)
 483                 && (is_dead || intermission))
 484         {
 485                 // no zoom while dead or in intermission please
 486                 localcmd("-zoom\n");
 487                 button_zoom = FALSE;
 488         }
 489
 490         // event chase camera
 491         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 492         {
 493                 if((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission)
 494                 {
 495                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 496                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 497
 498                         // detect maximum viewoffset and use it
 499                         if(autocvar_cl_eventchase_viewoffset)
 500                         {
 501                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 502                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 503                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 504                         }
 505
 506                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 507                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 508                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 509                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 510
 511                         // make the camera smooth back
 512                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 513                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 514                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 515                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 516
 517                         makevectors(view_angles);
 518
 519                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 520                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 521
 522                         // If the boxtrace fails, revert back to line tracing.
 523                         if(trace_startsolid)
 524                         {
 525                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 526                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 527                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 528                         }
 529                         else { setproperty(VF_ORIGIN, trace_endpos); }
 530
 531                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 532                 }
 533                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 534                 {
 535                         cvar_set("chase_active", "0");
 536                         eventchase_current_distance = 0; // start from 0 next time
 537                 }
 538         }
 539         // workaround for camera stuck between player's legs when using chase_active 1
 540         // because the engine stops updating the chase_active camera when the game ends
 541         else if(intermission)
 542         {
 543                 cvar_settemp("chase_active", "-1");
 544                 eventchase_current_distance = 0;
 545         }
 546
 547         // do lockview after event chase camera so that it still applies whenever necessary.
 548         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 549         {
 550                 setproperty(VF_ORIGIN, freeze_org);
 551                 setproperty(VF_ANGLES, freeze_ang);
 552         }
 553         else
 554         {
 555                 freeze_org = getpropertyvec(VF_ORIGIN);
 556                 freeze_ang = getpropertyvec(VF_ANGLES);
 557         }
 558
 559         WarpZone_FixView();
 560         //WarpZone_FixPMove();
 561
 562         if(autocvar_cl_orthoview)
 563         {
 564                 float width = (mi_picmax_x - mi_picmin_x);
 565                 float height = (mi_picmax_y - mi_picmin_y);
 566                 setproperty(VF_ORIGIN, '0 0 1' * (512 * max(width, height)));
 567                 setproperty(VF_ANGLES, '90 0 0');
 568         }
 569
 570         // Render the Scene
 571         view_origin = getpropertyvec(VF_ORIGIN);
 572         view_angles = getpropertyvec(VF_ANGLES);
 573         makevectors(view_angles);
 574         view_forward = v_forward;
 575         view_right = v_right;
 576         view_up = v_up;
 577
 578 #ifdef BLURTEST
 579         if(time > blurtest_time0 && time < blurtest_time1)
 580         {
 581                 float r, t;
 582
 583                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 584                 r = t * blurtest_radius;
 585                 f = 1 / pow(t, blurtest_power) - 1;
 586
 587                 cvar_set("r_glsl_postprocess", "1");
 588                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 589         }
 590         else
 591         {
 592                 cvar_set("r_glsl_postprocess", "0");
 593                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 594         }
 595 #endif
 596
 597         TargetMusic_Advance();
 598         Fog_Force();
 599
 600         if(drawtime == 0)
 601                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 602         else
 603                 drawframetime = bound(0.000001, time - drawtime, 1);
 604         drawtime = time;
 605
 606         // watch for gametype changes here...
 607         // in ParseStuffCMD the cmd isn't executed yet :/
 608         // might even be better to add the gametype to TE_CSQC_INIT...?
 609         if(!postinit)
 610                 PostInit();
 611
 612         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 613         {
 614                 if(calledhooks & HOOK_START)
 615                 {
 616                         localcmd("\ncl_hook_gameend\n");
 617                         calledhooks |= HOOK_END;
 618                 }
 619         }
 620
 621         Announcer();
 622
 623         fov = autocvar_fov;
 624         if(fov <= 59.5)
 625         {
 626                 if(!zoomscript_caught)
 627                 {
 628                         localcmd("+button9\n");
 629                         zoomscript_caught = 1;
 630                 }
 631         }
 632         else
 633         {
 634                 if(zoomscript_caught)
 635                 {
 636                         localcmd("-button9\n");
 637                         zoomscript_caught = 0;
 638                 }
 639         }
 640
 641         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 642
 643         // next WANTED weapon (for HUD)
 644         switchweapon = getstati(STAT_SWITCHWEAPON);
 645
 646         // currently switching-to weapon (for crosshair)
 647         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 648
 649         // actually active weapon (for zoom)
 650         activeweapon = getstati(STAT_ACTIVEWEAPON);
 651
 652         f = (serverflags & SERVERFLAG_TEAMPLAY);
 653         if(f != teamplay)
 654         {
 655                 teamplay = f;
 656                 HUD_InitScores();
 657         }
 658
 659         if(last_switchweapon != switchweapon)
 660         {
 661                 weapontime = time;
 662                 last_switchweapon = switchweapon;
 663                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 664                 {
 665                         localcmd("-zoom\n");
 666                         button_zoom = FALSE;
 667                 }
 668                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 669                 {
 670                         localcmd("-fire\n");
 671                         localcmd("-fire2\n");
 672                         button_attack2 = FALSE;
 673                 }
 674         }
 675         if(last_activeweapon != activeweapon)
 676         {
 677                 last_activeweapon = activeweapon;
 678
 679                 e = get_weaponinfo(activeweapon);
 680                 if(e.netname != "")
 681                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 682                 else
 683                         localcmd("\ncl_hook_activeweapon none\n");
 684         }
 685
 686         // ALWAYS Clear Current Scene First
 687         clearscene();
 688 #ifdef WORKAROUND_XON010
 689         if(checkextension("DP_CSQC_ROTATEMOVES"))
 690         {
 691 #endif
 692         setproperty(VF_ORIGIN, view_origin);
 693         setproperty(VF_ANGLES, view_angles);
 694 #ifdef WORKAROUND_XON010
 695         }
 696 #endif
 697
 698         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 699         setproperty(VF_SIZE, vf_size);
 700         setproperty(VF_MIN, vf_min);
 701
 702         // Assign Standard Viewflags
 703         // Draw the World (and sky)
 704         setproperty(VF_DRAWWORLD, 1);
 705
 706         // Set the console size vars
 707         vid_conwidth = autocvar_vid_conwidth;
 708         vid_conheight = autocvar_vid_conheight;
 709         vid_pixelheight = autocvar_vid_pixelheight;
 710
 711         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV()); }
 712         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 713
 714         // Camera for demo playback
 715         if(camera_active)
 716         {
 717                 if(autocvar_camera_enable)
 718                         CSQC_Demo_Camera();
 719                 else
 720                 {
 721                         cvar_set("chase_active", ftos(chase_active_backup));
 722                         cvar_set("cl_demo_mousegrab", "0");
 723                         camera_active = FALSE;
 724                 }
 725         }
 726 #ifdef CAMERATEST
 727         else if(autocvar_camera_enable)
 728 #else
 729         else if(autocvar_camera_enable && isdemo())
 730 #endif
 731         {
 732                 // Enable required Darkplaces cvars
 733                 chase_active_backup = autocvar_chase_active;
 734                 cvar_set("chase_active", "2");
 735                 cvar_set("cl_demo_mousegrab", "1");
 736                 camera_active = TRUE;
 737                 camera_mode = FALSE;
 738         }
 739
 740         // Draw the Crosshair
 741         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 742
 743         // Draw the Engine Status Bar (the default Quake HUD)
 744         setproperty(VF_DRAWENGINESBAR, 0);
 745
 746         // Update the mouse position
 747         /*
 748            mousepos_x = vid_conwidth;
 749            mousepos_y = vid_conheight;
 750            mousepos = mousepos*0.5 + getmousepos();
 751          */
 752
 753         e = self;
 754         for(self = world; (self = nextent(self)); )
 755                 if(self.draw)
 756                         self.draw();
 757         self = e;
 758
 759         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 760         renderscene();
 761
 762         // now switch to 2D drawing mode by calling a 2D drawing function
 763         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 764         // next R_RenderScene call
 765         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 766
 767         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 768         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 769         {
 770                 // apply night vision effect
 771                 vector tc_00, tc_01, tc_10, tc_11;
 772                 vector rgb;
 773                 rgb_x = 0; // fteqcc sucks
 774                 rgb_y = 0; // fteqcc sucks
 775                 rgb_z = 0; // fteqcc sucks
 776
 777                 if(!nightvision_noise)
 778                 {
 779                         nightvision_noise = spawn();
 780                         nightvision_noise.classname = "nightvision_noise";
 781                 }
 782                 if(!nightvision_noise2)
 783                 {
 784                         nightvision_noise2 = spawn();
 785                         nightvision_noise2.classname = "nightvision_noise2";
 786                 }
 787
 788                 // color tint in yellow
 789                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 790
 791                 // draw BG
 792                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 793                 rgb = '1 1 1';
 794                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 795                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 796                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 797                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 798                 tc_11 = tc_01 + tc_10 - tc_00;
 799                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 800                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 801                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 802                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 803                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 804                 R_EndPolygon();
 805
 806                 // draw FG
 807                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 808                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 809                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 810                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 811                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 812                 tc_11 = tc_01 + tc_10 - tc_00;
 813                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 814                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 815                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 816                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 817                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 818                 R_EndPolygon();
 819         }
 820
 821         // Draw the aiming reticle for weapons that use it
 822         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 823         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 824         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 825         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 826                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 827         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 828                 reticle_type = 2; // nex zoom
 829         else if(button_zoom || zoomscript_caught)
 830                 reticle_type = 1; // normal zoom
 831         else if((activeweapon == WEP_NEX) && button_attack2)
 832                 reticle_type = 2; // nex zoom
 833
 834         if(reticle_type && autocvar_cl_reticle)
 835         {
 836                 if(autocvar_cl_reticle_stretch)
 837                 {
 838                         reticle_size_x = vid_conwidth;
 839                         reticle_size_y = vid_conheight;
 840                         reticle_pos_x = 0;
 841                         reticle_pos_y = 0;
 842                 }
 843                 else
 844                 {
 845                         reticle_size_x = max(vid_conwidth, vid_conheight);
 846                         reticle_size_y = max(vid_conwidth, vid_conheight);
 847                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 848                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 849                 }
 850
 851                 f = current_zoomfraction;
 852                 if(zoomscript_caught)
 853                         f = 1;
 854                 if(autocvar_cl_reticle_item_normal)
 855                 {
 856                         if(reticle_type == 1 && f)
 857                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 858                 }
 859                 if(autocvar_cl_reticle_item_nex)
 860                 {
 861                         if(reticle_type == 2 && f)
 862                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 863                 }
 864         }
 865
 866
 867         // improved polyblend
 868         if(autocvar_hud_contents)
 869         {
 870                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 871                 vector liquidcolor;
 872
 873                 switch(pointcontents(view_origin))
 874                 {
 875                         case CONTENT_WATER:
 876                                 liquidalpha = autocvar_hud_contents_water_alpha;
 877                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 878                                 incontent = 1;
 879                                 break;
 880
 881                         case CONTENT_LAVA:
 882                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 883                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 884                                 incontent = 1;
 885                                 break;
 886
 887                         case CONTENT_SLIME:
 888                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 889                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 890                                 incontent = 1;
 891                                 break;
 892
 893                         default:
 894                                 liquidalpha = 0;
 895                                 liquidcolor = '0 0 0';
 896                                 incontent = 0;
 897                                 break;
 898                 }
 899
 900                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 901                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 902                         contentfadetime = autocvar_hud_contents_fadeintime;
 903                         liquidalpha_prev = liquidalpha;
 904                         liquidcolor_prev = liquidcolor;
 905                 }
 906                 else
 907                         contentfadetime = autocvar_hud_contents_fadeouttime;
 908
 909                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 910                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 911
 912                 if(contentavgalpha)
 913                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 914
 915                 if(autocvar_hud_postprocessing)
 916                 {
 917                         if(autocvar_hud_contents_blur && contentavgalpha)
 918                         {
 919                                 content_blurpostprocess_x = 1;
 920                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 921                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 922                         }
 923                         else
 924                         {
 925                                 content_blurpostprocess_x = 0;
 926                                 content_blurpostprocess_y = 0;
 927                                 content_blurpostprocess_z = 0;
 928                         }
 929                 }
 930         }
 931
 932         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 933         {
 934                 splash_size_x = max(vid_conwidth, vid_conheight);
 935                 splash_size_y = max(vid_conwidth, vid_conheight);
 936                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 937                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 938
 939                 float myhealth_flash_temp;
 940                 myhealth = getstati(STAT_HEALTH);
 941
 942                 // fade out
 943                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 944                 // add new damage
 945                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 946
 947                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 948                 pain_threshold = autocvar_hud_damage_pain_threshold;
 949                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 950                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 951
 952                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 953                 {
 954                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 955                 }
 956
 957                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 958
 959                 if(myhealth_prev < 1)
 960                 {
 961                         if(myhealth >= 1)
 962                         {
 963                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 964                                 myhealth_flash_temp = 0;
 965                         }
 966                         else
 967                         {
 968                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 969                         }
 970                 }
 971
 972                 if(spectatee_status == -1 || intermission)
 973                 {
 974                         myhealth_flash = 0; // observing, or match ended
 975                         myhealth_flash_temp = 0;
 976                 }
 977
 978                 myhealth_prev = myhealth;
 979
 980                 // IDEA: change damage color/picture based on player model for robot/alien species?
 981                 // pro: matches model better
 982                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 983                 // maybe different reddish pics?
 984                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 985                 {
 986                         if(autocvar_cl_gentle_damage == 2)
 987                         {
 988                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 989                                 {
 990                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 991                                 }
 992                         }
 993                         else
 994                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 995
 996                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 997                 }
 998                 else
 999                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1000
1001                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1002                 {
1003                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1004                         {
1005                                 damage_blurpostprocess_x = 1;
1006                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1007                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1008                         }
1009                         else
1010                         {
1011                                 damage_blurpostprocess_x = 0;
1012                                 damage_blurpostprocess_y = 0;
1013                                 damage_blurpostprocess_z = 0;
1014                         }
1015                 }
1016         }
1017
1018         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1019         float e2 = (autocvar_hud_powerup != 0);
1020         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1021         {
1022                 // enable or disable rendering types if they are used or not
1023                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1024                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1025
1026                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1027                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1028                 {
1029                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1030                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1031                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1032                         {
1033                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1034                                 old_blurradius = blurradius;
1035                                 old_bluralpha = bluralpha;
1036                         }
1037                 }
1038                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1039                 {
1040                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1041                         old_blurradius = 0;
1042                         old_bluralpha = 0;
1043                 }
1044
1045                 // edge detection postprocess handling done second (used by hud_powerup)
1046                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1047                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1048                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1049
1050                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1051
1052                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1053                 {
1054                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1055                         {
1056                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1057                                 old_sharpen_intensity = sharpen_intensity;
1058                         }
1059                 }
1060                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1061                 {
1062                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1063                         old_sharpen_intensity = 0;
1064                 }
1065
1066                 if(cvar("r_glsl_postprocess") == 0)
1067                         cvar_set("r_glsl_postprocess", "2");
1068         }
1069         else if(cvar("r_glsl_postprocess") == 2)
1070                 cvar_set("r_glsl_postprocess", "0");
1071
1072         if(menu_visible)
1073                 menu_show();
1074
1075         /*if(gametype == MAPINFO_TYPE_CTF)
1076           {
1077           ctf_view();
1078           } else */
1079
1080         // draw 2D entities
1081         e = self;
1082         for(self = world; (self = nextent(self)); )
1083                 if(self.draw2d)
1084                         self.draw2d();
1085         self = e;
1086         Draw_ShowNames_All();
1087
1088         scoreboard_active = HUD_WouldDrawScoreboard();
1089
1090         hit_time = getstatf(STAT_HIT_TIME);
1091         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1092         {
1093                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1094                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1095
1096                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1097         }
1098         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1099         if(typehit_time > nextsound_typehit_time)
1100         {
1101                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1102                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1103
1104                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1105         }
1106
1107         //else
1108         {
1109                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1110                 {
1111                         if(getstati(STAT_FROZEN))
1112                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1113                         if(getstatf(STAT_REVIVE_PROGRESS))
1114                         {
1115                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1116                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1117                         }
1118                 }
1119
1120                 if(autocvar_r_letterbox == 0)
1121                         if(autocvar_viewsize < 120)
1122                                 CSQC_common_hud();
1123
1124                 // crosshair goes VERY LAST
1125                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1126                 {
1127                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1128                                 return;
1129
1130                         string wcross_style;
1131                         float wcross_alpha, wcross_resolution;
1132                         wcross_style = autocvar_crosshair;
1133                         if (wcross_style == "0")
1134                                 return;
1135                         wcross_resolution = autocvar_crosshair_size;
1136                         if (wcross_resolution == 0)
1137                                 return;
1138                         wcross_alpha = autocvar_crosshair_alpha;
1139                         if (wcross_alpha == 0)
1140                                 return;
1141
1142                         // TrueAim check
1143                         float shottype;
1144
1145                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1146                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1147                         wcross_origin_z = 0;
1148                         if(autocvar_crosshair_hittest)
1149                         {
1150                                 vector wcross_oldorigin;
1151                                 wcross_oldorigin = wcross_origin;
1152                                 shottype = TrueAimCheck();
1153                                 if(shottype == SHOTTYPE_HITWORLD)
1154                                 {
1155                                         v = wcross_origin - wcross_oldorigin;
1156                                         v_x /= vid_conwidth;
1157                                         v_y /= vid_conheight;
1158                                         if(vlen(v) > 0.01)
1159                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1160                                 }
1161                                 if(!autocvar_crosshair_hittest_showimpact)
1162                                         wcross_origin = wcross_oldorigin;
1163                         }
1164                         else
1165                                 shottype = SHOTTYPE_HITWORLD;
1166
1167                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1168                         string wcross_wep = "", wcross_name;
1169                         float wcross_scale, wcross_blur;
1170
1171                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1172                         {
1173                                 e = get_weaponinfo(switchingweapon);
1174                                 if (e && e.netname != "")
1175                                 {
1176                                         wcross_wep = e.netname;
1177                                         if(autocvar_crosshair_per_weapon)
1178                                         {
1179                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1180                                                 if (wcross_resolution == 0)
1181                                                         return;
1182                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1183                                                 if (wcross_alpha == 0)
1184                                                         return;
1185
1186                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1187                                                 if(wcross_style == "" || wcross_style == "0")
1188                                                         wcross_style = wcross_wep;
1189                                         }
1190                                 }
1191                         }
1192
1193                         //print(sprintf("crosshair style: %s\n", wcross_style));
1194                         wcross_name = strcat("gfx/crosshair", wcross_style);
1195
1196                         // MAIN CROSSHAIR COLOR DECISION
1197                         switch(autocvar_crosshair_color_special)
1198                         {
1199                                 case 1: // crosshair_color_per_weapon
1200                                 {
1201                                         if(wcross_wep != "")
1202                                         {
1203                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1204                                                 break;
1205                                         }
1206                                         else { goto normalcolor; }
1207                                 }
1208
1209                                 case 2: // crosshair_color_by_health
1210                                 {
1211                                         float x = getstati(STAT_HEALTH);
1212
1213                                         //x = red
1214                                         //y = green
1215                                         //z = blue
1216
1217                                         wcross_color_z = 0;
1218
1219                                         if(x > 200)
1220                                         {
1221                                                 wcross_color_x = 0;
1222                                                 wcross_color_y = 1;
1223                                         }
1224                                         else if(x > 150)
1225                                         {
1226                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1227                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1228                                         }
1229                                         else if(x > 100)
1230                                         {
1231                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1232                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1233                                                 wcross_color_z = 1 - (x-100)*0.02;
1234                                         }
1235                                         else if(x > 50)
1236                                         {
1237                                                 wcross_color_x = 1;
1238                                                 wcross_color_y = 1;
1239                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1240                                         }
1241                                         else if(x > 20)
1242                                         {
1243                                                 wcross_color_x = 1;
1244                                                 wcross_color_y = (x-20)*90/27/100;
1245                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1246                                         }
1247                                         else
1248                                         {
1249                                                 wcross_color_x = 1;
1250                                                 wcross_color_y = 0;
1251                                         }
1252                                         break;
1253                                 }
1254
1255                                 case 3: // crosshair_color_rainbow
1256                                 {
1257                                         if(time >= rainbow_last_flicker)
1258                                         {
1259                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1260                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1261                                         }
1262                                         wcross_color = rainbow_prev_color;
1263                                         break;
1264                                 }
1265                                 :normalcolor
1266                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1267                         }
1268
1269                         if(autocvar_crosshair_effect_scalefade)
1270                         {
1271                                 wcross_scale = wcross_resolution;
1272                                 wcross_resolution = 1;
1273                         }
1274                         else
1275                         {
1276                                 wcross_scale = 1;
1277                         }
1278
1279                         if(autocvar_crosshair_pickup)
1280                         {
1281                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1282
1283                                 if(pickup_crosshair_time < stat_pickup_time)
1284                                 {
1285                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1286                                                 pickup_crosshair_size = 1;
1287
1288                                         pickup_crosshair_time = stat_pickup_time;
1289                                 }
1290
1291                                 if(pickup_crosshair_size > 0)
1292                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1293                                 else
1294                                         pickup_crosshair_size = 0;
1295
1296                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1297                         }
1298
1299                         if(autocvar_crosshair_hitindication)
1300                         {
1301                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1302
1303                                 if(hitindication_crosshair_time < hit_time)
1304                                 {
1305                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1306                                                 hitindication_crosshair_size = 1;
1307
1308                                         hitindication_crosshair_time = hit_time;
1309                                 }
1310
1311                                 if(hitindication_crosshair_size > 0)
1312                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1313                                 else
1314                                         hitindication_crosshair_size = 0;
1315
1316                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1317                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1318                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1319                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1320                         }
1321
1322                         if(shottype == SHOTTYPE_HITENEMY)
1323                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1324                         if(shottype == SHOTTYPE_HITTEAM)
1325                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1326
1327                         f = fabs(autocvar_crosshair_effect_time);
1328                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1329                         {
1330                                 wcross_changedonetime = time + f;
1331                         }
1332                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1333                         {
1334                                 wcross_name_changestarttime = time;
1335                                 wcross_name_changedonetime = time + f;
1336                                 if(wcross_name_goal_prev_prev)
1337                                         strunzone(wcross_name_goal_prev_prev);
1338                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1339                                 wcross_name_goal_prev = strzone(wcross_name);
1340                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1341                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1342                                 wcross_resolution_goal_prev = wcross_resolution;
1343                         }
1344
1345                         wcross_scale_goal_prev = wcross_scale;
1346                         wcross_alpha_goal_prev = wcross_alpha;
1347                         wcross_color_goal_prev = wcross_color;
1348
1349                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1350                         {
1351                                 wcross_blur = 1;
1352                                 wcross_alpha *= 0.75;
1353                         }
1354                         else
1355                                 wcross_blur = 0;
1356                         // *_prev is at time-frametime
1357                         // * is at wcross_changedonetime+f
1358                         // what do we have at time?
1359                         if(time < wcross_changedonetime)
1360                         {
1361                                 f = frametime / (wcross_changedonetime - time + frametime);
1362                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1363                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1364                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1365                         }
1366
1367                         wcross_scale_prev = wcross_scale;
1368                         wcross_alpha_prev = wcross_alpha;
1369                         wcross_color_prev = wcross_color;
1370
1371                         wcross_scale *= 1 - autocvar__menu_alpha;
1372                         wcross_alpha *= 1 - autocvar__menu_alpha;
1373                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1374
1375                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1376                         {
1377                                 // crosshair rings for weapon stats
1378                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1379                                 {
1380                                         // declarations and stats
1381                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1382                                         string ring_image = string_null, ring_inner_image = string_null;
1383                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1384
1385                                         ring_scale = autocvar_crosshair_ring_size;
1386
1387                                         float weapon_clipload, weapon_clipsize;
1388                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1389                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1390
1391                                         float nex_charge, nex_chargepool;
1392                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1393                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1394
1395                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1396                                                 nex_charge_movingavg = nex_charge;
1397
1398
1399                                         // handle the values
1400                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1401                                         {
1402                                                 if (nex_chargepool || use_nex_chargepool) {
1403                                                         use_nex_chargepool = 1;
1404                                                         ring_inner_value = nex_chargepool;
1405                                                 } else {
1406                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1407                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1408                                                 }
1409
1410                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1411                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1412                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1413
1414                                                 // draw the outer ring to show the current charge of the weapon
1415                                                 ring_value = nex_charge;
1416                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1417                                                 ring_rgb = wcross_color;
1418                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1419                                         }
1420                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1421                                         {
1422                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1423                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1424                                                 ring_rgb = wcross_color;
1425                                                 ring_image = "gfx/crosshair_ring.tga";
1426                                         }
1427                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1428                                         {
1429                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1430                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1431                                                 ring_rgb = wcross_color;
1432                                                 ring_image = "gfx/crosshair_ring.tga";
1433                                         }
1434
1435                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1436                                         {
1437                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1438                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1439                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1440                                                 ring_rgb = wcross_color;
1441
1442                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1443                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1444                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1445                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1446                                                 else
1447                                                         ring_image = "gfx/crosshair_ring.tga";
1448                                         }
1449
1450                                         // if in weapon switch animation, fade ring out/in
1451                                         if(autocvar_crosshair_effect_time > 0)
1452                                         {
1453                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1454                                                 if not(f < 1)
1455                                                 {
1456                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1457                                                 }
1458
1459                                                 if(wcross_ring_prev)
1460                                                 {
1461                                                         if(f < 1)
1462                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1463                                                 }
1464                                                 else
1465                                                 {
1466                                                         if(f < 1)
1467                                                                 ring_alpha *= bound(0, f, 1);
1468                                                 }
1469                                         }
1470
1471                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1472                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1473
1474                                         if (ring_value)
1475                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1476                                 }
1477
1478 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1479                                 do \
1480                                 { \
1481                                         if(wcross_blur > 0) \
1482                                         { \
1483                                                 for(i = -2; i <= 2; ++i) \
1484                                                 for(j = -2; j <= 2; ++j) \
1485                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1486                                         } \
1487                                         else \
1488                                         { \
1489                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1490                                         } \
1491                                 } \
1492                                 while(0)
1493
1494 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1495                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1496
1497 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1498                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1499
1500                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1501                                 {
1502                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1503                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1504                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1505                                         f = 1 - f;
1506                                 }
1507                                 else
1508                                 {
1509                                         f = 1;
1510                                 }
1511                                 wcross_name_alpha_goal_prev = f;
1512
1513                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1514                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1515
1516                                 if(autocvar_crosshair_dot)
1517                                 {
1518                                         vector wcross_color_old;
1519                                         wcross_color_old = wcross_color;
1520
1521                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1522                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1523
1524                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1525                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1526                                         wcross_color = wcross_color_old;
1527                                 }
1528                         }
1529                 }
1530                 else
1531                 {
1532                         wcross_scale_prev = 0;
1533                         wcross_alpha_prev = 0;
1534                         wcross_scale_goal_prev = 0;
1535                         wcross_alpha_goal_prev = 0;
1536                         wcross_changedonetime = 0;
1537                         if(wcross_name_goal_prev)
1538                                 strunzone(wcross_name_goal_prev);
1539                         wcross_name_goal_prev = string_null;
1540                         if(wcross_name_goal_prev_prev)
1541                                 strunzone(wcross_name_goal_prev_prev);
1542                         wcross_name_goal_prev_prev = string_null;
1543                         wcross_name_changestarttime = 0;
1544                         wcross_name_changedonetime = 0;
1545                         wcross_name_alpha_goal_prev = 0;
1546                         wcross_name_alpha_goal_prev_prev = 0;
1547                         wcross_resolution_goal_prev = 0;
1548                         wcross_resolution_goal_prev_prev = 0;
1549                 }
1550         }
1551
1552         if(NextFrameCommand)
1553         {
1554                 localcmd("\n", NextFrameCommand, "\n");
1555                 NextFrameCommand = string_null;
1556         }
1557
1558         // we must do this check AFTER a frame was rendered, or it won't work
1559         if(cs_project_is_b0rked == 0)
1560         {
1561                 string w0, h0;
1562                 w0 = ftos(autocvar_vid_conwidth);
1563                 h0 = ftos(autocvar_vid_conheight);
1564                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1565                 //setproperty(VF_FOV, '90 90 0');
1566                 setproperty(VF_ORIGIN, '0 0 0');
1567                 setproperty(VF_ANGLES, '0 0 0');
1568                 setproperty(VF_PERSPECTIVE, 1);
1569                 makevectors('0 0 0');
1570                 vector v1, v2;
1571                 cvar_set("vid_conwidth", "800");
1572                 cvar_set("vid_conheight", "600");
1573                 v1 = cs_project(v_forward);
1574                 cvar_set("vid_conwidth", "640");
1575                 cvar_set("vid_conheight", "480");
1576                 v2 = cs_project(v_forward);
1577                 if(v1 == v2)
1578                         cs_project_is_b0rked = 1;
1579                 else
1580                         cs_project_is_b0rked = -1;
1581                 cvar_set("vid_conwidth", w0);
1582                 cvar_set("vid_conheight", h0);
1583         }
1584
1585         if(autocvar__hud_configure)
1586                 HUD_Panel_Mouse();
1587
1588     if(hud && !intermission)
1589     {
1590         if(hud == HUD_SPIDERBOT)
1591             CSQC_SPIDER_HUD();
1592         else if(hud == HUD_WAKIZASHI)
1593             CSQC_WAKIZASHI_HUD();
1594         else if(hud == HUD_RAPTOR)
1595             CSQC_RAPTOR_HUD();
1596         else if(hud == HUD_BUMBLEBEE)
1597             CSQC_BUMBLE_HUD();
1598         else if(hud == HUD_BUMBLEBEE_GUN)
1599             CSQC_BUMBLE_GUN_HUD();
1600     }
1601
1602         cl_notice_run();
1603
1604         // let's reset the view back to normal for the end
1605         setproperty(VF_MIN, '0 0 0');
1606         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1607 }
1608
1609
1610 void CSQC_common_hud(void)
1611 {
1612         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1613                 Accuracy_LoadLevels();
1614
1615     HUD_Main(); // always run these functions for alpha checks
1616     HUD_DrawScoreboard();
1617
1618     if (scoreboard_active) // scoreboard/accuracy
1619         HUD_Reset();
1620     else if (intermission == 2) // map voting screen
1621     {
1622         HUD_FinaleOverlay();
1623         HUD_Reset();
1624     }
1625         /*
1626         switch(hud)
1627         {
1628                 case HUD_SPIDERBOT:
1629                         CSQC_SPIDER_HUD();
1630                         break;
1631
1632                 case HUD_WAKIZASHI:
1633                         CSQC_WAKIZASHI_HUD();
1634                         break;
1635
1636         case HUD_BUMBLEBEE:
1637             CSQC_BUMBLE_HUD();
1638             break;
1639         }
1640         */
1641 }
1642
1643
1644 // following vectors must be global to allow seamless switching between camera modes
1645 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1646 void CSQC_Demo_Camera()
1647 {
1648         float speed, attenuation, dimensions;
1649         vector tmp, delta;
1650
1651         if( autocvar_camera_reset || !camera_mode )
1652         {
1653                 camera_offset = '0 0 0';
1654                 current_angles = '0 0 0';
1655                 camera_direction = '0 0 0';
1656                 camera_offset_z += 30;
1657                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1658                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1659                 current_origin = view_origin;
1660                 current_camera_offset  = camera_offset;
1661                 cvar_set("camera_reset", "0");
1662                 camera_mode = CAMERA_CHASE;
1663         }
1664
1665         // Camera angles
1666         if( camera_roll )
1667                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1668
1669         if(autocvar_camera_look_player)
1670         {
1671                 vector dir;
1672                 float n;
1673
1674                 dir = normalize(view_origin - current_position);
1675                 n = mouse_angles_z;
1676                 mouse_angles = vectoangles(dir);
1677                 mouse_angles_x = mouse_angles_x * -1;
1678                 mouse_angles_z = n;
1679         }
1680         else
1681         {
1682                 tmp = getmousepos() * 0.1;
1683                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1684                 {
1685                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1686                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1687                 }
1688         }
1689
1690         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1691         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1692         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1693         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1694
1695         // Fix difference when angles don't have the same sign
1696         delta = '0 0 0';
1697         if(mouse_angles_y < -60 && current_angles_y > 60)
1698                 delta = '0 360 0';
1699         if(mouse_angles_y > 60 && current_angles_y < -60)
1700                 delta = '0 -360 0';
1701
1702         if(autocvar_camera_look_player)
1703                 attenuation = autocvar_camera_look_attenuation;
1704         else
1705                 attenuation = autocvar_camera_speed_attenuation;
1706
1707         attenuation = 1 / max(1, attenuation);
1708         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1709
1710         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1711         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1712         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1713         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1714
1715         // Camera position
1716         tmp = '0 0 0';
1717         dimensions = 0;
1718
1719         if( camera_direction_x )
1720         {
1721                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1722                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1723                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1724                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1725                 ++dimensions;
1726         }
1727
1728         if( camera_direction_y )
1729         {
1730                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1731                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1732                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1733                 ++dimensions;
1734         }
1735
1736         if( camera_direction_z )
1737         {
1738                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1739                 ++dimensions;
1740         }
1741
1742         if(autocvar_camera_free)
1743                 speed = autocvar_camera_speed_free;
1744         else
1745                 speed = autocvar_camera_speed_chase;
1746
1747         if(dimensions)
1748         {
1749                 speed = speed * sqrt(1 / dimensions);
1750                 camera_offset += tmp * speed;
1751         }
1752
1753         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1754
1755         // Camera modes
1756         if( autocvar_camera_free )
1757         {
1758                 if ( camera_mode == CAMERA_CHASE )
1759                 {
1760                         current_camera_offset = current_origin + current_camera_offset;
1761                         camera_offset = current_origin + camera_offset;
1762                 }
1763
1764                 camera_mode = CAMERA_FREE;
1765                 current_position = current_camera_offset;
1766         }
1767         else
1768         {
1769                 if ( camera_mode == CAMERA_FREE )
1770                 {
1771                         current_origin = view_origin;
1772                         camera_offset = camera_offset - current_origin;
1773                         current_camera_offset = current_camera_offset - current_origin;
1774                 }
1775
1776                 camera_mode = CAMERA_CHASE;
1777
1778                 if(autocvar_camera_chase_smoothly)
1779                         current_origin += (view_origin - current_origin) * attenuation;
1780                 else
1781                         current_origin = view_origin;
1782
1783                 current_position = current_origin + current_camera_offset;
1784         }
1785
1786         setproperty(VF_ANGLES, current_angles);
1787         setproperty(VF_ORIGIN, current_position);
1788 }