qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107         if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir) { zoomin_effect = 0; }
 127
 128         if(camera_active)
 129         {
 130                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 131         }
 132         else if(autocvar_cl_spawnzoom && zoomin_effect)
 133         {
 134                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 135
 136                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 137                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 138                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 139         }
 140         else
 141         {
 142                 if(zoomspeed < 0) // instant zoom
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / zoomfactor;
 146                         else
 147                                 current_viewzoom = 1;
 148                 }
 149                 else
 150                 {
 151                         if(zoomdir)
 152                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 153                         else
 154                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 155                 }
 156         }
 157
 158         if(almost_equals(current_viewzoom, 1))
 159                 current_zoomfraction = 0;
 160         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 161                 current_zoomfraction = 1;
 162         else
 163                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 164
 165         if(zoomsensitivity < 1)
 166                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 167         else
 168                 setsensitivityscale(1);
 169
 170         makevectors(view_angles);
 171
 172         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 173         {
 174                 v = pmove_vel;
 175                 if(csqcplayer)
 176                         v = csqcplayer.velocity;
 177
 178                 switch(autocvar_cl_velocityzoom_type)
 179                 {
 180                         case 3: curspeed = max(0, v_forward * v); break;
 181                         case 2: curspeed = (v_forward * v); break;
 182                         case 1: default: curspeed = vlen(v); break;
 183                 }
 184
 185                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 186                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 187                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 188
 189                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 190         }
 191         else
 192                 velocityzoom = 1;
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217
 218 float wcross_ring_prev;
 219
 220 entity trueaim;
 221 entity trueaim_rifle;
 222
 223 #define SHOTTYPE_HITTEAM 1
 224 #define SHOTTYPE_HITOBSTRUCTION 2
 225 #define SHOTTYPE_HITWORLD 3
 226 #define SHOTTYPE_HITENEMY 4
 227
 228 void TrueAim_Init()
 229 {
 230         trueaim = spawn();
 231         trueaim.classname = "trueaim";
 232         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233         trueaim_rifle = spawn();
 234         trueaim_rifle.classname = "trueaim_rifle";
 235         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 236 }
 237
 238 float EnemyHitCheck()
 239 {
 240         float t, n;
 241         wcross_origin = project_3d_to_2d(trace_endpos);
 242         wcross_origin_z = 0;
 243         if(trace_ent)
 244                 n = trace_ent.entnum;
 245         else
 246                 n = trace_networkentity;
 247         if(n < 1)
 248                 return SHOTTYPE_HITWORLD;
 249         if(n > maxclients)
 250                 return SHOTTYPE_HITWORLD;
 251         t = GetPlayerColor(n - 1);
 252         if(teamplay)
 253                 if(t == myteam)
 254                         return SHOTTYPE_HITTEAM;
 255         if(t == NUM_SPECTATOR)
 256                 return SHOTTYPE_HITWORLD;
 257         return SHOTTYPE_HITENEMY;
 258 }
 259
 260 float TrueAimCheck()
 261 {
 262         float nudge = 1; // added to traceline target and subtracted from result
 263         vector vecs, trueaimpoint, w_shotorg;
 264         vector mi, ma, dv;
 265         float shottype;
 266         entity ta;
 267         float mv;
 268
 269         mi = ma = '0 0 0';
 270         ta = trueaim;
 271         mv = MOVE_NOMONSTERS;
 272
 273         switch(activeweapon)
 274         {
 275                 case WEP_TUBA: // no aim
 276                 case WEP_PORTO: // shoots from eye
 277                 case WEP_HOOK: // no trueaim
 278                 case WEP_GRENADE_LAUNCHER: // toss curve
 279                         return SHOTTYPE_HITWORLD;
 280                 case WEP_NEX:
 281                 case WEP_MINSTANEX:
 282                         mv = MOVE_NORMAL;
 283                         break;
 284                 case WEP_RIFLE:
 285                         ta = trueaim_rifle;
 286                         mv = MOVE_NORMAL;
 287                         if(zoomscript_caught)
 288                         {
 289                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 290                                 return EnemyHitCheck();
 291                         }
 292                         break;
 293                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 294                         mi = '-3 -3 -3';
 295                         ma = '3 3 3';
 296                         break;
 297                 case WEP_FIREBALL: // projectile has a size!
 298                         mi = '-16 -16 -16';
 299                         ma = '16 16 16';
 300                         break;
 301                 case WEP_SEEKER: // projectile has a size!
 302                         mi = '-2 -2 -2';
 303                         ma = '2 2 2';
 304                         break;
 305                 case WEP_ELECTRO: // projectile has a size!
 306                         mi = '0 0 -3';
 307                         ma = '0 0 -3';
 308                         break;
 309         }
 310
 311         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 312
 313         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 314         trueaimpoint = trace_endpos;
 315
 316         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 317                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 318
 319         if(vecs_x > 0)
 320                 vecs_y = -vecs_y;
 321         else
 322                 vecs = '0 0 0';
 323
 324         dv = view_right * vecs_y + view_up * vecs_z;
 325         w_shotorg = view_origin + dv;
 326
 327         // now move the vecs forward as much as requested if possible
 328         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 329         w_shotorg = trace_endpos - view_forward * nudge;
 330
 331         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 332         shottype = EnemyHitCheck();
 333         if(shottype != SHOTTYPE_HITWORLD)
 334                 return shottype;
 335
 336 #if 0
 337         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 338         // or rather, I know why, but see no fix
 339         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 340                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 341                 return SHOTTYPE_HITOBSTRUCTION;
 342 #endif
 343
 344         return SHOTTYPE_HITWORLD;
 345 }
 346
 347 void CSQC_common_hud(void);
 348
 349 void PostInit(void);
 350 void CSQC_Demo_Camera();
 351 float HUD_WouldDrawScoreboard();
 352 float camera_mode;
 353 float CAMERA_FREE = 1;
 354 float CAMERA_CHASE = 2;
 355 float reticle_type;
 356 string NextFrameCommand;
 357 void CSQC_SPIDER_HUD();
 358 void CSQC_RAPTOR_HUD();
 359
 360 vector freeze_org, freeze_ang;
 361 entity nightvision_noise, nightvision_noise2;
 362
 363 #define MAX_TIME_DIFF 5
 364 float pickup_crosshair_time, pickup_crosshair_size;
 365 float hit_time, typehit_time;
 366 float nextsound_hit_time, nextsound_typehit_time;
 367 float hitindication_crosshair_time, hitindication_crosshair_size;
 368 float use_nex_chargepool;
 369
 370 float myhealth, myhealth_prev;
 371 float myhealth_flash;
 372
 373 float old_blurradius, old_bluralpha;
 374 float old_sharpen_intensity;
 375
 376 vector myhealth_gentlergb;
 377
 378 float contentavgalpha, liquidalpha_prev;
 379 vector liquidcolor_prev;
 380
 381 float eventchase_current_distance;
 382
 383 vector damage_blurpostprocess, content_blurpostprocess;
 384
 385 float checkfail[16];
 386
 387 float rainbow_last_flicker;
 388 vector rainbow_prev_color;
 389
 390 #define BUTTON_3 4
 391 #define BUTTON_4 8
 392 float cl_notice_run();
 393 float prev_myteam;
 394 void CSQC_UpdateView(float w, float h)
 395 {
 396         entity e;
 397         float fov;
 398         float f, i, j;
 399         vector v;
 400         vector vf_size, vf_min;
 401         float a;
 402
 403         execute_next_frame();
 404
 405         ++framecount;
 406
 407         hud = getstati(STAT_HUD);
 408
 409         if(autocvar__hud_showbinds_reload) // menu can set this one
 410         {
 411                 db_close(binddb);
 412                 binddb = db_create();
 413                 cvar_set("_hud_showbinds_reload", "0");
 414         }
 415
 416         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 417                 view_quality = getproperty(VF_MINFPS_QUALITY);
 418         else
 419                 view_quality = 1;
 420
 421         button_attack2 = (input_buttons & BUTTON_3);
 422         button_zoom = (input_buttons & BUTTON_4);
 423
 424 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 425         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 426         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 427         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 428         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 429         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 430         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 431         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 432
 433         vf_size = getpropertyvec(VF_SIZE);
 434         vf_min = getpropertyvec(VF_MIN);
 435         vid_width = vf_size_x;
 436         vid_height = vf_size_y;
 437
 438         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 439         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 440
 441         WaypointSprite_Load();
 442
 443         CSQCPlayer_SetCamera();
 444
 445 #ifdef COMPAT_XON050_ENGINE
 446         if(spectatee_status)
 447                 myteam = GetPlayerColor(spectatee_status - 1);
 448         else
 449 #endif
 450                 myteam = GetPlayerColor(player_localentnum - 1);
 451
 452         if(myteam != prev_myteam)
 453         {
 454                 myteamcolors = colormapPaletteColor(myteam, 1);
 455                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 456                         hud_panel[i].update_time = time;
 457                 prev_myteam = myteam;
 458         }
 459
 460         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 461
 462         float is_dead = (getstati(STAT_HEALTH) <= 0);
 463
 464         // FIXME do we need this hack?
 465         if(isdemo())
 466         {
 467                 // in demos, input_buttons do not work
 468                 button_zoom = (autocvar__togglezoom == "-");
 469         }
 470         else if(button_zoom
 471                 && autocvar_cl_unpress_zoom_on_death
 472                 && (spectatee_status >= 0)
 473                 && (is_dead || intermission))
 474         {
 475                 // no zoom while dead or in intermission please
 476                 localcmd("-zoom\n");
 477                 button_zoom = FALSE;
 478         }
 479
 480         // event chase camera
 481         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 482         {
 483                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead) || intermission)
 484                 {
 485                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 486                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_cl_eventchase_viewoffset);
 487
 488                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 489                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 490                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 491                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 492
 493                         // make the camera smooth back
 494                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 495                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 496                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 497                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 498
 499                         makevectors(view_angles);
 500
 501                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 502                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 503
 504                         // If the boxtrace fails, revert back to line tracing.
 505                         if(trace_startsolid)
 506                         {
 507                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 508                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 509                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 510                         }
 511                         else { setproperty(VF_ORIGIN, trace_endpos); }
 512
 513                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 514                 }
 515                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 516                 {
 517                         cvar_set("chase_active", "0");
 518                         eventchase_current_distance = 0; // start from 0 next time
 519                 }
 520         }
 521         // workaround for camera stuck between player's legs when using chase_active 1
 522         // because the engine stops updating the chase_active camera when the game ends
 523         else if(intermission)
 524         {
 525                 cvar_settemp("chase_active", "-1");
 526                 eventchase_current_distance = 0;
 527         }
 528
 529         // do lockview after event chase camera so that it still applies whenever necessary.
 530         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 531         {
 532                 setproperty(VF_ORIGIN, freeze_org);
 533                 setproperty(VF_ANGLES, freeze_ang);
 534         }
 535         else
 536         {
 537                 freeze_org = getpropertyvec(VF_ORIGIN);
 538                 freeze_ang = getpropertyvec(VF_ANGLES);
 539         }
 540
 541         WarpZone_FixView();
 542         //WarpZone_FixPMove();
 543
 544         // Render the Scene
 545         view_origin = getpropertyvec(VF_ORIGIN);
 546         view_angles = getpropertyvec(VF_ANGLES);
 547         makevectors(view_angles);
 548         view_forward = v_forward;
 549         view_right = v_right;
 550         view_up = v_up;
 551
 552 #ifdef BLURTEST
 553         if(time > blurtest_time0 && time < blurtest_time1)
 554         {
 555                 float r, t;
 556
 557                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 558                 r = t * blurtest_radius;
 559                 f = 1 / pow(t, blurtest_power) - 1;
 560
 561                 cvar_set("r_glsl_postprocess", "1");
 562                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 563         }
 564         else
 565         {
 566                 cvar_set("r_glsl_postprocess", "0");
 567                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 568         }
 569 #endif
 570
 571         TargetMusic_Advance();
 572         Fog_Force();
 573
 574         if(drawtime == 0)
 575                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 576         else
 577                 drawframetime = bound(0.000001, time - drawtime, 1);
 578         drawtime = time;
 579
 580         // watch for gametype changes here...
 581         // in ParseStuffCMD the cmd isn't executed yet :/
 582         // might even be better to add the gametype to TE_CSQC_INIT...?
 583         if(!postinit)
 584                 PostInit();
 585
 586         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 587         {
 588                 if(calledhooks & HOOK_START)
 589                 {
 590                         localcmd("\ncl_hook_gameend\n");
 591                         calledhooks |= HOOK_END;
 592                 }
 593         }
 594
 595         Announcer();
 596
 597         fov = autocvar_fov;
 598         if(fov <= 59.5)
 599         {
 600                 if(!zoomscript_caught)
 601                 {
 602                         localcmd("+button9\n");
 603                         zoomscript_caught = 1;
 604                 }
 605         }
 606         else
 607         {
 608                 if(zoomscript_caught)
 609                 {
 610                         localcmd("-button9\n");
 611                         zoomscript_caught = 0;
 612                 }
 613         }
 614
 615         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 616
 617         // next WANTED weapon (for HUD)
 618         switchweapon = getstati(STAT_SWITCHWEAPON);
 619
 620         // currently switching-to weapon (for crosshair)
 621         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 622
 623         // actually active weapon (for zoom)
 624         activeweapon = getstati(STAT_ACTIVEWEAPON);
 625
 626         f = (serverflags & SERVERFLAG_TEAMPLAY);
 627         if(f != teamplay)
 628         {
 629                 teamplay = f;
 630                 HUD_InitScores();
 631         }
 632
 633         if(last_switchweapon != switchweapon)
 634         {
 635                 weapontime = time;
 636                 last_switchweapon = switchweapon;
 637                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 638                 {
 639                         localcmd("-zoom\n");
 640                         button_zoom = FALSE;
 641                 }
 642                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 643                 {
 644                         localcmd("-fire\n");
 645                         localcmd("-fire2\n");
 646                         button_attack2 = FALSE;
 647                 }
 648         }
 649         if(last_activeweapon != activeweapon)
 650         {
 651                 last_activeweapon = activeweapon;
 652
 653                 e = get_weaponinfo(activeweapon);
 654                 if(e.netname != "")
 655                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 656                 else
 657                         localcmd("\ncl_hook_activeweapon none\n");
 658         }
 659
 660         // ALWAYS Clear Current Scene First
 661         clearscene();
 662 #ifdef WORKAROUND_XON010
 663         if(checkextension("DP_CSQC_ROTATEMOVES"))
 664         {
 665 #endif
 666         setproperty(VF_ORIGIN, view_origin);
 667         setproperty(VF_ANGLES, view_angles);
 668 #ifdef WORKAROUND_XON010
 669         }
 670 #endif
 671
 672         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 673         setproperty(VF_SIZE, vf_size);
 674         setproperty(VF_MIN, vf_min);
 675
 676         // Assign Standard Viewflags
 677         // Draw the World (and sky)
 678         setproperty(VF_DRAWWORLD, 1);
 679
 680         // Set the console size vars
 681         vid_conwidth = autocvar_vid_conwidth;
 682         vid_conheight = autocvar_vid_conheight;
 683         vid_pixelheight = autocvar_vid_pixelheight;
 684
 685         setproperty(VF_FOV, GetCurrentFov(fov));
 686
 687         // Camera for demo playback
 688         if(camera_active)
 689         {
 690                 if(autocvar_camera_enable)
 691                         CSQC_Demo_Camera();
 692                 else
 693                 {
 694                         cvar_set("chase_active", ftos(chase_active_backup));
 695                         cvar_set("cl_demo_mousegrab", "0");
 696                         camera_active = FALSE;
 697                 }
 698         }
 699 #ifdef CAMERATEST
 700         else if(autocvar_camera_enable)
 701 #else
 702         else if(autocvar_camera_enable && isdemo())
 703 #endif
 704         {
 705                 // Enable required Darkplaces cvars
 706                 chase_active_backup = autocvar_chase_active;
 707                 cvar_set("chase_active", "2");
 708                 cvar_set("cl_demo_mousegrab", "1");
 709                 camera_active = TRUE;
 710                 camera_mode = FALSE;
 711         }
 712
 713         // Draw the Crosshair
 714         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 715
 716         // Draw the Engine Status Bar (the default Quake HUD)
 717         setproperty(VF_DRAWENGINESBAR, 0);
 718
 719         // Update the mouse position
 720         /*
 721            mousepos_x = vid_conwidth;
 722            mousepos_y = vid_conheight;
 723            mousepos = mousepos*0.5 + getmousepos();
 724          */
 725
 726         e = self;
 727         for(self = world; (self = nextent(self)); )
 728                 if(self.draw)
 729                         self.draw();
 730         self = e;
 731
 732         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 733         renderscene();
 734
 735         // now switch to 2D drawing mode by calling a 2D drawing function
 736         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 737         // next R_RenderScene call
 738         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 739
 740         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 741         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 742         {
 743                 // apply night vision effect
 744                 vector tc_00, tc_01, tc_10, tc_11;
 745                 vector rgb;
 746                 rgb_x = 0; // fteqcc sucks
 747                 rgb_y = 0; // fteqcc sucks
 748                 rgb_z = 0; // fteqcc sucks
 749
 750                 if(!nightvision_noise)
 751                 {
 752                         nightvision_noise = spawn();
 753                         nightvision_noise.classname = "nightvision_noise";
 754                 }
 755                 if(!nightvision_noise2)
 756                 {
 757                         nightvision_noise2 = spawn();
 758                         nightvision_noise2.classname = "nightvision_noise2";
 759                 }
 760
 761                 // color tint in yellow
 762                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 763
 764                 // draw BG
 765                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 766                 rgb = '1 1 1';
 767                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 768                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 769                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 770                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 771                 tc_11 = tc_01 + tc_10 - tc_00;
 772                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 773                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 774                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 775                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 776                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 777                 R_EndPolygon();
 778
 779                 // draw FG
 780                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 781                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 782                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 783                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 784                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 785                 tc_11 = tc_01 + tc_10 - tc_00;
 786                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 787                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 788                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 789                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 790                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 791                 R_EndPolygon();
 792         }
 793
 794         // Draw the aiming reticle for weapons that use it
 795         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 796         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 797         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 798         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 799                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 800         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 801                 reticle_type = 2; // nex zoom
 802         else if(button_zoom || zoomscript_caught)
 803                 reticle_type = 1; // normal zoom
 804         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 805                 reticle_type = 2; // nex zoom
 806
 807         if(reticle_type && autocvar_cl_reticle)
 808         {
 809                 if(autocvar_cl_reticle_stretch)
 810                 {
 811                         reticle_size_x = vid_conwidth;
 812                         reticle_size_y = vid_conheight;
 813                         reticle_pos_x = 0;
 814                         reticle_pos_y = 0;
 815                 }
 816                 else
 817                 {
 818                         reticle_size_x = max(vid_conwidth, vid_conheight);
 819                         reticle_size_y = max(vid_conwidth, vid_conheight);
 820                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 821                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 822                 }
 823
 824                 f = current_zoomfraction;
 825                 if(zoomscript_caught)
 826                         f = 1;
 827                 if(autocvar_cl_reticle_item_normal)
 828                 {
 829                         if(reticle_type == 1 && f)
 830                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 831                 }
 832                 if(autocvar_cl_reticle_item_nex)
 833                 {
 834                         if(reticle_type == 2 && f)
 835                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 836                 }
 837         }
 838
 839
 840         // improved polyblend
 841         if(autocvar_hud_contents)
 842         {
 843                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 844                 vector liquidcolor;
 845
 846                 switch(pointcontents(view_origin))
 847                 {
 848                         case CONTENT_WATER:
 849                                 liquidalpha = autocvar_hud_contents_water_alpha;
 850                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 851                                 incontent = 1;
 852                                 break;
 853
 854                         case CONTENT_LAVA:
 855                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 856                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 857                                 incontent = 1;
 858                                 break;
 859
 860                         case CONTENT_SLIME:
 861                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 862                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 863                                 incontent = 1;
 864                                 break;
 865
 866                         default:
 867                                 liquidalpha = 0;
 868                                 liquidcolor = '0 0 0';
 869                                 incontent = 0;
 870                                 break;
 871                 }
 872
 873                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 874                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 875                         contentfadetime = autocvar_hud_contents_fadeintime;
 876                         liquidalpha_prev = liquidalpha;
 877                         liquidcolor_prev = liquidcolor;
 878                 }
 879                 else
 880                         contentfadetime = autocvar_hud_contents_fadeouttime;
 881
 882                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 883                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 884
 885                 if(contentavgalpha)
 886                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 887
 888                 if(autocvar_hud_postprocessing)
 889                 {
 890                         if(autocvar_hud_contents_blur && contentavgalpha)
 891                         {
 892                                 content_blurpostprocess_x = 1;
 893                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 894                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 895                         }
 896                         else
 897                         {
 898                                 content_blurpostprocess_x = 0;
 899                                 content_blurpostprocess_y = 0;
 900                                 content_blurpostprocess_z = 0;
 901                         }
 902                 }
 903         }
 904
 905         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 906         {
 907                 splash_size_x = max(vid_conwidth, vid_conheight);
 908                 splash_size_y = max(vid_conwidth, vid_conheight);
 909                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 910                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 911
 912                 float myhealth_flash_temp;
 913                 myhealth = getstati(STAT_HEALTH);
 914
 915                 // fade out
 916                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 917                 // add new damage
 918                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 919
 920                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 921                 pain_threshold = autocvar_hud_damage_pain_threshold;
 922                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 923                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 924
 925                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 926                 {
 927                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 928                 }
 929
 930                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 931
 932                 if(myhealth_prev < 1)
 933                 {
 934                         if(myhealth >= 1)
 935                         {
 936                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 937                                 myhealth_flash_temp = 0;
 938                         }
 939                         else
 940                         {
 941                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 942                         }
 943                 }
 944
 945                 if(spectatee_status == -1 || intermission)
 946                 {
 947                         myhealth_flash = 0; // observing, or match ended
 948                         myhealth_flash_temp = 0;
 949                 }
 950
 951                 myhealth_prev = myhealth;
 952
 953                 // IDEA: change damage color/picture based on player model for robot/alien species?
 954                 // pro: matches model better
 955                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 956                 // maybe different reddish pics?
 957                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 958                 {
 959                         if(autocvar_cl_gentle_damage == 2)
 960                         {
 961                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 962                                 {
 963                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 964                                 }
 965                         }
 966                         else
 967                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 968
 969                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 970                 }
 971                 else
 972                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 973
 974                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 975                 {
 976                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 977                         {
 978                                 damage_blurpostprocess_x = 1;
 979                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 980                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 981                         }
 982                         else
 983                         {
 984                                 damage_blurpostprocess_x = 0;
 985                                 damage_blurpostprocess_y = 0;
 986                                 damage_blurpostprocess_z = 0;
 987                         }
 988                 }
 989         }
 990
 991         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 992         float e2 = (autocvar_hud_powerup != 0);
 993         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 994         {
 995                 // enable or disable rendering types if they are used or not
 996                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 997                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 998
 999                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1000                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1001                 {
1002                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1003                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1004                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1005                         {
1006                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1007                                 old_blurradius = blurradius;
1008                                 old_bluralpha = bluralpha;
1009                         }
1010                 }
1011                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1012                 {
1013                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1014                         old_blurradius = 0;
1015                         old_bluralpha = 0;
1016                 }
1017
1018                 // edge detection postprocess handling done second (used by hud_powerup)
1019                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1020                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1021                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1022
1023                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1024
1025                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1026                 {
1027                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1028                         {
1029                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1030                                 old_sharpen_intensity = sharpen_intensity;
1031                         }
1032                 }
1033                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1034                 {
1035                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1036                         old_sharpen_intensity = 0;
1037                 }
1038
1039                 if(cvar("r_glsl_postprocess") == 0)
1040                         cvar_set("r_glsl_postprocess", "2");
1041         }
1042         else if(cvar("r_glsl_postprocess") == 2)
1043                 cvar_set("r_glsl_postprocess", "0");
1044
1045         if(menu_visible)
1046                 menu_show();
1047
1048         /*if(gametype == MAPINFO_TYPE_CTF)
1049           {
1050           ctf_view();
1051           } else */
1052
1053         // draw 2D entities
1054         e = self;
1055         for(self = world; (self = nextent(self)); )
1056                 if(self.draw2d)
1057                         self.draw2d();
1058         self = e;
1059         Draw_ShowNames_All();
1060
1061         scoreboard_active = HUD_WouldDrawScoreboard();
1062
1063         hit_time = getstatf(STAT_HIT_TIME);
1064         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1065         {
1066                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1067                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1068
1069                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1070         }
1071         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1072         if(typehit_time > nextsound_typehit_time)
1073         {
1074                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1075                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1076
1077                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1078         }
1079
1080         //else
1081         {
1082                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1083                 {
1084                         if(getstati(STAT_FROZEN))
1085                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1086                         if(getstatf(STAT_REVIVE_PROGRESS))
1087                         {
1088                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1089                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1090                         }
1091                 }
1092
1093                 if(autocvar_r_letterbox == 0)
1094                         if(autocvar_viewsize < 120)
1095                                 CSQC_common_hud();
1096
1097                 // crosshair goes VERY LAST
1098                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1099                 {
1100                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1101                                 return;
1102
1103                         string wcross_style;
1104                         float wcross_alpha, wcross_resolution;
1105                         wcross_style = autocvar_crosshair;
1106                         if (wcross_style == "0")
1107                                 return;
1108                         wcross_resolution = autocvar_crosshair_size;
1109                         if (wcross_resolution == 0)
1110                                 return;
1111                         wcross_alpha = autocvar_crosshair_alpha;
1112                         if (wcross_alpha == 0)
1113                                 return;
1114
1115                         // TrueAim check
1116                         float shottype;
1117
1118                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1119                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1120                         wcross_origin_z = 0;
1121                         if(autocvar_crosshair_hittest)
1122                         {
1123                                 vector wcross_oldorigin;
1124                                 wcross_oldorigin = wcross_origin;
1125                                 shottype = TrueAimCheck();
1126                                 if(shottype == SHOTTYPE_HITWORLD)
1127                                 {
1128                                         v = wcross_origin - wcross_oldorigin;
1129                                         v_x /= vid_conwidth;
1130                                         v_y /= vid_conheight;
1131                                         if(vlen(v) > 0.01)
1132                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1133                                 }
1134                                 if(!autocvar_crosshair_hittest_showimpact)
1135                                         wcross_origin = wcross_oldorigin;
1136                         }
1137                         else
1138                                 shottype = SHOTTYPE_HITWORLD;
1139
1140                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1141                         string wcross_wep = "", wcross_name;
1142                         float wcross_scale, wcross_blur;
1143
1144                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1145                         {
1146                                 e = get_weaponinfo(switchingweapon);
1147                                 if (e && e.netname != "")
1148                                 {
1149                                         wcross_wep = e.netname;
1150                                         if(autocvar_crosshair_per_weapon)
1151                                         {
1152                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1153                                                 if (wcross_resolution == 0)
1154                                                         return;
1155                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1156                                                 if (wcross_alpha == 0)
1157                                                         return;
1158
1159                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1160                                                 if(wcross_style == "" || wcross_style == "0")
1161                                                         wcross_style = wcross_wep;
1162                                         }
1163                                 }
1164                         }
1165
1166                         //print(sprintf("crosshair style: %s\n", wcross_style));
1167                         wcross_name = strcat("gfx/crosshair", wcross_style);
1168
1169                         // MAIN CROSSHAIR COLOR DECISION
1170                         switch(autocvar_crosshair_color_special)
1171                         {
1172                                 case 1: // crosshair_color_per_weapon
1173                                 {
1174                                         if(wcross_wep != "")
1175                                         {
1176                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1177                                                 break;
1178                                         }
1179                                         else { goto normalcolor; }
1180                                 }
1181
1182                                 case 2: // crosshair_color_by_health
1183                                 {
1184                                         float x = getstati(STAT_HEALTH);
1185
1186                                         //x = red
1187                                         //y = green
1188                                         //z = blue
1189
1190                                         wcross_color_z = 0;
1191
1192                                         if(x > 200)
1193                                         {
1194                                                 wcross_color_x = 0;
1195                                                 wcross_color_y = 1;
1196                                         }
1197                                         else if(x > 150)
1198                                         {
1199                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1200                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1201                                         }
1202                                         else if(x > 100)
1203                                         {
1204                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1205                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1206                                                 wcross_color_z = 1 - (x-100)*0.02;
1207                                         }
1208                                         else if(x > 50)
1209                                         {
1210                                                 wcross_color_x = 1;
1211                                                 wcross_color_y = 1;
1212                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1213                                         }
1214                                         else if(x > 20)
1215                                         {
1216                                                 wcross_color_x = 1;
1217                                                 wcross_color_y = (x-20)*90/27/100;
1218                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1219                                         }
1220                                         else
1221                                         {
1222                                                 wcross_color_x = 1;
1223                                                 wcross_color_y = 0;
1224                                         }
1225                                         break;
1226                                 }
1227
1228                                 case 3: // crosshair_color_rainbow
1229                                 {
1230                                         if(time >= rainbow_last_flicker)
1231                                         {
1232                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1233                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1234                                         }
1235                                         wcross_color = rainbow_prev_color;
1236                                         break;
1237                                 }
1238                                 :normalcolor
1239                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1240                         }
1241
1242                         if(autocvar_crosshair_effect_scalefade)
1243                         {
1244                                 wcross_scale = wcross_resolution;
1245                                 wcross_resolution = 1;
1246                         }
1247                         else
1248                         {
1249                                 wcross_scale = 1;
1250                         }
1251
1252                         if(autocvar_crosshair_pickup)
1253                         {
1254                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1255
1256                                 if(pickup_crosshair_time < stat_pickup_time)
1257                                 {
1258                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1259                                                 pickup_crosshair_size = 1;
1260
1261                                         pickup_crosshair_time = stat_pickup_time;
1262                                 }
1263
1264                                 if(pickup_crosshair_size > 0)
1265                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1266                                 else
1267                                         pickup_crosshair_size = 0;
1268
1269                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1270                         }
1271
1272                         if(autocvar_crosshair_hitindication)
1273                         {
1274                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1275
1276                                 if(hitindication_crosshair_time < hit_time)
1277                                 {
1278                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1279                                                 hitindication_crosshair_size = 1;
1280
1281                                         hitindication_crosshair_time = hit_time;
1282                                 }
1283
1284                                 if(hitindication_crosshair_size > 0)
1285                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1286                                 else
1287                                         hitindication_crosshair_size = 0;
1288
1289                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1290                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1291                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1292                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1293                         }
1294
1295                         if(shottype == SHOTTYPE_HITENEMY)
1296                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1297                         if(shottype == SHOTTYPE_HITTEAM)
1298                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1299
1300                         f = fabs(autocvar_crosshair_effect_time);
1301                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1302                         {
1303                                 wcross_changedonetime = time + f;
1304                         }
1305                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1306                         {
1307                                 wcross_name_changestarttime = time;
1308                                 wcross_name_changedonetime = time + f;
1309                                 if(wcross_name_goal_prev_prev)
1310                                         strunzone(wcross_name_goal_prev_prev);
1311                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1312                                 wcross_name_goal_prev = strzone(wcross_name);
1313                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1314                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1315                                 wcross_resolution_goal_prev = wcross_resolution;
1316                         }
1317
1318                         wcross_scale_goal_prev = wcross_scale;
1319                         wcross_alpha_goal_prev = wcross_alpha;
1320                         wcross_color_goal_prev = wcross_color;
1321
1322                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1323                         {
1324                                 wcross_blur = 1;
1325                                 wcross_alpha *= 0.75;
1326                         }
1327                         else
1328                                 wcross_blur = 0;
1329                         // *_prev is at time-frametime
1330                         // * is at wcross_changedonetime+f
1331                         // what do we have at time?
1332                         if(time < wcross_changedonetime)
1333                         {
1334                                 f = frametime / (wcross_changedonetime - time + frametime);
1335                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1336                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1337                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1338                         }
1339
1340                         wcross_scale_prev = wcross_scale;
1341                         wcross_alpha_prev = wcross_alpha;
1342                         wcross_color_prev = wcross_color;
1343
1344                         wcross_scale *= 1 - autocvar__menu_alpha;
1345                         wcross_alpha *= 1 - autocvar__menu_alpha;
1346                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1347
1348                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1349                         {
1350                                 // crosshair rings for weapon stats
1351                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1352                                 {
1353                                         // declarations and stats
1354                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1355                                         string ring_image = string_null, ring_inner_image = string_null;
1356                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1357
1358                                         ring_scale = autocvar_crosshair_ring_size;
1359
1360                                         float weapon_clipload, weapon_clipsize;
1361                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1362                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1363
1364                                         float nex_charge, nex_chargepool;
1365                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1366                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1367
1368                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1369                                                 nex_charge_movingavg = nex_charge;
1370
1371
1372                                         // handle the values
1373                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1374                                         {
1375                                                 if (nex_chargepool || use_nex_chargepool) {
1376                                                         use_nex_chargepool = 1;
1377                                                         ring_inner_value = nex_chargepool;
1378                                                 } else {
1379                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1380                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1381                                                 }
1382
1383                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1384                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1385                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1386
1387                                                 // draw the outer ring to show the current charge of the weapon
1388                                                 ring_value = nex_charge;
1389                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1390                                                 ring_rgb = wcross_color;
1391                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1392                                         }
1393                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1394                                         {
1395                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1396                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1397                                                 ring_rgb = wcross_color;
1398                                                 ring_image = "gfx/crosshair_ring.tga";
1399                                         }
1400                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1401                                         {
1402                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1403                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1404                                                 ring_rgb = wcross_color;
1405                                                 ring_image = "gfx/crosshair_ring.tga";
1406                                         }
1407
1408                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1409                                         {
1410                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1411                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1412                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1413                                                 ring_rgb = wcross_color;
1414
1415                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1416                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1417                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1418                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1419                                                 else
1420                                                         ring_image = "gfx/crosshair_ring.tga";
1421                                         }
1422
1423                                         // if in weapon switch animation, fade ring out/in
1424                                         if(autocvar_crosshair_effect_time > 0)
1425                                         {
1426                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1427                                                 if not(f < 1)
1428                                                 {
1429                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1430                                                 }
1431
1432                                                 if(wcross_ring_prev)
1433                                                 {
1434                                                         if(f < 1)
1435                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1436                                                 }
1437                                                 else
1438                                                 {
1439                                                         if(f < 1)
1440                                                                 ring_alpha *= bound(0, f, 1);
1441                                                 }
1442                                         }
1443
1444                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1445                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1446
1447                                         if (ring_value)
1448                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1449                                 }
1450
1451 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1452                                 do \
1453                                 { \
1454                                         if(wcross_blur > 0) \
1455                                         { \
1456                                                 for(i = -2; i <= 2; ++i) \
1457                                                 for(j = -2; j <= 2; ++j) \
1458                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1459                                         } \
1460                                         else \
1461                                         { \
1462                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1463                                         } \
1464                                 } \
1465                                 while(0)
1466
1467 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1468                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1469
1470 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1471                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1472
1473                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1474                                 {
1475                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1476                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1477                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1478                                         f = 1 - f;
1479                                 }
1480                                 else
1481                                 {
1482                                         f = 1;
1483                                 }
1484                                 wcross_name_alpha_goal_prev = f;
1485
1486                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1487                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1488
1489                                 if(autocvar_crosshair_dot)
1490                                 {
1491                                         vector wcross_color_old;
1492                                         wcross_color_old = wcross_color;
1493
1494                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1495                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1496
1497                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1498                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1499                                         wcross_color = wcross_color_old;
1500                                 }
1501                         }
1502                 }
1503                 else
1504                 {
1505                         wcross_scale_prev = 0;
1506                         wcross_alpha_prev = 0;
1507                         wcross_scale_goal_prev = 0;
1508                         wcross_alpha_goal_prev = 0;
1509                         wcross_changedonetime = 0;
1510                         if(wcross_name_goal_prev)
1511                                 strunzone(wcross_name_goal_prev);
1512                         wcross_name_goal_prev = string_null;
1513                         if(wcross_name_goal_prev_prev)
1514                                 strunzone(wcross_name_goal_prev_prev);
1515                         wcross_name_goal_prev_prev = string_null;
1516                         wcross_name_changestarttime = 0;
1517                         wcross_name_changedonetime = 0;
1518                         wcross_name_alpha_goal_prev = 0;
1519                         wcross_name_alpha_goal_prev_prev = 0;
1520                         wcross_resolution_goal_prev = 0;
1521                         wcross_resolution_goal_prev_prev = 0;
1522                 }
1523         }
1524
1525         if(NextFrameCommand)
1526         {
1527                 localcmd("\n", NextFrameCommand, "\n");
1528                 NextFrameCommand = string_null;
1529         }
1530
1531         // we must do this check AFTER a frame was rendered, or it won't work
1532         if(cs_project_is_b0rked == 0)
1533         {
1534                 string w0, h0;
1535                 w0 = ftos(autocvar_vid_conwidth);
1536                 h0 = ftos(autocvar_vid_conheight);
1537                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1538                 //setproperty(VF_FOV, '90 90 0');
1539                 setproperty(VF_ORIGIN, '0 0 0');
1540                 setproperty(VF_ANGLES, '0 0 0');
1541                 setproperty(VF_PERSPECTIVE, 1);
1542                 makevectors('0 0 0');
1543                 vector v1, v2;
1544                 cvar_set("vid_conwidth", "800");
1545                 cvar_set("vid_conheight", "600");
1546                 v1 = cs_project(v_forward);
1547                 cvar_set("vid_conwidth", "640");
1548                 cvar_set("vid_conheight", "480");
1549                 v2 = cs_project(v_forward);
1550                 if(v1 == v2)
1551                         cs_project_is_b0rked = 1;
1552                 else
1553                         cs_project_is_b0rked = -1;
1554                 cvar_set("vid_conwidth", w0);
1555                 cvar_set("vid_conheight", h0);
1556         }
1557
1558         if(autocvar__hud_configure)
1559                 HUD_Panel_Mouse();
1560
1561     if(hud && !intermission)
1562     {
1563         if(hud == HUD_SPIDERBOT)
1564             CSQC_SPIDER_HUD();
1565         else if(hud == HUD_WAKIZASHI)
1566             CSQC_WAKIZASHI_HUD();
1567         else if(hud == HUD_RAPTOR)
1568             CSQC_RAPTOR_HUD();
1569         else if(hud == HUD_BUMBLEBEE)
1570             CSQC_BUMBLE_HUD();
1571         else if(hud == HUD_BUMBLEBEE_GUN)
1572             CSQC_BUMBLE_GUN_HUD();
1573     }
1574
1575         cl_notice_run();
1576
1577         // let's reset the view back to normal for the end
1578         setproperty(VF_MIN, '0 0 0');
1579         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1580 }
1581
1582
1583 void CSQC_common_hud(void)
1584 {
1585         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1586                 Accuracy_LoadLevels();
1587
1588     HUD_Main(); // always run these functions for alpha checks
1589     HUD_DrawScoreboard();
1590
1591     if (scoreboard_active) // scoreboard/accuracy
1592         HUD_Reset();
1593     else if (intermission == 2) // map voting screen
1594     {
1595         HUD_FinaleOverlay();
1596         HUD_Reset();
1597     }
1598         /*
1599         switch(hud)
1600         {
1601                 case HUD_SPIDERBOT:
1602                         CSQC_SPIDER_HUD();
1603                         break;
1604
1605                 case HUD_WAKIZASHI:
1606                         CSQC_WAKIZASHI_HUD();
1607                         break;
1608
1609         case HUD_BUMBLEBEE:
1610             CSQC_BUMBLE_HUD();
1611             break;
1612         }
1613         */
1614 }
1615
1616
1617 // following vectors must be global to allow seamless switching between camera modes
1618 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1619 void CSQC_Demo_Camera()
1620 {
1621         float speed, attenuation, dimensions;
1622         vector tmp, delta;
1623
1624         if( autocvar_camera_reset || !camera_mode )
1625         {
1626                 camera_offset = '0 0 0';
1627                 current_angles = '0 0 0';
1628                 camera_direction = '0 0 0';
1629                 camera_offset_z += 30;
1630                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1631                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1632                 current_origin = view_origin;
1633                 current_camera_offset  = camera_offset;
1634                 cvar_set("camera_reset", "0");
1635                 camera_mode = CAMERA_CHASE;
1636         }
1637
1638         // Camera angles
1639         if( camera_roll )
1640                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1641
1642         if(autocvar_camera_look_player)
1643         {
1644                 vector dir;
1645                 float n;
1646
1647                 dir = normalize(view_origin - current_position);
1648                 n = mouse_angles_z;
1649                 mouse_angles = vectoangles(dir);
1650                 mouse_angles_x = mouse_angles_x * -1;
1651                 mouse_angles_z = n;
1652         }
1653         else
1654         {
1655                 tmp = getmousepos() * 0.1;
1656                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1657                 {
1658                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1659                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1660                 }
1661         }
1662
1663         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1664         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1665         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1666         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1667
1668         // Fix difference when angles don't have the same sign
1669         delta = '0 0 0';
1670         if(mouse_angles_y < -60 && current_angles_y > 60)
1671                 delta = '0 360 0';
1672         if(mouse_angles_y > 60 && current_angles_y < -60)
1673                 delta = '0 -360 0';
1674
1675         if(autocvar_camera_look_player)
1676                 attenuation = autocvar_camera_look_attenuation;
1677         else
1678                 attenuation = autocvar_camera_speed_attenuation;
1679
1680         attenuation = 1 / max(1, attenuation);
1681         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1682
1683         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1684         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1685         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1686         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1687
1688         // Camera position
1689         tmp = '0 0 0';
1690         dimensions = 0;
1691
1692         if( camera_direction_x )
1693         {
1694                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1695                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1696                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1697                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1698                 ++dimensions;
1699         }
1700
1701         if( camera_direction_y )
1702         {
1703                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1704                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1705                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1706                 ++dimensions;
1707         }
1708
1709         if( camera_direction_z )
1710         {
1711                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1712                 ++dimensions;
1713         }
1714
1715         if(autocvar_camera_free)
1716                 speed = autocvar_camera_speed_free;
1717         else
1718                 speed = autocvar_camera_speed_chase;
1719
1720         if(dimensions)
1721         {
1722                 speed = speed * sqrt(1 / dimensions);
1723                 camera_offset += tmp * speed;
1724         }
1725
1726         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1727
1728         // Camera modes
1729         if( autocvar_camera_free )
1730         {
1731                 if ( camera_mode == CAMERA_CHASE )
1732                 {
1733                         current_camera_offset = current_origin + current_camera_offset;
1734                         camera_offset = current_origin + camera_offset;
1735                 }
1736
1737                 camera_mode = CAMERA_FREE;
1738                 current_position = current_camera_offset;
1739         }
1740         else
1741         {
1742                 if ( camera_mode == CAMERA_FREE )
1743                 {
1744                         current_origin = view_origin;
1745                         camera_offset = camera_offset - current_origin;
1746                         current_camera_offset = current_camera_offset - current_origin;
1747                 }
1748
1749                 camera_mode = CAMERA_CHASE;
1750
1751                 if(autocvar_camera_chase_smoothly)
1752                         current_origin += (view_origin - current_origin) * attenuation;
1753                 else
1754                         current_origin = view_origin;
1755
1756                 current_position = current_origin + current_camera_offset;
1757         }
1758
1759         setproperty(VF_ANGLES, current_angles);
1760         setproperty(VF_ORIGIN, current_position);
1761 }