qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_RIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float camera_mode;
 346 float reticle_type;
 347 string NextFrameCommand;
 348 void CSQC_SPIDER_HUD();
 349 void CSQC_RAPTOR_HUD();
 350
 351 vector freeze_pmove_org, freeze_input_angles;
 352 entity nightvision_noise, nightvision_noise2;
 353
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 vector myhealth_gentlergb;
 364
 365 float contentavgalpha, liquidalpha_prev;
 366 vector liquidcolor_prev;
 367
 368 float eventchase_current_distance;
 369
 370 float checkfail[16];
 371
 372 void CSQC_UpdateView(float w, float h)
 373 {
 374         entity e;
 375         float fov;
 376         float f, i, j;
 377         vector v, vo;
 378         vector vf_size, vf_min;
 379         float a;
 380
 381         button_attack2 = (input_buttons & BUTTON_3);
 382         button_zoom = (input_buttons & BUTTON_4);
 383
 384 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 385         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 386         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 387         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 388         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 389         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 390         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 391
 392         vf_size = R_SetView3fv(VF_SIZE);
 393         vf_min = R_SetView3fv(VF_MIN);
 394         vid_width = vf_size_x;
 395         vid_height = vf_size_y;
 396
 397         vector reticle_pos, reticle_size;
 398         vector splash_pos, splash_size;
 399
 400         WaypointSprite_Load();
 401
 402         if(spectatee_status)
 403                 myteam = GetPlayerColor(spectatee_status - 1);
 404         else
 405                 myteam = GetPlayerColor(player_localentnum - 1);
 406
 407         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 408         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 409
 410         warpzone_fixview_origin = pmove_org + vo;
 411         warpzone_fixview_cl_viewangles = input_angles;
 412         warpzone_fixview_angles = view_angles;
 413         WarpZone_FixView();
 414         pmove_org = warpzone_fixview_origin - vo;
 415         input_angles = warpzone_fixview_cl_viewangles;
 416         view_angles = warpzone_fixview_angles;
 417
 418         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 419         {
 420                 pmove_org = freeze_pmove_org;
 421                 input_angles = view_angles = freeze_input_angles;
 422                 R_SetView(VF_ORIGIN, pmove_org + vo);
 423                 R_SetView(VF_ANGLES, view_angles);
 424                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 425         }
 426         freeze_pmove_org = pmove_org;
 427         freeze_input_angles = input_angles;
 428
 429         // event chase camera
 430         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 431         {
 432                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 433                 {
 434                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 435                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 436                         if(!autocvar_chase_active)
 437                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 438
 439                         // make the camera smooth back
 440                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 441                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 442                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 443                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 444
 445                         vector eventchase_target_origin;
 446                         makevectors(view_angles);
 447                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 448                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance;
 449
 450                         traceline(pmove_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 451                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 452                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 453                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 454
 455                         R_SetView(VF_ORIGIN, eventchase_target_origin);
 456                         R_SetView(VF_ANGLES, view_angles);
 457                 }
 458                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 459                 {
 460                         cvar_set("chase_active", "0");
 461                         eventchase_current_distance = 0; // start from 0 next time
 462                 }
 463         }
 464
 465         // Render the Scene
 466         view_origin = pmove_org + vo;
 467         view_angles = input_angles;
 468         makevectors(view_angles);
 469         view_forward = v_forward;
 470         view_right = v_right;
 471         view_up = v_up;
 472
 473 #ifdef BLURTEST
 474         if(time > blurtest_time0 && time < blurtest_time1)
 475         {
 476                 float r, t;
 477
 478                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 479                 r = t * blurtest_radius;
 480                 f = 1 / pow(t, blurtest_power) - 1;
 481
 482                 cvar_set("r_glsl_postprocess", "1");
 483                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 484         }
 485         else
 486         {
 487                 cvar_set("r_glsl_postprocess", "0");
 488                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 489         }
 490 #endif
 491
 492         TargetMusic_Advance();
 493         Fog_Force();
 494
 495         drawframetime = max(0.000001, time - drawtime);
 496         drawtime = time;
 497
 498         // watch for gametype changes here...
 499         // in ParseStuffCMD the cmd isn't executed yet :/
 500         // might even be better to add the gametype to TE_CSQC_INIT...?
 501         if(!postinit)
 502                 PostInit();
 503
 504         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 505                 if(calledhooks & HOOK_START)
 506                 {
 507                         localcmd("\ncl_hook_gameend\n");
 508                         calledhooks |= HOOK_END;
 509                 }
 510
 511         CheckForGamestartChange();
 512         serverAnnouncer();
 513         maptimeAnnouncer();
 514         carrierAnnouncer();
 515
 516         fov = autocvar_fov;
 517         if(fov <= 59.5)
 518         {
 519                 if(!zoomscript_caught)
 520                 {
 521                         localcmd("+button9\n");
 522                         zoomscript_caught = 1;
 523                 }
 524         }
 525         else
 526         {
 527                 if(zoomscript_caught)
 528                 {
 529                         localcmd("-button9\n");
 530                         zoomscript_caught = 0;
 531                 }
 532         }
 533
 534         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 535         activeweapon = getstati(STAT_SWITCHWEAPON);
 536         f = (serverflags & SERVERFLAG_TEAMPLAY);
 537         if(f != teamplay)
 538         {
 539                 teamplay = f;
 540                 HUD_InitScores();
 541         }
 542
 543         if(last_weapon != activeweapon) {
 544                 weapontime = time;
 545                 last_weapon = activeweapon;
 546
 547                 e = get_weaponinfo(activeweapon);
 548                 if(e.netname != "")
 549                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 550                 else
 551                         localcmd("\ncl_hook_activeweapon none\n");
 552         }
 553
 554         // ALWAYS Clear Current Scene First
 555         R_ClearScene();
 556
 557         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 558         R_SetView(VF_SIZE, vf_size);
 559         R_SetView(VF_MIN, vf_min);
 560
 561         // Assign Standard Viewflags
 562         // Draw the World (and sky)
 563         R_SetView(VF_DRAWWORLD, 1);
 564
 565         // Set the console size vars
 566         vid_conwidth = autocvar_vid_conwidth;
 567         vid_conheight = autocvar_vid_conheight;
 568         vid_pixelheight = autocvar_vid_pixelheight;
 569
 570         R_SetView(VF_FOV, GetCurrentFov(fov));
 571
 572         // Camera for demo playback
 573         if(camera_active)
 574         {
 575                 if(autocvar_camera_enable)
 576                         CSQC_Demo_Camera();
 577                 else
 578                 {
 579                         cvar_set("chase_active", ftos(chase_active_backup));
 580                         cvar_set("cl_demo_mousegrab", "0");
 581                         camera_active = FALSE;
 582                 }
 583         }
 584 #ifdef CAMERATEST
 585         else if(autocvar_camera_enable)
 586 #else
 587         else if(autocvar_camera_enable && isdemo())
 588 #endif
 589         {
 590                 // Enable required Darkplaces cvars
 591                 chase_active_backup = autocvar_chase_active;
 592                 cvar_set("chase_active", "2");
 593                 cvar_set("cl_demo_mousegrab", "1");
 594                 camera_active = TRUE;
 595                 camera_mode = FALSE;
 596         }
 597
 598         // Draw the Crosshair
 599         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 600
 601         // Draw the Engine Status Bar (the default Quake HUD)
 602         R_SetView(VF_DRAWENGINEHUD, 0);
 603
 604         // Update the mouse position
 605         /*
 606            mousepos_x = vid_conwidth;
 607            mousepos_y = vid_conheight;
 608            mousepos = mousepos*0.5 + getmousepos();
 609          */
 610
 611         e = self;
 612         for(self = world; (self = nextent(self)); )
 613                 if(self.draw)
 614                         self.draw();
 615         self = e;
 616
 617         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 618         R_RenderScene();
 619
 620         // now switch to 2D drawing mode by calling a 2D drawing function
 621         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 622         // next R_RenderScene call
 623         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 624
 625         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 626         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 627         {
 628                 // apply night vision effect
 629                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 630
 631                 if(!nightvision_noise)
 632                 {
 633                         nightvision_noise = spawn();
 634                         nightvision_noise.classname = "nightvision_noise";
 635                 }
 636                 if(!nightvision_noise2)
 637                 {
 638                         nightvision_noise2 = spawn();
 639                         nightvision_noise2.classname = "nightvision_noise2";
 640                 }
 641
 642                 // color tint in yellow
 643                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 644
 645                 // draw BG
 646                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 647                 rgb = '1 1 1';
 648                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 649                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 650                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 651                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 652                 tc_11 = tc_01 + tc_10 - tc_00;
 653                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 654                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 655                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 656                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 657                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 658                 R_EndPolygon();
 659
 660                 // draw FG
 661                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 662                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 663                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 664                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 665                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 666                 tc_11 = tc_01 + tc_10 - tc_00;
 667                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 668                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 669                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 670                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 671                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 672                 R_EndPolygon();
 673         }
 674
 675         // Draw the aiming reticle for weapons that use it
 676         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 677         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 678         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 679         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 680                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 681         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 682                 reticle_type = 2; // nex zoom
 683         else if(button_zoom || zoomscript_caught)
 684                 reticle_type = 1; // normal zoom
 685         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 686                 reticle_type = 2; // nex zoom
 687
 688         if (reticle_type)
 689         {
 690                 if(autocvar_cl_reticle_stretch)
 691                 {
 692                         reticle_size_x = vid_conwidth;
 693                         reticle_size_y = vid_conheight;
 694                         reticle_pos_x = 0;
 695                         reticle_pos_y = 0;
 696                 }
 697                 else
 698                 {
 699                         reticle_size_x = max(vid_conwidth, vid_conheight);
 700                         reticle_size_y = max(vid_conwidth, vid_conheight);
 701                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 702                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 703                 }
 704
 705                 f = current_zoomfraction;
 706                 if(zoomscript_caught)
 707                         f = 1;
 708                 if(autocvar_cl_reticle_item_normal)
 709                 {
 710                         if(reticle_type == 1 && f)
 711                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 712                 }
 713                 if(autocvar_cl_reticle_item_nex)
 714                 {
 715                         if(reticle_type == 2 && f)
 716                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 717                 }
 718         }
 719
 720
 721         // improved polyblend
 722         vector rgb;
 723         if(autocvar_hud_contents)
 724         {
 725                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 726                 vector liquidcolor;
 727
 728                 switch(pointcontents(view_origin))
 729                 {
 730                         case CONTENT_WATER:
 731                                 liquidalpha = autocvar_hud_contents_water_alpha;
 732                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 733                                 incontent = 1;
 734                                 break;
 735
 736                         case CONTENT_LAVA:
 737                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 738                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 739                                 incontent = 1;
 740                                 break;
 741
 742                         case CONTENT_SLIME:
 743                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 744                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 745                                 incontent = 1;
 746                                 break;
 747
 748                         default:
 749                                 liquidalpha = 0;
 750                                 liquidcolor = '0 0 0';
 751                                 incontent = 0;
 752                                 break;
 753                 }
 754
 755                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 756                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 757                         contentfadetime = autocvar_hud_contents_fadeintime;
 758                         liquidalpha_prev = liquidalpha;
 759                         liquidcolor_prev = liquidcolor;
 760                 }
 761                 else
 762                         contentfadetime = autocvar_hud_contents_fadeouttime;
 763
 764                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 765                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 766
 767                 if(contentavgalpha)
 768                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 769         }
 770
 771         if(autocvar_hud_damage && !autocvar_chase_active)
 772         {
 773                 splash_size_x = max(vid_conwidth, vid_conheight);
 774                 splash_size_y = max(vid_conwidth, vid_conheight);
 775                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 776                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 777
 778                 float myhealth_flash_temp;
 779                 myhealth = getstati(STAT_HEALTH);
 780
 781                 // fade out
 782                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 783                 // add new damage
 784                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 785
 786                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 787                 pain_threshold = autocvar_hud_damage_pain_threshold;
 788                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 789                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 790
 791                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 792                 {
 793                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 794                 }
 795
 796                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 797
 798                 if(myhealth_prev < 1)
 799                 {
 800                         if(myhealth >= 1)
 801                         {
 802                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 803                                 myhealth_flash_temp = 0;
 804                         }
 805                         else
 806                         {
 807                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 808                         }
 809                 }
 810
 811                 if(spectatee_status == -1 || intermission)
 812                 {
 813                         myhealth_flash = 0; // observing, or match ended
 814                         myhealth_flash_temp = 0;
 815                 }
 816
 817                 myhealth_prev = myhealth;
 818
 819                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 820                 {
 821                         if(autocvar_cl_gentle_damage == 2)
 822                         {
 823                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 824                                 {
 825                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 826                                 }
 827                         }
 828                         else
 829                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 830
 831                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 832                 }
 833                 else
 834                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 835         }
 836
 837         // Draw the mouse cursor
 838         // NOTE: drawpic must happen after R_RenderScene for some reason
 839         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 840         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 841         //self = edict_num(player_localnum);
 842         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 843         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 844         // as long as the ctf part isn't in, this is useless
 845         if(menu_visible)
 846                 menu_show();
 847
 848         /*if(gametype == GAME_CTF)
 849           {
 850           ctf_view();
 851           } else */
 852
 853         // draw 2D entities
 854         e = self;
 855         for(self = world; (self = nextent(self)); )
 856                 if(self.draw2d)
 857                         self.draw2d();
 858         self = e;
 859         Draw_ShowNames_All();
 860
 861         scoreboard_active = HUD_WouldDrawScoreboard();
 862
 863         hit_time = getstatf(STAT_HIT_TIME);
 864         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 865         {
 866                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 867                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 868         }
 869         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 870         if(typehit_time > nextsound_typehit_time)
 871         {
 872                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 873                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 874         }
 875
 876         float hud;
 877         hud = getstati(STAT_HUD);
 878         if(hud == HUD_SPIDERBOT)
 879                 CSQC_SPIDER_HUD();
 880         else if(hud == HUD_WAKIZASHI)
 881         CSQC_WAKIZASHI_HUD();
 882     else if(hud == HUD_RAPTOR)
 883         CSQC_RAPTOR_HUD();
 884         else
 885         {
 886                 if(gametype == GAME_FREEZETAG)
 887                 {
 888                         if(getstati(STAT_FROZEN))
 889                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 890                         if(getstatf(STAT_REVIVE_PROGRESS))
 891                         {
 892                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 893                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 894                         }
 895                 }
 896
 897                 if(autocvar_r_letterbox == 0)
 898                         if(autocvar_viewsize < 120)
 899                                 CSQC_common_hud();
 900
 901                 // crosshair goes VERY LAST
 902                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
 903                         string wcross_style;
 904                         float wcross_alpha, wcross_resolution;
 905                         wcross_style = autocvar_crosshair;
 906                         if (wcross_style == "0")
 907                                 return;
 908                         wcross_resolution = autocvar_crosshair_size;
 909                         if (wcross_resolution == 0)
 910                                 return;
 911                         wcross_alpha = autocvar_crosshair_alpha;
 912                         if (wcross_alpha == 0)
 913                                 return;
 914
 915                         // TrueAim check
 916                         float shottype;
 917
 918                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 919                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 920                         wcross_origin_z = 0;
 921                         if(autocvar_crosshair_hittest)
 922                         {
 923                                 vector wcross_oldorigin;
 924                                 wcross_oldorigin = wcross_origin;
 925                                 shottype = TrueAimCheck();
 926                                 if(shottype == SHOTTYPE_HITWORLD)
 927                                 {
 928                                         v = wcross_origin - wcross_oldorigin;
 929                                         v_x /= vid_conwidth;
 930                                         v_y /= vid_conheight;
 931                                         if(vlen(v) > 0.01)
 932                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 933                                 }
 934                                 if(!autocvar_crosshair_hittest_showimpact)
 935                                         wcross_origin = wcross_oldorigin;
 936                         }
 937                         else
 938                                 shottype = SHOTTYPE_HITWORLD;
 939
 940                         vector wcross_color, wcross_size;
 941                         string wcross_wep, wcross_name;
 942                         float wcross_scale, wcross_blur;
 943
 944                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 945                                 e = get_weaponinfo(activeweapon);
 946                                 if (e && e.netname != "")
 947                                 {
 948                                         wcross_wep = e.netname;
 949                                         if(autocvar_crosshair_per_weapon)
 950                                         {
 951                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 952                                                 if (wcross_resolution == 0)
 953                                                         return;
 954                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 955                                                 if (wcross_alpha == 0)
 956                                                         return;
 957
 958                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 959                                                 if(wcross_style == "" || wcross_style == "0")
 960                                                         wcross_style = wcross_wep;
 961                                         }
 962                                 }
 963                         }
 964                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 965                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 966                         else if(autocvar_crosshair_color_by_health)
 967                         {
 968                                 local float x = getstati(STAT_HEALTH);
 969
 970                                 //x = red
 971                                 //y = green
 972                                 //z = blue
 973
 974                                 wcross_color_z = 0;
 975
 976                                 if(x > 200)
 977                                 {
 978                                         wcross_color_x = 0;
 979                                         wcross_color_y = 1;
 980                                 }
 981                                 else if(x > 150)
 982                                 {
 983                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 984                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 985                                 }
 986                                 else if(x > 100)
 987                                 {
 988                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 989                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 990                                         wcross_color_z = 1 - (x-100)*0.02;
 991                                 }
 992                                 else if(x > 50)
 993                                 {
 994                                         wcross_color_x = 1;
 995                                         wcross_color_y = 1;
 996                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 997                                 }
 998                                 else if(x > 20)
 999                                 {
1000                                         wcross_color_x = 1;
1001                                         wcross_color_y = (x-20)*90/27/100;
1002                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1003                                 }
1004                                 else
1005                                 {
1006                                         wcross_color_x = 1;
1007                                         wcross_color_y = 0;
1008                                 }
1009                         }
1010                         else
1011                                 wcross_color = stov(autocvar_crosshair_color);
1012
1013                         wcross_name = strcat("gfx/crosshair", wcross_style);
1014
1015                         if(autocvar_crosshair_effect_scalefade)
1016                         {
1017                                 wcross_scale = wcross_resolution;
1018                                 wcross_resolution = 1;
1019                         }
1020                         else
1021                         {
1022                                 wcross_scale = 1;
1023                         }
1024
1025                         if(autocvar_crosshair_pickup)
1026                         {
1027                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1028                                 {
1029                                         pickup_crosshair_size = 1;
1030                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1031                                 }
1032
1033                                 if(pickup_crosshair_size > 0)
1034                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1035                                 else
1036                                         pickup_crosshair_size = 0;
1037
1038                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1039                         }
1040
1041                         vector hitindication_color;
1042                         if(autocvar_crosshair_hitindication)
1043                         {
1044                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1045                                 if(hitindication_crosshair_time < hit_time)
1046                                 {
1047                                         hitindication_crosshair_size = 1;
1048                                         hitindication_crosshair_time = hit_time;
1049                                 }
1050
1051                                 if(hitindication_crosshair_size > 0)
1052                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1053                                 else
1054                                         hitindication_crosshair_size = 0;
1055
1056                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1057                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1058                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1059                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1060                         }
1061
1062                         if(shottype == SHOTTYPE_HITENEMY)
1063                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1064                         if(shottype == SHOTTYPE_HITTEAM)
1065                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1066
1067                         f = autocvar_crosshair_effect_speed;
1068                         if(f < 0)
1069                                 f *= -2 * g_weaponswitchdelay;
1070                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1071                         {
1072                                 wcross_changedonetime = time + f;
1073                         }
1074                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1075                         {
1076                                 wcross_name_changestarttime = time;
1077                                 wcross_name_changedonetime = time + f;
1078                                 if(wcross_name_goal_prev_prev)
1079                                         strunzone(wcross_name_goal_prev_prev);
1080                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1081                                 wcross_name_goal_prev = strzone(wcross_name);
1082                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1083                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1084                                 wcross_resolution_goal_prev = wcross_resolution;
1085                         }
1086
1087                         wcross_scale_goal_prev = wcross_scale;
1088                         wcross_alpha_goal_prev = wcross_alpha;
1089                         wcross_color_goal_prev = wcross_color;
1090
1091                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1092                         {
1093                                 wcross_blur = 1;
1094                                 wcross_alpha *= 0.75;
1095                         }
1096                         else
1097                                 wcross_blur = 0;
1098                         // *_prev is at time-frametime
1099                         // * is at wcross_changedonetime+f
1100                         // what do we have at time?
1101                         if(time < wcross_changedonetime)
1102                         {
1103                                 f = frametime / (wcross_changedonetime - time + frametime);
1104                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1105                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1106                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1107                         }
1108
1109                         wcross_scale_prev = wcross_scale;
1110                         wcross_alpha_prev = wcross_alpha;
1111                         wcross_color_prev = wcross_color;
1112
1113                         wcross_scale *= 1 - autocvar__menu_alpha;
1114                         wcross_alpha *= 1 - autocvar__menu_alpha;
1115                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1116
1117                         // crosshair rings for weapon stats
1118                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1119                         {
1120                                 // declarations and stats
1121                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1122                                 string ring_image, ring_inner_image;
1123                                 vector ring_rgb, ring_inner_rgb;
1124
1125                                 ring_scale = autocvar_crosshair_ring_size;
1126
1127                                 float weapon_clipload, weapon_clipsize;
1128                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1129                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1130
1131                                 float nex_charge, nex_chargepool;
1132                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1133                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1134
1135                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1136                                         nex_charge_movingavg = nex_charge;
1137
1138
1139                                 // handle the values
1140                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1141                                 {
1142                                         if (nex_chargepool || use_nex_chargepool) {
1143                                                 use_nex_chargepool = 1;
1144                                                 ring_inner_value = nex_chargepool;
1145                                         } else {
1146                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1147                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1148                                         }
1149
1150                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1151                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1152                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1153
1154                                         // draw the outer ring to show the current charge of the weapon
1155                                         ring_value = nex_charge;
1156                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1157                                         ring_rgb = wcross_color;
1158                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1159                                 }
1160                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1161                                 {
1162                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1163                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1164                                         ring_rgb = wcross_color;
1165                                         ring_image = "gfx/crosshair_ring.tga";
1166                                 }
1167                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1168                                 {
1169                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1170                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1171                                         ring_rgb = wcross_color;
1172                                         ring_image = "gfx/crosshair_ring.tga";
1173                                 }
1174
1175                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1176                                 {
1177                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1178                                         ring_scale = autocvar_crosshair_ring_reload_size;
1179                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1180                                         ring_rgb = wcross_color;
1181
1182                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1183                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1184                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1185                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1186                                         else
1187                                                 ring_image = "gfx/crosshair_ring.tga";
1188                                 }
1189
1190                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1191                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1192
1193                                 if (ring_value)
1194                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1195                         }
1196
1197 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1198                         do \
1199                         { \
1200                                 if(wcross_blur > 0) \
1201                                 { \
1202                                         for(i = -2; i <= 2; ++i) \
1203                                                 for(j = -2; j <= 2; ++j) \
1204                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1205                                 } \
1206                                 else \
1207                                 { \
1208                                         M(0,0,sz,wcross_name,wcross_alpha); \
1209                                 } \
1210                         } \
1211                         while(0)
1212
1213 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1214                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1215
1216 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1217                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1218
1219                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1220                         {
1221                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1222                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1223                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1224                                 f = 1 - f;
1225                         }
1226                         else
1227                         {
1228                                 f = 1;
1229                         }
1230
1231                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1232                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1233
1234                         if(autocvar_crosshair_dot)
1235             {
1236                 vector wcross_color_old;
1237                 wcross_color_old = wcross_color;
1238                 if(autocvar_crosshair_dot_color != "0")
1239                     wcross_color = stov(autocvar_crosshair_dot_color);
1240                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1241                 wcross_color = wcross_color_old;
1242             }
1243
1244                         wcross_name_alpha_goal_prev = f;
1245                 }
1246                 else
1247                 {
1248                         wcross_scale_prev = 0;
1249                         wcross_alpha_prev = 0;
1250                         wcross_scale_goal_prev = 0;
1251                         wcross_alpha_goal_prev = 0;
1252                         wcross_changedonetime = 0;
1253                         if(wcross_name_goal_prev)
1254                                 strunzone(wcross_name_goal_prev);
1255                         wcross_name_goal_prev = string_null;
1256                         if(wcross_name_goal_prev_prev)
1257                                 strunzone(wcross_name_goal_prev_prev);
1258                         wcross_name_goal_prev_prev = string_null;
1259                         wcross_name_changestarttime = 0;
1260                         wcross_name_changedonetime = 0;
1261                         wcross_name_alpha_goal_prev = 0;
1262                         wcross_name_alpha_goal_prev_prev = 0;
1263                         wcross_resolution_goal_prev = 0;
1264                         wcross_resolution_goal_prev_prev = 0;
1265                 }
1266         }
1267
1268         if(NextFrameCommand)
1269         {
1270                 localcmd("\n", NextFrameCommand, "\n");
1271                 NextFrameCommand = string_null;
1272         }
1273
1274         // we must do this check AFTER a frame was rendered, or it won't work
1275         if(cs_project_is_b0rked == 0)
1276         {
1277                 string w0, h0;
1278                 w0 = ftos(autocvar_vid_conwidth);
1279                 h0 = ftos(autocvar_vid_conheight);
1280                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1281                 //R_SetView(VF_FOV, '90 90 0');
1282                 R_SetView(VF_ORIGIN, '0 0 0');
1283                 R_SetView(VF_ANGLES, '0 0 0');
1284                 R_SetView(VF_PERSPECTIVE, 1);
1285                 makevectors('0 0 0');
1286                 vector v1, v2;
1287                 cvar_set("vid_conwidth", "800");
1288                 cvar_set("vid_conheight", "600");
1289                 v1 = cs_project(v_forward);
1290                 cvar_set("vid_conwidth", "640");
1291                 cvar_set("vid_conheight", "480");
1292                 v2 = cs_project(v_forward);
1293                 if(v1 == v2)
1294                         cs_project_is_b0rked = 1;
1295                 else
1296                         cs_project_is_b0rked = -1;
1297                 cvar_set("vid_conwidth", w0);
1298                 cvar_set("vid_conheight", h0);
1299         }
1300
1301         if(autocvar__hud_configure)
1302                 HUD_Panel_Mouse();
1303
1304         // let's reset the view back to normal for the end
1305         R_SetView(VF_MIN, '0 0 0');
1306         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1307 }
1308
1309 #define spider_h "gfx/vehicles/hud_bg.tga"
1310 #define spider_b "gfx/vehicles/sbot.tga"
1311 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1312 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1313 #define spider_s "gfx/vehicles/shiled.tga"
1314 #define spider_a1 "gfx/hud/sb_rocket.tga"
1315 #define spider_a2 "gfx/sb_bullets.tga"
1316
1317 void CSQC_SPIDER_HUD()
1318 {
1319         float rockets, reload, heat, hp, shield;
1320         vector picsize, hudloc;
1321
1322     // Fetch health & ammo stats
1323     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1324         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1325         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1326         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1327         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1328
1329     // Draw the crosshairs
1330     picsize = drawgetimagesize(SPIDER_CROSS);
1331     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1332     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1333     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1334
1335     hudloc_y =  4;
1336     hudloc_x = 4;
1337
1338     picsize = drawgetimagesize(spider_h) * 0.5;
1339     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1340
1341     picsize = drawgetimagesize(spider_a2) * 0.5;
1342     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1343
1344     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1345     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1346     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1347
1348     picsize = drawgetimagesize(spider_a1) * 0.85;
1349     if(rockets == 9)
1350     {
1351         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1352         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1353     }
1354     else
1355     {
1356         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1357         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1358     }
1359
1360     picsize = drawgetimagesize(spider_b) * 0.5;
1361     hudloc_y = 10.5;
1362     hudloc_x = 10.5;
1363
1364     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1365     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1366     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1367     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1368
1369
1370         /*
1371         // Draw health bar
1372         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1373         p = p + '0 1 0' * vid_conheight - '0 32 0';
1374         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1375         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1376         p_y += 8;
1377         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1378         p_x += 256 * hp;
1379         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1380
1381         // Draw minigun heat indicator
1382         p = '0.5 0 0' * (vid_conwidth - 256);
1383         p = p + '0 1 0' * vid_conheight - '0 34  0';
1384         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1385         p_x += 256 * (1-heat);
1386         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1387
1388
1389         // Draw rocket icons for loaded/empty tubes.
1390         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1391         pp += '0 1 0' * vid_conheight - '0 64 0';
1392         for(i = 0; i < 8; ++i)
1393         {
1394                 p = pp + '1 0 0' * (rkt_size * i);
1395                 if(rockets == 8)
1396                 {
1397                         if(floor(reload * 8) == i)
1398                         {
1399                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1400                         }
1401                         else if(i < reload * 8)
1402                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1403                         else
1404                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1405                 }
1406                 else
1407                 {
1408                         if(i < rockets)
1409                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1410                         else
1411                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1412                 }
1413         }
1414         */
1415
1416         if (scoreboard_showscores)
1417         {
1418                 HUD_DrawScoreboard();
1419                 HUD_DrawCenterPrint();
1420         }
1421
1422 }
1423
1424 #define raptor_h "gfx/vehicles/hud_bg.tga"
1425 #define raptor_b "gfx/vehicles/raptor.tga"
1426 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1427 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1428 #define raptor_s "gfx/vehicles/shiled.tga"
1429
1430 void CSQC_RAPTOR_HUD()
1431 {
1432         float reload, hp, shield, energy;
1433         vector picsize, hudloc;
1434
1435     // Fetch health & ammo stats
1436     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1437         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1438         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1439         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1440
1441     // Draw the crosshairs
1442     picsize = drawgetimagesize(SPIDER_CROSS);
1443     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1444     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1445     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1446
1447     hudloc_y =  4;
1448     hudloc_x = 4;
1449
1450     picsize = drawgetimagesize(raptor_h) * 0.5;
1451     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1452
1453     picsize = drawgetimagesize(spider_a2) * 0.5;
1454     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1455
1456     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1457     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1458     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1459
1460
1461     picsize = drawgetimagesize(spider_a1) * 0.85;
1462     if(reload == 1)
1463     {
1464         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1465         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1466     }
1467     else
1468     {
1469         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1470         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1471     }
1472
1473     picsize = drawgetimagesize(raptor_b) * 0.5;
1474     hudloc_y = 10.5;
1475     hudloc_x = 10.5;
1476
1477     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1478     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1479     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1480     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1481
1482
1483         if (scoreboard_showscores)
1484         {
1485                 HUD_DrawScoreboard();
1486                 HUD_DrawCenterPrint();
1487         }
1488
1489 }
1490
1491 #define waki_h "gfx/vehicles/hud_bg.tga"
1492 #define waki_b "gfx/vehicles/waki.tga"
1493 #define waki_e "gfx/vehicles/waki_e.tga"
1494 #define waki_g "gfx/vehicles/waki_guns.tga"
1495 #define waki_r "gfx/vehicles/waki_rockets.tga"
1496 #define waki_s "gfx/vehicles/shiled.tga"
1497
1498 #define waki_a1 "gfx/hud/sb_rocket.tga"
1499 #define waki_a2 "gfx/sb_cells.tga"
1500
1501 void CSQC_WAKIZASHI_HUD()
1502 {
1503         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1504         float health, shield, energy, rockets;
1505         vector picsize, hudloc;
1506
1507     picsize = drawgetimagesize(SPIDER_CROSS);
1508     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1509     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1510     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1511
1512 /*
1513 const float STAT_VEHICLESTAT_HEALTH  = 60;
1514 const float STAT_VEHICLESTAT_SHIELD  = 61;
1515 const float STAT_VEHICLESTAT_ENERGY  = 62;
1516 const float STAT_VEHICLESTAT_AMMO1   = 63;
1517 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1518 const float STAT_VEHICLESTAT_AMMO2   = 65;
1519 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1520 */
1521     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1522         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1523         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1524         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1525
1526     hudloc_y =  4;
1527     hudloc_x = 4;
1528
1529     picsize = drawgetimagesize(waki_h) * 0.5;
1530     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1531
1532     picsize = drawgetimagesize(waki_a2) * 0.7;
1533     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1534
1535
1536     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1537     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1538
1539     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1540
1541     picsize = drawgetimagesize(waki_a1) * 0.75;
1542     if(rockets == 1)
1543     {
1544         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1545         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1546     }
1547     else
1548     {
1549         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1550         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1551         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1552     }
1553
1554     picsize = drawgetimagesize(waki_b) * 0.5;
1555     hudloc_y = 10.5;
1556     hudloc_x = 10.5;
1557
1558     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1559     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1560     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1561     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1562
1563
1564
1565         /*
1566         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1567         p = p + '0 1 0' * vid_conheight - '0 32 0';
1568
1569         // Draw health bar
1570         p_y += 8;
1571         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1572         p_x += 256 * health;
1573         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1574
1575         // Draw shiled bar
1576         p_x -= 256 * health;
1577         p_y += 4;
1578         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1579
1580         // Draw energy
1581         //p_x -= 256 * health;
1582         p_y -= 8;
1583         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1584
1585         // Draw rockets bar
1586         p_y += 12;
1587         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1588         */
1589
1590
1591
1592
1593         if (scoreboard_showscores)
1594         {
1595                 HUD_DrawScoreboard();
1596                 HUD_DrawCenterPrint();
1597         }
1598
1599 }
1600
1601 void CSQC_common_hud(void)
1602 {
1603         // HUD_SortFrags(); done in HUD_Draw
1604         float hud;
1605         hud = getstati(STAT_HUD);
1606
1607         //hud = 10;
1608         switch(hud)
1609         {
1610                 case HUD_NORMAL:
1611                         // do some accuracy var caching
1612                         float i;
1613                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1614                         {
1615                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1616                                 {
1617                                         if(acc_color_levels)
1618                                                 strunzone(acc_color_levels);
1619                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1620                                         acc_levels = tokenize(acc_color_levels);
1621                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1622                                                 acc_levels = MAX_ACCURACY_LEVELS;
1623
1624                                         for (i = 0; i < acc_levels; ++i)
1625                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1626                                 }
1627                                 // let know that acc_col[] needs to be loaded
1628                                 acc_col_x[0] = -1;
1629                         }
1630
1631                         HUD_Main(); // always run these functions for alpha checks
1632                         HUD_DrawScoreboard();
1633
1634                         if (scoreboard_active) // scoreboard/accuracy
1635                         {
1636                                 HUD_Reset();
1637                                 // HUD_DrawScoreboard takes care of centerprint_start
1638                         }
1639                         else if (intermission == 2) // map voting screen
1640                         {
1641                                 HUD_FinaleOverlay();
1642                                 HUD_Reset();
1643
1644                                 centerprint_start_x = 0;
1645                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1646                         }
1647                         else // hud
1648                         {
1649                                 centerprint_start_x = 0;
1650                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1651                         }
1652
1653                         HUD_DrawCenterPrint();
1654                         break;
1655
1656                 case HUD_SPIDERBOT:
1657                         CSQC_SPIDER_HUD();
1658                         break;
1659
1660                 case HUD_WAKIZASHI:
1661                         CSQC_WAKIZASHI_HUD();
1662                         break;
1663         }
1664 }
1665
1666
1667 // following vectors must be global to allow seamless switching between camera modes
1668 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1669 void CSQC_Demo_Camera()
1670 {
1671         float speed, attenuation, dimensions;
1672         vector tmp, delta;
1673
1674         if( autocvar_camera_reset || !camera_mode )
1675         {
1676                 camera_offset = '0 0 0';
1677                 current_angles = '0 0 0';
1678                 camera_direction = '0 0 0';
1679                 camera_offset_z += 30;
1680                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1681                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1682                 current_origin = view_origin;
1683                 current_camera_offset  = camera_offset;
1684                 cvar_set("camera_reset", "0");
1685                 camera_mode = CAMERA_CHASE;
1686         }
1687
1688         // Camera angles
1689         if( camera_roll )
1690                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1691
1692         if(autocvar_camera_look_player)
1693         {
1694                 local vector dir;
1695                 local float n;
1696
1697                 dir = normalize(view_origin - current_position);
1698                 n = mouse_angles_z;
1699                 mouse_angles = vectoangles(dir);
1700                 mouse_angles_x = mouse_angles_x * -1;
1701                 mouse_angles_z = n;
1702         }
1703         else
1704         {
1705                 tmp = getmousepos() * 0.1;
1706                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1707                 {
1708                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1709                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1710                 }
1711         }
1712
1713         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1714         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1715         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1716         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1717
1718         // Fix difference when angles don't have the same sign
1719         delta = '0 0 0';
1720         if(mouse_angles_y < -60 && current_angles_y > 60)
1721                 delta = '0 360 0';
1722         if(mouse_angles_y > 60 && current_angles_y < -60)
1723                 delta = '0 -360 0';
1724
1725         if(autocvar_camera_look_player)
1726                 attenuation = autocvar_camera_look_attenuation;
1727         else
1728                 attenuation = autocvar_camera_speed_attenuation;
1729
1730         attenuation = 1 / max(1, attenuation);
1731         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1732
1733         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1734         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1735         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1736         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1737
1738         // Camera position
1739         tmp = '0 0 0';
1740         dimensions = 0;
1741
1742         if( camera_direction_x )
1743         {
1744                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1745                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1746                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1747                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1748                 ++dimensions;
1749         }
1750
1751         if( camera_direction_y )
1752         {
1753                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1754                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1755                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1756                 ++dimensions;
1757         }
1758
1759         if( camera_direction_z )
1760         {
1761                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1762                 ++dimensions;
1763         }
1764
1765         if(autocvar_camera_free)
1766                 speed = autocvar_camera_speed_free;
1767         else
1768                 speed = autocvar_camera_speed_chase;
1769
1770         if(dimensions)
1771         {
1772                 speed = speed * sqrt(1 / dimensions);
1773                 camera_offset += tmp * speed;
1774         }
1775
1776         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1777
1778         // Camera modes
1779         if( autocvar_camera_free )
1780         {
1781                 if ( camera_mode == CAMERA_CHASE )
1782                 {
1783                         current_camera_offset = current_origin + current_camera_offset;
1784                         camera_offset = current_origin + camera_offset;
1785                 }
1786
1787                 camera_mode = CAMERA_FREE;
1788                 current_position = current_camera_offset;
1789         }
1790         else
1791         {
1792                 if ( camera_mode == CAMERA_FREE )
1793                 {
1794                         current_origin = view_origin;
1795                         camera_offset = camera_offset - current_origin;
1796                         current_camera_offset = current_camera_offset - current_origin;
1797                 }
1798
1799                 camera_mode = CAMERA_CHASE;
1800
1801                 if(autocvar_camera_chase_smoothly)
1802                         current_origin += (view_origin - current_origin) * attenuation;
1803                 else
1804                         current_origin = view_origin;
1805
1806                 current_position = current_origin + current_camera_offset;
1807         }
1808
1809         R_SetView(VF_ANGLES, current_angles);
1810         R_SetView(VF_ORIGIN, current_position);
1811 }