qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                         zoomdir = 0 + !zoomdir;
 137                 // do not even THINK about removing this 0
 138                 // _I_ know what I am doing
 139                 // fteqcc does not
 140         }
 141
 142         if(zoomdir)
 143                 zoomin_effect = 0;
 144
 145         if(zoomin_effect || camera_active)
 146         {
 147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 148         }
 149         else
 150         {
 151                 if(zoomspeed < 0) // instant zoom
 152                 {
 153                         if(zoomdir)
 154                                 current_viewzoom = 1 / zoomfactor;
 155                         else
 156                                 current_viewzoom = 1;
 157                 }
 158                 else
 159                 {
 160                         if(zoomdir)
 161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 162                         else
 163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 164                 }
 165         }
 166
 167         if(almost_equals(current_viewzoom, 1))
 168                 current_zoomfraction = 0;
 169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 170                 current_zoomfraction = 1;
 171         else
 172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 173
 174         if(zoomsensitivity < 1)
 175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 176         else
 177                 setsensitivityscale(1);
 178
 179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 182
 183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_networkentity < 1)
 232                 return SHOTTYPE_HITWORLD;
 233         if(trace_networkentity > maxclients)
 234                 return SHOTTYPE_HITWORLD;
 235         t = GetPlayerColor(trace_networkentity - 1);
 236         if(teamplay)
 237                 if(t == myteam)
 238                         return SHOTTYPE_HITTEAM;
 239         if(t == COLOR_SPECTATOR)
 240                 return SHOTTYPE_HITWORLD;
 241         return SHOTTYPE_HITENEMY;
 242 }
 243
 244 float TrueAimCheck()
 245 {
 246         float nudge = 1; // added to traceline target and subtracted from result
 247         vector vecs, trueaimpoint, w_shotorg;
 248         vector mi, ma, dv;
 249         float shottype;
 250         entity ta;
 251         float mv;
 252
 253         mi = ma = '0 0 0';
 254         ta = trueaim;
 255         mv = MOVE_NOMONSTERS;
 256
 257         switch(activeweapon)
 258         {
 259                 case WEP_TUBA: // no aim
 260                 case WEP_PORTO: // shoots from eye
 261                 case WEP_HOOK: // no trueaim
 262                 case WEP_GRENADE_LAUNCHER: // toss curve
 263                         return SHOTTYPE_HITWORLD;
 264                 case WEP_NEX:
 265                 case WEP_MINSTANEX:
 266                         mv = MOVE_NORMAL;
 267                         break;
 268                 case WEP_RIFLE:
 269                         ta = trueaim_rifle;
 270                         mv = MOVE_NORMAL;
 271                         if(zoomscript_caught)
 272                         {
 273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 274                                 return EnemyHitCheck();
 275                         }
 276                         break;
 277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 278                         mi = '-3 -3 -3';
 279                         ma = '3 3 3';
 280                         break;
 281                 case WEP_FIREBALL: // projectile has a size!
 282                         mi = '-16 -16 -16';
 283                         ma = '16 16 16';
 284                         break;
 285                 case WEP_SEEKER: // projectile has a size!
 286                         mi = '-2 -2 -2';
 287                         ma = '2 2 2';
 288                         break;
 289                 case WEP_ELECTRO: // projectile has a size!
 290                         mi = '0 0 -3';
 291                         ma = '0 0 -3';
 292                         break;
 293         }
 294
 295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 296
 297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 298         trueaimpoint = trace_endpos;
 299
 300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 302
 303         if(vecs_x > 0)
 304                 vecs_y = -vecs_y;
 305         else
 306                 vecs = '0 0 0';
 307
 308         dv = view_right * vecs_y + view_up * vecs_z;
 309         w_shotorg = view_origin + dv;
 310
 311         // now move the vecs forward as much as requested if possible
 312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 313         w_shotorg = trace_endpos - view_forward * nudge;
 314
 315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 316         shottype = EnemyHitCheck();
 317         if(shottype != SHOTTYPE_HITWORLD)
 318                 return shottype;
 319
 320 #if 0
 321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 322         // or rather, I know why, but see no fix
 323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 325                 return SHOTTYPE_HITOBSTRUCTION;
 326 #endif
 327
 328         return SHOTTYPE_HITWORLD;
 329 }
 330
 331 void CSQC_common_hud(void);
 332
 333 void PostInit(void);
 334 void CSQC_Demo_Camera();
 335 float HUD_WouldDrawScoreboard();
 336 float camera_mode;
 337 float reticle_type;
 338 string NextFrameCommand;
 339 void CSQC_SPIDER_HUD();
 340 void CSQC_RAPTOR_HUD();
 341
 342 vector freeze_org, freeze_ang;
 343 entity nightvision_noise, nightvision_noise2;
 344
 345 float pickup_crosshair_time, pickup_crosshair_size;
 346 float hit_time, typehit_time;
 347 float nextsound_hit_time, nextsound_typehit_time;
 348 float hitindication_crosshair_time, hitindication_crosshair_size;
 349 float use_nex_chargepool;
 350
 351 float myhealth, myhealth_prev;
 352 float myhealth_flash;
 353
 354 vector myhealth_gentlergb;
 355
 356 float contentavgalpha, liquidalpha_prev;
 357 vector liquidcolor_prev;
 358
 359 float eventchase_current_distance;
 360
 361 float checkfail[16];
 362
 363 void CSQC_UpdateView(float w, float h)
 364 {
 365         entity e;
 366         float fov;
 367         float f, i, j;
 368         vector v, vo;
 369         vector vf_size, vf_min;
 370         float a;
 371         float hud;
 372         hud = getstati(STAT_HUD);
 373
 374         button_attack2 = (input_buttons & BUTTON_3);
 375         button_zoom = (input_buttons & BUTTON_4);
 376
 377 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 378         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 379         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 380         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 381         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 382         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 383         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 384
 385         vf_size = R_SetView3fv(VF_SIZE);
 386         vf_min = R_SetView3fv(VF_MIN);
 387         vid_width = vf_size_x;
 388         vid_height = vf_size_y;
 389
 390         vector reticle_pos, reticle_size;
 391         vector splash_pos, splash_size;
 392
 393         WaypointSprite_Load();
 394
 395         if(spectatee_status)
 396                 myteam = GetPlayerColor(spectatee_status - 1);
 397         else
 398                 myteam = GetPlayerColor(player_localentnum - 1);
 399
 400         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 401         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 402
 403         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 404         {
 405                 R_SetView(VF_ORIGIN, freeze_org);
 406                 R_SetView(VF_ANGLES, freeze_ang);
 407         }
 408         else
 409         {
 410                 freeze_org = R_SetView3fv(VF_ORIGIN);
 411                 freeze_ang = R_SetView3fv(VF_ANGLES);
 412         }
 413
 414         // event chase camera
 415         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 416         {
 417                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 418                 {
 419                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 420                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 421                         if(!autocvar_chase_active)
 422                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 423
 424                         // make the camera smooth back
 425                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 426                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 427                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 428                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 429
 430                         vector eventchase_target_origin;
 431                         makevectors(view_angles);
 432                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 433                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 434
 435                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 436                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 437                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 438                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 439                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 440
 441                         R_SetView(VF_ORIGIN, trace_endpos);
 442                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 443                 }
 444                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 445                 {
 446                         cvar_set("chase_active", "0");
 447                         eventchase_current_distance = 0; // start from 0 next time
 448                 }
 449         }
 450
 451         WarpZone_FixView();
 452         //WarpZone_FixPMove();
 453
 454         // Render the Scene
 455         view_origin = R_SetView3fv(VF_ORIGIN);
 456         view_angles = R_SetView3fv(VF_ANGLES);
 457         makevectors(view_angles);
 458         view_forward = v_forward;
 459         view_right = v_right;
 460         view_up = v_up;
 461
 462 #ifdef BLURTEST
 463         if(time > blurtest_time0 && time < blurtest_time1)
 464         {
 465                 float r, t;
 466
 467                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 468                 r = t * blurtest_radius;
 469                 f = 1 / pow(t, blurtest_power) - 1;
 470
 471                 cvar_set("r_glsl_postprocess", "1");
 472                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 473         }
 474         else
 475         {
 476                 cvar_set("r_glsl_postprocess", "0");
 477                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 478         }
 479 #endif
 480
 481         TargetMusic_Advance();
 482         Fog_Force();
 483
 484         drawframetime = max(0.000001, time - drawtime);
 485         drawtime = time;
 486
 487         // watch for gametype changes here...
 488         // in ParseStuffCMD the cmd isn't executed yet :/
 489         // might even be better to add the gametype to TE_CSQC_INIT...?
 490         if(!postinit)
 491                 PostInit();
 492
 493         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 494                 if(calledhooks & HOOK_START)
 495                 {
 496                         localcmd("\ncl_hook_gameend\n");
 497                         calledhooks |= HOOK_END;
 498                 }
 499
 500         CheckForGamestartChange();
 501         serverAnnouncer();
 502         maptimeAnnouncer();
 503         carrierAnnouncer();
 504
 505         fov = autocvar_fov;
 506         if(fov <= 59.5)
 507         {
 508                 if(!zoomscript_caught)
 509                 {
 510                         localcmd("+button9\n");
 511                         zoomscript_caught = 1;
 512                 }
 513         }
 514         else
 515         {
 516                 if(zoomscript_caught)
 517                 {
 518                         localcmd("-button9\n");
 519                         zoomscript_caught = 0;
 520                 }
 521         }
 522
 523         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 524         activeweapon = getstati(STAT_SWITCHWEAPON);
 525         f = (serverflags & SERVERFLAG_TEAMPLAY);
 526         if(f != teamplay)
 527         {
 528                 teamplay = f;
 529                 HUD_InitScores();
 530         }
 531
 532         if(last_weapon != activeweapon) {
 533                 weapontime = time;
 534                 last_weapon = activeweapon;
 535
 536                 e = get_weaponinfo(activeweapon);
 537                 if(e.netname != "")
 538                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 539                 else
 540                         localcmd("\ncl_hook_activeweapon none\n");
 541         }
 542
 543         // ALWAYS Clear Current Scene First
 544         R_ClearScene();
 545         R_SetView(VF_ORIGIN, view_origin);
 546         R_SetView(VF_ANGLES, view_angles);
 547
 548         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 549         R_SetView(VF_SIZE, vf_size);
 550         R_SetView(VF_MIN, vf_min);
 551
 552         // Assign Standard Viewflags
 553         // Draw the World (and sky)
 554         R_SetView(VF_DRAWWORLD, 1);
 555
 556         // Set the console size vars
 557         vid_conwidth = autocvar_vid_conwidth;
 558         vid_conheight = autocvar_vid_conheight;
 559         vid_pixelheight = autocvar_vid_pixelheight;
 560
 561         R_SetView(VF_FOV, GetCurrentFov(fov));
 562
 563         // Camera for demo playback
 564         if(camera_active)
 565         {
 566                 if(autocvar_camera_enable)
 567                         CSQC_Demo_Camera();
 568                 else
 569                 {
 570                         cvar_set("chase_active", ftos(chase_active_backup));
 571                         cvar_set("cl_demo_mousegrab", "0");
 572                         camera_active = FALSE;
 573                 }
 574         }
 575 #ifdef CAMERATEST
 576         else if(autocvar_camera_enable)
 577 #else
 578         else if(autocvar_camera_enable && isdemo())
 579 #endif
 580         {
 581                 // Enable required Darkplaces cvars
 582                 chase_active_backup = autocvar_chase_active;
 583                 cvar_set("chase_active", "2");
 584                 cvar_set("cl_demo_mousegrab", "1");
 585                 camera_active = TRUE;
 586                 camera_mode = FALSE;
 587         }
 588
 589         // Draw the Crosshair
 590         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 591
 592         // Draw the Engine Status Bar (the default Quake HUD)
 593         R_SetView(VF_DRAWENGINEHUD, 0);
 594
 595         // Update the mouse position
 596         /*
 597            mousepos_x = vid_conwidth;
 598            mousepos_y = vid_conheight;
 599            mousepos = mousepos*0.5 + getmousepos();
 600          */
 601
 602         e = self;
 603         for(self = world; (self = nextent(self)); )
 604                 if(self.draw)
 605                         self.draw();
 606         self = e;
 607
 608         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 609         R_RenderScene();
 610
 611         // now switch to 2D drawing mode by calling a 2D drawing function
 612         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 613         // next R_RenderScene call
 614         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 615
 616         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 617         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 618         {
 619                 // apply night vision effect
 620                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 621
 622                 if(!nightvision_noise)
 623                 {
 624                         nightvision_noise = spawn();
 625                         nightvision_noise.classname = "nightvision_noise";
 626                 }
 627                 if(!nightvision_noise2)
 628                 {
 629                         nightvision_noise2 = spawn();
 630                         nightvision_noise2.classname = "nightvision_noise2";
 631                 }
 632
 633                 // color tint in yellow
 634                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 635
 636                 // draw BG
 637                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 638                 rgb = '1 1 1';
 639                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 640                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 641                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 642                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 643                 tc_11 = tc_01 + tc_10 - tc_00;
 644                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 645                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 646                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 647                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 648                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 649                 R_EndPolygon();
 650
 651                 // draw FG
 652                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 653                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 654                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 655                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 656                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 657                 tc_11 = tc_01 + tc_10 - tc_00;
 658                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 659                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 660                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 661                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 662                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 663                 R_EndPolygon();
 664         }
 665
 666         // Draw the aiming reticle for weapons that use it
 667         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 668         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 669         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 670         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 671                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 672         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 673                 reticle_type = 2; // nex zoom
 674         else if(button_zoom || zoomscript_caught)
 675                 reticle_type = 1; // normal zoom
 676         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 677                 reticle_type = 2; // nex zoom
 678
 679         if (reticle_type)
 680         {
 681                 if(autocvar_cl_reticle_stretch)
 682                 {
 683                         reticle_size_x = vid_conwidth;
 684                         reticle_size_y = vid_conheight;
 685                         reticle_pos_x = 0;
 686                         reticle_pos_y = 0;
 687                 }
 688                 else
 689                 {
 690                         reticle_size_x = max(vid_conwidth, vid_conheight);
 691                         reticle_size_y = max(vid_conwidth, vid_conheight);
 692                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 693                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 694                 }
 695
 696                 f = current_zoomfraction;
 697                 if(zoomscript_caught)
 698                         f = 1;
 699                 if(autocvar_cl_reticle_item_normal)
 700                 {
 701                         if(reticle_type == 1 && f)
 702                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 703                 }
 704                 if(autocvar_cl_reticle_item_nex)
 705                 {
 706                         if(reticle_type == 2 && f)
 707                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 708                 }
 709         }
 710
 711
 712         // improved polyblend
 713         vector rgb;
 714         if(autocvar_hud_contents)
 715         {
 716                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 717                 vector liquidcolor;
 718
 719                 switch(pointcontents(view_origin))
 720                 {
 721                         case CONTENT_WATER:
 722                                 liquidalpha = autocvar_hud_contents_water_alpha;
 723                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 724                                 incontent = 1;
 725                                 break;
 726
 727                         case CONTENT_LAVA:
 728                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 729                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 730                                 incontent = 1;
 731                                 break;
 732
 733                         case CONTENT_SLIME:
 734                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 735                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 736                                 incontent = 1;
 737                                 break;
 738
 739                         default:
 740                                 liquidalpha = 0;
 741                                 liquidcolor = '0 0 0';
 742                                 incontent = 0;
 743                                 break;
 744                 }
 745
 746                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 747                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 748                         contentfadetime = autocvar_hud_contents_fadeintime;
 749                         liquidalpha_prev = liquidalpha;
 750                         liquidcolor_prev = liquidcolor;
 751                 }
 752                 else
 753                         contentfadetime = autocvar_hud_contents_fadeouttime;
 754
 755                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 756                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 757
 758                 if(contentavgalpha)
 759                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 760         }
 761
 762         if(autocvar_hud_damage && !autocvar_chase_active)
 763
 764         {
 765                 splash_size_x = max(vid_conwidth, vid_conheight);
 766                 splash_size_y = max(vid_conwidth, vid_conheight);
 767                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 768                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 769
 770                 float myhealth_flash_temp;
 771                 myhealth = getstati(STAT_HEALTH);
 772
 773                 // fade out
 774                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 775                 // add new damage
 776                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 777
 778                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 779                 pain_threshold = autocvar_hud_damage_pain_threshold;
 780                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 781                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 782
 783                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 784                 {
 785                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 786                 }
 787
 788                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 789
 790                 if(myhealth_prev < 1)
 791                 {
 792                         if(myhealth >= 1)
 793                         {
 794                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 795                                 myhealth_flash_temp = 0;
 796                         }
 797                         else
 798                         {
 799                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 800                         }
 801                 }
 802
 803                 if(spectatee_status == -1 || intermission)
 804                 {
 805                         myhealth_flash = 0; // observing, or match ended
 806                         myhealth_flash_temp = 0;
 807                 }
 808
 809                 myhealth_prev = myhealth;
 810
 811                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 812                 {
 813                         if(autocvar_cl_gentle_damage == 2)
 814                         {
 815                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 816                                 {
 817                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 818                                 }
 819                         }
 820                         else
 821                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 822
 823                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 824                 }
 825                 else
 826                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 827         }
 828
 829         if(menu_visible)
 830                 menu_show();
 831
 832         /*if(gametype == GAME_CTF)
 833           {
 834           ctf_view();
 835           } else */
 836
 837         // draw 2D entities
 838         e = self;
 839         for(self = world; (self = nextent(self)); )
 840                 if(self.draw2d)
 841                         self.draw2d();
 842         self = e;
 843         Draw_ShowNames_All();
 844
 845         scoreboard_active = HUD_WouldDrawScoreboard();
 846
 847         hit_time = getstatf(STAT_HIT_TIME);
 848         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 849         {
 850                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 851                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 852         }
 853         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 854         if(typehit_time > nextsound_typehit_time)
 855         {
 856                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 857                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 858         }
 859
 860         if(hud == HUD_SPIDERBOT)
 861                 CSQC_SPIDER_HUD();
 862         else if(hud == HUD_WAKIZASHI)
 863         CSQC_WAKIZASHI_HUD();
 864     else if(hud == HUD_RAPTOR)
 865         CSQC_RAPTOR_HUD();
 866     else if(hud == HUD_BUMBLEBEE)
 867         CSQC_BUMBLE_HUD();
 868         else
 869         {
 870                 if(gametype == GAME_FREEZETAG)
 871                 {
 872                         if(getstati(STAT_FROZEN))
 873                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 874                         if(getstatf(STAT_REVIVE_PROGRESS))
 875                         {
 876                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 877                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 878                         }
 879                 }
 880
 881                 if(autocvar_r_letterbox == 0)
 882                         if(autocvar_viewsize < 120)
 883                                 CSQC_common_hud();
 884
 885                 // crosshair goes VERY LAST
 886                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
 887                         string wcross_style;
 888                         float wcross_alpha, wcross_resolution;
 889                         wcross_style = autocvar_crosshair;
 890                         if (wcross_style == "0")
 891                                 return;
 892                         wcross_resolution = autocvar_crosshair_size;
 893                         if (wcross_resolution == 0)
 894                                 return;
 895                         wcross_alpha = autocvar_crosshair_alpha;
 896                         if (wcross_alpha == 0)
 897                                 return;
 898
 899                         // TrueAim check
 900                         float shottype;
 901
 902                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 903                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 904                         wcross_origin_z = 0;
 905                         if(autocvar_crosshair_hittest)
 906                         {
 907                                 vector wcross_oldorigin;
 908                                 wcross_oldorigin = wcross_origin;
 909                                 shottype = TrueAimCheck();
 910                                 if(shottype == SHOTTYPE_HITWORLD)
 911                                 {
 912                                         v = wcross_origin - wcross_oldorigin;
 913                                         v_x /= vid_conwidth;
 914                                         v_y /= vid_conheight;
 915                                         if(vlen(v) > 0.01)
 916                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 917                                 }
 918                                 if(!autocvar_crosshair_hittest_showimpact)
 919                                         wcross_origin = wcross_oldorigin;
 920                         }
 921                         else
 922                                 shottype = SHOTTYPE_HITWORLD;
 923
 924                         vector wcross_color, wcross_size;
 925                         string wcross_wep, wcross_name;
 926                         float wcross_scale, wcross_blur;
 927
 928                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 929                                 e = get_weaponinfo(activeweapon);
 930                                 if (e && e.netname != "")
 931                                 {
 932                                         wcross_wep = e.netname;
 933                                         if(autocvar_crosshair_per_weapon)
 934                                         {
 935                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 936                                                 if (wcross_resolution == 0)
 937                                                         return;
 938                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 939                                                 if (wcross_alpha == 0)
 940                                                         return;
 941
 942                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 943                                                 if(wcross_style == "" || wcross_style == "0")
 944                                                         wcross_style = wcross_wep;
 945                                         }
 946                                 }
 947                         }
 948                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 949                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 950                         else if(autocvar_crosshair_color_by_health)
 951                         {
 952                                 local float x = getstati(STAT_HEALTH);
 953
 954                                 //x = red
 955                                 //y = green
 956                                 //z = blue
 957
 958                                 wcross_color_z = 0;
 959
 960                                 if(x > 200)
 961                                 {
 962                                         wcross_color_x = 0;
 963                                         wcross_color_y = 1;
 964                                 }
 965                                 else if(x > 150)
 966                                 {
 967                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 968                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 969                                 }
 970                                 else if(x > 100)
 971                                 {
 972                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 973                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 974                                         wcross_color_z = 1 - (x-100)*0.02;
 975                                 }
 976                                 else if(x > 50)
 977                                 {
 978                                         wcross_color_x = 1;
 979                                         wcross_color_y = 1;
 980                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 981                                 }
 982                                 else if(x > 20)
 983                                 {
 984                                         wcross_color_x = 1;
 985                                         wcross_color_y = (x-20)*90/27/100;
 986                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 987                                 }
 988                                 else
 989                                 {
 990                                         wcross_color_x = 1;
 991                                         wcross_color_y = 0;
 992                                 }
 993                         }
 994                         else
 995                                 wcross_color = stov(autocvar_crosshair_color);
 996
 997                         wcross_name = strcat("gfx/crosshair", wcross_style);
 998
 999                         if(autocvar_crosshair_effect_scalefade)
