qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_RIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float camera_mode;
 346 float reticle_type;
 347 string NextFrameCommand;
 348 void CSQC_SPIDER_HUD();
 349 void CSQC_RAPTOR_HUD();
 350
 351 vector freeze_org, freeze_ang;
 352 entity nightvision_noise, nightvision_noise2;
 353
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 vector myhealth_gentlergb;
 364
 365 float contentavgalpha, liquidalpha_prev;
 366 vector liquidcolor_prev;
 367
 368 float eventchase_current_distance;
 369
 370 float checkfail[16];
 371
 372 void CSQC_UpdateView(float w, float h)
 373 {
 374         entity e;
 375         float fov;
 376         float f, i, j;
 377         vector v, vo;
 378         vector vf_size, vf_min;
 379         float a;
 380
 381         button_attack2 = (input_buttons & BUTTON_3);
 382         button_zoom = (input_buttons & BUTTON_4);
 383
 384 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 385         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 386         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 387         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 388         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 389         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 390         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 391
 392         vf_size = R_SetView3fv(VF_SIZE);
 393         vf_min = R_SetView3fv(VF_MIN);
 394         vid_width = vf_size_x;
 395         vid_height = vf_size_y;
 396
 397         vector reticle_pos, reticle_size;
 398         vector splash_pos, splash_size;
 399
 400         WaypointSprite_Load();
 401
 402         if(spectatee_status)
 403                 myteam = GetPlayerColor(spectatee_status - 1);
 404         else
 405                 myteam = GetPlayerColor(player_localentnum - 1);
 406
 407         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 408         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 409
 410         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 411         {
 412                 R_SetView(VF_ORIGIN, freeze_org);
 413                 R_SetView(VF_ANGLES, freeze_ang);
 414         }
 415         else
 416         {
 417                 freeze_org = R_SetView3fv(VF_ORIGIN);
 418                 freeze_ang = R_SetView3fv(VF_ANGLES);
 419         }
 420
 421         // event chase camera
 422         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 423         {
 424                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 425                 {
 426                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 427                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 428                         if(!autocvar_chase_active)
 429                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 430
 431                         // make the camera smooth back
 432                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 433                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 434                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 435                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 436
 437                         vector eventchase_target_origin;
 438                         makevectors(view_angles);
 439                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 440                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 441
 442                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 443                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 444                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 445                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 446                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 447
 448                         R_SetView(VF_ORIGIN, trace_endpos);
 449                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 450                 }
 451                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 452                 {
 453                         cvar_set("chase_active", "0");
 454                         eventchase_current_distance = 0; // start from 0 next time
 455                 }
 456         }
 457
 458         WarpZone_FixView();
 459         //WarpZone_FixPMove();
 460
 461         // Render the Scene
 462         view_origin = R_SetView3fv(VF_ORIGIN);
 463         view_angles = R_SetView3fv(VF_ANGLES);
 464         makevectors(view_angles);
 465         view_forward = v_forward;
 466         view_right = v_right;
 467         view_up = v_up;
 468
 469 #ifdef BLURTEST
 470         if(time > blurtest_time0 && time < blurtest_time1)
 471         {
 472                 float r, t;
 473
 474                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 475                 r = t * blurtest_radius;
 476                 f = 1 / pow(t, blurtest_power) - 1;
 477
 478                 cvar_set("r_glsl_postprocess", "1");
 479                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 480         }
 481         else
 482         {
 483                 cvar_set("r_glsl_postprocess", "0");
 484                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 485         }
 486 #endif
 487
 488         TargetMusic_Advance();
 489         Fog_Force();
 490
 491         if(drawtime == 0)
 492                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 493         else
 494                 drawframetime = bound(0.000001, time - drawtime, 1);
 495         drawtime = time;
 496
 497         // watch for gametype changes here...
 498         // in ParseStuffCMD the cmd isn't executed yet :/
 499         // might even be better to add the gametype to TE_CSQC_INIT...?
 500         if(!postinit)
 501                 PostInit();
 502
 503         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 504                 if(calledhooks & HOOK_START)
 505                 {
 506                         localcmd("\ncl_hook_gameend\n");
 507                         calledhooks |= HOOK_END;
 508                 }
 509
 510         CheckForGamestartChange();
 511         serverAnnouncer();
 512         maptimeAnnouncer();
 513         carrierAnnouncer();
 514
 515         fov = autocvar_fov;
 516         if(fov <= 59.5)
 517         {
 518                 if(!zoomscript_caught)
 519                 {
 520                         localcmd("+button9\n");
 521                         zoomscript_caught = 1;
 522                 }
 523         }
 524         else
 525         {
 526                 if(zoomscript_caught)
 527                 {
 528                         localcmd("-button9\n");
 529                         zoomscript_caught = 0;
 530                 }
 531         }
 532
 533         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 534         activeweapon = getstati(STAT_SWITCHWEAPON);
 535         f = (serverflags & SERVERFLAG_TEAMPLAY);
 536         if(f != teamplay)
 537         {
 538                 teamplay = f;
 539                 HUD_InitScores();
 540         }
 541
 542         if(last_weapon != activeweapon) {
 543                 weapontime = time;
 544                 last_weapon = activeweapon;
 545
 546                 e = get_weaponinfo(activeweapon);
 547                 if(e.netname != "")
 548                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 549                 else
 550                         localcmd("\ncl_hook_activeweapon none\n");
 551         }
 552
 553         // ALWAYS Clear Current Scene First
 554         R_ClearScene();
 555         R_SetView(VF_ORIGIN, view_origin);
 556         R_SetView(VF_ANGLES, view_angles);
 557
 558         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 559         R_SetView(VF_SIZE, vf_size);
 560         R_SetView(VF_MIN, vf_min);
 561
 562         // Assign Standard Viewflags
 563         // Draw the World (and sky)
 564         R_SetView(VF_DRAWWORLD, 1);
 565
 566         // Set the console size vars
 567         vid_conwidth = autocvar_vid_conwidth;
 568         vid_conheight = autocvar_vid_conheight;
 569         vid_pixelheight = autocvar_vid_pixelheight;
 570
 571         R_SetView(VF_FOV, GetCurrentFov(fov));
 572
 573         // Camera for demo playback
 574         if(camera_active)
 575         {
 576                 if(autocvar_camera_enable)
 577                         CSQC_Demo_Camera();
 578                 else
 579                 {
 580                         cvar_set("chase_active", ftos(chase_active_backup));
 581                         cvar_set("cl_demo_mousegrab", "0");
 582                         camera_active = FALSE;
 583                 }
 584         }
 585 #ifdef CAMERATEST
 586         else if(autocvar_camera_enable)
 587 #else
 588         else if(autocvar_camera_enable && isdemo())
 589 #endif
 590         {
 591                 // Enable required Darkplaces cvars
 592                 chase_active_backup = autocvar_chase_active;
 593                 cvar_set("chase_active", "2");
 594                 cvar_set("cl_demo_mousegrab", "1");
 595                 camera_active = TRUE;
 596                 camera_mode = FALSE;
 597         }
 598
 599         // Draw the Crosshair
 600         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 601
 602         // Draw the Engine Status Bar (the default Quake HUD)
 603         R_SetView(VF_DRAWENGINEHUD, 0);
 604
 605         // Update the mouse position
 606         /*
 607            mousepos_x = vid_conwidth;
 608            mousepos_y = vid_conheight;
 609            mousepos = mousepos*0.5 + getmousepos();
 610          */
 611
 612         e = self;
 613         for(self = world; (self = nextent(self)); )
 614                 if(self.draw)
 615                         self.draw();
 616         self = e;
 617
 618         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 619         R_RenderScene();
 620
 621         // now switch to 2D drawing mode by calling a 2D drawing function
 622         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 623         // next R_RenderScene call
 624         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 625
 626         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 627         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 628         {
 629                 // apply night vision effect
 630                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 631
 632                 if(!nightvision_noise)
 633                 {
 634                         nightvision_noise = spawn();
 635                         nightvision_noise.classname = "nightvision_noise";
 636                 }
 637                 if(!nightvision_noise2)
 638                 {
 639                         nightvision_noise2 = spawn();
 640                         nightvision_noise2.classname = "nightvision_noise2";
 641                 }
 642
 643                 // color tint in yellow
 644                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 645
 646                 // draw BG
 647                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 648                 rgb = '1 1 1';
 649                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 650                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 651                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 652                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 653                 tc_11 = tc_01 + tc_10 - tc_00;
 654                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 655                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 656                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 657                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 658                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 659                 R_EndPolygon();
 660
 661                 // draw FG
 662                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 663                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 664                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 665                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 666                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 667                 tc_11 = tc_01 + tc_10 - tc_00;
 668                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 669                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 670                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 671                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 672                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 673                 R_EndPolygon();
 674         }
 675
 676         // Draw the aiming reticle for weapons that use it
 677         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 678         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 679         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 680         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 681                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 682         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 683                 reticle_type = 2; // nex zoom
 684         else if(button_zoom || zoomscript_caught)
 685                 reticle_type = 1; // normal zoom
 686         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 687                 reticle_type = 2; // nex zoom
 688
 689         if (reticle_type)
 690         {
 691                 if(autocvar_cl_reticle_stretch)
 692                 {
 693                         reticle_size_x = vid_conwidth;
 694                         reticle_size_y = vid_conheight;
 695                         reticle_pos_x = 0;
 696                         reticle_pos_y = 0;
 697                 }
 698                 else
 699                 {
 700                         reticle_size_x = max(vid_conwidth, vid_conheight);
 701                         reticle_size_y = max(vid_conwidth, vid_conheight);
 702                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 703                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 704                 }
 705
 706                 f = current_zoomfraction;
 707                 if(zoomscript_caught)
 708                         f = 1;
 709                 if(autocvar_cl_reticle_item_normal)
 710                 {
 711                         if(reticle_type == 1 && f)
 712                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 713                 }
 714                 if(autocvar_cl_reticle_item_nex)
 715                 {
 716                         if(reticle_type == 2 && f)
 717                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 718                 }
 719         }
 720
 721
 722         // improved polyblend
 723         vector rgb;
 724         if(autocvar_hud_contents)
 725         {
 726                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 727                 vector liquidcolor;
 728
 729                 switch(pointcontents(view_origin))
 730                 {
 731                         case CONTENT_WATER:
 732                                 liquidalpha = autocvar_hud_contents_water_alpha;
 733                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 734                                 incontent = 1;
 735                                 break;
 736
 737                         case CONTENT_LAVA:
 738                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 739                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 740                                 incontent = 1;
 741                                 break;
 742
 743                         case CONTENT_SLIME:
 744                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 745                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 746                                 incontent = 1;
 747                                 break;
 748
 749                         default:
 750                                 liquidalpha = 0;
 751                                 liquidcolor = '0 0 0';
 752                                 incontent = 0;
 753                                 break;
 754                 }
 755
 756                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 757                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 758                         contentfadetime = autocvar_hud_contents_fadeintime;
 759                         liquidalpha_prev = liquidalpha;
 760                         liquidcolor_prev = liquidcolor;
 761                 }
 762                 else
 763                         contentfadetime = autocvar_hud_contents_fadeouttime;
 764
 765                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 766                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 767
 768                 if(contentavgalpha)
 769                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 770         }
 771
 772         if(autocvar_hud_damage && !autocvar_chase_active)
 773         {
 774                 splash_size_x = max(vid_conwidth, vid_conheight);
 775                 splash_size_y = max(vid_conwidth, vid_conheight);
 776                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 777                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 778
 779                 float myhealth_flash_temp;
 780                 myhealth = getstati(STAT_HEALTH);
 781
 782                 // fade out
 783                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 784                 // add new damage
 785                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 786
 787                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 788                 pain_threshold = autocvar_hud_damage_pain_threshold;
 789                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 790                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 791
 792                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 793                 {
 794                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 795                 }
 796
 797                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 798
 799                 if(myhealth_prev < 1)
 800                 {
 801                         if(myhealth >= 1)
 802                         {
 803                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 804                                 myhealth_flash_temp = 0;
 805                         }
 806                         else
 807                         {
 808                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 809                         }
 810                 }
 811
 812                 if(spectatee_status == -1 || intermission)
 813                 {
 814                         myhealth_flash = 0; // observing, or match ended
 815                         myhealth_flash_temp = 0;
 816                 }
 817
 818                 myhealth_prev = myhealth;
 819
 820                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 821                 {
 822                         if(autocvar_cl_gentle_damage == 2)
 823                         {
 824                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 825                                 {
 826                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 827                                 }
 828                         }
 829                         else
 830                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 831
 832                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 833                 }
 834                 else
 835                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 836         }
 837
 838         if(menu_visible)
 839                 menu_show();
 840
 841         /*if(gametype == GAME_CTF)
 842           {
 843           ctf_view();
 844           } else */
 845
 846         // draw 2D entities
 847         e = self;
 848         for(self = world; (self = nextent(self)); )
 849                 if(self.draw2d)
 850                         self.draw2d();
 851         self = e;
 852         Draw_ShowNames_All();
 853
 854         scoreboard_active = HUD_WouldDrawScoreboard();
 855
 856         hit_time = getstatf(STAT_HIT_TIME);
 857         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 858         {
 859                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 860                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 861         }
 862         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 863         if(typehit_time > nextsound_typehit_time)
 864         {
 865                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 866                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 867         }
 868
 869         float hud;
 870         hud = getstati(STAT_HUD);
 871         if(hud == HUD_SPIDERBOT)
 872                 CSQC_SPIDER_HUD();
 873         else if(hud == HUD_WAKIZASHI)
 874         CSQC_WAKIZASHI_HUD();
 875     else if(hud == HUD_RAPTOR)
 876         CSQC_RAPTOR_HUD();
 877         else
 878         {
 879                 if(gametype == GAME_FREEZETAG)
 880                 {
 881                         if(getstati(STAT_FROZEN))
 882                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 883                         if(getstatf(STAT_REVIVE_PROGRESS))
 884                         {
 885                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 886                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 887                         }
 888                 }
 889
 890                 if(autocvar_r_letterbox == 0)
 891                         if(autocvar_viewsize < 120)
 892                                 CSQC_common_hud();
 893
 894                 // crosshair goes VERY LAST
 895                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
 896                         string wcross_style;
 897                         float wcross_alpha, wcross_resolution;
 898                         wcross_style = autocvar_crosshair;
 899                         if (wcross_style == "0")
 900                                 return;
 901                         wcross_resolution = autocvar_crosshair_size;
 902                         if (wcross_resolution == 0)
 903                                 return;
 904                         wcross_alpha = autocvar_crosshair_alpha;
 905                         if (wcross_alpha == 0)
 906                                 return;
 907
 908                         // TrueAim check
 909                         float shottype;
 910
 911                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 912                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 913                         wcross_origin_z = 0;
 914                         if(autocvar_crosshair_hittest)
 915                         {
 916                                 vector wcross_oldorigin;
 917                                 wcross_oldorigin = wcross_origin;
 918                                 shottype = TrueAimCheck();
 919                                 if(shottype == SHOTTYPE_HITWORLD)
 920                                 {
 921                                         v = wcross_origin - wcross_oldorigin;
 922                                         v_x /= vid_conwidth;
 923                                         v_y /= vid_conheight;
 924                                         if(vlen(v) > 0.01)
 925                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 926                                 }
 927                                 if(!autocvar_crosshair_hittest_showimpact)
 928                                         wcross_origin = wcross_oldorigin;
 929                         }
 930                         else
 931                                 shottype = SHOTTYPE_HITWORLD;
 932
 933                         vector wcross_color, wcross_size;
 934                         string wcross_wep, wcross_name;
 935                         float wcross_scale, wcross_blur;
 936
 937                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 938                                 e = get_weaponinfo(activeweapon);
 939                                 if (e && e.netname != "")
 940                                 {
 941                                         wcross_wep = e.netname;
 942                                         if(autocvar_crosshair_per_weapon)
 943                                         {
 944                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 945                                                 if (wcross_resolution == 0)
 946                                                         return;
 947                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 948                                                 if (wcross_alpha == 0)
 949                                                         return;
 950
 951                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 952                                                 if(wcross_style == "" || wcross_style == "0")
 953                                                         wcross_style = wcross_wep;
 954                                         }
 955                                 }
 956                         }
 957                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 958                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 959                         else if(autocvar_crosshair_color_by_health)
 960                         {
 961                                 local float x = getstati(STAT_HEALTH);
 962
 963                                 //x = red
 964                                 //y = green
 965                                 //z = blue
 966
 967                                 wcross_color_z = 0;
 968
 969                                 if(x > 200)
 970                                 {
 971                                         wcross_color_x = 0;
 972                                         wcross_color_y = 1;
 973                                 }
 974                                 else if(x > 150)
 975                                 {
 976                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 977                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 978                                 }
 979                                 else if(x > 100)
 980                                 {
 981                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 982                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 983                                         wcross_color_z = 1 - (x-100)*0.02;
 984                                 }
 985                                 else if(x > 50)
 986                                 {
 987                                         wcross_color_x = 1;
 988                                         wcross_color_y = 1;
 989                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 990                                 }
 991                                 else if(x > 20)
 992                                 {
 993                                         wcross_color_x = 1;
 994                                         wcross_color_y = (x-20)*90/27/100;
 995                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 996                                 }
 997                                 else
 998                                 {
 999                                         wcross_color_x = 1;
1000                                         wcross_color_y = 0;
1001                                 }
1002                         }
1003                         else
1004                                 wcross_color = stov(autocvar_crosshair_color);
1005
1006                         wcross_name = strcat("gfx/crosshair", wcross_style);
1007
1008                         if(autocvar_crosshair_effect_scalefade)
1009                         {
1010                                 wcross_scale = wcross_resolution;
1011                                 wcross_resolution = 1;
1012                         }
1013                         else
1014                         {
1015                                 wcross_scale = 1;
1016                         }
1017
1018                         if(autocvar_crosshair_pickup)
1019                         {
1020                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1021                                 {
1022                                         pickup_crosshair_size = 1;
1023                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1024                                 }
1025
1026                                 if(pickup_crosshair_size > 0)
1027                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1028                                 else
1029                                         pickup_crosshair_size = 0;
1030
1031                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1032                         }
1033
1034                         vector hitindication_color;
1035                         if(autocvar_crosshair_hitindication)
1036                         {
1037                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1038                                 if(hitindication_crosshair_time < hit_time)
1039                                 {
1040                                         hitindication_crosshair_size = 1;
1041                                         hitindication_crosshair_time = hit_time;
1042                                 }
1043
1044                                 if(hitindication_crosshair_size > 0)
1045                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1046                                 else
1047                                         hitindication_crosshair_size = 0;
1048
1049                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1050                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1051                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1052                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1053                         }
1054
1055                         if(shottype == SHOTTYPE_HITENEMY)
1056                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1057                         if(shottype == SHOTTYPE_HITTEAM)
1058                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1059
1060                         f = autocvar_crosshair_effect_speed;
1061                         if(f < 0)
1062                                 f *= -2 * g_weaponswitchdelay;
1063                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1064                         {
1065                                 wcross_changedonetime = time + f;
1066                         }
1067                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1068                         {
1069                                 wcross_name_changestarttime = time;
1070                                 wcross_name_changedonetime = time + f;
1071                                 if(wcross_name_goal_prev_prev)
1072                                         strunzone(wcross_name_goal_prev_prev);
1073                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1074                                 wcross_name_goal_prev = strzone(wcross_name);
1075                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1076                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1077                                 wcross_resolution_goal_prev = wcross_resolution;
1078                         }
1079
1080                         wcross_scale_goal_prev = wcross_scale;
1081                         wcross_alpha_goal_prev = wcross_alpha;
1082                         wcross_color_goal_prev = wcross_color;
1083
1084                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1085                         {
1086                                 wcross_blur = 1;
1087                                 wcross_alpha *= 0.75;
1088                         }
1089                         else
1090                                 wcross_blur = 0;
1091                         // *_prev is at time-frametime
1092                         // * is at wcross_changedonetime+f
1093                         // what do we have at time?
1094                         if(time < wcross_changedonetime)
1095                         {
1096                                 f = frametime / (wcross_changedonetime - time + frametime);
1097                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1098                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1099                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1100                         }
1101
1102                         wcross_scale_prev = wcross_scale;
1103                         wcross_alpha_prev = wcross_alpha;
1104                         wcross_color_prev = wcross_color;
1105
1106                         wcross_scale *= 1 - autocvar__menu_alpha;
1107                         wcross_alpha *= 1 - autocvar__menu_alpha;
1108                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1109
1110                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1111                         {
1112                                 // crosshair rings for weapon stats
1113                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1114                                 {
1115                                         // declarations and stats
1116                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1117                                         string ring_image, ring_inner_image;
1118                                         vector ring_rgb, ring_inner_rgb;
1119
1120                                         ring_scale = autocvar_crosshair_ring_size;
1121
1122                                         float weapon_clipload, weapon_clipsize;
1123                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1124                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1125
1126                                         float nex_charge, nex_chargepool;
1127                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1128                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1129
1130                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1131                                                 nex_charge_movingavg = nex_charge;
1132
1133
1134                                         // handle the values
1135                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1136                                         {
1137                                                 if (nex_chargepool || use_nex_chargepool) {
1138                                                         use_nex_chargepool = 1;
1139                                                         ring_inner_value = nex_chargepool;
1140                                                 } else {
1141                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1142                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1143                                                 }
1144
1145                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1146                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1147                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1148
1149                                                 // draw the outer ring to show the current charge of the weapon
1150                                                 ring_value = nex_charge;
1151                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1152                                                 ring_rgb = wcross_color;
1153                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1154                                         }
1155                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1156                                         {
1157                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1158                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1159                                                 ring_rgb = wcross_color;
1160                                                 ring_image = "gfx/crosshair_ring.tga";
1161                                         }
1162                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1163                                         {
1164                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1165                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1166                                                 ring_rgb = wcross_color;
1167                                                 ring_image = "gfx/crosshair_ring.tga";
1168                                         }
1169
1170                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1171                                         {
1172                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1173                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1174                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1175                                                 ring_rgb = wcross_color;
1176
1177                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1178                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1179                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1180                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1181                                                 else
1182                                                         ring_image = "gfx/crosshair_ring.tga";
1183                                         }
1184
1185                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1186                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1187
1188                                         if (ring_value)
1189                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1190                                 }
1191
1192 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1193                                 do \
1194                                 { \
1195                                         if(wcross_blur > 0) \
1196                                         { \
1197                                                 for(i = -2; i <= 2; ++i) \
1198                                                 for(j = -2; j <= 2; ++j) \
1199                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1200                                         } \
1201                                         else \
1202                                         { \
1203                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1204                                         } \
1205                                 } \
1206                                 while(0)
1207
1208 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1209                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1210
1211 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1212                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1213
1214                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1215                                 {
1216                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1217                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1218                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1219                                         f = 1 - f;
1220                                 }
1221                                 else
1222                                 {
1223                                         f = 1;
1224                                 }
1225                                 wcross_name_alpha_goal_prev = f;
1226
1227                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1228                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1229
1230                                 if(autocvar_crosshair_dot)
1231                                 {
1232                                         vector wcross_color_old;
1233                                         wcross_color_old = wcross_color;
1234                                         if(autocvar_crosshair_dot_color != "0")
1235                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1236                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1237                                         // FIXME why don't we use wcross_alpha here?
1238                                         wcross_color = wcross_color_old;
1239                                 }
1240                         }
1241                 }
1242                 else
1243                 {
1244                         wcross_scale_prev = 0;
1245                         wcross_alpha_prev = 0;
1246                         wcross_scale_goal_prev = 0;
1247                         wcross_alpha_goal_prev = 0;
1248                         wcross_changedonetime = 0;
1249                         if(wcross_name_goal_prev)
1250                                 strunzone(wcross_name_goal_prev);
1251                         wcross_name_goal_prev = string_null;
1252                         if(wcross_name_goal_prev_prev)
1253                                 strunzone(wcross_name_goal_prev_prev);
1254                         wcross_name_goal_prev_prev = string_null;
1255                         wcross_name_changestarttime = 0;
1256                         wcross_name_changedonetime = 0;
1257                         wcross_name_alpha_goal_prev = 0;
1258                         wcross_name_alpha_goal_prev_prev = 0;
1259                         wcross_resolution_goal_prev = 0;
1260                         wcross_resolution_goal_prev_prev = 0;
1261                 }
1262         }
1263
1264         if(NextFrameCommand)
1265         {
1266                 localcmd("\n", NextFrameCommand, "\n");
1267                 NextFrameCommand = string_null;
1268         }
1269
1270         // we must do this check AFTER a frame was rendered, or it won't work
1271         if(cs_project_is_b0rked == 0)
1272         {
1273                 string w0, h0;
1274                 w0 = ftos(autocvar_vid_conwidth);
1275                 h0 = ftos(autocvar_vid_conheight);
1276                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1277                 //R_SetView(VF_FOV, '90 90 0');
1278                 R_SetView(VF_ORIGIN, '0 0 0');
1279                 R_SetView(VF_ANGLES, '0 0 0');
1280                 R_SetView(VF_PERSPECTIVE, 1);
1281                 makevectors('0 0 0');
1282                 vector v1, v2;
1283                 cvar_set("vid_conwidth", "800");
1284                 cvar_set("vid_conheight", "600");
1285                 v1 = cs_project(v_forward);
1286                 cvar_set("vid_conwidth", "640");
1287                 cvar_set("vid_conheight", "480");
1288                 v2 = cs_project(v_forward);
1289                 if(v1 == v2)
1290                         cs_project_is_b0rked = 1;
1291                 else
1292                         cs_project_is_b0rked = -1;
1293                 cvar_set("vid_conwidth", w0);
1294                 cvar_set("vid_conheight", h0);
1295         }
1296
1297         if(autocvar__hud_configure)
1298                 HUD_Panel_Mouse();
1299
1300         // let's reset the view back to normal for the end
1301         R_SetView(VF_MIN, '0 0 0');
1302         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1303 }
1304
1305 #define spider_h "gfx/vehicles/hud_bg.tga"
1306 #define spider_b "gfx/vehicles/sbot.tga"
1307 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1308 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1309 #define spider_s "gfx/vehicles/shiled.tga"
1310 #define spider_a1 "gfx/hud/sb_rocket.tga"
1311 #define spider_a2 "gfx/sb_bullets.tga"
1312
1313 void CSQC_SPIDER_HUD()
1314 {
1315         float rockets, reload, heat, hp, shield;
1316         vector picsize, hudloc;
1317
1318     // Fetch health & ammo stats
1319     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1320         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1321         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1322         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1323         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1324
1325     // Draw the crosshairs
1326     picsize = drawgetimagesize(SPIDER_CROSS);
1327     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1328     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1329     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1330
1331     hudloc_y =  4;
1332     hudloc_x = 4;
1333
1334     picsize = drawgetimagesize(spider_h) * 0.5;
1335     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1336
1337     picsize = drawgetimagesize(spider_a2) * 0.5;
1338     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1339
1340     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1341     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1342     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1343
1344     picsize = drawgetimagesize(spider_a1) * 0.85;
1345     if(rockets == 9)
1346     {
1347         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1348         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1349     }
1350     else
1351     {
1352         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1353         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1354     }
1355
1356     picsize = drawgetimagesize(spider_b) * 0.5;
1357     hudloc_y = 10.5;
1358     hudloc_x = 10.5;
1359
1360     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1361     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1362     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1363     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1364
1365
1366         /*
1367         // Draw health bar
1368         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1369         p = p + '0 1 0' * vid_conheight - '0 32 0';
1370         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1371         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1372         p_y += 8;
1373         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1374         p_x += 256 * hp;
1375         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1376
1377         // Draw minigun heat indicator
1378         p = '0.5 0 0' * (vid_conwidth - 256);
1379         p = p + '0 1 0' * vid_conheight - '0 34  0';
1380         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1381         p_x += 256 * (1-heat);
1382         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1383
1384
1385         // Draw rocket icons for loaded/empty tubes.
1386         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1387         pp += '0 1 0' * vid_conheight - '0 64 0';
1388         for(i = 0; i < 8; ++i)
1389         {
1390                 p = pp + '1 0 0' * (rkt_size * i);
1391                 if(rockets == 8)
1392                 {
1393                         if(floor(reload * 8) == i)
1394                         {
1395                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1396                         }
1397                         else if(i < reload * 8)
1398                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1399                         else
1400                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1401                 }
1402                 else
1403                 {
1404                         if(i < rockets)
1405                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1406                         else
1407                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1408                 }
1409         }
1410         */
1411
1412         if (scoreboard_showscores)
1413         {
1414                 HUD_DrawScoreboard();
1415                 HUD_DrawCenterPrint();
1416         }
1417
1418 }
1419
1420 #define raptor_h "gfx/vehicles/hud_bg.tga"
1421 #define raptor_b "gfx/vehicles/raptor.tga"
1422 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1423 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1424 #define raptor_s "gfx/vehicles/shiled.tga"
1425
1426 void CSQC_RAPTOR_HUD()
1427 {
1428         float reload, hp, shield, energy;
1429         vector picsize, hudloc;
1430
1431     // Fetch health & ammo stats
1432     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1433         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1434         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1435         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1436
1437     // Draw the crosshairs
1438     picsize = drawgetimagesize(SPIDER_CROSS);
1439     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1440     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1441     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1442
1443     hudloc_y =  4;
1444     hudloc_x = 4;
1445
1446     picsize = drawgetimagesize(raptor_h) * 0.5;
1447     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1448
1449     picsize = drawgetimagesize(spider_a2) * 0.5;
1450     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1451
1452     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1453     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1454     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1455
1456
1457     picsize = drawgetimagesize(spider_a1) * 0.85;
1458     if(reload == 1)
1459     {
1460         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1461         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1462     }
1463     else
1464     {
1465         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1466         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1467     }
1468
1469     picsize = drawgetimagesize(raptor_b) * 0.5;
1470     hudloc_y = 10.5;
1471     hudloc_x = 10.5;
1472
1473     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1474     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1475     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1476     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1477
1478
1479         if (scoreboard_showscores)
1480         {
1481                 HUD_DrawScoreboard();
1482                 HUD_DrawCenterPrint();
1483         }
1484
1485 }
1486
1487 #define waki_h "gfx/vehicles/hud_bg.tga"
1488 #define waki_b "gfx/vehicles/waki.tga"
1489 #define waki_e "gfx/vehicles/waki_e.tga"
1490 #define waki_g "gfx/vehicles/waki_guns.tga"
1491 #define waki_r "gfx/vehicles/waki_rockets.tga"
1492 #define waki_s "gfx/vehicles/shiled.tga"
1493
1494 #define waki_a1 "gfx/hud/sb_rocket.tga"
1495 #define waki_a2 "gfx/sb_cells.tga"
1496
1497 void CSQC_WAKIZASHI_HUD()
1498 {
1499         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1500         float health, shield, energy, rockets;
1501         vector picsize, hudloc;
1502
1503     picsize = drawgetimagesize(SPIDER_CROSS);
1504     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1505     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1506     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1507
1508 /*
1509 const float STAT_VEHICLESTAT_HEALTH  = 60;
1510 const float STAT_VEHICLESTAT_SHIELD  = 61;
1511 const float STAT_VEHICLESTAT_ENERGY  = 62;
1512 const float STAT_VEHICLESTAT_AMMO1   = 63;
1513 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1514 const float STAT_VEHICLESTAT_AMMO2   = 65;
1515 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1516 */
1517     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1518         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1519         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1520         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1521
1522     hudloc_y =  4;
1523     hudloc_x = 4;
1524
1525     picsize = drawgetimagesize(waki_h) * 0.5;
1526     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1527
1528     picsize = drawgetimagesize(waki_a2) * 0.7;
1529     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1530
1531
1532     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1533     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1534
1535     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1536
1537     picsize = drawgetimagesize(waki_a1) * 0.75;
1538     if(rockets == 1)
1539     {
1540         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1541         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1542     }
1543     else
1544     {
1545         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1546         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1547         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1548     }
1549
1550     picsize = drawgetimagesize(waki_b) * 0.5;
1551     hudloc_y = 10.5;
1552     hudloc_x = 10.5;
1553
1554     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1555     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1556     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1557     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1558
1559
1560
1561         /*
1562         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1563         p = p + '0 1 0' * vid_conheight - '0 32 0';
1564
1565         // Draw health bar
1566         p_y += 8;
1567         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1568         p_x += 256 * health;
1569         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1570
1571         // Draw shiled bar
1572         p_x -= 256 * health;
1573         p_y += 4;
1574         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1575
1576         // Draw energy
1577         //p_x -= 256 * health;
1578         p_y -= 8;
1579         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1580
1581         // Draw rockets bar
1582         p_y += 12;
1583         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1584         */
1585
1586
1587
1588
1589         if (scoreboard_showscores)
1590         {
1591                 HUD_DrawScoreboard();
1592                 HUD_DrawCenterPrint();
1593         }
1594
1595 }
1596
1597 void CSQC_common_hud(void)
1598 {
1599         // HUD_SortFrags(); done in HUD_Draw
1600         float hud;
1601         hud = getstati(STAT_HUD);
1602
1603         //hud = 10;
1604         switch(hud)
1605         {
1606                 case HUD_NORMAL:
1607                         // do some accuracy var caching
1608                         float i;
1609                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1610                         {
1611                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1612                                 {
1613                                         if(acc_color_levels)
1614                                                 strunzone(acc_color_levels);
1615                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1616                                         acc_levels = tokenize(acc_color_levels);
1617                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1618                                                 acc_levels = MAX_ACCURACY_LEVELS;
1619
1620                                         for (i = 0; i < acc_levels; ++i)
1621                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1622                                 }
1623                                 // let know that acc_col[] needs to be loaded
1624                                 acc_col_x[0] = -1;
1625                         }
1626
1627                         HUD_Main(); // always run these functions for alpha checks
1628                         HUD_DrawScoreboard();
1629
1630                         if (scoreboard_active) // scoreboard/accuracy
1631                         {
1632                                 HUD_Reset();
1633                                 // HUD_DrawScoreboard takes care of centerprint_start
1634                         }
1635                         else if (intermission == 2) // map voting screen
1636                         {
1637                                 HUD_FinaleOverlay();
1638                                 HUD_Reset();
1639
1640                                 centerprint_start_x = 0;
1641                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1642                         }
1643                         else // hud
1644                         {
1645                                 centerprint_start_x = 0;
1646                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1647                         }
1648
1649                         HUD_DrawCenterPrint();
1650                         break;
1651
1652                 case HUD_SPIDERBOT:
1653                         CSQC_SPIDER_HUD();
1654                         break;
1655
1656                 case HUD_WAKIZASHI:
1657                         CSQC_WAKIZASHI_HUD();
1658                         break;
1659         }
1660 }
1661
1662
1663 // following vectors must be global to allow seamless switching between camera modes
1664 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1665 void CSQC_Demo_Camera()
1666 {
1667         float speed, attenuation, dimensions;
1668         vector tmp, delta;
1669
1670         if( autocvar_camera_reset || !camera_mode )
1671         {
1672                 camera_offset = '0 0 0';
1673                 current_angles = '0 0 0';
1674                 camera_direction = '0 0 0';
1675                 camera_offset_z += 30;
1676                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1677                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1678                 current_origin = view_origin;
1679                 current_camera_offset  = camera_offset;
1680                 cvar_set("camera_reset", "0");
1681                 camera_mode = CAMERA_CHASE;
1682         }
1683
1684         // Camera angles
1685         if( camera_roll )
1686                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1687
1688         if(autocvar_camera_look_player)
1689         {
1690                 local vector dir;
1691                 local float n;
1692
1693                 dir = normalize(view_origin - current_position);
1694                 n = mouse_angles_z;
1695                 mouse_angles = vectoangles(dir);
1696                 mouse_angles_x = mouse_angles_x * -1;
1697                 mouse_angles_z = n;
1698         }
1699         else
1700         {
1701                 tmp = getmousepos() * 0.1;
1702                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1703                 {
1704                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1705                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1706                 }
1707         }
1708
1709         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1710         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1711         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1712         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1713
1714         // Fix difference when angles don't have the same sign
1715         delta = '0 0 0';
1716         if(mouse_angles_y < -60 && current_angles_y > 60)
1717                 delta = '0 360 0';
1718         if(mouse_angles_y > 60 && current_angles_y < -60)
1719                 delta = '0 -360 0';
1720
1721         if(autocvar_camera_look_player)
1722                 attenuation = autocvar_camera_look_attenuation;
1723         else
1724                 attenuation = autocvar_camera_speed_attenuation;
1725
1726         attenuation = 1 / max(1, attenuation);
1727         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1728
1729         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1730         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1731         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1732         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1733
1734         // Camera position
1735         tmp = '0 0 0';
1736         dimensions = 0;
1737
1738         if( camera_direction_x )
1739         {
1740                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1741                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1742                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1743                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1744                 ++dimensions;
1745         }
1746
1747         if( camera_direction_y )
1748         {
1749                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1750                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1751                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1752                 ++dimensions;
1753         }
1754
1755         if( camera_direction_z )
1756         {
1757                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1758                 ++dimensions;
1759         }
1760
1761         if(autocvar_camera_free)
1762                 speed = autocvar_camera_speed_free;
1763         else
1764                 speed = autocvar_camera_speed_chase;
1765
1766         if(dimensions)
1767         {
1768                 speed = speed * sqrt(1 / dimensions);
1769                 camera_offset += tmp * speed;
1770         }
1771
1772         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1773
1774         // Camera modes
1775         if( autocvar_camera_free )
1776         {
1777                 if ( camera_mode == CAMERA_CHASE )
1778                 {
1779                         current_camera_offset = current_origin + current_camera_offset;
1780                         camera_offset = current_origin + camera_offset;
1781                 }
1782
1783                 camera_mode = CAMERA_FREE;
1784                 current_position = current_camera_offset;
1785         }
1786         else
1787         {
1788                 if ( camera_mode == CAMERA_FREE )
1789                 {
1790                         current_origin = view_origin;
1791                         camera_offset = camera_offset - current_origin;
1792                         current_camera_offset = current_camera_offset - current_origin;
1793                 }
1794
1795                 camera_mode = CAMERA_CHASE;
1796
1797                 if(autocvar_camera_chase_smoothly)
1798                         current_origin += (view_origin - current_origin) * attenuation;
1799                 else
1800                         current_origin = view_origin;
1801
1802                 current_position = current_origin + current_camera_offset;
1803         }
1804
1805         R_SetView(VF_ANGLES, current_angles);
1806         R_SetView(VF_ORIGIN, current_position);
1807 }