qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107         if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110
 111         float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 112         float spawnzoomspeed = autocvar_cl_spawnzoom_speed;
 113
 114         zoomdir = button_zoom;
 115         if(hud == HUD_NORMAL)
 116         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 117                 zoomdir += button_attack2;
 118         if(spectatee_status > 0 || isdemo())
 119         {
 120                 if(spectatorbutton_zoom)
 121                 {
 122                         if(zoomdir)
 123                                 zoomdir = 0;
 124                         else
 125                                 zoomdir = 1;
 126                 }
 127                 // fteqcc failed twice here already, don't optimize this
 128         }
 129
 130         if(zoomdir) { zoomin_effect = 0; }
 131
 132         if(camera_active)
 133         {
 134                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 135         }
 136         else if(zoomin_effect)
 137         {
 138                 /*if(autocvar_cl_spawnzoom_type == 1) { current_viewzoom = (current_viewzoom + drawframetime * spawnzoomspeed * (1 - 1 / spawnzoomfactor)); }
 139                 else                                                            { */
 140
 141                 current_viewzoom += (spawnzoomspeed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 142                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 143                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 144         }
 145         else
 146         {
 147                 if(zoomspeed < 0) // instant zoom
 148                 {
 149                         if(zoomdir)
 150                                 current_viewzoom = 1 / zoomfactor;
 151                         else
 152                                 current_viewzoom = 1;
 153                 }
 154                 else
 155                 {
 156                         if(zoomdir)
 157                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 158                         else
 159                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 160                 }
 161         }
 162
 163         if(almost_equals(current_viewzoom, 1))
 164                 current_zoomfraction = 0;
 165         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 166                 current_zoomfraction = 1;
 167         else
 168                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 169
 170         if(zoomsensitivity < 1)
 171                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 172         else
 173                 setsensitivityscale(1);
 174
 175         makevectors(view_angles);
 176
 177         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 178         {
 179                 v = pmove_vel;
 180                 if(csqcplayer)
 181                         v = csqcplayer.velocity;
 182
 183                 switch(autocvar_cl_velocityzoom_type)
 184                 {
 185                         case 3: curspeed = max(0, v_forward * v); break;
 186                         case 2: curspeed = (v_forward * v); break;
 187                         case 1: default: curspeed = vlen(v); break;
 188                 }
 189
 190                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 191                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 192                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 193
 194                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 195         }
 196         else
 197                 velocityzoom = 1;
 198
 199         float frustumx, frustumy, fovx, fovy;
 200         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 201         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 202         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 203         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 204
 205         return '1 0 0' * fovx + '0 1 0' * fovy;
 206 }
 207
 208 // this function must match W_SetupShot!
 209 float zoomscript_caught;
 210
 211 vector wcross_origin;
 212 float wcross_scale_prev, wcross_alpha_prev;
 213 vector wcross_color_prev;
 214 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 215 vector wcross_color_goal_prev;
 216 float wcross_changedonetime;
 217
 218 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 219 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 220 float wcross_name_changestarttime, wcross_name_changedonetime;
 221 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 222 entity trueaim;
 223 entity trueaim_rifle;
 224
 225 #define SHOTTYPE_HITTEAM 1
 226 #define SHOTTYPE_HITOBSTRUCTION 2
 227 #define SHOTTYPE_HITWORLD 3
 228 #define SHOTTYPE_HITENEMY 4
 229
 230 void TrueAim_Init()
 231 {
 232         trueaim = spawn();
 233         trueaim.classname = "trueaim";
 234         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 235         trueaim_rifle = spawn();
 236         trueaim_rifle.classname = "trueaim_rifle";
 237         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 238 }
 239
 240 float EnemyHitCheck()
 241 {
 242         float t, n;
 243         wcross_origin = project_3d_to_2d(trace_endpos);
 244         wcross_origin_z = 0;
 245         if(trace_ent)
 246                 n = trace_ent.entnum;
 247         else
 248                 n = trace_networkentity;
 249         if(n < 1)
 250                 return SHOTTYPE_HITWORLD;
 251         if(n > maxclients)
 252                 return SHOTTYPE_HITWORLD;
 253         t = GetPlayerColor(n - 1);
 254         if(teamplay)
 255                 if(t == myteam)
 256                         return SHOTTYPE_HITTEAM;
 257         if(t == COLOR_SPECTATOR)
 258                 return SHOTTYPE_HITWORLD;
 259         return SHOTTYPE_HITENEMY;
 260 }
 261
 262 float TrueAimCheck()
 263 {
 264         float nudge = 1; // added to traceline target and subtracted from result
 265         vector vecs, trueaimpoint, w_shotorg;
 266         vector mi, ma, dv;
 267         float shottype;
 268         entity ta;
 269         float mv;
 270
 271         mi = ma = '0 0 0';
 272         ta = trueaim;
 273         mv = MOVE_NOMONSTERS;
 274
 275         switch(activeweapon)
 276         {
 277                 case WEP_TUBA: // no aim
 278                 case WEP_PORTO: // shoots from eye
 279                 case WEP_HOOK: // no trueaim
 280                 case WEP_GRENADE_LAUNCHER: // toss curve
 281                         return SHOTTYPE_HITWORLD;
 282                 case WEP_NEX:
 283                 case WEP_MINSTANEX:
 284                         mv = MOVE_NORMAL;
 285                         break;
 286                 case WEP_RIFLE:
 287                         ta = trueaim_rifle;
 288                         mv = MOVE_NORMAL;
 289                         if(zoomscript_caught)
 290                         {
 291                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 292                                 return EnemyHitCheck();
 293                         }
 294                         break;
 295                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 296                         mi = '-3 -3 -3';
 297                         ma = '3 3 3';
 298                         break;
 299                 case WEP_FIREBALL: // projectile has a size!
 300                         mi = '-16 -16 -16';
 301                         ma = '16 16 16';
 302                         break;
 303                 case WEP_SEEKER: // projectile has a size!
 304                         mi = '-2 -2 -2';
 305                         ma = '2 2 2';
 306                         break;
 307                 case WEP_ELECTRO: // projectile has a size!
 308                         mi = '0 0 -3';
 309                         ma = '0 0 -3';
 310                         break;
 311         }
 312
 313         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 314
 315         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 316         trueaimpoint = trace_endpos;
 317
 318         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 319                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 320
 321         if(vecs_x > 0)
 322                 vecs_y = -vecs_y;
 323         else
 324                 vecs = '0 0 0';
 325
 326         dv = view_right * vecs_y + view_up * vecs_z;
 327         w_shotorg = view_origin + dv;
 328
 329         // now move the vecs forward as much as requested if possible
 330         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 331         w_shotorg = trace_endpos - view_forward * nudge;
 332
 333         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 334         shottype = EnemyHitCheck();
 335         if(shottype != SHOTTYPE_HITWORLD)
 336                 return shottype;
 337
 338 #if 0
 339         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 340         // or rather, I know why, but see no fix
 341         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 342                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 343                 return SHOTTYPE_HITOBSTRUCTION;
 344 #endif
 345
 346         return SHOTTYPE_HITWORLD;
 347 }
 348
 349 void CSQC_common_hud(void);
 350
 351 void PostInit(void);
 352 void CSQC_Demo_Camera();
 353 float HUD_WouldDrawScoreboard();
 354 float camera_mode;
 355 float CAMERA_FREE = 1;
 356 float CAMERA_CHASE = 2;
 357 float reticle_type;
 358 string NextFrameCommand;
 359 void CSQC_SPIDER_HUD();
 360 void CSQC_RAPTOR_HUD();
 361
 362 vector freeze_org, freeze_ang;
 363 entity nightvision_noise, nightvision_noise2;
 364
 365 #define MAX_TIME_DIFF 5
 366 float pickup_crosshair_time, pickup_crosshair_size;
 367 float hit_time, typehit_time;
 368 float nextsound_hit_time, nextsound_typehit_time;
 369 float hitindication_crosshair_time, hitindication_crosshair_size;
 370 float use_nex_chargepool;
 371
 372 float myhealth, myhealth_prev;
 373 float myhealth_flash;
 374
 375 float old_blurradius, old_bluralpha;
 376 float old_sharpen_intensity;
 377
 378 vector myhealth_gentlergb;
 379
 380 float contentavgalpha, liquidalpha_prev;
 381 vector liquidcolor_prev;
 382
 383 float eventchase_current_distance;
 384
 385 vector damage_blurpostprocess, content_blurpostprocess;
 386
 387 float checkfail[16];
 388
 389 #define BUTTON_3 4
 390 #define BUTTON_4 8
 391 float cl_notice_run();
 392 void CSQC_UpdateView(float w, float h)
 393 {
 394         entity e;
 395         float fov;
 396         float f, i, j;
 397         vector v;
 398         vector vf_size, vf_min;
 399         float a;
 400
 401         execute_next_frame();
 402
 403         ++framecount;
 404
 405         hud = getstati(STAT_HUD);
 406
 407         if(autocvar__hud_showbinds_reload) // menu can set this one
 408         {
 409                 db_close(binddb);
 410                 binddb = db_create();
 411                 cvar_set("_hud_showbinds_reload", "0");
 412         }
 413
 414         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 415                 view_quality = getproperty(VF_MINFPS_QUALITY);
 416         else
 417                 view_quality = 1;
 418
 419         button_attack2 = (input_buttons & BUTTON_3);
 420         button_zoom = (input_buttons & BUTTON_4);
 421
 422         // FIXME do we need this hack?
 423         if(isdemo())
 424         {
 425                 // in demos, input_buttons do not work
 426                 button_zoom = (autocvar__togglezoom == "-");
 427         }
 428
 429 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 430         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 431         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 432         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 433         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 434         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 435         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 436         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 437
 438         vf_size = getpropertyvec(VF_SIZE);
 439         vf_min = getpropertyvec(VF_MIN);
 440         vid_width = vf_size_x;
 441         vid_height = vf_size_y;
 442
 443         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 444         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 445
 446         WaypointSprite_Load();
 447
 448         CSQCPlayer_SetCamera();
 449
 450 #ifdef COMPAT_XON050_ENGINE
 451         if(spectatee_status)
 452                 myteam = GetPlayerColor(spectatee_status - 1);
 453         else
 454 #endif
 455                 myteam = GetPlayerColor(player_localentnum - 1);
 456
 457         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 458
 459         // event chase camera
 460         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 461         {
 462                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 463                 {
 464                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 465                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_cl_eventchase_viewoffset);
 466
 467                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 468                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 469                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 470                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 471
 472                         // make the camera smooth back
 473                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 474                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 475                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 476                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 477
 478                         makevectors(view_angles);
 479
 480                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 481                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 482
 483                         // If the boxtrace fails, revert back to line tracing.
 484                         if(trace_startsolid)
 485                         {
 486                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 487                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 488                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 489                         }
 490                         else { setproperty(VF_ORIGIN, trace_endpos); }
 491
 492                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 493                 }
 494                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 495                 {
 496                         cvar_set("chase_active", "0");
 497                         eventchase_current_distance = 0; // start from 0 next time
 498                 }
 499         }
 500         // workaround for camera stuck between player's legs when using chase_active 1
 501         // because the engine stops updating the chase_active camera when the game ends
 502         else if(intermission)
 503         {
 504                 cvar_settemp("chase_active", "-1");
 505                 eventchase_current_distance = 0;
 506         }
 507
 508         // do lockview after event chase camera so that it still applies whenever necessary.
 509         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 510         {
 511                 setproperty(VF_ORIGIN, freeze_org);
 512                 setproperty(VF_ANGLES, freeze_ang);
 513         }
 514         else
 515         {
 516                 freeze_org = getpropertyvec(VF_ORIGIN);
 517                 freeze_ang = getpropertyvec(VF_ANGLES);
 518         }
 519
 520         WarpZone_FixView();
 521         //WarpZone_FixPMove();
 522
 523         // Render the Scene
 524         view_origin = getpropertyvec(VF_ORIGIN);
 525         view_angles = getpropertyvec(VF_ANGLES);
 526         makevectors(view_angles);
 527         view_forward = v_forward;
 528         view_right = v_right;
 529         view_up = v_up;
 530
 531 #ifdef BLURTEST
 532         if(time > blurtest_time0 && time < blurtest_time1)
 533         {
 534                 float r, t;
 535
 536                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 537                 r = t * blurtest_radius;
 538                 f = 1 / pow(t, blurtest_power) - 1;
 539
 540                 cvar_set("r_glsl_postprocess", "1");
 541                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 542         }
 543         else
 544         {
 545                 cvar_set("r_glsl_postprocess", "0");
 546                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 547         }
 548 #endif
 549
 550         TargetMusic_Advance();
 551         Fog_Force();
 552
 553         if(drawtime == 0)
 554                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 555         else
 556                 drawframetime = bound(0.000001, time - drawtime, 1);
 557         drawtime = time;
 558
 559         // watch for gametype changes here...
 560         // in ParseStuffCMD the cmd isn't executed yet :/
 561         // might even be better to add the gametype to TE_CSQC_INIT...?
 562         if(!postinit)
 563                 PostInit();
 564
 565         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 566         {
 567                 if(calledhooks & HOOK_START)
 568                 {
 569                         localcmd("\ncl_hook_gameend\n");
 570                         calledhooks |= HOOK_END;
 571                 }
 572         }
 573
 574         Announcer();
 575
 576         fov = autocvar_fov;
 577         if(fov <= 59.5)
 578         {
 579                 if(!zoomscript_caught)
 580                 {
 581                         localcmd("+button9\n");
 582                         zoomscript_caught = 1;
 583                 }
 584         }
 585         else
 586         {
 587                 if(zoomscript_caught)
 588                 {
 589                         localcmd("-button9\n");
 590                         zoomscript_caught = 0;
 591                 }
 592         }
 593
 594         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 595
 596         // next WANTED weapon (for HUD)
 597         switchweapon = getstati(STAT_SWITCHWEAPON);
 598
 599         // currently switching-to weapon (for crosshair)
 600         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 601
 602         // actually active weapon (for zoom)
 603         activeweapon = getstati(STAT_ACTIVEWEAPON);
 604
 605         f = (serverflags & SERVERFLAG_TEAMPLAY);
 606         if(f != teamplay)
 607         {
 608                 teamplay = f;
 609                 HUD_InitScores();
 610         }
 611
 612         if(last_switchweapon != switchweapon) {
 613                 weapontime = time;
 614                 last_switchweapon = switchweapon;
 615         }
 616         if(last_activeweapon != activeweapon) {
 617                 last_activeweapon = activeweapon;
 618
 619                 e = get_weaponinfo(activeweapon);
 620                 if(e.netname != "")
 621                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 622                 else
 623                         localcmd("\ncl_hook_activeweapon none\n");
 624         }
 625
 626         // ALWAYS Clear Current Scene First
 627         clearscene();
 628 #ifdef WORKAROUND_XON010
 629         if(checkextension("DP_CSQC_ROTATEMOVES"))
 630         {
 631 #endif
 632         setproperty(VF_ORIGIN, view_origin);
 633         setproperty(VF_ANGLES, view_angles);
 634 #ifdef WORKAROUND_XON010
 635         }
 636 #endif
 637
 638         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 639         setproperty(VF_SIZE, vf_size);
 640         setproperty(VF_MIN, vf_min);
 641
 642         // Assign Standard Viewflags
 643         // Draw the World (and sky)
 644         setproperty(VF_DRAWWORLD, 1);
 645
 646         // Set the console size vars
 647         vid_conwidth = autocvar_vid_conwidth;
 648         vid_conheight = autocvar_vid_conheight;
 649         vid_pixelheight = autocvar_vid_pixelheight;
 650
 651         setproperty(VF_FOV, GetCurrentFov(fov));
 652
 653         // Camera for demo playback
 654         if(camera_active)
 655         {
 656                 if(autocvar_camera_enable)
 657                         CSQC_Demo_Camera();
 658                 else
 659                 {
 660                         cvar_set("chase_active", ftos(chase_active_backup));
 661                         cvar_set("cl_demo_mousegrab", "0");
 662                         camera_active = FALSE;
 663                 }
 664         }
 665 #ifdef CAMERATEST
 666         else if(autocvar_camera_enable)
 667 #else
 668         else if(autocvar_camera_enable && isdemo())
 669 #endif
 670         {
 671                 // Enable required Darkplaces cvars
 672                 chase_active_backup = autocvar_chase_active;
 673                 cvar_set("chase_active", "2");
 674                 cvar_set("cl_demo_mousegrab", "1");
 675                 camera_active = TRUE;
 676                 camera_mode = FALSE;
 677         }
 678
 679         // Draw the Crosshair
 680         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 681
 682         // Draw the Engine Status Bar (the default Quake HUD)
 683         setproperty(VF_DRAWENGINESBAR, 0);
 684
 685         // Update the mouse position
 686         /*
 687            mousepos_x = vid_conwidth;
 688            mousepos_y = vid_conheight;
 689            mousepos = mousepos*0.5 + getmousepos();
 690          */
 691
 692         e = self;
 693         for(self = world; (self = nextent(self)); )
 694                 if(self.draw)
 695                         self.draw();
 696         self = e;
 697
 698         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 699         renderscene();
 700
 701         // now switch to 2D drawing mode by calling a 2D drawing function
 702         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 703         // next R_RenderScene call
 704         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 705
 706         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 707         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 708         {
 709                 // apply night vision effect
 710                 vector tc_00, tc_01, tc_10, tc_11;
 711                 vector rgb;
 712                 rgb_x = 0; // fteqcc sucks
 713                 rgb_y = 0; // fteqcc sucks
 714                 rgb_z = 0; // fteqcc sucks
 715
 716                 if(!nightvision_noise)
 717                 {
 718                         nightvision_noise = spawn();
 719                         nightvision_noise.classname = "nightvision_noise";
 720                 }
 721                 if(!nightvision_noise2)
 722                 {
 723                         nightvision_noise2 = spawn();
 724                         nightvision_noise2.classname = "nightvision_noise2";
 725                 }
 726
 727                 // color tint in yellow
 728                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 729
 730                 // draw BG
 731                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 732                 rgb = '1 1 1';
 733                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 734                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 735                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 736                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 737                 tc_11 = tc_01 + tc_10 - tc_00;
 738                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 739                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 740                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 741                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 742                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 743                 R_EndPolygon();
 744
 745                 // draw FG
 746                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 747                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 748                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 749                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 750                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 751                 tc_11 = tc_01 + tc_10 - tc_00;
 752                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 753                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 754                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 755                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 756                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 757                 R_EndPolygon();
 758         }
 759
 760         // Draw the aiming reticle for weapons that use it
 761         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 762         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 763         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 764         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 765                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 766         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 767                 reticle_type = 2; // nex zoom
 768         else if(button_zoom || zoomscript_caught)
 769                 reticle_type = 1; // normal zoom
 770         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 771                 reticle_type = 2; // nex zoom
 772
 773         if(reticle_type && autocvar_cl_reticle)
 774         {
 775                 if(autocvar_cl_reticle_stretch)
 776                 {
 777                         reticle_size_x = vid_conwidth;
 778                         reticle_size_y = vid_conheight;
 779                         reticle_pos_x = 0;
 780                         reticle_pos_y = 0;
 781                 }
 782                 else
 783                 {
 784                         reticle_size_x = max(vid_conwidth, vid_conheight);
 785                         reticle_size_y = max(vid_conwidth, vid_conheight);
 786                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 787                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 788                 }
 789
 790                 f = current_zoomfraction;
 791                 if(zoomscript_caught)
 792                         f = 1;
 793                 if(autocvar_cl_reticle_item_normal)
 794                 {
 795                         if(reticle_type == 1 && f)
 796                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 797                 }
 798                 if(autocvar_cl_reticle_item_nex)
 799                 {
 800                         if(reticle_type == 2 && f)
 801                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 802                 }
 803         }
 804
 805
 806         // improved polyblend
 807         if(autocvar_hud_contents)
 808         {
 809                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 810                 vector liquidcolor;
 811
 812                 switch(pointcontents(view_origin))
 813                 {
 814                         case CONTENT_WATER:
 815                                 liquidalpha = autocvar_hud_contents_water_alpha;
 816                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 817                                 incontent = 1;
 818                                 break;
 819
 820                         case CONTENT_LAVA:
 821                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 822                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 823                                 incontent = 1;
 824                                 break;
 825
 826                         case CONTENT_SLIME:
 827                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 828                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 829                                 incontent = 1;
 830                                 break;
 831
 832                         default:
 833                                 liquidalpha = 0;
 834                                 liquidcolor = '0 0 0';
 835                                 incontent = 0;
 836                                 break;
 837                 }
 838
 839                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 840                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 841                         contentfadetime = autocvar_hud_contents_fadeintime;
 842                         liquidalpha_prev = liquidalpha;
 843                         liquidcolor_prev = liquidcolor;
 844                 }
 845                 else
 846                         contentfadetime = autocvar_hud_contents_fadeouttime;
 847
 848                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 849                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 850
 851                 if(contentavgalpha)
 852                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 853
 854                 if(autocvar_hud_postprocessing)
 855                 {
 856                         if(autocvar_hud_contents_blur && contentavgalpha)
 857                         {
 858                                 content_blurpostprocess_x = 1;
 859                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 860                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 861                         }
 862                         else
 863                         {
 864                                 content_blurpostprocess_x = 0;
 865                                 content_blurpostprocess_y = 0;
 866                                 content_blurpostprocess_z = 0;
 867                         }
 868                 }
 869         }
 870
 871         if(autocvar_hud_damage)
 872         {
 873                 splash_size_x = max(vid_conwidth, vid_conheight);
 874                 splash_size_y = max(vid_conwidth, vid_conheight);
 875                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 876                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 877
 878                 float myhealth_flash_temp;
 879                 myhealth = getstati(STAT_HEALTH);
 880
 881                 // fade out
 882                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 883                 // add new damage
 884                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 885
 886                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 887                 pain_threshold = autocvar_hud_damage_pain_threshold;
 888                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 889                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 890
 891                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 892                 {
 893                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 894                 }
 895
 896                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 897
 898                 if(myhealth_prev < 1)
 899                 {
 900                         if(myhealth >= 1)
 901                         {
 902                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 903                                 myhealth_flash_temp = 0;
 904                         }
 905                         else
 906                         {
 907                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 908                         }
 909                 }
 910
 911                 if(spectatee_status == -1 || intermission)
 912                 {
 913                         myhealth_flash = 0; // observing, or match ended
 914                         myhealth_flash_temp = 0;
 915                 }
 916
 917                 myhealth_prev = myhealth;
 918
 919                 // IDEA: change damage color/picture based on player model for robot/alien species?
 920                 // pro: matches model better
 921                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 922                 // maybe different reddish pics?
 923                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 924                 {
 925                         if(autocvar_cl_gentle_damage == 2)
 926                         {
 927                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 928                                 {
 929                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 930                                 }
 931                         }
 932                         else
 933                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 934
 935                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 936                 }
 937                 else
 938                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 939
 940                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 941                 {
 942                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 943                         {
 944                                 damage_blurpostprocess_x = 1;
 945                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 946                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 947                         }
 948                         else
 949                         {
 950                                 damage_blurpostprocess_x = 0;
 951                                 damage_blurpostprocess_y = 0;
 952                                 damage_blurpostprocess_z = 0;
 953                         }
 954                 }
 955         }
 956
 957         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 958         float e2 = (autocvar_hud_powerup != 0);
 959         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 960         {
 961                 // enable or disable rendering types if they are used or not
 962                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 963                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 964
 965                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 966                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
 967                 {
 968                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 969                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 970                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 971                         {
 972                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 973                                 old_blurradius = blurradius;
 974                                 old_bluralpha = bluralpha;
 975                         }
 976                 }
 977                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 978                 {
 979                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 980                         old_blurradius = 0;
 981                         old_bluralpha = 0;
 982                 }
 983
 984                 // edge detection postprocess handling done second (used by hud_powerup)
 985                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 986                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 987                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 988
 989                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 990
 991                 if(autocvar_hud_powerup && sharpen_intensity > 0)
 992                 {
 993                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 994                         {
 995                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 996                                 old_sharpen_intensity = sharpen_intensity;
 997                         }
 998                 }
 999                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1000                 {
1001                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1002                         old_sharpen_intensity = 0;
1003                 }
1004
1005                 if(cvar("r_glsl_postprocess") == 0)
1006                         cvar_set("r_glsl_postprocess", "2");
1007         }
1008         else if(cvar("r_glsl_postprocess") == 2)
1009                 cvar_set("r_glsl_postprocess", "0");
1010
1011         if(menu_visible)
1012                 menu_show();
1013
1014         /*if(gametype == MAPINFO_TYPE_CTF)
1015           {
1016           ctf_view();
1017           } else */
1018
1019         // draw 2D entities
1020         e = self;
1021         for(self = world; (self = nextent(self)); )
1022                 if(self.draw2d)
1023                         self.draw2d();
1024         self = e;
1025         Draw_ShowNames_All();
1026
1027         scoreboard_active = HUD_WouldDrawScoreboard();
1028
1029         hit_time = getstatf(STAT_HIT_TIME);
1030         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1031         {
1032                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1033                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1034
1035                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1036         }
1037         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1038         if(typehit_time > nextsound_typehit_time)
1039         {
1040                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1041                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1042
1043                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1044         }
1045
1046         //else
1047         {
1048                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1049                 {
1050                         if(getstati(STAT_FROZEN))
1051                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1052                         if(getstatf(STAT_REVIVE_PROGRESS))
1053                         {
1054                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1055                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1056                         }
1057                 }
1058
1059                 if(autocvar_r_letterbox == 0)
1060                         if(autocvar_viewsize < 120)
1061                                 CSQC_common_hud();
1062
1063                 // crosshair goes VERY LAST
1064                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1065                 {
1066                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1067                                 return;
1068
1069                         string wcross_style;
1070                         float wcross_alpha, wcross_resolution;
1071                         wcross_style = autocvar_crosshair;
1072                         if (wcross_style == "0")
1073                                 return;
1074                         wcross_resolution = autocvar_crosshair_size;
1075                         if (wcross_resolution == 0)
1076                                 return;
1077                         wcross_alpha = autocvar_crosshair_alpha;
1078                         if (wcross_alpha == 0)
1079                                 return;
1080
1081                         // TrueAim check
1082                         float shottype;
1083
1084                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1085                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1086                         wcross_origin_z = 0;
1087                         if(autocvar_crosshair_hittest)
1088                         {
1089                                 vector wcross_oldorigin;
1090                                 wcross_oldorigin = wcross_origin;
1091                                 shottype = TrueAimCheck();
1092                                 if(shottype == SHOTTYPE_HITWORLD)
1093                                 {
1094                                         v = wcross_origin - wcross_oldorigin;
1095                                         v_x /= vid_conwidth;
1096                                         v_y /= vid_conheight;
1097                                         if(vlen(v) > 0.01)
1098                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1099                                 }
1100                                 if(!autocvar_crosshair_hittest_showimpact)
1101                                         wcross_origin = wcross_oldorigin;
1102                         }
1103                         else
1104                                 shottype = SHOTTYPE_HITWORLD;
1105
1106                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1107                         string wcross_wep = "", wcross_name;
1108                         float wcross_scale, wcross_blur;
1109
1110                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1111                                 e = get_weaponinfo(switchingweapon);
1112                                 if (e && e.netname != "")
1113                                 {
1114                                         wcross_wep = e.netname;
1115                                         if(autocvar_crosshair_per_weapon)
1116                                         {
1117                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1118                                                 if (wcross_resolution == 0)
1119                                                         return;
1120                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1121                                                 if (wcross_alpha == 0)
1122                                                         return;
1123
1124                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1125                                                 if(wcross_style == "" || wcross_style == "0")
1126                                                         wcross_style = wcross_wep;
1127                                         }
1128                                 }
1129                         }
1130                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1131                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1132                         else if(autocvar_crosshair_color_by_health)
1133                         {
1134                                 float x = getstati(STAT_HEALTH);
1135
1136                                 //x = red
1137                                 //y = green
1138                                 //z = blue
1139
1140                                 wcross_color_z = 0;
1141
1142                                 if(x > 200)
1143                                 {
1144                                         wcross_color_x = 0;
1145                                         wcross_color_y = 1;
1146                                 }
1147                                 else if(x > 150)
1148                                 {
1149                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1150                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1151                                 }
1152                                 else if(x > 100)
1153                                 {
1154                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1155                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1156                                         wcross_color_z = 1 - (x-100)*0.02;
1157                                 }
1158                                 else if(x > 50)
1159                                 {
1160                                         wcross_color_x = 1;
1161                                         wcross_color_y = 1;
1162                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1163                                 }
1164                                 else if(x > 20)
1165                                 {
1166                                         wcross_color_x = 1;
1167                                         wcross_color_y = (x-20)*90/27/100;
1168                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1169                                 }
1170                                 else
1171                                 {
1172                                         wcross_color_x = 1;
1173                                         wcross_color_y = 0;
1174                                 }
1175                         }
1176                         else
1177                                 wcross_color = stov(autocvar_crosshair_color);
1178
1179                         wcross_name = strcat("gfx/crosshair", wcross_style);
1180
1181                         if(autocvar_crosshair_effect_scalefade)
1182                         {
1183                                 wcross_scale = wcross_resolution;
1184                                 wcross_resolution = 1;
1185                         }
1186                         else
1187                         {
1188                                 wcross_scale = 1;
1189                         }
1190
1191                         if(autocvar_crosshair_pickup)
1192                         {
1193                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1194
1195                                 if(pickup_crosshair_time < stat_pickup_time)
1196                                 {
1197                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1198                                                 pickup_crosshair_size = 1;
1199
1200                                         pickup_crosshair_time = stat_pickup_time;
1201                                 }
1202
1203                                 if(pickup_crosshair_size > 0)
1204                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1205                                 else
1206                                         pickup_crosshair_size = 0;
1207
1208                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1209                         }
1210
1211                         if(autocvar_crosshair_hitindication)
1212                         {
1213                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1214
1215                                 if(hitindication_crosshair_time < hit_time)
1216                                 {
1217                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1218                                                 hitindication_crosshair_size = 1;
1219
1220                                         hitindication_crosshair_time = hit_time;
1221                                 }
1222
1223                                 if(hitindication_crosshair_size > 0)
1224                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1225                                 else
1226                                         hitindication_crosshair_size = 0;
1227
1228                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1229                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1230                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1231                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1232                         }
1233
1234                         if(shottype == SHOTTYPE_HITENEMY)
1235                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1236                         if(shottype == SHOTTYPE_HITTEAM)
1237                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1238
1239                         f = autocvar_crosshair_effect_speed;
1240                         if(f < 0)
1241                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1242                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1243                         {
1244                                 wcross_changedonetime = time + f;
1245                         }
1246                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1247                         {
1248                                 wcross_name_changestarttime = time;
1249                                 wcross_name_changedonetime = time + f;
1250                                 if(wcross_name_goal_prev_prev)
1251                                         strunzone(wcross_name_goal_prev_prev);
1252                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1253                                 wcross_name_goal_prev = strzone(wcross_name);
1254                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1255                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1256                                 wcross_resolution_goal_prev = wcross_resolution;
1257                         }
1258
1259                         wcross_scale_goal_prev = wcross_scale;
1260                         wcross_alpha_goal_prev = wcross_alpha;
1261                         wcross_color_goal_prev = wcross_color;
1262
1263                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1264                         {
1265                                 wcross_blur = 1;
1266                                 wcross_alpha *= 0.75;
1267                         }
1268                         else
1269                                 wcross_blur = 0;
1270                         // *_prev is at time-frametime
1271                         // * is at wcross_changedonetime+f
1272                         // what do we have at time?
1273                         if(time < wcross_changedonetime)
1274                         {
1275                                 f = frametime / (wcross_changedonetime - time + frametime);
1276                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1277                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1278                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1279                         }
1280
1281                         wcross_scale_prev = wcross_scale;
1282                         wcross_alpha_prev = wcross_alpha;
1283                         wcross_color_prev = wcross_color;
1284
1285                         wcross_scale *= 1 - autocvar__menu_alpha;
1286                         wcross_alpha *= 1 - autocvar__menu_alpha;
1287                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1288
1289                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1290                         {
1291                                 // crosshair rings for weapon stats
1292                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1293                                 {
1294                                         // declarations and stats
1295                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1296                                         string ring_image = string_null, ring_inner_image = string_null;
1297                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1298
1299                                         ring_scale = autocvar_crosshair_ring_size;
1300
1301                                         float weapon_clipload, weapon_clipsize;
1302                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1303                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1304
1305                                         float nex_charge, nex_chargepool;
1306                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1307                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1308
1309                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1310                                                 nex_charge_movingavg = nex_charge;
1311
1312
1313                                         // handle the values
1314                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1315                                         {
1316                                                 if (nex_chargepool || use_nex_chargepool) {
1317                                                         use_nex_chargepool = 1;
1318                                                         ring_inner_value = nex_chargepool;
1319                                                 } else {
1320                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1321                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1322                                                 }
1323
1324                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1325                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1326                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1327
1328                                                 // draw the outer ring to show the current charge of the weapon
1329                                                 ring_value = nex_charge;
1330                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1331                                                 ring_rgb = wcross_color;
1332                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1333                                         }
1334                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1335                                         {
1336                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1337                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1338                                                 ring_rgb = wcross_color;
1339                                                 ring_image = "gfx/crosshair_ring.tga";
1340                                         }
1341                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1342                                         {
1343                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1344                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1345                                                 ring_rgb = wcross_color;
1346                                                 ring_image = "gfx/crosshair_ring.tga";
1347                                         }
1348
1349                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1350                                         {
1351                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1352                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1353                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1354                                                 ring_rgb = wcross_color;
1355
1356                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1357                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1358                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1359                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1360                                                 else
1361                                                         ring_image = "gfx/crosshair_ring.tga";
1362                                         }
1363
1364                                         // if in weapon switch animation, fade ring out/in
1365                                         if(g_weaponswitchdelay > 0)
1366                                         {
1367                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1368                                                 if(f > 0 && f < 2)
1369                                                         ring_alpha *= fabs(1 - f);
1370                                         }
1371
1372                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1373                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1374
1375                                         if (ring_value)
1376                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1377                                 }
1378
1379 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1380                                 do \
1381                                 { \
1382                                         if(wcross_blur > 0) \
1383                                         { \
1384                                                 for(i = -2; i <= 2; ++i) \
1385                                                 for(j = -2; j <= 2; ++j) \
1386                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1387                                         } \
1388                                         else \
1389                                         { \
1390                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1391                                         } \
1392                                 } \
1393                                 while(0)
1394
1395 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1396                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1397
1398 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1399                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1400
1401                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1402                                 {
1403                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1404                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1405                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1406                                         f = 1 - f;
1407                                 }
1408                                 else
1409                                 {
1410                                         f = 1;
1411                                 }
1412                                 wcross_name_alpha_goal_prev = f;
1413
1414                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1415                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1416
1417                                 if(autocvar_crosshair_dot)
1418                                 {
1419                                         vector wcross_color_old;
1420                                         wcross_color_old = wcross_color;
1421
1422                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1423                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1424
1425                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1426                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1427                                         wcross_color = wcross_color_old;
1428                                 }
1429                         }
1430                 }
1431                 else
1432                 {
1433                         wcross_scale_prev = 0;
1434                         wcross_alpha_prev = 0;
1435                         wcross_scale_goal_prev = 0;
1436                         wcross_alpha_goal_prev = 0;
1437                         wcross_changedonetime = 0;
1438                         if(wcross_name_goal_prev)
1439                                 strunzone(wcross_name_goal_prev);
1440                         wcross_name_goal_prev = string_null;
1441                         if(wcross_name_goal_prev_prev)
1442                                 strunzone(wcross_name_goal_prev_prev);
1443                         wcross_name_goal_prev_prev = string_null;
1444                         wcross_name_changestarttime = 0;
1445                         wcross_name_changedonetime = 0;
1446                         wcross_name_alpha_goal_prev = 0;
1447                         wcross_name_alpha_goal_prev_prev = 0;
1448                         wcross_resolution_goal_prev = 0;
1449                         wcross_resolution_goal_prev_prev = 0;
1450                 }
1451         }
1452
1453         if(NextFrameCommand)
1454         {
1455                 localcmd("\n", NextFrameCommand, "\n");
1456                 NextFrameCommand = string_null;
1457         }
1458
1459         // we must do this check AFTER a frame was rendered, or it won't work
1460         if(cs_project_is_b0rked == 0)
1461         {
1462                 string w0, h0;
1463                 w0 = ftos(autocvar_vid_conwidth);
1464                 h0 = ftos(autocvar_vid_conheight);
1465                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1466                 //setproperty(VF_FOV, '90 90 0');
1467                 setproperty(VF_ORIGIN, '0 0 0');
1468                 setproperty(VF_ANGLES, '0 0 0');
1469                 setproperty(VF_PERSPECTIVE, 1);
1470                 makevectors('0 0 0');
1471                 vector v1, v2;
1472                 cvar_set("vid_conwidth", "800");
1473                 cvar_set("vid_conheight", "600");
1474                 v1 = cs_project(v_forward);
1475                 cvar_set("vid_conwidth", "640");
1476                 cvar_set("vid_conheight", "480");
1477                 v2 = cs_project(v_forward);
1478                 if(v1 == v2)
1479                         cs_project_is_b0rked = 1;
1480                 else
1481                         cs_project_is_b0rked = -1;
1482                 cvar_set("vid_conwidth", w0);
1483                 cvar_set("vid_conheight", h0);
1484         }
1485
1486         if(autocvar__hud_configure)
1487                 HUD_Panel_Mouse();
1488
1489     if(hud && !intermission)
1490     {
1491         if(hud == HUD_SPIDERBOT)
1492             CSQC_SPIDER_HUD();
1493         else if(hud == HUD_WAKIZASHI)
1494             CSQC_WAKIZASHI_HUD();
1495         else if(hud == HUD_RAPTOR)
1496             CSQC_RAPTOR_HUD();
1497         else if(hud == HUD_BUMBLEBEE)
1498             CSQC_BUMBLE_HUD();
1499         else if(hud == HUD_BUMBLEBEE_GUN)
1500             CSQC_BUMBLE_GUN_HUD();
1501     }
1502
1503         cl_notice_run();
1504
1505         // let's reset the view back to normal for the end
1506         setproperty(VF_MIN, '0 0 0');
1507         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1508 }
1509
1510
1511 void CSQC_common_hud(void)
1512 {
1513     // do some accuracy var caching
1514     float i;
1515     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1516     {
1517         if(autocvar_accuracy_color_levels != acc_color_levels)
1518         {
1519             if(acc_color_levels)
1520                 strunzone(acc_color_levels);
1521             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1522             acc_levels = tokenize_console(acc_color_levels);
1523             if (acc_levels > MAX_ACCURACY_LEVELS)
1524                 acc_levels = MAX_ACCURACY_LEVELS;
1525
1526             for (i = 0; i < acc_levels; ++i)
1527                 acc_lev[i] = stof(argv(i)) / 100.0;
1528         }
1529         // let know that acc_col[] needs to be loaded
1530         acc_col[0] = '-1 0 0';
1531     }
1532
1533     HUD_Main(); // always run these functions for alpha checks
1534     HUD_DrawScoreboard();
1535
1536     if (scoreboard_active) // scoreboard/accuracy
1537         HUD_Reset();
1538     else if (intermission == 2) // map voting screen
1539     {
1540         HUD_FinaleOverlay();
1541         HUD_Reset();
1542     }
1543         /*
1544         switch(hud)
1545         {
1546                 case HUD_SPIDERBOT:
1547                         CSQC_SPIDER_HUD();
1548                         break;
1549
1550                 case HUD_WAKIZASHI:
1551                         CSQC_WAKIZASHI_HUD();
1552                         break;
1553
1554         case HUD_BUMBLEBEE:
1555             CSQC_BUMBLE_HUD();
1556             break;
1557         }
1558         */
1559 }
1560
1561
1562 // following vectors must be global to allow seamless switching between camera modes
1563 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1564 void CSQC_Demo_Camera()
1565 {
1566         float speed, attenuation, dimensions;
1567         vector tmp, delta;
1568
1569         if( autocvar_camera_reset || !camera_mode )
1570         {
1571                 camera_offset = '0 0 0';
1572                 current_angles = '0 0 0';
1573                 camera_direction = '0 0 0';
1574                 camera_offset_z += 30;
1575                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1576                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1577                 current_origin = view_origin;
1578                 current_camera_offset  = camera_offset;
1579                 cvar_set("camera_reset", "0");
1580                 camera_mode = CAMERA_CHASE;
1581         }
1582
1583         // Camera angles
1584         if( camera_roll )
1585                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1586
1587         if(autocvar_camera_look_player)
1588         {
1589                 vector dir;
1590                 float n;
1591
1592                 dir = normalize(view_origin - current_position);
1593                 n = mouse_angles_z;
1594                 mouse_angles = vectoangles(dir);
1595                 mouse_angles_x = mouse_angles_x * -1;
1596                 mouse_angles_z = n;
1597         }
1598         else
1599         {
1600                 tmp = getmousepos() * 0.1;
1601                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1602                 {
1603                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1604                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1605                 }
1606         }
1607
1608         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1609         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1610         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1611         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1612
1613         // Fix difference when angles don't have the same sign
1614         delta = '0 0 0';
1615         if(mouse_angles_y < -60 && current_angles_y > 60)
1616                 delta = '0 360 0';
1617         if(mouse_angles_y > 60 && current_angles_y < -60)
1618                 delta = '0 -360 0';
1619
1620         if(autocvar_camera_look_player)
1621                 attenuation = autocvar_camera_look_attenuation;
1622         else
1623                 attenuation = autocvar_camera_speed_attenuation;
1624
1625         attenuation = 1 / max(1, attenuation);
1626         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1627
1628         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1629         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1630         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1631         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1632
1633         // Camera position
1634         tmp = '0 0 0';
1635         dimensions = 0;
1636
1637         if( camera_direction_x )
1638         {
1639                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1640                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1641                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1642                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1643                 ++dimensions;
1644         }
1645
1646         if( camera_direction_y )
1647         {
1648                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1649                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1650                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1651                 ++dimensions;
1652         }
1653
1654         if( camera_direction_z )
1655         {
1656                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1657                 ++dimensions;
1658         }
1659
1660         if(autocvar_camera_free)
1661                 speed = autocvar_camera_speed_free;
1662         else
1663                 speed = autocvar_camera_speed_chase;
1664
1665         if(dimensions)
1666         {
1667                 speed = speed * sqrt(1 / dimensions);
1668                 camera_offset += tmp * speed;
1669         }
1670
1671         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1672
1673         // Camera modes
1674         if( autocvar_camera_free )
1675         {
1676                 if ( camera_mode == CAMERA_CHASE )
1677                 {
1678                         current_camera_offset = current_origin + current_camera_offset;
1679                         camera_offset = current_origin + camera_offset;
1680                 }
1681
1682                 camera_mode = CAMERA_FREE;
1683                 current_position = current_camera_offset;
1684         }
1685         else
1686         {
1687                 if ( camera_mode == CAMERA_FREE )
1688                 {
1689                         current_origin = view_origin;
1690                         camera_offset = camera_offset - current_origin;
1691                         current_camera_offset = current_camera_offset - current_origin;
1692                 }
1693
1694                 camera_mode = CAMERA_CHASE;
1695
1696                 if(autocvar_camera_chase_smoothly)
1697                         current_origin += (view_origin - current_origin) * attenuation;
1698                 else
1699                         current_origin = view_origin;
1700
1701                 current_position = current_origin + current_camera_offset;
1702         }
1703
1704         setproperty(VF_ANGLES, current_angles);
1705         setproperty(VF_ORIGIN, current_position);
1706 }