1000                         {
1001                                 wcross_scale = wcross_resolution;
1002                                 wcross_resolution = 1;
1003                         }
1004                         else
1005                         {
1006                                 wcross_scale = 1;
1007                         }
1008
1009                         if(autocvar_crosshair_pickup)
1010                         {
1011                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1012                                 {
1013                                         pickup_crosshair_size = 1;
1014                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1015                                 }
1016
1017                                 if(pickup_crosshair_size > 0)
1018                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1019                                 else
1020                                         pickup_crosshair_size = 0;
1021
1022                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1023                         }
1024
1025                         vector hitindication_color;
1026                         if(autocvar_crosshair_hitindication)
1027                         {
1028                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1029                                 if(hitindication_crosshair_time < hit_time)
1030                                 {
1031                                         hitindication_crosshair_size = 1;
1032                                         hitindication_crosshair_time = hit_time;
1033                                 }
1034
1035                                 if(hitindication_crosshair_size > 0)
1036                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1037                                 else
1038                                         hitindication_crosshair_size = 0;
1039
1040                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1041                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1042                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1043                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1044                         }
1045
1046                         if(shottype == SHOTTYPE_HITENEMY)
1047                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1048                         if(shottype == SHOTTYPE_HITTEAM)
1049                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1050
1051                         f = autocvar_crosshair_effect_speed;
1052                         if(f < 0)
1053                                 f *= -2 * g_weaponswitchdelay;
1054                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1055                         {
1056                                 wcross_changedonetime = time + f;
1057                         }
1058                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1059                         {
1060                                 wcross_name_changestarttime = time;
1061                                 wcross_name_changedonetime = time + f;
1062                                 if(wcross_name_goal_prev_prev)
1063                                         strunzone(wcross_name_goal_prev_prev);
1064                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1065                                 wcross_name_goal_prev = strzone(wcross_name);
1066                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1067                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1068                                 wcross_resolution_goal_prev = wcross_resolution;
1069                         }
1070
1071                         wcross_scale_goal_prev = wcross_scale;
1072                         wcross_alpha_goal_prev = wcross_alpha;
1073                         wcross_color_goal_prev = wcross_color;
1074
1075                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1076                         {
1077                                 wcross_blur = 1;
1078                                 wcross_alpha *= 0.75;
1079                         }
1080                         else
1081                                 wcross_blur = 0;
1082                         // *_prev is at time-frametime
1083                         // * is at wcross_changedonetime+f
1084                         // what do we have at time?
1085                         if(time < wcross_changedonetime)
1086                         {
1087                                 f = frametime / (wcross_changedonetime - time + frametime);
1088                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1089                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1090                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1091                         }
1092
1093                         wcross_scale_prev = wcross_scale;
1094                         wcross_alpha_prev = wcross_alpha;
1095                         wcross_color_prev = wcross_color;
1096
1097                         wcross_scale *= 1 - autocvar__menu_alpha;
1098                         wcross_alpha *= 1 - autocvar__menu_alpha;
1099                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1100
1101                         // crosshair rings for weapon stats
1102                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1103                         {
1104                                 // declarations and stats
1105                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1106                                 string ring_image, ring_inner_image;
1107                                 vector ring_rgb, ring_inner_rgb;
1108
1109                                 ring_scale = autocvar_crosshair_ring_size;
1110
1111                                 float weapon_clipload, weapon_clipsize;
1112                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1113                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1114
1115                                 float nex_charge, nex_chargepool;
1116                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1117                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1118
1119                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1120                                         nex_charge_movingavg = nex_charge;
1121
1122
1123                                 // handle the values
1124                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1125                                 {
1126                                         if (nex_chargepool || use_nex_chargepool) {
1127                                                 use_nex_chargepool = 1;
1128                                                 ring_inner_value = nex_chargepool;
1129                                         } else {
1130                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1131                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1132                                         }
1133
1134                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1135                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1136                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1137
1138                                         // draw the outer ring to show the current charge of the weapon
1139                                         ring_value = nex_charge;
1140                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1141                                         ring_rgb = wcross_color;
1142                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1143                                 }
1144                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1145                                 {
1146                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1147                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1148                                         ring_rgb = wcross_color;
1149                                         ring_image = "gfx/crosshair_ring.tga";
1150                                 }
1151                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1152                                 {
1153                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1154                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1155                                         ring_rgb = wcross_color;
1156                                         ring_image = "gfx/crosshair_ring.tga";
1157                                 }
1158
1159                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1160                                 {
1161                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1162                                         ring_scale = autocvar_crosshair_ring_reload_size;
1163                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1164                                         ring_rgb = wcross_color;
1165
1166                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1167                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1168                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1169                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1170                                         else
1171                                                 ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173
1174                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1175                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1176
1177                                 if (ring_value)
1178                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1179                         }
1180
1181 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1182                         do \
1183                         { \
1184                                 if(wcross_blur > 0) \
1185                                 { \
1186                                         for(i = -2; i <= 2; ++i) \
1187                                                 for(j = -2; j <= 2; ++j) \
1188                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1189                                 } \
1190                                 else \
1191                                 { \
1192                                         M(0,0,sz,wcross_name,wcross_alpha); \
1193                                 } \
1194                         } \
1195                         while(0)
1196
1197 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1198                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1199
1200 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1201                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1202
1203                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1204                         {
1205                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1206                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1207                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1208                                 f = 1 - f;
1209                         }
1210                         else
1211                         {
1212                                 f = 1;
1213                         }
1214
1215                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1216                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1217
1218                         if(autocvar_crosshair_dot)
1219             {
1220                 vector wcross_color_old;
1221                 wcross_color_old = wcross_color;
1222                 if(autocvar_crosshair_dot_color != "0")
1223                     wcross_color = stov(autocvar_crosshair_dot_color);
1224                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1225                 wcross_color = wcross_color_old;
1226             }
1227
1228                         wcross_name_alpha_goal_prev = f;
1229                 }
1230                 else
1231                 {
1232                         wcross_scale_prev = 0;
1233                         wcross_alpha_prev = 0;
1234                         wcross_scale_goal_prev = 0;
1235                         wcross_alpha_goal_prev = 0;
1236                         wcross_changedonetime = 0;
1237                         if(wcross_name_goal_prev)
1238                                 strunzone(wcross_name_goal_prev);
1239                         wcross_name_goal_prev = string_null;
1240                         if(wcross_name_goal_prev_prev)
1241                                 strunzone(wcross_name_goal_prev_prev);
1242                         wcross_name_goal_prev_prev = string_null;
1243                         wcross_name_changestarttime = 0;
1244                         wcross_name_changedonetime = 0;
1245                         wcross_name_alpha_goal_prev = 0;
1246                         wcross_name_alpha_goal_prev_prev = 0;
1247                         wcross_resolution_goal_prev = 0;
1248                         wcross_resolution_goal_prev_prev = 0;
1249                 }
1250         }
1251
1252         if(NextFrameCommand)
1253         {
1254                 localcmd("\n", NextFrameCommand, "\n");
1255                 NextFrameCommand = string_null;
1256         }
1257
1258         // we must do this check AFTER a frame was rendered, or it won't work
1259         if(cs_project_is_b0rked == 0)
1260         {
1261                 string w0, h0;
1262                 w0 = ftos(autocvar_vid_conwidth);
1263                 h0 = ftos(autocvar_vid_conheight);
1264                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1265                 //R_SetView(VF_FOV, '90 90 0');
1266                 R_SetView(VF_ORIGIN, '0 0 0');
1267                 R_SetView(VF_ANGLES, '0 0 0');
1268                 R_SetView(VF_PERSPECTIVE, 1);
1269                 makevectors('0 0 0');
1270                 vector v1, v2;
1271                 cvar_set("vid_conwidth", "800");
1272                 cvar_set("vid_conheight", "600");
1273                 v1 = cs_project(v_forward);
1274                 cvar_set("vid_conwidth", "640");
1275                 cvar_set("vid_conheight", "480");
1276                 v2 = cs_project(v_forward);
1277                 if(v1 == v2)
1278                         cs_project_is_b0rked = 1;
1279                 else
1280                         cs_project_is_b0rked = -1;
1281                 cvar_set("vid_conwidth", w0);
1282                 cvar_set("vid_conheight", h0);
1283         }
1284
1285         if(autocvar__hud_configure)
1286                 HUD_Panel_Mouse();
1287
1288         // let's reset the view back to normal for the end
1289         R_SetView(VF_MIN, '0 0 0');
1290         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1291 }
1292
1293
1294 void CSQC_common_hud(void)
1295 {
1296         // HUD_SortFrags(); done in HUD_Draw
1297         float hud;
1298         hud = getstati(STAT_HUD);
1299
1300         //hud = 10;
1301         switch(hud)
1302         {
1303                 case HUD_NORMAL:
1304                         // do some accuracy var caching
1305                         float i;
1306                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1307                         {
1308                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1309                                 {
1310                                         if(acc_color_levels)
1311                                                 strunzone(acc_color_levels);
1312                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1313                                         acc_levels = tokenize(acc_color_levels);
1314                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1315                                                 acc_levels = MAX_ACCURACY_LEVELS;
1316
1317                                         for (i = 0; i < acc_levels; ++i)
1318                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1319                                 }
1320                                 // let know that acc_col[] needs to be loaded
1321                                 acc_col_x[0] = -1;
1322                         }
1323
1324                         HUD_Main(); // always run these functions for alpha checks
1325                         HUD_DrawScoreboard();
1326
1327                         if (scoreboard_active) // scoreboard/accuracy
1328                         {
1329                                 HUD_Reset();
1330                                 // HUD_DrawScoreboard takes care of centerprint_start
1331                         }
1332                         else if (intermission == 2) // map voting screen
1333                         {
1334                                 HUD_FinaleOverlay();
1335                                 HUD_Reset();
1336
1337                                 centerprint_start_x = 0;
1338                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1339                         }
1340                         else // hud
1341                         {
1342                                 centerprint_start_x = 0;
1343                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1344                         }
1345
1346                         HUD_DrawCenterPrint();
1347                         break;
1348
1349                 case HUD_SPIDERBOT:
1350                         CSQC_SPIDER_HUD();
1351                         break;
1352
1353                 case HUD_WAKIZASHI:
1354                         CSQC_WAKIZASHI_HUD();
1355                         break;
1356
1357         case HUD_BUMBLEBEE:
1358             CSQC_BUMBLE_HUD();
1359             break;
1360
1361         }
1362 }
1363
1364
1365 // following vectors must be global to allow seamless switching between camera modes
1366 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1367 void CSQC_Demo_Camera()
1368 {
1369         float speed, attenuation, dimensions;
1370         vector tmp, delta;
1371
1372         if( autocvar_camera_reset || !camera_mode )
1373         {
1374                 camera_offset = '0 0 0';
1375                 current_angles = '0 0 0';
1376                 camera_direction = '0 0 0';
1377                 camera_offset_z += 30;
1378                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1379                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1380                 current_origin = view_origin;
1381                 current_camera_offset  = camera_offset;
1382                 cvar_set("camera_reset", "0");
1383                 camera_mode = CAMERA_CHASE;
1384         }
1385
1386         // Camera angles
1387         if( camera_roll )
1388                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1389
1390         if(autocvar_camera_look_player)
1391         {
1392                 local vector dir;
1393                 local float n;
1394
1395                 dir = normalize(view_origin - current_position);
1396                 n = mouse_angles_z;
1397                 mouse_angles = vectoangles(dir);
1398                 mouse_angles_x = mouse_angles_x * -1;
1399                 mouse_angles_z = n;
1400         }
1401         else
1402         {
1403                 tmp = getmousepos() * 0.1;
1404                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1405                 {
1406                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1407                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1408                 }
1409         }
1410
1411         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1412         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1413         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1414         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1415
1416         // Fix difference when angles don't have the same sign
1417         delta = '0 0 0';
1418         if(mouse_angles_y < -60 && current_angles_y > 60)
1419                 delta = '0 360 0';
1420         if(mouse_angles_y > 60 && current_angles_y < -60)
1421                 delta = '0 -360 0';
1422
1423         if(autocvar_camera_look_player)
1424                 attenuation = autocvar_camera_look_attenuation;
1425         else
1426                 attenuation = autocvar_camera_speed_attenuation;
1427
1428         attenuation = 1 / max(1, attenuation);
1429         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1430
1431         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1432         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1433         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1434         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1435
1436         // Camera position
1437         tmp = '0 0 0';
1438         dimensions = 0;
1439
1440         if( camera_direction_x )
1441         {
1442                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1443                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1444                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1445                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1446                 ++dimensions;
1447         }
1448
1449         if( camera_direction_y )
1450         {
1451                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1452                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1453                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1454                 ++dimensions;
1455         }
1456
1457         if( camera_direction_z )
1458         {
1459                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1460                 ++dimensions;
1461         }
1462
1463         if(autocvar_camera_free)
1464                 speed = autocvar_camera_speed_free;
1465         else
1466                 speed = autocvar_camera_speed_chase;
1467
1468         if(dimensions)
1469         {
1470                 speed = speed * sqrt(1 / dimensions);
1471                 camera_offset += tmp * speed;
1472         }
1473
1474         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1475
1476         // Camera modes
1477         if( autocvar_camera_free )
1478         {
1479                 if ( camera_mode == CAMERA_CHASE )
1480                 {
1481                         current_camera_offset = current_origin + current_camera_offset;
1482                         camera_offset = current_origin + camera_offset;
1483                 }
1484
1485                 camera_mode = CAMERA_FREE;
1486                 current_position = current_camera_offset;
1487         }
1488         else
1489         {
1490                 if ( camera_mode == CAMERA_FREE )
1491                 {
1492                         current_origin = view_origin;
1493                         camera_offset = camera_offset - current_origin;
1494                         current_camera_offset = current_camera_offset - current_origin;
1495                 }
1496
1497                 camera_mode = CAMERA_CHASE;
1498
1499                 if(autocvar_camera_chase_smoothly)
1500                         current_origin += (view_origin - current_origin) * attenuation;
1501                 else
1502                         current_origin = view_origin;
1503
1504                 current_position = current_origin + current_camera_offset;
1505         }
1506
1507         R_SetView(VF_ANGLES, current_angles);
1508         R_SetView(VF_ORIGIN, current_position);
1509 }