qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         // trust server's idea of "own player model"
 137                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 138                         forceplayermodels_model = self.forceplayermodels_savemodel;
 139                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 140                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 141                         forceplayermodels_attempted = 1;
 142                 }
 143         }
 144
 145         // forcemodel finding
 146         if(!forceplayermodels_attempted)
 147         {
 148                 forceplayermodels_attempted = 1;
 149
 150                 // only if this failed, find it out on our own
 151                 entity e;
 152                 e = spawn();
 153                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 154                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 155                 forceplayermodels_model = e.model;
 156                 forceplayermodels_modelindex = e.modelindex;
 157                 forceplayermodels_skin = autocvar__cl_playerskin;
 158                 remove(e);
 159         }
 160
 161         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 162         {
 163                 entity e;
 164                 e = spawn();
 165                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 166                 forceplayermodels_myisgoodmodel = fexists(e.model);
 167                 forceplayermodels_mymodel = e.model;
 168                 forceplayermodels_mymodelindex = e.modelindex;
 169                 remove(e);
 170         }
 171
 172         // apply it
 173         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 174         {
 175                 self.model = forceplayermodels_mymodel;
 176                 self.modelindex = forceplayermodels_mymodelindex;
 177                 self.skin = autocvar_cl_forcemyplayerskin;
 178         }
 179         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 180         {
 181                 self.model = forceplayermodels_model;
 182                 self.modelindex = forceplayermodels_modelindex;
 183                 self.skin = forceplayermodels_skin;
 184         }
 185         else if(self.forceplayermodels_isgoodmodel)
 186         {
 187                 self.model = self.forceplayermodels_savemodel;
 188                 self.modelindex = self.forceplayermodels_savemodelindex;
 189                 self.skin = self.forceplayermodels_saveskin;
 190         }
 191         else
 192         {
 193                 self.model = forceplayermodels_goodmodel;
 194                 self.modelindex = forceplayermodels_goodmodelindex;
 195                 self.skin = self.forceplayermodels_saveskin;
 196         }
 197
 198         // forceplayercolors too
 199         if(!teamplay)
 200         {
 201                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 202                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 203                 else if(autocvar_cl_forceplayercolors)
 204                         self.colormap = player_localnum + 1;
 205         }
 206 }
 207
 208 // FEATURE: fallback frames
 209 .float csqcmodel_saveframe;
 210 .float csqcmodel_saveframe2;
 211 .float csqcmodel_saveframe3;
 212 .float csqcmodel_saveframe4;
 213 .float csqcmodel_framecount;
 214
 215 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 216 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 217 {
 218         self.frame = self.csqcmodel_saveframe;
 219         self.frame2 = self.csqcmodel_saveframe2;
 220         self.frame3 = self.csqcmodel_saveframe3;
 221         self.frame4 = self.csqcmodel_saveframe4;
 222 }
 223 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 224 {
 225         self.csqcmodel_saveframe = self.frame;
 226         self.csqcmodel_saveframe2 = self.frame2;
 227         self.csqcmodel_saveframe3 = self.frame3;
 228         self.csqcmodel_saveframe4 = self.frame4;
 229
 230         // hack for death animations: set their frametime to zero in case a
 231         // player "pops in"
 232         if(isnew)
 233         {
 234 #define FIX_FRAMETIME(f,ft) \
 235                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 236                 { \
 237                         self.ft = self.death_time; \
 238                 }
 239                 FIX_FRAMETIME(frame, frame1time)
 240                 FIX_FRAMETIME(frame2, frame2time)
 241                 FIX_FRAMETIME(frame3, frame3time)
 242                 FIX_FRAMETIME(frame4, frame4time)
 243         }
 244         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 245 }
 246 float CSQCPlayer_FallbackFrame(float f)
 247 {
 248         if(frameduration(self.modelindex, f) > 0)
 249                 return f; // goooooood
 250         if(frameduration(self.modelindex, 1) <= 0)
 251                 return f; // this is a static model. We can't fix it if we wanted to
 252         switch(f)
 253         {
 254                 case 23: return 11; // anim_melee -> anim_shoot
 255                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 256                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 257                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 258                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 259                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 260                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 261                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 262         }
 263         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 264         return f;
 265 }
 266 void CSQCPlayer_FallbackFrame_Apply(void)
 267 {
 268         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 269         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 270         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 271         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 272 }
 273
 274 // FEATURE: auto tag_index
 275 .entity tag_entity;
 276 .float tag_entity_lastmodelindex;
 277 .float tag_index;
 278 void CSQCModel_AutoTagIndex_Apply(void)
 279 {
 280         if(self.tag_entity && wasfreed(self.tag_entity))
 281                 self.tag_entity = world;
 282
 283         if(self.tag_networkentity)
 284         {
 285                 // we are ATTACHED!
 286                 float changed = 0;
 287                 if(self.tag_entity.entnum != self.tag_networkentity)
 288                 {
 289                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 290                         changed = 1;
 291                 }
 292
 293                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 294                 if(self.tag_entity.classname == "csqcmodel")
 295                 {
 296                         entity oldself = self;
 297                         self = self.tag_entity;
 298                         CSQCModel_Hook_PreDraw();
 299                         self = oldself;
 300                 }
 301
 302                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 303                 {
 304                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 305                         changed = 1;
 306                 }
 307                 if(changed)
 308                 {
 309                         if(self.tag_entity)
 310                         {
 311                                 // the best part is: IT EXISTS
 312                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 313                                 {
 314                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 315                                         {
 316                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 317                                                 if(!self.tag_index)
 318                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 319                                                 if(!self.tag_index)
 320                                                 {
 321                                                         // we need to prevent this from 'appening
 322                                                         self.tag_entity = world;
 323                                                         self.drawmask = 0;
 324                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 325                                                 }
 326                                         }
 327                                         else if(self.tag_entity.isplayermodel)
 328                                         {
 329                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 330                                                 if(!self.tag_index)
 331                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 332                                                 if(!self.tag_index)
 333                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 334                                         }
 335                                 }
 336
 337                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 338                                 {
 339                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 340                                         if(!self.tag_index)
 341                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 342                                 }
 343                         }
 344                         else
 345                         {
 346                                 // damn, see you next frame
 347                                 self.drawmask = 0;
 348                         }
 349                 }
 350         }
 351 }
 352
 353 // FEATURE: EF_NODRAW workalike
 354 float EF_BRIGHTFIELD    = 1;
 355 float EF_BRIGHTLIGHT    = 4;
 356 float EF_DIMLIGHT       = 8;
 357 float EF_DOUBLESIDED = 32768;
 358 float EF_NOSELFSHADOW = 65536;
 359 float EF_DYNAMICMODELLIGHT = 131072;
 360 float MF_ROCKET  =   1; // leave a trail
 361 float MF_GRENADE =   2; // leave a trail
 362 float MF_GIB     =   4; // leave a trail
 363 float MF_ROTATE  =   8; // rotate (bonus items)
 364 float MF_TRACER  =  16; // green split trail
 365 float MF_ZOMGIB  =  32; // small blood trail
 366 float MF_TRACER2 =  64; // orange split trail
 367 float MF_TRACER3 = 128; // purple trail
 368 .float csqcmodel_effects;
 369 .float csqcmodel_modelflags;
 370 void CSQCModel_Effects_PreUpdate(void)
 371 {
 372         self.effects = self.csqcmodel_effects;
 373         self.modelflags = self.csqcmodel_modelflags;
 374 }
 375 void CSQCModel_Effects_PostUpdate(void)
 376 {
 377         self.csqcmodel_effects = self.effects;
 378         self.csqcmodel_modelflags = self.modelflags;
 379         self.effects = 0;
 380         self.modelflags = 0;
 381         if(self.csqcmodel_teleported)
 382                 Projectile_ResetTrail(self.origin);
 383 }
 384 void CSQCModel_Effects_Apply(void)
 385 {
 386         float eff = self.csqcmodel_effects;
 387         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 388
 389         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 390         self.effects = 0;
 391         self.traileffect = 0;
 392
 393         if(eff & EF_BRIGHTFIELD)
 394                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 395         // ignoring EF_MUZZLEFLASH
 396         if(eff & EF_BRIGHTLIGHT)
 397                 adddynamiclight(self.origin, 400, '3 3 3');
 398         if(eff & EF_DIMLIGHT)
 399                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 400         if((eff & EF_NODRAW) || (self.alpha < 0))
 401                 self.drawmask = 0;
 402         if(eff & EF_ADDITIVE)
 403                 self.renderflags |= RF_ADDITIVE;
 404         if(eff & EF_BLUE)
 405                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 406         if(eff & EF_RED)
 407                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 408         // ignoring EF_NOGUNBOB
 409         if(eff & EF_FULLBRIGHT)
 410                 self.renderflags |= RF_FULLBRIGHT;
 411         if(eff & EF_FLAME)
 412                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 413         if(eff & EF_STARDUST)
 414                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 415         if(eff & EF_NOSHADOW)
 416                 self.renderflags |= RF_NOSHADOW;
 417         if(eff & EF_NODEPTHTEST)
 418                 self.renderflags |= RF_DEPTHHACK;
 419         // ignoring EF_SELECTABLE
 420         if(eff & EF_DOUBLESIDED)
 421                 self.effects |= EF_DOUBLESIDED;
 422         if(eff & EF_NOSELFSHADOW)
 423                 self.effects |= EF_NOSELFSHADOW;
 424         if(eff & EF_DYNAMICMODELLIGHT)
 425                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 426         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 427         if(self.csqcmodel_modelflags & MF_ROCKET)
 428                 self.traileffect = particleeffectnum("TR_ROCKET");
 429         if(self.csqcmodel_modelflags & MF_GRENADE)
 430                 self.traileffect = particleeffectnum("TR_GRENADE");
 431         if(self.csqcmodel_modelflags & MF_GIB)
 432                 self.traileffect = particleeffectnum("TR_BLOOD");
 433         if(self.csqcmodel_modelflags & MF_ROTATE)
 434         {
 435                 self.renderflags |= RF_USEAXIS;
 436                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 437         }
 438         if(self.csqcmodel_modelflags & MF_TRACER)
 439                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 440         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 441                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 442         if(self.csqcmodel_modelflags & MF_TRACER2)
 443                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 444         if(self.csqcmodel_modelflags & MF_TRACER3)
 445                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 446
 447         if(self.drawmask)
 448                 Projectile_DrawTrail(self.origin);
 449         else
 450                 Projectile_ResetTrail(self.origin);
 451
 452         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 453                 self.renderflags |= RF_ADDITIVE;
 454                 // also special in CSQCPlayer_GlowMod_Apply
 455 }
 456
 457 // FEATURE: auto glowmod
 458 .vector glowmod;
 459 void CSQCPlayer_GlowMod_Apply(void)
 460 {
 461         float cm = self.colormap;
 462
 463         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 464                 cm = 1024;
 465
 466         if(self.colormap > 0)
 467                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 468         else
 469                 self.glowmod = '1 1 1';
 470
 471         if(autocvar_cl_deathglow > 0)
 472                 if(self.csqcmodel_isdead)
 473                 {
 474                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 475                         // prevent the zero vector
 476                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 477                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 478                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 479                 }
 480 }
 481
 482 // general functions
 483 .float csqcmodel_predraw_run;
 484 void CSQCModel_Hook_PreDraw()
 485 {
 486         if(self.csqcmodel_predraw_run == framecount)
 487                 return;
 488         self.csqcmodel_predraw_run = framecount;
 489
 490         if(!self.modelindex || self.model == "null")
 491         {
 492                 self.drawmask = 0;
 493                 return;
 494         }
 495         else
 496                 self.drawmask = MASK_NORMAL;
 497
 498         if(self.isplayermodel) // this checks if it's a player MODEL!
 499         {
 500                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 501                 CSQCPlayer_GlowMod_Apply();
 502                 CSQCPlayer_LOD_Apply();
 503                 CSQCPlayer_FallbackFrame_Apply();
 504         }
 505
 506         CSQCModel_AutoTagIndex_Apply();
 507
 508         CSQCModel_Effects_Apply();
 509 }
 510
 511 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 512 {
 513         // revert to values from server
 514         CSQCModel_Effects_PreUpdate();
 515         if(self.isplayermodel)
 516         {
 517                 CSQCPlayer_FallbackFrame_PreUpdate();
 518                 CSQCPlayer_ForceModel_PreUpdate();
 519         }
 520 }
 521
 522 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 523 {
 524         // is it a player model? (shared state)
 525         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 526
 527         // save values set by server
 528         if(self.isplayermodel)
 529         {
 530                 CSQCPlayer_ForceModel_PostUpdate();
 531                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 532         }
 533         CSQCModel_Effects_PostUpdate();
 534 }