qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107         if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir) { zoomin_effect = 0; }
 127
 128         if(camera_active)
 129         {
 130                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 131         }
 132         else if(autocvar_cl_spawnzoom && zoomin_effect)
 133         {
 134                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 135
 136                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 137                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 138                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 139         }
 140         else
 141         {
 142                 if(zoomspeed < 0) // instant zoom
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / zoomfactor;
 146                         else
 147                                 current_viewzoom = 1;
 148                 }
 149                 else
 150                 {
 151                         if(zoomdir)
 152                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 153                         else
 154                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 155                 }
 156         }
 157
 158         if(almost_equals(current_viewzoom, 1))
 159                 current_zoomfraction = 0;
 160         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 161                 current_zoomfraction = 1;
 162         else
 163                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 164
 165         if(zoomsensitivity < 1)
 166                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 167         else
 168                 setsensitivityscale(1);
 169
 170         makevectors(view_angles);
 171
 172         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 173         {
 174                 v = pmove_vel;
 175                 if(csqcplayer)
 176                         v = csqcplayer.velocity;
 177
 178                 switch(autocvar_cl_velocityzoom_type)
 179                 {
 180                         case 3: curspeed = max(0, v_forward * v); break;
 181                         case 2: curspeed = (v_forward * v); break;
 182                         case 1: default: curspeed = vlen(v); break;
 183                 }
 184
 185                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 186                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 187                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 188
 189                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 190         }
 191         else
 192                 velocityzoom = 1;
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t, n;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_ent)
 241                 n = trace_ent.entnum;
 242         else
 243                 n = trace_networkentity;
 244         if(n < 1)
 245                 return SHOTTYPE_HITWORLD;
 246         if(n > maxclients)
 247                 return SHOTTYPE_HITWORLD;
 248         t = GetPlayerColor(n - 1);
 249         if(teamplay)
 250                 if(t == myteam)
 251                         return SHOTTYPE_HITTEAM;
 252         if(t == NUM_SPECTATOR)
 253                 return SHOTTYPE_HITWORLD;
 254         return SHOTTYPE_HITENEMY;
 255 }
 256
 257 float TrueAimCheck()
 258 {
 259         float nudge = 1; // added to traceline target and subtracted from result
 260         vector vecs, trueaimpoint, w_shotorg;
 261         vector mi, ma, dv;
 262         float shottype;
 263         entity ta;
 264         float mv;
 265
 266         mi = ma = '0 0 0';
 267         ta = trueaim;
 268         mv = MOVE_NOMONSTERS;
 269
 270         switch(activeweapon)
 271         {
 272                 case WEP_TUBA: // no aim
 273                 case WEP_PORTO: // shoots from eye
 274                 case WEP_HOOK: // no trueaim
 275                 case WEP_GRENADE_LAUNCHER: // toss curve
 276                         return SHOTTYPE_HITWORLD;
 277                 case WEP_NEX:
 278                 case WEP_MINSTANEX:
 279                         mv = MOVE_NORMAL;
 280                         break;
 281                 case WEP_RIFLE:
 282                         ta = trueaim_rifle;
 283                         mv = MOVE_NORMAL;
 284                         if(zoomscript_caught)
 285                         {
 286                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 287                                 return EnemyHitCheck();
 288                         }
 289                         break;
 290                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 291                         mi = '-3 -3 -3';
 292                         ma = '3 3 3';
 293                         break;
 294                 case WEP_FIREBALL: // projectile has a size!
 295                         mi = '-16 -16 -16';
 296                         ma = '16 16 16';
 297                         break;
 298                 case WEP_SEEKER: // projectile has a size!
 299                         mi = '-2 -2 -2';
 300                         ma = '2 2 2';
 301                         break;
 302                 case WEP_ELECTRO: // projectile has a size!
 303                         mi = '0 0 -3';
 304                         ma = '0 0 -3';
 305                         break;
 306         }
 307
 308         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 309
 310         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 311         trueaimpoint = trace_endpos;
 312
 313         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 314                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 315
 316         if(vecs_x > 0)
 317                 vecs_y = -vecs_y;
 318         else
 319                 vecs = '0 0 0';
 320
 321         dv = view_right * vecs_y + view_up * vecs_z;
 322         w_shotorg = view_origin + dv;
 323
 324         // now move the vecs forward as much as requested if possible
 325         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 326         w_shotorg = trace_endpos - view_forward * nudge;
 327
 328         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 329         shottype = EnemyHitCheck();
 330         if(shottype != SHOTTYPE_HITWORLD)
 331                 return shottype;
 332
 333 #if 0
 334         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 335         // or rather, I know why, but see no fix
 336         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 337                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 338                 return SHOTTYPE_HITOBSTRUCTION;
 339 #endif
 340
 341         return SHOTTYPE_HITWORLD;
 342 }
 343
 344 void CSQC_common_hud(void);
 345
 346 void PostInit(void);
 347 void CSQC_Demo_Camera();
 348 float HUD_WouldDrawScoreboard();
 349 float camera_mode;
 350 float CAMERA_FREE = 1;
 351 float CAMERA_CHASE = 2;
 352 float reticle_type;
 353 string NextFrameCommand;
 354 void CSQC_SPIDER_HUD();
 355 void CSQC_RAPTOR_HUD();
 356
 357 vector freeze_org, freeze_ang;
 358 entity nightvision_noise, nightvision_noise2;
 359
 360 #define MAX_TIME_DIFF 5
 361 float pickup_crosshair_time, pickup_crosshair_size;
 362 float hit_time, typehit_time;
 363 float nextsound_hit_time, nextsound_typehit_time;
 364 float hitindication_crosshair_time, hitindication_crosshair_size;
 365 float use_nex_chargepool;
 366
 367 float myhealth, myhealth_prev;
 368 float myhealth_flash;
 369
 370 float old_blurradius, old_bluralpha;
 371 float old_sharpen_intensity;
 372
 373 vector myhealth_gentlergb;
 374
 375 float contentavgalpha, liquidalpha_prev;
 376 vector liquidcolor_prev;
 377
 378 float eventchase_current_distance;
 379
 380 vector damage_blurpostprocess, content_blurpostprocess;
 381
 382 float checkfail[16];
 383
 384 #define BUTTON_3 4
 385 #define BUTTON_4 8
 386 float cl_notice_run();
 387 float prev_myteam;
 388 void CSQC_UpdateView(float w, float h)
 389 {
 390         entity e;
 391         float fov;
 392         float f, i, j;
 393         vector v;
 394         vector vf_size, vf_min;
 395         float a;
 396
 397         execute_next_frame();
 398
 399         ++framecount;
 400
 401         hud = getstati(STAT_HUD);
 402
 403         if(autocvar__hud_showbinds_reload) // menu can set this one
 404         {
 405                 db_close(binddb);
 406                 binddb = db_create();
 407                 cvar_set("_hud_showbinds_reload", "0");
 408         }
 409
 410         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 411                 view_quality = getproperty(VF_MINFPS_QUALITY);
 412         else
 413                 view_quality = 1;
 414
 415         button_attack2 = (input_buttons & BUTTON_3);
 416         button_zoom = (input_buttons & BUTTON_4);
 417
 418 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 419         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 420         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 421         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 422         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 423         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 424         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 425         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 426
 427         vf_size = getpropertyvec(VF_SIZE);
 428         vf_min = getpropertyvec(VF_MIN);
 429         vid_width = vf_size_x;
 430         vid_height = vf_size_y;
 431
 432         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 433         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 434
 435         WaypointSprite_Load();
 436
 437         CSQCPlayer_SetCamera();
 438
 439 #ifdef COMPAT_XON050_ENGINE
 440         if(spectatee_status)
 441                 myteam = GetPlayerColor(spectatee_status - 1);
 442         else
 443 #endif
 444                 myteam = GetPlayerColor(player_localentnum - 1);
 445
 446         if(myteam != prev_myteam)
 447         {
 448                 myteamcolors = colormapPaletteColor(myteam, 1);
 449                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 450                         hud_panel[i].update_time = time;
 451                 prev_myteam = myteam;
 452         }
 453
 454         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 455
 456         float is_dead = (getstati(STAT_HEALTH) <= 0);
 457
 458         // FIXME do we need this hack?
 459         if(isdemo())
 460         {
 461                 // in demos, input_buttons do not work
 462                 button_zoom = (autocvar__togglezoom == "-");
 463         }
 464         else if(button_zoom
 465                 && autocvar_cl_unpress_zoom_on_death
 466                 && (spectatee_status >= 0)
 467                 && (is_dead || intermission))
 468         {
 469                 // no zoom while dead or in intermission please
 470                 localcmd("-zoom\n");
 471                 button_zoom = FALSE;
 472         }
 473
 474         // event chase camera
 475         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 476         {
 477                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead) || intermission)
 478                 {
 479                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 480                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_cl_eventchase_viewoffset);
 481
 482                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 483                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 484                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 485                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 486
 487                         // make the camera smooth back
 488                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 489                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 490                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 491                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 492
 493                         makevectors(view_angles);
 494
 495                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 496                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 497
 498                         // If the boxtrace fails, revert back to line tracing.
 499                         if(trace_startsolid)
 500                         {
 501                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 502                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 503                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 504                         }
 505                         else { setproperty(VF_ORIGIN, trace_endpos); }
 506
 507                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 508                 }
 509                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 510                 {
 511                         cvar_set("chase_active", "0");
 512                         eventchase_current_distance = 0; // start from 0 next time
 513                 }
 514         }
 515         // workaround for camera stuck between player's legs when using chase_active 1
 516         // because the engine stops updating the chase_active camera when the game ends
 517         else if(intermission)
 518         {
 519                 cvar_settemp("chase_active", "-1");
 520                 eventchase_current_distance = 0;
 521         }
 522
 523         // do lockview after event chase camera so that it still applies whenever necessary.
 524         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 525         {
 526                 setproperty(VF_ORIGIN, freeze_org);
 527                 setproperty(VF_ANGLES, freeze_ang);
 528         }
 529         else
 530         {
 531                 freeze_org = getpropertyvec(VF_ORIGIN);
 532                 freeze_ang = getpropertyvec(VF_ANGLES);
 533         }
 534
 535         WarpZone_FixView();
 536         //WarpZone_FixPMove();
 537
 538         // Render the Scene
 539         view_origin = getpropertyvec(VF_ORIGIN);
 540         view_angles = getpropertyvec(VF_ANGLES);
 541         makevectors(view_angles);
 542         view_forward = v_forward;
 543         view_right = v_right;
 544         view_up = v_up;
 545
 546 #ifdef BLURTEST
 547         if(time > blurtest_time0 && time < blurtest_time1)
 548         {
 549                 float r, t;
 550
 551                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 552                 r = t * blurtest_radius;
 553                 f = 1 / pow(t, blurtest_power) - 1;
 554
 555                 cvar_set("r_glsl_postprocess", "1");
 556                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 557         }
 558         else
 559         {
 560                 cvar_set("r_glsl_postprocess", "0");
 561                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 562         }
 563 #endif
 564
 565         TargetMusic_Advance();
 566         Fog_Force();
 567
 568         if(drawtime == 0)
 569                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 570         else
 571                 drawframetime = bound(0.000001, time - drawtime, 1);
 572         drawtime = time;
 573
 574         // watch for gametype changes here...
 575         // in ParseStuffCMD the cmd isn't executed yet :/
 576         // might even be better to add the gametype to TE_CSQC_INIT...?
 577         if(!postinit)
 578                 PostInit();
 579
 580         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 581         {
 582                 if(calledhooks & HOOK_START)
 583                 {
 584                         localcmd("\ncl_hook_gameend\n");
 585                         calledhooks |= HOOK_END;
 586                 }
 587         }
 588
 589         Announcer();
 590
 591         fov = autocvar_fov;
 592         if(fov <= 59.5)
 593         {
 594                 if(!zoomscript_caught)
 595                 {
 596                         localcmd("+button9\n");
 597                         zoomscript_caught = 1;
 598                 }
 599         }
 600         else
 601         {
 602                 if(zoomscript_caught)
 603                 {
 604                         localcmd("-button9\n");
 605                         zoomscript_caught = 0;
 606                 }
 607         }
 608
 609         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 610
 611         // next WANTED weapon (for HUD)
 612         switchweapon = getstati(STAT_SWITCHWEAPON);
 613
 614         // currently switching-to weapon (for crosshair)
 615         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 616
 617         // actually active weapon (for zoom)
 618         activeweapon = getstati(STAT_ACTIVEWEAPON);
 619
 620         f = (serverflags & SERVERFLAG_TEAMPLAY);
 621         if(f != teamplay)
 622         {
 623                 teamplay = f;
 624                 HUD_InitScores();
 625         }
 626
 627         if(last_switchweapon != switchweapon)
 628         {
 629                 weapontime = time;
 630                 last_switchweapon = switchweapon;
 631                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 632                 {
 633                         localcmd("-zoom\n");
 634                         button_zoom = FALSE;
 635                 }
 636                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 637                 {
 638                         localcmd("-fire\n");
 639                         localcmd("-fire2\n");
 640                         button_attack2 = FALSE;
 641                 }
 642         }
 643         if(last_activeweapon != activeweapon)
 644         {
 645                 last_activeweapon = activeweapon;
 646
 647                 e = get_weaponinfo(activeweapon);
 648                 if(e.netname != "")
 649                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 650                 else
 651                         localcmd("\ncl_hook_activeweapon none\n");
 652         }
 653
 654         // ALWAYS Clear Current Scene First
 655         clearscene();
 656 #ifdef WORKAROUND_XON010
 657         if(checkextension("DP_CSQC_ROTATEMOVES"))
 658         {
 659 #endif
 660         setproperty(VF_ORIGIN, view_origin);
 661         setproperty(VF_ANGLES, view_angles);
 662 #ifdef WORKAROUND_XON010
 663         }
 664 #endif
 665
 666         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 667         setproperty(VF_SIZE, vf_size);
 668         setproperty(VF_MIN, vf_min);
 669
 670         // Assign Standard Viewflags
 671         // Draw the World (and sky)
 672         setproperty(VF_DRAWWORLD, 1);
 673
 674         // Set the console size vars
 675         vid_conwidth = autocvar_vid_conwidth;
 676         vid_conheight = autocvar_vid_conheight;
 677         vid_pixelheight = autocvar_vid_pixelheight;
 678
 679         setproperty(VF_FOV, GetCurrentFov(fov));
 680
 681         // Camera for demo playback
 682         if(camera_active)
 683         {
 684                 if(autocvar_camera_enable)
 685                         CSQC_Demo_Camera();
 686                 else
 687                 {
 688                         cvar_set("chase_active", ftos(chase_active_backup));
 689                         cvar_set("cl_demo_mousegrab", "0");
 690                         camera_active = FALSE;
 691                 }
 692         }
 693 #ifdef CAMERATEST
 694         else if(autocvar_camera_enable)
 695 #else
 696         else if(autocvar_camera_enable && isdemo())
 697 #endif
 698         {
 699                 // Enable required Darkplaces cvars
 700                 chase_active_backup = autocvar_chase_active;
 701                 cvar_set("chase_active", "2");
 702                 cvar_set("cl_demo_mousegrab", "1");
 703                 camera_active = TRUE;
 704                 camera_mode = FALSE;
 705         }
 706
 707         // Draw the Crosshair
 708         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 709
 710         // Draw the Engine Status Bar (the default Quake HUD)
 711         setproperty(VF_DRAWENGINESBAR, 0);
 712
 713         // Update the mouse position
 714         /*
 715            mousepos_x = vid_conwidth;
 716            mousepos_y = vid_conheight;
 717            mousepos = mousepos*0.5 + getmousepos();
 718          */
 719
 720         e = self;
 721         for(self = world; (self = nextent(self)); )
 722                 if(self.draw)
 723                         self.draw();
 724         self = e;
 725
 726         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 727         renderscene();
 728
 729         // now switch to 2D drawing mode by calling a 2D drawing function
 730         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 731         // next R_RenderScene call
 732         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 733
 734         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 735         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 736         {
 737                 // apply night vision effect
 738                 vector tc_00, tc_01, tc_10, tc_11;
 739                 vector rgb;
 740                 rgb_x = 0; // fteqcc sucks
 741                 rgb_y = 0; // fteqcc sucks
 742                 rgb_z = 0; // fteqcc sucks
 743
 744                 if(!nightvision_noise)
 745                 {
 746                         nightvision_noise = spawn();
 747                         nightvision_noise.classname = "nightvision_noise";
 748                 }
 749                 if(!nightvision_noise2)
 750                 {
 751                         nightvision_noise2 = spawn();
 752                         nightvision_noise2.classname = "nightvision_noise2";
 753                 }
 754
 755                 // color tint in yellow
 756                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 757
 758                 // draw BG
 759                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 760                 rgb = '1 1 1';
 761                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 762                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 763                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 764                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 765                 tc_11 = tc_01 + tc_10 - tc_00;
 766                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 767                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 768                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 769                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 770                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 771                 R_EndPolygon();
 772
 773                 // draw FG
 774                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 775                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 776                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 777                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 778                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 779                 tc_11 = tc_01 + tc_10 - tc_00;
 780                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 781                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 782                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 783                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 784                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 785                 R_EndPolygon();
 786         }
 787
 788         // Draw the aiming reticle for weapons that use it
 789         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 790         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 791         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 792         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 793                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 794         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 795                 reticle_type = 2; // nex zoom
 796         else if(button_zoom || zoomscript_caught)
 797                 reticle_type = 1; // normal zoom
 798         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 799                 reticle_type = 2; // nex zoom
 800
 801         if(reticle_type && autocvar_cl_reticle)
 802         {
 803                 if(autocvar_cl_reticle_stretch)
 804                 {
 805                         reticle_size_x = vid_conwidth;
 806                         reticle_size_y = vid_conheight;
 807                         reticle_pos_x = 0;
 808                         reticle_pos_y = 0;
 809                 }
 810                 else
 811                 {
 812                         reticle_size_x = max(vid_conwidth, vid_conheight);
 813                         reticle_size_y = max(vid_conwidth, vid_conheight);
 814                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 815                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 816                 }
 817
 818                 f = current_zoomfraction;
 819                 if(zoomscript_caught)
 820                         f = 1;
 821                 if(autocvar_cl_reticle_item_normal)
 822                 {
 823                         if(reticle_type == 1 && f)
 824                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 825                 }
 826                 if(autocvar_cl_reticle_item_nex)
 827                 {
 828                         if(reticle_type == 2 && f)
 829                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 830                 }
 831         }
 832
 833
 834         // improved polyblend
 835         if(autocvar_hud_contents)
 836         {
 837                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 838                 vector liquidcolor;
 839
 840                 switch(pointcontents(view_origin))
 841                 {
 842                         case CONTENT_WATER:
 843                                 liquidalpha = autocvar_hud_contents_water_alpha;
 844                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 845                                 incontent = 1;
 846                                 break;
 847
 848                         case CONTENT_LAVA:
 849                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 850                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 851                                 incontent = 1;
 852                                 break;
 853
 854                         case CONTENT_SLIME:
 855                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 856                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 857                                 incontent = 1;
 858                                 break;
 859
 860                         default:
 861                                 liquidalpha = 0;
 862                                 liquidcolor = '0 0 0';
 863                                 incontent = 0;
 864                                 break;
 865                 }
 866
 867                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 868                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 869                         contentfadetime = autocvar_hud_contents_fadeintime;
 870                         liquidalpha_prev = liquidalpha;
 871                         liquidcolor_prev = liquidcolor;
 872                 }
 873                 else
 874                         contentfadetime = autocvar_hud_contents_fadeouttime;
 875
 876                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 877                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 878
 879                 if(contentavgalpha)
 880                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 881
 882                 if(autocvar_hud_postprocessing)
 883                 {
 884                         if(autocvar_hud_contents_blur && contentavgalpha)
 885                         {
 886                                 content_blurpostprocess_x = 1;
 887                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 888                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 889                         }
 890                         else
 891                         {
 892                                 content_blurpostprocess_x = 0;
 893                                 content_blurpostprocess_y = 0;
 894                                 content_blurpostprocess_z = 0;
 895                         }
 896                 }
 897         }
 898
 899         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 900         {
 901                 splash_size_x = max(vid_conwidth, vid_conheight);
 902                 splash_size_y = max(vid_conwidth, vid_conheight);
 903                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 904                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 905
 906                 float myhealth_flash_temp;
 907                 myhealth = getstati(STAT_HEALTH);
 908
 909                 // fade out
 910                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 911                 // add new damage
 912                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 913
 914                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 915                 pain_threshold = autocvar_hud_damage_pain_threshold;
 916                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 917                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 918
 919                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 920                 {
 921                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 922                 }
 923
 924                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 925
 926                 if(myhealth_prev < 1)
 927                 {
 928                         if(myhealth >= 1)
 929                         {
 930                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 931                                 myhealth_flash_temp = 0;
 932                         }
 933                         else
 934                         {
 935                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 936                         }
 937                 }
 938
 939                 if(spectatee_status == -1 || intermission)
 940                 {
 941                         myhealth_flash = 0; // observing, or match ended
 942                         myhealth_flash_temp = 0;
 943                 }
 944
 945                 myhealth_prev = myhealth;
 946
 947                 // IDEA: change damage color/picture based on player model for robot/alien species?
 948                 // pro: matches model better
 949                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 950                 // maybe different reddish pics?
 951                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 952                 {
 953                         if(autocvar_cl_gentle_damage == 2)
 954                         {
 955                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 956                                 {
 957                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 958                                 }
 959                         }
 960                         else
 961                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 962
 963                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 964                 }
 965                 else
 966                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 967
 968                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 969                 {
 970                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 971                         {
 972                                 damage_blurpostprocess_x = 1;
 973                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 974                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 975                         }
 976                         else
 977                         {
 978                                 damage_blurpostprocess_x = 0;
 979                                 damage_blurpostprocess_y = 0;
 980                                 damage_blurpostprocess_z = 0;
 981                         }
 982                 }
 983         }
 984
 985         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 986         float e2 = (autocvar_hud_powerup != 0);
 987         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 988         {
 989                 // enable or disable rendering types if they are used or not
 990                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 991                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 992
 993                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 994                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
 995                 {
 996                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 997                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 998                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 999                         {
1000                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1001                                 old_blurradius = blurradius;
1002                                 old_bluralpha = bluralpha;
1003                         }
1004                 }
1005                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1006                 {
1007                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1008                         old_blurradius = 0;
1009                         old_bluralpha = 0;
1010                 }
1011
1012                 // edge detection postprocess handling done second (used by hud_powerup)
1013                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1014                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1015                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1016
1017                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1018
1019                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1020                 {
1021                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1022                         {
1023                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1024                                 old_sharpen_intensity = sharpen_intensity;
1025                         }
1026                 }
1027                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1028                 {
1029                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1030                         old_sharpen_intensity = 0;
1031                 }
1032
1033                 if(cvar("r_glsl_postprocess") == 0)
1034                         cvar_set("r_glsl_postprocess", "2");
1035         }
1036         else if(cvar("r_glsl_postprocess") == 2)
1037                 cvar_set("r_glsl_postprocess", "0");
1038
1039         if(menu_visible)
1040                 menu_show();
1041
1042         /*if(gametype == MAPINFO_TYPE_CTF)
1043           {
1044           ctf_view();
1045           } else */
1046
1047         // draw 2D entities
1048         e = self;
1049         for(self = world; (self = nextent(self)); )
1050                 if(self.draw2d)
1051                         self.draw2d();
1052         self = e;
1053         Draw_ShowNames_All();
1054
1055         scoreboard_active = HUD_WouldDrawScoreboard();
1056
1057         hit_time = getstatf(STAT_HIT_TIME);
1058         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1059         {
1060                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1061                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1062
1063                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1064         }
1065         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1066         if(typehit_time > nextsound_typehit_time)
1067         {
1068                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1069                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1070
1071                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1072         }
1073
1074         //else
1075         {
1076                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1077                 {
1078                         if(getstati(STAT_FROZEN))
1079                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1080                         if(getstatf(STAT_REVIVE_PROGRESS))
1081                         {
1082                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1083                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1084                         }
1085                 }
1086
1087                 if(autocvar_r_letterbox == 0)
1088                         if(autocvar_viewsize < 120)
1089                                 CSQC_common_hud();
1090
1091                 // crosshair goes VERY LAST
1092                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1093                 {
1094                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1095                                 return;
1096
1097                         string wcross_style;
1098                         float wcross_alpha, wcross_resolution;
1099                         wcross_style = autocvar_crosshair;
1100                         if (wcross_style == "0")
1101                                 return;
1102                         wcross_resolution = autocvar_crosshair_size;
1103                         if (wcross_resolution == 0)
1104                                 return;
1105                         wcross_alpha = autocvar_crosshair_alpha;
1106                         if (wcross_alpha == 0)
1107                                 return;
1108
1109                         // TrueAim check
1110                         float shottype;
1111
1112                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1113                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1114                         wcross_origin_z = 0;
1115                         if(autocvar_crosshair_hittest)
1116                         {
1117                                 vector wcross_oldorigin;
1118                                 wcross_oldorigin = wcross_origin;
1119                                 shottype = TrueAimCheck();
1120                                 if(shottype == SHOTTYPE_HITWORLD)
1121                                 {
1122                                         v = wcross_origin - wcross_oldorigin;
1123                                         v_x /= vid_conwidth;
1124                                         v_y /= vid_conheight;
1125                                         if(vlen(v) > 0.01)
1126                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1127                                 }
1128                                 if(!autocvar_crosshair_hittest_showimpact)
1129                                         wcross_origin = wcross_oldorigin;
1130                         }
1131                         else
1132                                 shottype = SHOTTYPE_HITWORLD;
1133
1134                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1135                         string wcross_wep = "", wcross_name;
1136                         float wcross_scale, wcross_blur;
1137
1138                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1139                                 e = get_weaponinfo(switchingweapon);
1140                                 if (e && e.netname != "")
1141                                 {
1142                                         wcross_wep = e.netname;
1143                                         if(autocvar_crosshair_per_weapon)
1144                                         {
1145                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1146                                                 if (wcross_resolution == 0)
1147                                                         return;
1148                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1149                                                 if (wcross_alpha == 0)
1150                                                         return;
1151
1152                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1153                                                 if(wcross_style == "" || wcross_style == "0")
1154                                                         wcross_style = wcross_wep;
1155                                         }
1156                                 }
1157                         }
1158                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1159                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1160                         else if(autocvar_crosshair_color_by_health)
1161                         {
1162                                 float x = getstati(STAT_HEALTH);
1163
1164                                 //x = red
1165                                 //y = green
1166                                 //z = blue
1167
1168                                 wcross_color_z = 0;
1169
1170                                 if(x > 200)
1171                                 {
1172                                         wcross_color_x = 0;
1173                                         wcross_color_y = 1;
1174                                 }
1175                                 else if(x > 150)
1176                                 {
1177                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1178                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1179                                 }
1180                                 else if(x > 100)
1181                                 {
1182                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1183                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1184                                         wcross_color_z = 1 - (x-100)*0.02;
1185                                 }
1186                                 else if(x > 50)
1187                                 {
1188                                         wcross_color_x = 1;
1189                                         wcross_color_y = 1;
1190                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1191                                 }
1192                                 else if(x > 20)
1193                                 {
1194                                         wcross_color_x = 1;
1195                                         wcross_color_y = (x-20)*90/27/100;
1196                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1197                                 }
1198                                 else
1199                                 {
1200                                         wcross_color_x = 1;
1201                                         wcross_color_y = 0;
1202                                 }
1203                         }
1204                         else
1205                                 wcross_color = stov(autocvar_crosshair_color);
1206
1207                         wcross_name = strcat("gfx/crosshair", wcross_style);
1208
1209                         if(autocvar_crosshair_effect_scalefade)
1210                         {
1211                                 wcross_scale = wcross_resolution;
1212                                 wcross_resolution = 1;
1213                         }
1214                         else
1215                         {
1216                                 wcross_scale = 1;
1217                         }
1218
1219                         if(autocvar_crosshair_pickup)
1220                         {
1221                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1222
1223                                 if(pickup_crosshair_time < stat_pickup_time)
1224                                 {
1225                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1226                                                 pickup_crosshair_size = 1;
1227
1228                                         pickup_crosshair_time = stat_pickup_time;
1229                                 }
1230
1231                                 if(pickup_crosshair_size > 0)
1232                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1233                                 else
1234                                         pickup_crosshair_size = 0;
1235
1236                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1237                         }
1238
1239                         if(autocvar_crosshair_hitindication)
1240                         {
1241                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1242
1243                                 if(hitindication_crosshair_time < hit_time)
1244                                 {
1245                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1246                                                 hitindication_crosshair_size = 1;
1247
1248                                         hitindication_crosshair_time = hit_time;
1249                                 }
1250
1251                                 if(hitindication_crosshair_size > 0)
1252                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1253                                 else
1254                                         hitindication_crosshair_size = 0;
1255
1256                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1257                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1258                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1259                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1260                         }
1261
1262                         if(shottype == SHOTTYPE_HITENEMY)
1263                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1264                         if(shottype == SHOTTYPE_HITTEAM)
1265                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1266
1267                         f = autocvar_crosshair_effect_speed;
1268                         if(f < 0)
1269                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1270                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1271                         {
1272                                 wcross_changedonetime = time + f;
1273                         }
1274                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1275                         {
1276                                 wcross_name_changestarttime = time;
1277                                 wcross_name_changedonetime = time + f;
1278                                 if(wcross_name_goal_prev_prev)
1279                                         strunzone(wcross_name_goal_prev_prev);
1280                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1281                                 wcross_name_goal_prev = strzone(wcross_name);
1282                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1283                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1284                                 wcross_resolution_goal_prev = wcross_resolution;
1285                         }
1286
1287                         wcross_scale_goal_prev = wcross_scale;
1288                         wcross_alpha_goal_prev = wcross_alpha;
1289                         wcross_color_goal_prev = wcross_color;
1290
1291                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1292                         {
1293                                 wcross_blur = 1;
1294                                 wcross_alpha *= 0.75;
1295                         }
1296                         else
1297                                 wcross_blur = 0;
1298                         // *_prev is at time-frametime
1299                         // * is at wcross_changedonetime+f
1300                         // what do we have at time?
1301                         if(time < wcross_changedonetime)
1302                         {
1303                                 f = frametime / (wcross_changedonetime - time + frametime);
1304                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1305                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1306                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1307                         }
1308
1309                         wcross_scale_prev = wcross_scale;
1310                         wcross_alpha_prev = wcross_alpha;
1311                         wcross_color_prev = wcross_color;
1312
1313                         wcross_scale *= 1 - autocvar__menu_alpha;
1314                         wcross_alpha *= 1 - autocvar__menu_alpha;
1315                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1316
1317                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1318                         {
1319                                 // crosshair rings for weapon stats
1320                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1321                                 {
1322                                         // declarations and stats
1323                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1324                                         string ring_image = string_null, ring_inner_image = string_null;
1325                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1326
1327                                         ring_scale = autocvar_crosshair_ring_size;
1328
1329                                         float weapon_clipload, weapon_clipsize;
1330                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1331                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1332
1333                                         float nex_charge, nex_chargepool;
1334                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1335                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1336
1337                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1338                                                 nex_charge_movingavg = nex_charge;
1339
1340
1341                                         // handle the values
1342                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1343                                         {
1344                                                 if (nex_chargepool || use_nex_chargepool) {
1345                                                         use_nex_chargepool = 1;
1346                                                         ring_inner_value = nex_chargepool;
1347                                                 } else {
1348                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1349                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1350                                                 }
1351
1352                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1353                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1354                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1355
1356                                                 // draw the outer ring to show the current charge of the weapon
1357                                                 ring_value = nex_charge;
1358                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1359                                                 ring_rgb = wcross_color;
1360                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1361                                         }
1362                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1363                                         {
1364                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1365                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1366                                                 ring_rgb = wcross_color;
1367                                                 ring_image = "gfx/crosshair_ring.tga";
1368                                         }
1369                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1370                                         {
1371                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1372                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1373                                                 ring_rgb = wcross_color;
1374                                                 ring_image = "gfx/crosshair_ring.tga";
1375                                         }
1376
1377                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1378                                         {
1379                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1380                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1381                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1382                                                 ring_rgb = wcross_color;
1383
1384                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1385                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1386                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1387                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1388                                                 else
1389                                                         ring_image = "gfx/crosshair_ring.tga";
1390                                         }
1391
1392                                         // if in weapon switch animation, fade ring out/in
1393                                         if(g_weaponswitchdelay > 0)
1394                                         {
1395                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1396                                                 if(f > 0 && f < 2)
1397                                                         ring_alpha *= fabs(1 - f);
1398                                         }
1399
1400                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1401                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1402
1403                                         if (ring_value)
1404                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1405                                 }
1406
1407 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1408                                 do \
1409                                 { \
1410                                         if(wcross_blur > 0) \
1411                                         { \
1412                                                 for(i = -2; i <= 2; ++i) \
1413                                                 for(j = -2; j <= 2; ++j) \
1414                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1415                                         } \
1416                                         else \
1417                                         { \
1418                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1419                                         } \
1420                                 } \
1421                                 while(0)
1422
1423 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1424                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1425
1426 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1427                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1428
1429                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1430                                 {
1431                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1432                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1433                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1434                                         f = 1 - f;
1435                                 }
1436                                 else
1437                                 {
1438                                         f = 1;
1439                                 }
1440                                 wcross_name_alpha_goal_prev = f;
1441
1442                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1443                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1444
1445                                 if(autocvar_crosshair_dot)
1446                                 {
1447                                         vector wcross_color_old;
1448                                         wcross_color_old = wcross_color;
1449
1450                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1451                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1452
1453                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1454                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1455                                         wcross_color = wcross_color_old;
1456                                 }
1457                         }
1458                 }
1459                 else
1460                 {
1461                         wcross_scale_prev = 0;
1462                         wcross_alpha_prev = 0;
1463                         wcross_scale_goal_prev = 0;
1464                         wcross_alpha_goal_prev = 0;
1465                         wcross_changedonetime = 0;
1466                         if(wcross_name_goal_prev)
1467                                 strunzone(wcross_name_goal_prev);
1468                         wcross_name_goal_prev = string_null;
1469                         if(wcross_name_goal_prev_prev)
1470                                 strunzone(wcross_name_goal_prev_prev);
1471                         wcross_name_goal_prev_prev = string_null;
1472                         wcross_name_changestarttime = 0;
1473                         wcross_name_changedonetime = 0;
1474                         wcross_name_alpha_goal_prev = 0;
1475                         wcross_name_alpha_goal_prev_prev = 0;
1476                         wcross_resolution_goal_prev = 0;
1477                         wcross_resolution_goal_prev_prev = 0;
1478                 }
1479         }
1480
1481         if(NextFrameCommand)
1482         {
1483                 localcmd("\n", NextFrameCommand, "\n");
1484                 NextFrameCommand = string_null;
1485         }
1486
1487         // we must do this check AFTER a frame was rendered, or it won't work
1488         if(cs_project_is_b0rked == 0)
1489         {
1490                 string w0, h0;
1491                 w0 = ftos(autocvar_vid_conwidth);
1492                 h0 = ftos(autocvar_vid_conheight);
1493                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1494                 //setproperty(VF_FOV, '90 90 0');
1495                 setproperty(VF_ORIGIN, '0 0 0');
1496                 setproperty(VF_ANGLES, '0 0 0');
1497                 setproperty(VF_PERSPECTIVE, 1);
1498                 makevectors('0 0 0');
1499                 vector v1, v2;
1500                 cvar_set("vid_conwidth", "800");
1501                 cvar_set("vid_conheight", "600");
1502                 v1 = cs_project(v_forward);
1503                 cvar_set("vid_conwidth", "640");
1504                 cvar_set("vid_conheight", "480");
1505                 v2 = cs_project(v_forward);
1506                 if(v1 == v2)
1507                         cs_project_is_b0rked = 1;
1508                 else
1509                         cs_project_is_b0rked = -1;
1510                 cvar_set("vid_conwidth", w0);
1511                 cvar_set("vid_conheight", h0);
1512         }
1513
1514         if(autocvar__hud_configure)
1515                 HUD_Panel_Mouse();
1516
1517     if(hud && !intermission)
1518     {
1519         if(hud == HUD_SPIDERBOT)
1520             CSQC_SPIDER_HUD();
1521         else if(hud == HUD_WAKIZASHI)
1522             CSQC_WAKIZASHI_HUD();
1523         else if(hud == HUD_RAPTOR)
1524             CSQC_RAPTOR_HUD();
1525         else if(hud == HUD_BUMBLEBEE)
1526             CSQC_BUMBLE_HUD();
1527         else if(hud == HUD_BUMBLEBEE_GUN)
1528             CSQC_BUMBLE_GUN_HUD();
1529     }
1530
1531         cl_notice_run();
1532
1533         // let's reset the view back to normal for the end
1534         setproperty(VF_MIN, '0 0 0');
1535         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1536 }
1537
1538
1539 void CSQC_common_hud(void)
1540 {
1541         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1542                 Accuracy_LoadLevels();
1543
1544     HUD_Main(); // always run these functions for alpha checks
1545     HUD_DrawScoreboard();
1546
1547     if (scoreboard_active) // scoreboard/accuracy
1548         HUD_Reset();
1549     else if (intermission == 2) // map voting screen
1550     {
1551         HUD_FinaleOverlay();
1552         HUD_Reset();
1553     }
1554         /*
1555         switch(hud)
1556         {
1557                 case HUD_SPIDERBOT:
1558                         CSQC_SPIDER_HUD();
1559                         break;
1560
1561                 case HUD_WAKIZASHI:
1562                         CSQC_WAKIZASHI_HUD();
1563                         break;
1564
1565         case HUD_BUMBLEBEE:
1566             CSQC_BUMBLE_HUD();
1567             break;
1568         }
1569         */
1570 }
1571
1572
1573 // following vectors must be global to allow seamless switching between camera modes
1574 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1575 void CSQC_Demo_Camera()
1576 {
1577         float speed, attenuation, dimensions;
1578         vector tmp, delta;
1579
1580         if( autocvar_camera_reset || !camera_mode )
1581         {
1582                 camera_offset = '0 0 0';
1583                 current_angles = '0 0 0';
1584                 camera_direction = '0 0 0';
1585                 camera_offset_z += 30;
1586                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1587                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1588                 current_origin = view_origin;
1589                 current_camera_offset  = camera_offset;
1590                 cvar_set("camera_reset", "0");
1591                 camera_mode = CAMERA_CHASE;
1592         }
1593
1594         // Camera angles
1595         if( camera_roll )
1596                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1597
1598         if(autocvar_camera_look_player)
1599         {
1600                 vector dir;
1601                 float n;
1602
1603                 dir = normalize(view_origin - current_position);
1604                 n = mouse_angles_z;
1605                 mouse_angles = vectoangles(dir);
1606                 mouse_angles_x = mouse_angles_x * -1;
1607                 mouse_angles_z = n;
1608         }
1609         else
1610         {
1611                 tmp = getmousepos() * 0.1;
1612                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1613                 {
1614                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1615                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1616                 }
1617         }
1618
1619         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1620         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1621         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1622         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1623
1624         // Fix difference when angles don't have the same sign
1625         delta = '0 0 0';
1626         if(mouse_angles_y < -60 && current_angles_y > 60)
1627                 delta = '0 360 0';
1628         if(mouse_angles_y > 60 && current_angles_y < -60)
1629                 delta = '0 -360 0';
1630
1631         if(autocvar_camera_look_player)
1632                 attenuation = autocvar_camera_look_attenuation;
1633         else
1634                 attenuation = autocvar_camera_speed_attenuation;
1635
1636         attenuation = 1 / max(1, attenuation);
1637         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1638
1639         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1640         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1641         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1642         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1643
1644         // Camera position
1645         tmp = '0 0 0';
1646         dimensions = 0;
1647
1648         if( camera_direction_x )
1649         {
1650                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1651                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1652                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1653                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1654                 ++dimensions;
1655         }
1656
1657         if( camera_direction_y )
1658         {
1659                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1660                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1661                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1662                 ++dimensions;
1663         }
1664
1665         if( camera_direction_z )
1666         {
1667                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1668                 ++dimensions;
1669         }
1670
1671         if(autocvar_camera_free)
1672                 speed = autocvar_camera_speed_free;
1673         else
1674                 speed = autocvar_camera_speed_chase;
1675
1676         if(dimensions)
1677         {
1678                 speed = speed * sqrt(1 / dimensions);
1679                 camera_offset += tmp * speed;
1680         }
1681
1682         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1683
1684         // Camera modes
1685         if( autocvar_camera_free )
1686         {
1687                 if ( camera_mode == CAMERA_CHASE )
1688                 {
1689                         current_camera_offset = current_origin + current_camera_offset;
1690                         camera_offset = current_origin + camera_offset;
1691                 }
1692
1693                 camera_mode = CAMERA_FREE;
1694                 current_position = current_camera_offset;
1695         }
1696         else
1697         {
1698                 if ( camera_mode == CAMERA_FREE )
1699                 {
1700                         current_origin = view_origin;
1701                         camera_offset = camera_offset - current_origin;
1702                         current_camera_offset = current_camera_offset - current_origin;
1703                 }
1704
1705                 camera_mode = CAMERA_CHASE;
1706
1707                 if(autocvar_camera_chase_smoothly)
1708                         current_origin += (view_origin - current_origin) * attenuation;
1709                 else
1710                         current_origin = view_origin;
1711
1712                 current_position = current_origin + current_camera_offset;
1713         }
1714
1715         setproperty(VF_ANGLES, current_angles);
1716         setproperty(VF_ORIGIN, current_position);
1717 }