qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107         if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir) { zoomin_effect = 0; }
 127
 128         if(camera_active)
 129         {
 130                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 131         }
 132         else if(autocvar_cl_spawnzoom && zoomin_effect)
 133         {
 134                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 135
 136                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 137                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 138                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 139         }
 140         else
 141         {
 142                 if(zoomspeed < 0) // instant zoom
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / zoomfactor;
 146                         else
 147                                 current_viewzoom = 1;
 148                 }
 149                 else
 150                 {
 151                         if(zoomdir)
 152                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 153                         else
 154                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 155                 }
 156         }
 157
 158         if(almost_equals(current_viewzoom, 1))
 159                 current_zoomfraction = 0;
 160         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 161                 current_zoomfraction = 1;
 162         else
 163                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 164
 165         if(zoomsensitivity < 1)
 166                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 167         else
 168                 setsensitivityscale(1);
 169
 170         makevectors(view_angles);
 171
 172         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 173         {
 174                 v = pmove_vel;
 175                 if(csqcplayer)
 176                         v = csqcplayer.velocity;
 177
 178                 switch(autocvar_cl_velocityzoom_type)
 179                 {
 180                         case 3: curspeed = max(0, v_forward * v); break;
 181                         case 2: curspeed = (v_forward * v); break;
 182                         case 1: default: curspeed = vlen(v); break;
 183                 }
 184
 185                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 186                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 187                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 188
 189                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 190         }
 191         else
 192                 velocityzoom = 1;
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t, n;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_ent)
 241                 n = trace_ent.entnum;
 242         else
 243                 n = trace_networkentity;
 244         if(n < 1)
 245                 return SHOTTYPE_HITWORLD;
 246         if(n > maxclients)
 247                 return SHOTTYPE_HITWORLD;
 248         t = GetPlayerColor(n - 1);
 249         if(teamplay)
 250                 if(t == myteam)
 251                         return SHOTTYPE_HITTEAM;
 252         if(t == FL_SPECTATOR)
 253                 return SHOTTYPE_HITWORLD;
 254         return SHOTTYPE_HITENEMY;
 255 }
 256
 257 float TrueAimCheck()
 258 {
 259         float nudge = 1; // added to traceline target and subtracted from result
 260         vector vecs, trueaimpoint, w_shotorg;
 261         vector mi, ma, dv;
 262         float shottype;
 263         entity ta;
 264         float mv;
 265
 266         mi = ma = '0 0 0';
 267         ta = trueaim;
 268         mv = MOVE_NOMONSTERS;
 269
 270         switch(activeweapon)
 271         {
 272                 case WEP_TUBA: // no aim
 273                 case WEP_PORTO: // shoots from eye
 274                 case WEP_HOOK: // no trueaim
 275                 case WEP_GRENADE_LAUNCHER: // toss curve
 276                         return SHOTTYPE_HITWORLD;
 277                 case WEP_NEX:
 278                 case WEP_MINSTANEX:
 279                         mv = MOVE_NORMAL;
 280                         break;
 281                 case WEP_RIFLE:
 282                         ta = trueaim_rifle;
 283                         mv = MOVE_NORMAL;
 284                         if(zoomscript_caught)
 285                         {
 286                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 287                                 return EnemyHitCheck();
 288                         }
 289                         break;
 290                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 291                         mi = '-3 -3 -3';
 292                         ma = '3 3 3';
 293                         break;
 294                 case WEP_FIREBALL: // projectile has a size!
 295                         mi = '-16 -16 -16';
 296                         ma = '16 16 16';
 297                         break;
 298                 case WEP_SEEKER: // projectile has a size!
 299                         mi = '-2 -2 -2';
 300                         ma = '2 2 2';
 301                         break;
 302                 case WEP_ELECTRO: // projectile has a size!
 303                         mi = '0 0 -3';
 304                         ma = '0 0 -3';
 305                         break;
 306         }
 307
 308         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 309
 310         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 311         trueaimpoint = trace_endpos;
 312
 313         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 314                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 315
 316         if(vecs_x > 0)
 317                 vecs_y = -vecs_y;
 318         else
 319                 vecs = '0 0 0';
 320
 321         dv = view_right * vecs_y + view_up * vecs_z;
 322         w_shotorg = view_origin + dv;
 323
 324         // now move the vecs forward as much as requested if possible
 325         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 326         w_shotorg = trace_endpos - view_forward * nudge;
 327
 328         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 329         shottype = EnemyHitCheck();
 330         if(shottype != SHOTTYPE_HITWORLD)
 331                 return shottype;
 332
 333 #if 0
 334         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 335         // or rather, I know why, but see no fix
 336         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 337                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 338                 return SHOTTYPE_HITOBSTRUCTION;
 339 #endif
 340
 341         return SHOTTYPE_HITWORLD;
 342 }
 343
 344 void CSQC_common_hud(void);
 345
 346 void PostInit(void);
 347 void CSQC_Demo_Camera();
 348 float HUD_WouldDrawScoreboard();
 349 float camera_mode;
 350 float CAMERA_FREE = 1;
 351 float CAMERA_CHASE = 2;
 352 float reticle_type;
 353 string NextFrameCommand;
 354 void CSQC_SPIDER_HUD();
 355 void CSQC_RAPTOR_HUD();
 356
 357 vector freeze_org, freeze_ang;
 358 entity nightvision_noise, nightvision_noise2;
 359
 360 #define MAX_TIME_DIFF 5
 361 float pickup_crosshair_time, pickup_crosshair_size;
 362 float hit_time, typehit_time;
 363 float nextsound_hit_time, nextsound_typehit_time;
 364 float hitindication_crosshair_time, hitindication_crosshair_size;
 365 float use_nex_chargepool;
 366
 367 float myhealth, myhealth_prev;
 368 float myhealth_flash;
 369
 370 float old_blurradius, old_bluralpha;
 371 float old_sharpen_intensity;
 372
 373 vector myhealth_gentlergb;
 374
 375 float contentavgalpha, liquidalpha_prev;
 376 vector liquidcolor_prev;
 377
 378 float eventchase_current_distance;
 379
 380 vector damage_blurpostprocess, content_blurpostprocess;
 381
 382 float checkfail[16];
 383
 384 #define BUTTON_3 4
 385 #define BUTTON_4 8
 386 float cl_notice_run();
 387 void CSQC_UpdateView(float w, float h)
 388 {
 389         entity e;
 390         float fov;
 391         float f, i, j;
 392         vector v;
 393         vector vf_size, vf_min;
 394         float a;
 395
 396         execute_next_frame();
 397
 398         ++framecount;
 399
 400         hud = getstati(STAT_HUD);
 401
 402         if(autocvar__hud_showbinds_reload) // menu can set this one
 403         {
 404                 db_close(binddb);
 405                 binddb = db_create();
 406                 cvar_set("_hud_showbinds_reload", "0");
 407         }
 408
 409         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 410                 view_quality = getproperty(VF_MINFPS_QUALITY);
 411         else
 412                 view_quality = 1;
 413
 414         button_attack2 = (input_buttons & BUTTON_3);
 415         button_zoom = (input_buttons & BUTTON_4);
 416
 417         // FIXME do we need this hack?
 418         if(isdemo())
 419         {
 420                 // in demos, input_buttons do not work
 421                 button_zoom = (autocvar__togglezoom == "-");
 422         }
 423
 424 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 425         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 426         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 427         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 428         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 429         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 430         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 431         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 432
 433         vf_size = getpropertyvec(VF_SIZE);
 434         vf_min = getpropertyvec(VF_MIN);
 435         vid_width = vf_size_x;
 436         vid_height = vf_size_y;
 437
 438         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 439         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 440
 441         WaypointSprite_Load();
 442
 443         CSQCPlayer_SetCamera();
 444
 445 #ifdef COMPAT_XON050_ENGINE
 446         if(spectatee_status)
 447                 myteam = GetPlayerColor(spectatee_status - 1);
 448         else
 449 #endif
 450                 myteam = GetPlayerColor(player_localentnum - 1);
 451
 452         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 453
 454         // event chase camera
 455         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 456         {
 457                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 458                 {
 459                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 460                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_cl_eventchase_viewoffset);
 461
 462                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 463                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 464                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 465                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 466
 467                         // make the camera smooth back
 468                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 469                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 470                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 471                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 472
 473                         makevectors(view_angles);
 474
 475                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 476                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 477
 478                         // If the boxtrace fails, revert back to line tracing.
 479                         if(trace_startsolid)
 480                         {
 481                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 482                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 483                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 484                         }
 485                         else { setproperty(VF_ORIGIN, trace_endpos); }
 486
 487                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 488                 }
 489                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 490                 {
 491                         cvar_set("chase_active", "0");
 492                         eventchase_current_distance = 0; // start from 0 next time
 493                 }
 494         }
 495         // workaround for camera stuck between player's legs when using chase_active 1
 496         // because the engine stops updating the chase_active camera when the game ends
 497         else if(intermission)
 498         {
 499                 cvar_settemp("chase_active", "-1");
 500                 eventchase_current_distance = 0;
 501         }
 502
 503         // do lockview after event chase camera so that it still applies whenever necessary.
 504         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 505         {
 506                 setproperty(VF_ORIGIN, freeze_org);
 507                 setproperty(VF_ANGLES, freeze_ang);
 508         }
 509         else
 510         {
 511                 freeze_org = getpropertyvec(VF_ORIGIN);
 512                 freeze_ang = getpropertyvec(VF_ANGLES);
 513         }
 514
 515         WarpZone_FixView();
 516         //WarpZone_FixPMove();
 517
 518         // Render the Scene
 519         view_origin = getpropertyvec(VF_ORIGIN);
 520         view_angles = getpropertyvec(VF_ANGLES);
 521         makevectors(view_angles);
 522         view_forward = v_forward;
 523         view_right = v_right;
 524         view_up = v_up;
 525
 526 #ifdef BLURTEST
 527         if(time > blurtest_time0 && time < blurtest_time1)
 528         {
 529                 float r, t;
 530
 531                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 532                 r = t * blurtest_radius;
 533                 f = 1 / pow(t, blurtest_power) - 1;
 534
 535                 cvar_set("r_glsl_postprocess", "1");
 536                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 537         }
 538         else
 539         {
 540                 cvar_set("r_glsl_postprocess", "0");
 541                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 542         }
 543 #endif
 544
 545         TargetMusic_Advance();
 546         Fog_Force();
 547
 548         if(drawtime == 0)
 549                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 550         else
 551                 drawframetime = bound(0.000001, time - drawtime, 1);
 552         drawtime = time;
 553
 554         // watch for gametype changes here...
 555         // in ParseStuffCMD the cmd isn't executed yet :/
 556         // might even be better to add the gametype to TE_CSQC_INIT...?
 557         if(!postinit)
 558                 PostInit();
 559
 560         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 561         {
 562                 if(calledhooks & HOOK_START)
 563                 {
 564                         localcmd("\ncl_hook_gameend\n");
 565                         calledhooks |= HOOK_END;
 566                 }
 567         }
 568
 569         Announcer();
 570
 571         fov = autocvar_fov;
 572         if(fov <= 59.5)
 573         {
 574                 if(!zoomscript_caught)
 575                 {
 576                         localcmd("+button9\n");
 577                         zoomscript_caught = 1;
 578                 }
 579         }
 580         else
 581         {
 582                 if(zoomscript_caught)
 583                 {
 584                         localcmd("-button9\n");
 585                         zoomscript_caught = 0;
 586                 }
 587         }
 588
 589         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 590
 591         // next WANTED weapon (for HUD)
 592         switchweapon = getstati(STAT_SWITCHWEAPON);
 593
 594         // currently switching-to weapon (for crosshair)
 595         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 596
 597         // actually active weapon (for zoom)
 598         activeweapon = getstati(STAT_ACTIVEWEAPON);
 599
 600         f = (serverflags & SERVERFLAG_TEAMPLAY);
 601         if(f != teamplay)
 602         {
 603                 teamplay = f;
 604                 HUD_InitScores();
 605         }
 606
 607         if(last_switchweapon != switchweapon) {
 608                 weapontime = time;
 609                 last_switchweapon = switchweapon;
 610         }
 611         if(last_activeweapon != activeweapon) {
 612                 last_activeweapon = activeweapon;
 613
 614                 e = get_weaponinfo(activeweapon);
 615                 if(e.netname != "")
 616                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 617                 else
 618                         localcmd("\ncl_hook_activeweapon none\n");
 619         }
 620
 621         // ALWAYS Clear Current Scene First
 622         clearscene();
 623 #ifdef WORKAROUND_XON010
 624         if(checkextension("DP_CSQC_ROTATEMOVES"))
 625         {
 626 #endif
 627         setproperty(VF_ORIGIN, view_origin);
 628         setproperty(VF_ANGLES, view_angles);
 629 #ifdef WORKAROUND_XON010
 630         }
 631 #endif
 632
 633         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 634         setproperty(VF_SIZE, vf_size);
 635         setproperty(VF_MIN, vf_min);
 636
 637         // Assign Standard Viewflags
 638         // Draw the World (and sky)
 639         setproperty(VF_DRAWWORLD, 1);
 640
 641         // Set the console size vars
 642         vid_conwidth = autocvar_vid_conwidth;
 643         vid_conheight = autocvar_vid_conheight;
 644         vid_pixelheight = autocvar_vid_pixelheight;
 645
 646         setproperty(VF_FOV, GetCurrentFov(fov));
 647
 648         // Camera for demo playback
 649         if(camera_active)
 650         {
 651                 if(autocvar_camera_enable)
 652                         CSQC_Demo_Camera();
 653                 else
 654                 {
 655                         cvar_set("chase_active", ftos(chase_active_backup));
 656                         cvar_set("cl_demo_mousegrab", "0");
 657                         camera_active = FALSE;
 658                 }
 659         }
 660 #ifdef CAMERATEST
 661         else if(autocvar_camera_enable)
 662 #else
 663         else if(autocvar_camera_enable && isdemo())
 664 #endif
 665         {
 666                 // Enable required Darkplaces cvars
 667                 chase_active_backup = autocvar_chase_active;
 668                 cvar_set("chase_active", "2");
 669                 cvar_set("cl_demo_mousegrab", "1");
 670                 camera_active = TRUE;
 671                 camera_mode = FALSE;
 672         }
 673
 674         // Draw the Crosshair
 675         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 676
 677         // Draw the Engine Status Bar (the default Quake HUD)
 678         setproperty(VF_DRAWENGINESBAR, 0);
 679
 680         // Update the mouse position
 681         /*
 682            mousepos_x = vid_conwidth;
 683            mousepos_y = vid_conheight;
 684            mousepos = mousepos*0.5 + getmousepos();
 685          */
 686
 687         e = self;
 688         for(self = world; (self = nextent(self)); )
 689                 if(self.draw)
 690                         self.draw();
 691         self = e;
 692
 693         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 694         renderscene();
 695
 696         // now switch to 2D drawing mode by calling a 2D drawing function
 697         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 698         // next R_RenderScene call
 699         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 700
 701         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 702         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 703         {
 704                 // apply night vision effect
 705                 vector tc_00, tc_01, tc_10, tc_11;
 706                 vector rgb;
 707                 rgb_x = 0; // fteqcc sucks
 708                 rgb_y = 0; // fteqcc sucks
 709                 rgb_z = 0; // fteqcc sucks
 710
 711                 if(!nightvision_noise)
 712                 {
 713                         nightvision_noise = spawn();
 714                         nightvision_noise.classname = "nightvision_noise";
 715                 }
 716                 if(!nightvision_noise2)
 717                 {
 718                         nightvision_noise2 = spawn();
 719                         nightvision_noise2.classname = "nightvision_noise2";
 720                 }
 721
 722                 // color tint in yellow
 723                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 724
 725                 // draw BG
 726                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 727                 rgb = '1 1 1';
 728                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 729                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 730                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 731                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 732                 tc_11 = tc_01 + tc_10 - tc_00;
 733                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 734                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 735                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 736                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 737                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 738                 R_EndPolygon();
 739
 740                 // draw FG
 741                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 742                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 743                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 744                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 745                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 746                 tc_11 = tc_01 + tc_10 - tc_00;
 747                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 748                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 749                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 750                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 751                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 752                 R_EndPolygon();
 753         }
 754
 755         // Draw the aiming reticle for weapons that use it
 756         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 757         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 758         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 759         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 760                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 761         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 762                 reticle_type = 2; // nex zoom
 763         else if(button_zoom || zoomscript_caught)
 764                 reticle_type = 1; // normal zoom
 765         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 766                 reticle_type = 2; // nex zoom
 767
 768         if(reticle_type && autocvar_cl_reticle)
 769         {
 770                 if(autocvar_cl_reticle_stretch)
 771                 {
 772                         reticle_size_x = vid_conwidth;
 773                         reticle_size_y = vid_conheight;
 774                         reticle_pos_x = 0;
 775                         reticle_pos_y = 0;
 776                 }
 777                 else
 778                 {
 779                         reticle_size_x = max(vid_conwidth, vid_conheight);
 780                         reticle_size_y = max(vid_conwidth, vid_conheight);
 781                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 782                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 783                 }
 784
 785                 f = current_zoomfraction;
 786                 if(zoomscript_caught)
 787                         f = 1;
 788                 if(autocvar_cl_reticle_item_normal)
 789                 {
 790                         if(reticle_type == 1 && f)
 791                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 792                 }
 793                 if(autocvar_cl_reticle_item_nex)
 794                 {
 795                         if(reticle_type == 2 && f)
 796                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 797                 }
 798         }
 799
 800
 801         // improved polyblend
 802         if(autocvar_hud_contents)
 803         {
 804                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 805                 vector liquidcolor;
 806
 807                 switch(pointcontents(view_origin))
 808                 {
 809                         case CONTENT_WATER:
 810                                 liquidalpha = autocvar_hud_contents_water_alpha;
 811                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 812                                 incontent = 1;
 813                                 break;
 814
 815                         case CONTENT_LAVA:
 816                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 817                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 818                                 incontent = 1;
 819                                 break;
 820
 821                         case CONTENT_SLIME:
 822                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 823                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 824                                 incontent = 1;
 825                                 break;
 826
 827                         default:
 828                                 liquidalpha = 0;
 829                                 liquidcolor = '0 0 0';
 830                                 incontent = 0;
 831                                 break;
 832                 }
 833
 834                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 835                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 836                         contentfadetime = autocvar_hud_contents_fadeintime;
 837                         liquidalpha_prev = liquidalpha;
 838                         liquidcolor_prev = liquidcolor;
 839                 }
 840                 else
 841                         contentfadetime = autocvar_hud_contents_fadeouttime;
 842
 843                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 844                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 845
 846                 if(contentavgalpha)
 847                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 848
 849                 if(autocvar_hud_postprocessing)
 850                 {
 851                         if(autocvar_hud_contents_blur && contentavgalpha)
 852                         {
 853                                 content_blurpostprocess_x = 1;
 854                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 855                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 856                         }
 857                         else
 858                         {
 859                                 content_blurpostprocess_x = 0;
 860                                 content_blurpostprocess_y = 0;
 861                                 content_blurpostprocess_z = 0;
 862                         }
 863                 }
 864         }
 865
 866         if(autocvar_hud_damage)
 867         {
 868                 splash_size_x = max(vid_conwidth, vid_conheight);
 869                 splash_size_y = max(vid_conwidth, vid_conheight);
 870                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 871                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 872
 873                 float myhealth_flash_temp;
 874                 myhealth = getstati(STAT_HEALTH);
 875
 876                 // fade out
 877                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 878                 // add new damage
 879                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 880
 881                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 882                 pain_threshold = autocvar_hud_damage_pain_threshold;
 883                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 884                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 885
 886                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 887                 {
 888                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 889                 }
 890
 891                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 892
 893                 if(myhealth_prev < 1)
 894                 {
 895                         if(myhealth >= 1)
 896                         {
 897                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 898                                 myhealth_flash_temp = 0;
 899                         }
 900                         else
 901                         {
 902                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 903                         }
 904                 }
 905
 906                 if(spectatee_status == -1 || intermission)
 907                 {
 908                         myhealth_flash = 0; // observing, or match ended
 909                         myhealth_flash_temp = 0;
 910                 }
 911
 912                 myhealth_prev = myhealth;
 913
 914                 // IDEA: change damage color/picture based on player model for robot/alien species?
 915                 // pro: matches model better
 916                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 917                 // maybe different reddish pics?
 918                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 919                 {
 920                         if(autocvar_cl_gentle_damage == 2)
 921                         {
 922                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 923                                 {
 924                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 925                                 }
 926                         }
 927                         else
 928                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 929
 930                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 931                 }
 932                 else
 933                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 934
 935                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 936                 {
 937                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 938                         {
 939                                 damage_blurpostprocess_x = 1;
 940                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 941                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 942                         }
 943                         else
 944                         {
 945                                 damage_blurpostprocess_x = 0;
 946                                 damage_blurpostprocess_y = 0;
 947                                 damage_blurpostprocess_z = 0;
 948                         }
 949                 }
 950         }
 951
 952         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 953         float e2 = (autocvar_hud_powerup != 0);
 954         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 955         {
 956                 // enable or disable rendering types if they are used or not
 957                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 958                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 959
 960                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 961                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
 962                 {
 963                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 964                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 965                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 966                         {
 967                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 968                                 old_blurradius = blurradius;
 969                                 old_bluralpha = bluralpha;
 970                         }
 971                 }
 972                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 973                 {
 974                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 975                         old_blurradius = 0;
 976                         old_bluralpha = 0;
 977                 }
 978
 979                 // edge detection postprocess handling done second (used by hud_powerup)
 980                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 981                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 982                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 983
 984                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 985
 986                 if(autocvar_hud_powerup && sharpen_intensity > 0)
 987                 {
 988                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 989                         {
 990                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 991                                 old_sharpen_intensity = sharpen_intensity;
 992                         }
 993                 }
 994                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 995                 {
 996                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 997                         old_sharpen_intensity = 0;
 998                 }
 999
1000                 if(cvar("r_glsl_postprocess") == 0)
1001                         cvar_set("r_glsl_postprocess", "2");
1002         }
1003         else if(cvar("r_glsl_postprocess") == 2)
1004                 cvar_set("r_glsl_postprocess", "0");
1005
1006         if(menu_visible)
1007                 menu_show();
1008
1009         /*if(gametype == MAPINFO_TYPE_CTF)
1010           {
1011           ctf_view();
1012           } else */
1013
1014         // draw 2D entities
1015         e = self;
1016         for(self = world; (self = nextent(self)); )
1017                 if(self.draw2d)
1018                         self.draw2d();
1019         self = e;
1020         Draw_ShowNames_All();
1021
1022         scoreboard_active = HUD_WouldDrawScoreboard();
1023
1024         hit_time = getstatf(STAT_HIT_TIME);
1025         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1026         {
1027                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1028                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1029
1030                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1031         }
1032         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1033         if(typehit_time > nextsound_typehit_time)
1034         {
1035                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1036                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1037
1038                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1039         }
1040
1041         //else
1042         {
1043                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1044                 {
1045                         if(getstati(STAT_FROZEN))
1046                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1047                         if(getstatf(STAT_REVIVE_PROGRESS))
1048                         {
1049                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1050                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1051                         }
1052                 }
1053
1054                 if(autocvar_r_letterbox == 0)
1055                         if(autocvar_viewsize < 120)
1056                                 CSQC_common_hud();
1057
1058                 // crosshair goes VERY LAST
1059                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1060                 {
1061                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1062                                 return;
1063
1064                         string wcross_style;
1065                         float wcross_alpha, wcross_resolution;
1066                         wcross_style = autocvar_crosshair;
1067                         if (wcross_style == "0")
1068                                 return;
1069                         wcross_resolution = autocvar_crosshair_size;
1070                         if (wcross_resolution == 0)
1071                                 return;
1072                         wcross_alpha = autocvar_crosshair_alpha;
1073                         if (wcross_alpha == 0)
1074                                 return;
1075
1076                         // TrueAim check
1077                         float shottype;
1078
1079                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1080                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1081                         wcross_origin_z = 0;
1082                         if(autocvar_crosshair_hittest)
1083                         {
1084                                 vector wcross_oldorigin;
1085                                 wcross_oldorigin = wcross_origin;
1086                                 shottype = TrueAimCheck();
1087                                 if(shottype == SHOTTYPE_HITWORLD)
1088                                 {
1089                                         v = wcross_origin - wcross_oldorigin;
1090                                         v_x /= vid_conwidth;
1091                                         v_y /= vid_conheight;
1092                                         if(vlen(v) > 0.01)
1093                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1094                                 }
1095                                 if(!autocvar_crosshair_hittest_showimpact)
1096                                         wcross_origin = wcross_oldorigin;
1097                         }
1098                         else
1099                                 shottype = SHOTTYPE_HITWORLD;
1100
1101                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1102                         string wcross_wep = "", wcross_name;
1103                         float wcross_scale, wcross_blur;
1104
1105                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1106                                 e = get_weaponinfo(switchingweapon);
1107                                 if (e && e.netname != "")
1108                                 {
1109                                         wcross_wep = e.netname;
1110                                         if(autocvar_crosshair_per_weapon)
1111                                         {
1112                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1113                                                 if (wcross_resolution == 0)
1114                                                         return;
1115                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1116                                                 if (wcross_alpha == 0)
1117                                                         return;
1118
1119                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1120                                                 if(wcross_style == "" || wcross_style == "0")
1121                                                         wcross_style = wcross_wep;
1122                                         }
1123                                 }
1124                         }
1125                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1126                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1127                         else if(autocvar_crosshair_color_by_health)
1128                         {
1129                                 float x = getstati(STAT_HEALTH);
1130
1131                                 //x = red
1132                                 //y = green
1133                                 //z = blue
1134
1135                                 wcross_color_z = 0;
1136
1137                                 if(x > 200)
1138                                 {
1139                                         wcross_color_x = 0;
1140                                         wcross_color_y = 1;
1141                                 }
1142                                 else if(x > 150)
1143                                 {
1144                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1145                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1146                                 }
1147                                 else if(x > 100)
1148                                 {
1149                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1150                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1151                                         wcross_color_z = 1 - (x-100)*0.02;
1152                                 }
1153                                 else if(x > 50)
1154                                 {
1155                                         wcross_color_x = 1;
1156                                         wcross_color_y = 1;
1157                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1158                                 }
1159                                 else if(x > 20)
1160                                 {
1161                                         wcross_color_x = 1;
1162                                         wcross_color_y = (x-20)*90/27/100;
1163                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1164                                 }
1165                                 else
1166                                 {
1167                                         wcross_color_x = 1;
1168                                         wcross_color_y = 0;
1169                                 }
1170                         }
1171                         else
1172                                 wcross_color = stov(autocvar_crosshair_color);
1173
1174                         wcross_name = strcat("gfx/crosshair", wcross_style);
1175
1176                         if(autocvar_crosshair_effect_scalefade)
1177                         {
1178                                 wcross_scale = wcross_resolution;
1179                                 wcross_resolution = 1;
1180                         }
1181                         else
1182                         {
1183                                 wcross_scale = 1;
1184                         }
1185
1186                         if(autocvar_crosshair_pickup)
1187                         {
1188                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1189
1190                                 if(pickup_crosshair_time < stat_pickup_time)
1191                                 {
1192                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1193                                                 pickup_crosshair_size = 1;
1194
1195                                         pickup_crosshair_time = stat_pickup_time;
1196                                 }
1197
1198                                 if(pickup_crosshair_size > 0)
1199                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1200                                 else
1201                                         pickup_crosshair_size = 0;
1202
1203                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1204                         }
1205
1206                         if(autocvar_crosshair_hitindication)
1207                         {
1208                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1209
1210                                 if(hitindication_crosshair_time < hit_time)
1211                                 {
1212                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1213                                                 hitindication_crosshair_size = 1;
1214
1215                                         hitindication_crosshair_time = hit_time;
1216                                 }
1217
1218                                 if(hitindication_crosshair_size > 0)
1219                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1220                                 else
1221                                         hitindication_crosshair_size = 0;
1222
1223                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1224                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1225                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1226                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1227                         }
1228
1229                         if(shottype == SHOTTYPE_HITENEMY)
1230                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1231                         if(shottype == SHOTTYPE_HITTEAM)
1232                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1233
1234                         f = autocvar_crosshair_effect_speed;
1235                         if(f < 0)
1236                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1237                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1238                         {
1239                                 wcross_changedonetime = time + f;
1240                         }
1241                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1242                         {
1243                                 wcross_name_changestarttime = time;
1244                                 wcross_name_changedonetime = time + f;
1245                                 if(wcross_name_goal_prev_prev)
1246                                         strunzone(wcross_name_goal_prev_prev);
1247                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1248                                 wcross_name_goal_prev = strzone(wcross_name);
1249                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1250                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1251                                 wcross_resolution_goal_prev = wcross_resolution;
1252                         }
1253
1254                         wcross_scale_goal_prev = wcross_scale;
1255                         wcross_alpha_goal_prev = wcross_alpha;
1256                         wcross_color_goal_prev = wcross_color;
1257
1258                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1259                         {
1260                                 wcross_blur = 1;
1261                                 wcross_alpha *= 0.75;
1262                         }
1263                         else
1264                                 wcross_blur = 0;
1265                         // *_prev is at time-frametime
1266                         // * is at wcross_changedonetime+f
1267                         // what do we have at time?
1268                         if(time < wcross_changedonetime)
1269                         {
1270                                 f = frametime / (wcross_changedonetime - time + frametime);
1271                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1272                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1273                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1274                         }
1275
1276                         wcross_scale_prev = wcross_scale;
1277                         wcross_alpha_prev = wcross_alpha;
1278                         wcross_color_prev = wcross_color;
1279
1280                         wcross_scale *= 1 - autocvar__menu_alpha;
1281                         wcross_alpha *= 1 - autocvar__menu_alpha;
1282                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1283
1284                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1285                         {
1286                                 // crosshair rings for weapon stats
1287                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1288                                 {
1289                                         // declarations and stats
1290                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1291                                         string ring_image = string_null, ring_inner_image = string_null;
1292                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1293
1294                                         ring_scale = autocvar_crosshair_ring_size;
1295
1296                                         float weapon_clipload, weapon_clipsize;
1297                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1298                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1299
1300                                         float nex_charge, nex_chargepool;
1301                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1302                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1303
1304                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1305                                                 nex_charge_movingavg = nex_charge;
1306
1307
1308                                         // handle the values
1309                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1310                                         {
1311                                                 if (nex_chargepool || use_nex_chargepool) {
1312                                                         use_nex_chargepool = 1;
1313                                                         ring_inner_value = nex_chargepool;
1314                                                 } else {
1315                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1316                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1317                                                 }
1318
1319                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1320                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1321                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1322
1323                                                 // draw the outer ring to show the current charge of the weapon
1324                                                 ring_value = nex_charge;
1325                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1326                                                 ring_rgb = wcross_color;
1327                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1328                                         }
1329                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1330                                         {
1331                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1332                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1333                                                 ring_rgb = wcross_color;
1334                                                 ring_image = "gfx/crosshair_ring.tga";
1335                                         }
1336                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1337                                         {
1338                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1339                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1340                                                 ring_rgb = wcross_color;
1341                                                 ring_image = "gfx/crosshair_ring.tga";
1342                                         }
1343
1344                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1345                                         {
1346                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1347                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1348                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1349                                                 ring_rgb = wcross_color;
1350
1351                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1352                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1353                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1354                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1355                                                 else
1356                                                         ring_image = "gfx/crosshair_ring.tga";
1357                                         }
1358
1359                                         // if in weapon switch animation, fade ring out/in
1360                                         if(g_weaponswitchdelay > 0)
1361                                         {
1362                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1363                                                 if(f > 0 && f < 2)
1364                                                         ring_alpha *= fabs(1 - f);
1365                                         }
1366
1367                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1368                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1369
1370                                         if (ring_value)
1371                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1372                                 }
1373
1374 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1375                                 do \
1376                                 { \
1377                                         if(wcross_blur > 0) \
1378                                         { \
1379                                                 for(i = -2; i <= 2; ++i) \
1380                                                 for(j = -2; j <= 2; ++j) \
1381                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1382                                         } \
1383                                         else \
1384                                         { \
1385                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1386                                         } \
1387                                 } \
1388                                 while(0)
1389
1390 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1391                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1392
1393 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1394                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1395
1396                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1397                                 {
1398                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1399                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1400                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1401                                         f = 1 - f;
1402                                 }
1403                                 else
1404                                 {
1405                                         f = 1;
1406                                 }
1407                                 wcross_name_alpha_goal_prev = f;
1408
1409                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1410                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1411
1412                                 if(autocvar_crosshair_dot)
1413                                 {
1414                                         vector wcross_color_old;
1415                                         wcross_color_old = wcross_color;
1416
1417                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1418                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1419
1420                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1421                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1422                                         wcross_color = wcross_color_old;
1423                                 }
1424                         }
1425                 }
1426                 else
1427                 {
1428                         wcross_scale_prev = 0;
1429                         wcross_alpha_prev = 0;
1430                         wcross_scale_goal_prev = 0;
1431                         wcross_alpha_goal_prev = 0;
1432                         wcross_changedonetime = 0;
1433                         if(wcross_name_goal_prev)
1434                                 strunzone(wcross_name_goal_prev);
1435                         wcross_name_goal_prev = string_null;
1436                         if(wcross_name_goal_prev_prev)
1437                                 strunzone(wcross_name_goal_prev_prev);
1438                         wcross_name_goal_prev_prev = string_null;
1439                         wcross_name_changestarttime = 0;
1440                         wcross_name_changedonetime = 0;
1441                         wcross_name_alpha_goal_prev = 0;
1442                         wcross_name_alpha_goal_prev_prev = 0;
1443                         wcross_resolution_goal_prev = 0;
1444                         wcross_resolution_goal_prev_prev = 0;
1445                 }
1446         }
1447
1448         if(NextFrameCommand)
1449         {
1450                 localcmd("\n", NextFrameCommand, "\n");
1451                 NextFrameCommand = string_null;
1452         }
1453
1454         // we must do this check AFTER a frame was rendered, or it won't work
1455         if(cs_project_is_b0rked == 0)
1456         {
1457                 string w0, h0;
1458                 w0 = ftos(autocvar_vid_conwidth);
1459                 h0 = ftos(autocvar_vid_conheight);
1460                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1461                 //setproperty(VF_FOV, '90 90 0');
1462                 setproperty(VF_ORIGIN, '0 0 0');
1463                 setproperty(VF_ANGLES, '0 0 0');
1464                 setproperty(VF_PERSPECTIVE, 1);
1465                 makevectors('0 0 0');
1466                 vector v1, v2;
1467                 cvar_set("vid_conwidth", "800");
1468                 cvar_set("vid_conheight", "600");
1469                 v1 = cs_project(v_forward);
1470                 cvar_set("vid_conwidth", "640");
1471                 cvar_set("vid_conheight", "480");
1472                 v2 = cs_project(v_forward);
1473                 if(v1 == v2)
1474                         cs_project_is_b0rked = 1;
1475                 else
1476                         cs_project_is_b0rked = -1;
1477                 cvar_set("vid_conwidth", w0);
1478                 cvar_set("vid_conheight", h0);
1479         }
1480
1481         if(autocvar__hud_configure)
1482                 HUD_Panel_Mouse();
1483
1484     if(hud && !intermission)
1485     {
1486         if(hud == HUD_SPIDERBOT)
1487             CSQC_SPIDER_HUD();
1488         else if(hud == HUD_WAKIZASHI)
1489             CSQC_WAKIZASHI_HUD();
1490         else if(hud == HUD_RAPTOR)
1491             CSQC_RAPTOR_HUD();
1492         else if(hud == HUD_BUMBLEBEE)
1493             CSQC_BUMBLE_HUD();
1494         else if(hud == HUD_BUMBLEBEE_GUN)
1495             CSQC_BUMBLE_GUN_HUD();
1496     }
1497
1498         cl_notice_run();
1499
1500         // let's reset the view back to normal for the end
1501         setproperty(VF_MIN, '0 0 0');
1502         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1503 }
1504
1505
1506 void CSQC_common_hud(void)
1507 {
1508         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1509                 Accuracy_LoadLevels();
1510
1511     HUD_Main(); // always run these functions for alpha checks
1512     HUD_DrawScoreboard();
1513
1514     if (scoreboard_active) // scoreboard/accuracy
1515         HUD_Reset();
1516     else if (intermission == 2) // map voting screen
1517     {
1518         HUD_FinaleOverlay();
1519         HUD_Reset();
1520     }
1521         /*
1522         switch(hud)
1523         {
1524                 case HUD_SPIDERBOT:
1525                         CSQC_SPIDER_HUD();
1526                         break;
1527
1528                 case HUD_WAKIZASHI:
1529                         CSQC_WAKIZASHI_HUD();
1530                         break;
1531
1532         case HUD_BUMBLEBEE:
1533             CSQC_BUMBLE_HUD();
1534             break;
1535         }
1536         */
1537 }
1538
1539
1540 // following vectors must be global to allow seamless switching between camera modes
1541 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1542 void CSQC_Demo_Camera()
1543 {
1544         float speed, attenuation, dimensions;
1545         vector tmp, delta;
1546
1547         if( autocvar_camera_reset || !camera_mode )
1548         {
1549                 camera_offset = '0 0 0';
1550                 current_angles = '0 0 0';
1551                 camera_direction = '0 0 0';
1552                 camera_offset_z += 30;
1553                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1554                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1555                 current_origin = view_origin;
1556                 current_camera_offset  = camera_offset;
1557                 cvar_set("camera_reset", "0");
1558                 camera_mode = CAMERA_CHASE;
1559         }
1560
1561         // Camera angles
1562         if( camera_roll )
1563                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1564
1565         if(autocvar_camera_look_player)
1566         {
1567                 vector dir;
1568                 float n;
1569
1570                 dir = normalize(view_origin - current_position);
1571                 n = mouse_angles_z;
1572                 mouse_angles = vectoangles(dir);
1573                 mouse_angles_x = mouse_angles_x * -1;
1574                 mouse_angles_z = n;
1575         }
1576         else
1577         {
1578                 tmp = getmousepos() * 0.1;
1579                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1580                 {
1581                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1582                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1583                 }
1584         }
1585
1586         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1587         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1588         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1589         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1590
1591         // Fix difference when angles don't have the same sign
1592         delta = '0 0 0';
1593         if(mouse_angles_y < -60 && current_angles_y > 60)
1594                 delta = '0 360 0';
1595         if(mouse_angles_y > 60 && current_angles_y < -60)
1596                 delta = '0 -360 0';
1597
1598         if(autocvar_camera_look_player)
1599                 attenuation = autocvar_camera_look_attenuation;
1600         else
1601                 attenuation = autocvar_camera_speed_attenuation;
1602
1603         attenuation = 1 / max(1, attenuation);
1604         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1605
1606         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1607         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1608         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1609         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1610
1611         // Camera position
1612         tmp = '0 0 0';
1613         dimensions = 0;
1614
1615         if( camera_direction_x )
1616         {
1617                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1618                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1619                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1620                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1621                 ++dimensions;
1622         }
1623
1624         if( camera_direction_y )
1625         {
1626                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1627                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1628                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1629                 ++dimensions;
1630         }
1631
1632         if( camera_direction_z )
1633         {
1634                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1635                 ++dimensions;
1636         }
1637
1638         if(autocvar_camera_free)
1639                 speed = autocvar_camera_speed_free;
1640         else
1641                 speed = autocvar_camera_speed_chase;
1642
1643         if(dimensions)
1644         {
1645                 speed = speed * sqrt(1 / dimensions);
1646                 camera_offset += tmp * speed;
1647         }
1648
1649         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1650
1651         // Camera modes
1652         if( autocvar_camera_free )
1653         {
1654                 if ( camera_mode == CAMERA_CHASE )
1655                 {
1656                         current_camera_offset = current_origin + current_camera_offset;
1657                         camera_offset = current_origin + camera_offset;
1658                 }
1659
1660                 camera_mode = CAMERA_FREE;
1661                 current_position = current_camera_offset;
1662         }
1663         else
1664         {
1665                 if ( camera_mode == CAMERA_FREE )
1666                 {
1667                         current_origin = view_origin;
1668                         camera_offset = camera_offset - current_origin;
1669                         current_camera_offset = current_camera_offset - current_origin;
1670                 }
1671
1672                 camera_mode = CAMERA_CHASE;
1673
1674                 if(autocvar_camera_chase_smoothly)
1675                         current_origin += (view_origin - current_origin) * attenuation;
1676                 else
1677                         current_origin = view_origin;
1678
1679                 current_position = current_origin + current_camera_offset;
1680         }
1681
1682         setproperty(VF_ANGLES, current_angles);
1683         setproperty(VF_ORIGIN, current_position);
1684 }