qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void CSQC_kh_hud(void);
 340 void CSQC_ctf_hud(void);
 341 void PostInit(void);
 342 void CSQC_Demo_Camera();
 343 float HUD_WouldDrawScoreboard ();
 344 float view_set;
 345 float camera_mode;
 346 string NextFrameCommand;
 347 void CSQC_SPIDER_HUD();
 348 void CSQC_RAPTOR_HUD();
 349
 350 vector freeze_pmove_org, freeze_input_angles;
 351
 352 void CSQC_UpdateView(float w, float h)
 353 {
 354         entity e;
 355         float fov;
 356         float f, i, j;
 357         vector v, vo;
 358
 359         WaypointSprite_Load();
 360
 361         if(spectatee_status)
 362                 myteam = GetPlayerColor(spectatee_status - 1);
 363         else
 364                 myteam = GetPlayerColor(player_localentnum - 1);
 365
 366         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 367         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 368
 369         warpzone_fixview_origin = pmove_org + vo;
 370         warpzone_fixview_cl_viewangles = input_angles;
 371         warpzone_fixview_angles = view_angles;
 372         WarpZone_FixView();
 373         pmove_org = warpzone_fixview_origin - vo;
 374         input_angles = warpzone_fixview_cl_viewangles;
 375         view_angles = warpzone_fixview_angles;
 376
 377         if(cvar("cl_lockview"))
 378         {
 379                 pmove_org = freeze_pmove_org;
 380                 input_angles = view_angles = freeze_input_angles;
 381                 R_SetView(VF_ORIGIN, pmove_org + vo);
 382                 R_SetView(VF_ANGLES, view_angles);
 383                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 384         }
 385         freeze_pmove_org = pmove_org;
 386         freeze_input_angles = input_angles;
 387
 388         // Render the Scene
 389         if(!intermission || !view_set)
 390         {
 391                 view_origin = pmove_org + vo;
 392                 view_angles = input_angles;
 393                 makevectors(view_angles);
 394                 view_forward = v_forward;
 395                 view_right = v_right;
 396                 view_up = v_up;
 397                 view_set = 1;
 398         }
 399
 400         hudconf_active = cvar("_hud_configure");
 401         if(hudconf_active)
 402                 R_SetView(VF_ANGLES, self.angles); // TODO: this should freeze the view as it is, not change it to '0 0 0' or whatever it currently does...
 403
 404         vid_width = w;
 405         vid_height = h;
 406
 407 #ifdef BLURTEST
 408         if(time > blurtest_time0 && time < blurtest_time1)
 409         {
 410                 float r, t;
 411
 412                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 413                 r = t * blurtest_radius;
 414                 f = 1 / pow(t, blurtest_power) - 1;
 415
 416                 cvar_set("r_glsl_postprocess", "1");
 417                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 418         }
 419         else
 420         {
 421                 cvar_set("r_glsl_postprocess", "0");
 422                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 423         }
 424 #endif
 425
 426         TargetMusic_Advance();
 427         Fog_Force();
 428
 429         drawframetime = max(0.000001, time - drawtime);
 430         drawtime = time;
 431
 432         // watch for gametype changes here...
 433         // in ParseStuffCMD the cmd isn't executed yet :/
 434         // might even be better to add the gametype to TE_CSQC_INIT...?
 435         if(!postinit)
 436                 PostInit();
 437
 438         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 439                 if(calledhooks & HOOK_START)
 440                 {
 441                         localcmd("\ncl_hook_gameend;");
 442                         calledhooks |= HOOK_END;
 443                 }
 444
 445         CheckForGamestartChange();
 446         serverAnnouncer();
 447         maptimeAnnouncer();
 448         carrierAnnouncer();
 449
 450         fov = cvar("fov");
 451         if(button_zoom || fov <= 59.5)
 452         {
 453                 if(!zoomscript_caught)
 454                 {
 455                         localcmd("+button4\n");
 456                         zoomscript_caught = 1;
 457                         ignore_plus_zoom += 1;
 458                 }
 459         }
 460         else
 461         {
 462                 if(zoomscript_caught)
 463                 {
 464                         localcmd("-button4\n");
 465                         zoomscript_caught = 0;
 466                         ignore_minus_zoom += 1;
 467                 }
 468         }
 469
 470         hud_alpha_fg = cvar_or("hud_fg_alpha", 1) * (1 - cvar("_menu_alpha"));
 471         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 472         ColorTranslateMode = cvar("cl_stripcolorcodes");
 473         activeweapon = getstati(STAT_SWITCHWEAPON);
 474         f = cvar("teamplay");
 475         if(f != teamplay)
 476         {
 477                 teamplay = f;
 478                 HUD_InitScores();
 479         }
 480
 481         if(last_weapon != activeweapon) {
 482                 weapontime = time;
 483                 last_weapon = activeweapon;
 484         }
 485
 486         // ALWAYS Clear Current Scene First
 487         R_ClearScene();
 488
 489         // Assign Standard Viewflags
 490         // Draw the World (and sky)
 491         R_SetView(VF_DRAWWORLD, 1);
 492
 493         // Set the console size vars
 494         vid_conwidth = cvar("vid_conwidth");
 495         vid_conheight = cvar("vid_conheight");
 496         vid_pixelheight = cvar("vid_pixelheight");
 497
 498         R_SetView(VF_FOV, GetCurrentFov(fov));
 499
 500         // Camera for demo playback
 501         if(camera_active)
 502         {
 503                 if(cvar("camera_enable"))
 504                         CSQC_Demo_Camera();
 505                 else
 506                 {
 507                         cvar_set("chase_active", ftos(chase_active_backup));
 508                         cvar_set("cl_demo_mousegrab", "0");
 509                         camera_active = FALSE;
 510                 }
 511         }
 512 #ifdef CAMERATEST
 513         else if(cvar("camera_enable"))
 514 #else
 515         else if(cvar("camera_enable") && isdemo())
 516 #endif
 517         {
 518                 // Enable required Darkplaces cvars
 519                 chase_active_backup = cvar("chase_active");
 520                 cvar_set("chase_active", "2");
 521                 cvar_set("cl_demo_mousegrab", "1");
 522                 camera_active = TRUE;
 523                 camera_mode = FALSE;
 524         }
 525
 526         // Draw the Crosshair
 527         float scoreboard_active;
 528         scoreboard_active = HUD_WouldDrawScoreboard();
 529         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 530
 531         // Draw the Engine Status Bar (the default Quake HUD)
 532         R_SetView(VF_DRAWENGINEHUD, 0);
 533
 534         // fetch this one only once per frame
 535         hud_showbinds = cvar("hud_showbinds");
 536         hud_showbinds_limit = cvar("hud_showbinds_limit");
 537
 538         // Update the mouse position
 539         /*
 540            mousepos_x = vid_conwidth;
 541            mousepos_y = vid_conheight;
 542            mousepos = mousepos*0.5 + getmousepos();
 543          */
 544
 545         e = self;
 546         for(self = world; (self = nextent(self)); )
 547                 if(self.draw)
 548                         self.draw();
 549         self = e;
 550
 551         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 552         R_RenderScene();
 553
 554         // now switch to 2D drawing mode by calling a 2D drawing function
 555         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 556         // next R_RenderScene call
 557         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 558
 559         // Draw the mouse cursor
 560         // NOTE: drawpic must happen after R_RenderScene for some reason
 561         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 562         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 563         //self = edict_num(player_localnum);
 564         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 565         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 566         // as long as the ctf part isn't in, this is useless
 567         if(menu_visible)
 568                 menu_show();
 569
 570         /*if(gametype == GAME_CTF)
 571           {
 572           ctf_view();
 573           } else */
 574
 575         // draw 2D entities
 576         e = self;
 577         for(self = world; (self = nextent(self)); )
 578                 if(self.draw2d)
 579                         self.draw2d();
 580         self = e;
 581
 582         // draw hud
 583         if(cvar("r_letterbox") == 0) {
 584                 HUD_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 585         }
 586
 587         float hud;
 588         hud = getstati(STAT_HUD);
 589         if(hud == HUD_SPIDERBOT)
 590         {
 591                 CSQC_SPIDER_HUD();
 592         }
 593         else if(hud == HUD_WAKIZASHI)
 594         CSQC_WAKIZASHI_HUD();
 595     else if(hud == HUD_RAPTOR)
 596         CSQC_RAPTOR_HUD();
 597         else
 598         {
 599                 if(cvar("r_letterbox") == 0)
 600                         if(cvar("viewsize") < 120)
 601                                 CSQC_common_hud();
 602
 603                 // crosshair goes VERY LAST
 604                 if(!scoreboard_active && !ons_showmap && !camera_active && !hudconf_active) {
 605                         // TrueAim check
 606                         float shottype;
 607                         float bullets, ring_scale;
 608                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 609                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 610                         wcross_origin_z = 0;
 611                         if(cvar("crosshair_hittest"))
 612                         {
 613                                 vector wcross_oldorigin;
 614                                 wcross_oldorigin = wcross_origin;
 615                                 shottype = TrueAimCheck();
 616                                 if(shottype == SHOTTYPE_HITWORLD)
 617                                 {
 618                                         v = wcross_origin - wcross_oldorigin;
 619                                         v_x /= vid_conwidth;
 620                                         v_y /= vid_conheight;
 621                                         if(vlen(v) > 0.01)
 622                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 623                                 }
 624                                 if(!cvar("crosshair_hittest_showimpact"))
 625                                         wcross_origin = wcross_oldorigin;
 626                         }
 627                         else
 628                                 shottype = SHOTTYPE_HITWORLD;
 629
 630                         string wcross_style;
 631                         wcross_style = cvar_string("crosshair");
 632
 633                         if (wcross_style != "0") {
 634                                 vector wcross_color, wcross_size;
 635                                 string wcross_wep, wcross_name;
 636                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 637
 638                                 wcross_color_x = cvar("crosshair_color_red");
 639                                 wcross_color_y = cvar("crosshair_color_green");
 640                                 wcross_color_z = cvar("crosshair_color_blue");
 641                                 wcross_alpha = cvar("crosshair_color_alpha");
 642                                 wcross_resolution = cvar("crosshair_size");
 643                                 if (cvar("crosshair_per_weapon")) {
 644                                         e = get_weaponinfo(activeweapon);
 645                                         if (e && e.netname != "")
 646                                         {
 647                                                 wcross_wep = e.netname;
 648                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 649                                                 if(wcross_style == "")
 650                                                         wcross_style = e.netname;
 651
 652                                                 if(!cvar("crosshair_color_override"))
 653                                                 {
 654                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 655                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 656                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 657                                                 }
 658
 659                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 660                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 661                                         }
 662                                 }
 663
 664                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 665
 666                                 if(cvar("crosshair_effect_scalefade"))
 667                                 {
 668                                         wcross_scale = wcross_resolution;
 669                                         wcross_resolution = 1;
 670                                 }
 671                                 else
 672                                 {
 673                                         wcross_scale = 1;
 674                                 }
 675
 676                                 if(shottype == SHOTTYPE_HITENEMY)
 677                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 678                                 if(shottype == SHOTTYPE_HITTEAM)
 679                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 680
 681                                 f = cvar("crosshair_effect_speed");
 682                                 if(f < 0)
 683                                         f *= -2 * g_weaponswitchdelay;
 684                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 685                                 {
 686                                         wcross_changedonetime = time + f;
 687                                 }
 688                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 689                                 {
 690                                         wcross_name_changestarttime = time;
 691                                         wcross_name_changedonetime = time + f;
 692                                         if(wcross_name_goal_prev_prev)
 693                                                 strunzone(wcross_name_goal_prev_prev);
 694                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 695                                         wcross_name_goal_prev = strzone(wcross_name);
 696                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 697                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 698                                         wcross_resolution_goal_prev = wcross_resolution;
 699                                 }
 700
 701                                 wcross_scale_goal_prev = wcross_scale;
 702                                 wcross_alpha_goal_prev = wcross_alpha;
 703                                 wcross_color_goal_prev = wcross_color;
 704
 705                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 706                                 {
 707                                         wcross_blur = 1;
 708                                         wcross_alpha *= 0.75;
 709                                 }
 710                                 else
 711                                         wcross_blur = 0;
 712                                 // *_prev is at time-frametime
 713                                 // * is at wcross_changedonetime+f
 714                                 // what do we have at time?
 715                                 if(time < wcross_changedonetime)
 716                                 {
 717                                         f = frametime / (wcross_changedonetime - time + frametime);
 718                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 719                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 720                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 721                                 }
 722
 723                                 wcross_scale_prev = wcross_scale;
 724                                 wcross_alpha_prev = wcross_alpha;
 725                                 wcross_color_prev = wcross_color;
 726
 727                                 wcross_scale *= 1 - cvar("_menu_alpha");
 728                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 729
 730                                 // ring around crosshair representing bullets left in camping rifle clip
 731                                 if (activeweapon == WEP_CAMPINGRIFLE)
 732                                 {
 733                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 734                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 735                                 }
 736                                 else
 737                                         bullets = 0;
 738
 739 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 740                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 741
 742 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 743                                 do \
 744                                 { \
 745                                         if(wcross_blur > 0) \
 746                                         { \
 747                                                 for(i = -2; i <= 2; ++i) \
 748                                                         for(j = -2; j <= 2; ++j) \
 749                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 750                                         } \
 751                                         else \
 752                                         { \
 753                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 754                                         } \
 755                                 } \
 756                                 while(0)
 757
 758 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 759                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 760
 761 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 762                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 763
 764                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 765                                 {
 766                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 767                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 768                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 769                                         f = 1 - f;
 770                                 }
 771                                 else
 772                                 {
 773                                         f = 1;
 774                                 }
 775
 776                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 777                                 if(bullets)
 778                                 {
 779                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 780                                 }
 781                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 782                                 wcross_name_alpha_goal_prev = f;
 783                         }
 784                 }
 785                 else
 786                 {
 787                         wcross_scale_prev = 0;
 788                         wcross_alpha_prev = 0;
 789                         wcross_scale_goal_prev = 0;
 790                         wcross_alpha_goal_prev = 0;
 791                         wcross_changedonetime = 0;
 792                         if(wcross_name_goal_prev)
 793                                 strunzone(wcross_name_goal_prev);
 794                         wcross_name_goal_prev = string_null;
 795                         if(wcross_name_goal_prev_prev)
 796                                 strunzone(wcross_name_goal_prev_prev);
 797                         wcross_name_goal_prev_prev = string_null;
 798                         wcross_name_changestarttime = 0;
 799                         wcross_name_changedonetime = 0;
 800                         wcross_name_alpha_goal_prev = 0;
 801                         wcross_name_alpha_goal_prev_prev = 0;
 802                         wcross_resolution_goal_prev = 0;
 803                         wcross_resolution_goal_prev_prev = 0;
 804                 }
 805         }
 806
 807         if(NextFrameCommand)
 808         {
 809                 localcmd("\n", NextFrameCommand, "\n");
 810                 NextFrameCommand = string_null;
 811         }
 812
 813         // we must do this check AFTER a frame was rendered, or it won't work
 814         if(cs_project_is_b0rked == 0)
 815         {
 816                 string w0, h0;
 817                 w0 = cvar_string("vid_conwidth");
 818                 h0 = cvar_string("vid_conheight");
 819                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 820                 //R_SetView(VF_FOV, '90 90 0');
 821                 R_SetView(VF_ORIGIN, '0 0 0');
 822                 R_SetView(VF_ANGLES, '0 0 0');
 823                 R_SetView(VF_PERSPECTIVE, 1);
 824                 makevectors('0 0 0');
 825                 vector v1, v2;
 826                 cvar_set("vid_conwidth", "800");
 827                 cvar_set("vid_conheight", "600");
 828                 v1 = cs_project(v_forward);
 829                 cvar_set("vid_conwidth", "640");
 830                 cvar_set("vid_conheight", "480");
 831                 v2 = cs_project(v_forward);
 832                 if(v1 == v2)
 833                         cs_project_is_b0rked = 1;
 834                 else
 835                         cs_project_is_b0rked = -1;
 836                 cvar_set("vid_conwidth", w0);
 837                 cvar_set("vid_conheight", h0);
 838         }
 839
 840         if(hudconf_active)
 841                 HUD_Panel_Mouse();
 842         // be safe against triggerbots until everyone has the fixed engine
 843         // this call is meant to overwrite the trace globals by something
 844         // unsuspicious
 845         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 846 }
 847
 848 #define spider_h "gfx/vehicles/hud_bg.tga"
 849 #define spider_b "gfx/vehicles/sbot.tga"
 850 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 851 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 852 #define spider_s "gfx/vehicles/shiled.tga"
 853 #define spider_a1 "gfx/hud/sb_rocket.tga"
 854 #define spider_a2 "gfx/sb_bullets.tga"
 855
 856 void CSQC_SPIDER_HUD()
 857 {
 858         float rockets, reload, heat, hp, shield;
 859         vector picsize, hudloc;
 860
 861     // Fetch health & ammo stats
 862     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 863         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 864         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 865         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 866         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 867
 868     // Draw the crosshairs
 869     picsize = drawgetimagesize(SPIDER_CROSS);
 870     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 871     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 872     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 873
 874     hudloc_y =  4;
 875     hudloc_x = 4;
 876
 877     picsize = drawgetimagesize(spider_h) * 0.5;
 878     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 879
 880     picsize = drawgetimagesize(spider_a2) * 0.5;
 881     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 882
 883     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
 884     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
 885     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 886
 887     picsize = drawgetimagesize(spider_a1) * 0.85;
 888     if(rockets == 9)
 889     {
 890         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
 891         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 892     }
 893     else
 894     {
 895         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 896         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 897     }
 898
 899     picsize = drawgetimagesize(spider_b) * 0.5;
 900     hudloc_y = 10.5;
 901     hudloc_x = 10.5;
 902
 903     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
 904     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
 905     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
 906     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
 907
 908
 909         /*
 910         // Draw health bar
 911         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 912         p = p + '0 1 0' * vid_conheight - '0 32 0';
 913         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 914         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 915         p_y += 8;
 916         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 917         p_x += 256 * hp;
 918         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 919
 920         // Draw minigun heat indicator
 921         p = '0.5 0 0' * (vid_conwidth - 256);
 922         p = p + '0 1 0' * vid_conheight - '0 34  0';
 923         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 924         p_x += 256 * (1-heat);
 925         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 926
 927
 928         // Draw rocket icons for loaded/empty tubes.
 929         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 930         pp += '0 1 0' * vid_conheight - '0 64 0';
 931         for(i = 0; i < 8; ++i)
 932         {
 933                 p = pp + '1 0 0' * (rkt_size * i);
 934                 if(rockets == 8)
 935                 {
 936                         if(floor(reload * 8) == i)
 937                         {
 938                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 939                         }
 940                         else if(i < reload * 8)
 941                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 942                         else
 943                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 944                 }
 945                 else
 946                 {
 947                         if(i < rockets)
 948                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 949                         else
 950                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 951                 }
 952         }
 953         */
 954
 955         if (sb_showscores)
 956         {
 957                 HUD_DrawScoreboard();
 958                 HUD_DrawCenterPrint();
 959         }
 960
 961 }
 962
 963 #define raptor_h "gfx/vehicles/hud_bg.tga"
 964 #define raptor_b "gfx/vehicles/raptor.tga"
 965 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
 966 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
 967 #define raptor_s "gfx/vehicles/shiled.tga"
 968
 969 #define spider_a1 "gfx/hud/sb_rocket.tga"
 970 #define spider_a2 "gfx/sb_bullets.tga"
 971
 972 void CSQC_RAPTOR_HUD()
 973 {
 974         float rockets, reload, heat, hp, shield, energy;
 975         vector picsize, hudloc;
 976
 977     // Fetch health & ammo stats
 978     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 979         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 980         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 981         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
 982
 983     // Draw the crosshairs
 984     picsize = drawgetimagesize(SPIDER_CROSS);
 985     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 986     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 987     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 988
 989     hudloc_y =  4;
 990     hudloc_x = 4;
 991
 992     picsize = drawgetimagesize(raptor_h) * 0.5;
 993     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 994
 995     picsize = drawgetimagesize(spider_a2) * 0.5;
 996     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 997
 998     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
 999     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1000     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1001
1002
1003     picsize = drawgetimagesize(spider_a1) * 0.85;
1004     if(reload == 1)
1005     {
1006         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1007         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1008     }
1009     else
1010     {
1011         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1012         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1013     }
1014
1015     picsize = drawgetimagesize(raptor_b) * 0.5;
1016     hudloc_y = 10.5;
1017     hudloc_x = 10.5;
1018
1019     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1020     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1021     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1022     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1023
1024
1025         if (sb_showscores)
1026         {
1027                 HUD_DrawScoreboard();
1028                 HUD_DrawCenterPrint();
1029         }
1030
1031 }
1032
1033 #define waki_h "gfx/vehicles/hud_bg.tga"
1034 #define waki_b "gfx/vehicles/waki.tga"
1035 #define waki_e "gfx/vehicles/waki_e.tga"
1036 #define waki_g "gfx/vehicles/waki_guns.tga"
1037 #define waki_r "gfx/vehicles/waki_rockets.tga"
1038 #define waki_s "gfx/vehicles/shiled.tga"
1039
1040 #define waki_a1 "gfx/hud/sb_rocket.tga"
1041 #define waki_a2 "gfx/sb_cells.tga"
1042
1043 void CSQC_WAKIZASHI_HUD()
1044 {
1045         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1046         float health, shield, energy, rockets;
1047         vector picsize, hudloc;
1048
1049     picsize = drawgetimagesize(SPIDER_CROSS);
1050     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1051     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1052     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1053
1054 /*
1055 const float STAT_VEHICLESTAT_HEALTH  = 60;
1056 const float STAT_VEHICLESTAT_SHIELD  = 61;
1057 const float STAT_VEHICLESTAT_ENERGY  = 62;
1058 const float STAT_VEHICLESTAT_AMMO1   = 63;
1059 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1060 const float STAT_VEHICLESTAT_AMMO2   = 65;
1061 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1062 */
1063     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1064         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1065         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1066         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1067
1068     hudloc_y =  4;
1069     hudloc_x = 4;
1070
1071     picsize = drawgetimagesize(waki_h) * 0.5;
1072     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1073
1074     picsize = drawgetimagesize(waki_a2) * 0.7;
1075     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1076
1077
1078     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1079     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1080
1081     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1082
1083     picsize = drawgetimagesize(waki_a1) * 0.75;
1084     if(rockets == 1)
1085     {
1086         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1087         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1088     }
1089     else
1090     {
1091         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1092         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1093         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1094     }
1095
1096     picsize = drawgetimagesize(waki_b) * 0.5;
1097     hudloc_y = 10.5;
1098     hudloc_x = 10.5;
1099
1100     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1101     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1102     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1103     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1104
1105
1106
1107         /*
1108         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1109         p = p + '0 1 0' * vid_conheight - '0 32 0';
1110
1111         // Draw health bar
1112         p_y += 8;
1113         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1114         p_x += 256 * health;
1115         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1116
1117         // Draw shiled bar
1118         p_x -= 256 * health;
1119         p_y += 4;
1120         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1121
1122         // Draw energy
1123         //p_x -= 256 * health;
1124         p_y -= 8;
1125         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1126
1127         // Draw rockets bar
1128         p_y += 12;
1129         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1130         */
1131
1132
1133
1134
1135         if (sb_showscores)
1136         {
1137                 HUD_DrawScoreboard();
1138                 HUD_DrawCenterPrint();
1139         }
1140
1141 }
1142
1143
1144 void CSQC_common_hud(void)
1145 {
1146         // HUD_SortFrags(); done in HUD_Draw
1147         float hud;
1148         hud = getstati(STAT_HUD);
1149
1150         //hud = 10;
1151         switch(hud)
1152         {
1153                 case HUD_NORMAL:
1154                         // hud first
1155                         HUD_Main();
1156
1157                         // is this needed?
1158                         //HUD_UpdatePlayerTeams();
1159
1160                         if (intermission == 2) // map voting screen
1161                         {
1162                                 if(sb_showaccuracy && spectatee_status != -1) {
1163                                         HUD_DrawAccuracyStats();
1164                                 }
1165                                 else if(sb_showscores) {
1166                                         HUD_DrawScoreboard();
1167                                 }
1168                                 else
1169                                         HUD_FinaleOverlay();
1170
1171                                 HUD_Reset();
1172                         }
1173                         else if (sb_showscores || sb_showaccuracy || sb_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1)
1174                         {
1175                                 if(sb_showaccuracy && spectatee_status != -1)
1176                                         HUD_DrawAccuracyStats();
1177                                 else
1178                                         HUD_DrawScoreboard();
1179
1180                                 HUD_Reset();
1181                         }
1182                         break;
1183
1184                 case HUD_SPIDERBOT:
1185                         CSQC_SPIDER_HUD();
1186                         break;
1187
1188                 case HUD_WAKIZASHI:
1189                         CSQC_WAKIZASHI_HUD();
1190                         break;
1191         }
1192 }
1193
1194
1195 // following vectors must be global to allow seamless switching between camera modes
1196 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1197 void CSQC_Demo_Camera()
1198 {
1199         float speed, attenuation, dimensions;
1200         vector tmp, delta;
1201
1202         if( cvar("camera_reset") || !camera_mode )
1203         {
1204                 camera_offset = '0 0 0';
1205                 current_angles = '0 0 0';
1206                 camera_direction = '0 0 0';
1207                 camera_offset_z += 30;
1208                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1209                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1210                 current_origin = view_origin;
1211                 current_camera_offset  = camera_offset;
1212                 cvar_set("camera_reset", "0");
1213                 camera_mode = CAMERA_CHASE;
1214         }
1215
1216         // Camera angles
1217         if( camera_roll )
1218                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1219
1220         if(cvar("camera_look_player"))
1221         {
1222                 local vector dir;
1223                 local float n;
1224
1225                 dir = normalize(view_origin - current_position);
1226                 n = mouse_angles_z;
1227                 mouse_angles = vectoangles(dir);
1228                 mouse_angles_x = mouse_angles_x * -1;
1229                 mouse_angles_z = n;
1230         }
1231         else
1232         {
1233                 tmp = getmousepos() * 0.1;
1234                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1235                 {
1236                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1237                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1238                 }
1239         }
1240
1241         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1242         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1243         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1244         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1245
1246         // Fix difference when angles don't have the same sign
1247         delta = '0 0 0';
1248         if(mouse_angles_y < -60 && current_angles_y > 60)
1249                 delta = '0 360 0';
1250         if(mouse_angles_y > 60 && current_angles_y < -60)
1251                 delta = '0 -360 0';
1252
1253         if(cvar("camera_look_player"))
1254                 attenuation = cvar("camera_look_attenuation");
1255         else
1256                 attenuation = cvar("camera_speed_attenuation");
1257
1258         attenuation = 1 / max(1, attenuation);
1259         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1260
1261         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1262         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1263         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1264         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1265
1266         // Camera position
1267         tmp = '0 0 0';
1268         dimensions = 0;
1269
1270         if( camera_direction_x )
1271         {
1272                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1273                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1274                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1275                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1276                 ++dimensions;
1277         }
1278
1279         if( camera_direction_y )
1280         {
1281                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1282                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1283                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1284                 ++dimensions;
1285         }
1286
1287         if( camera_direction_z )
1288         {
1289                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1290                 ++dimensions;
1291         }
1292
1293         if(cvar("camera_free"))
1294                 speed = cvar("camera_speed_free");
1295         else
1296                 speed = cvar("camera_speed_chase");
1297
1298         if(dimensions)
1299         {
1300                 speed = speed * sqrt(1 / dimensions);
1301                 camera_offset += tmp * speed;
1302         }
1303
1304         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1305
1306         // Camera modes
1307         if( cvar("camera_free") )
1308         {
1309                 if ( camera_mode == CAMERA_CHASE )
1310                 {
1311                         current_camera_offset = current_origin + current_camera_offset;
1312                         camera_offset = current_origin + camera_offset;
1313                 }
1314
1315                 camera_mode = CAMERA_FREE;
1316                 current_position = current_camera_offset;
1317         }
1318         else
1319         {
1320                 if ( camera_mode == CAMERA_FREE )
1321                 {
1322                         current_origin = view_origin;
1323                         camera_offset = camera_offset - current_origin;
1324                         current_camera_offset = current_camera_offset - current_origin;
1325                 }
1326
1327                 camera_mode = CAMERA_CHASE;
1328
1329                 if(cvar("camera_chase_smoothly"))
1330                         current_origin += (view_origin - current_origin) * attenuation;
1331                 else
1332                         current_origin = view_origin;
1333
1334                 current_position = current_origin + current_camera_offset;
1335         }
1336
1337         R_SetView(VF_ANGLES, current_angles);
1338         R_SetView(VF_ORIGIN, current_position);
1339 }