qcsrc/client/csqcmodel_hooks.qc

   1 #include "csqcmodel_hooks.qh"
   2
   3 #include <client/mutators/_mod.qh>
   4 #include <client/player_skeleton.qh>
   5 #include <client/weapons/projectile.qh>
   6 #include <common/animdecide.qh>
   7 #include <common/effects/all.inc>
   8 #include <common/effects/all.qh>
   9 #include <common/ent_cs.qh>
  10 #include <common/gamemodes/_mod.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/viewloc.qh>
  15 #include <lib/csqcmodel/cl_model.qh>
  16 #include <lib/csqcmodel/cl_player.qh>
  17 #include <lib/csqcmodel/interpolate.qh>
  18
  19 .float death_time;
  20 .int modelflags;
  21
  22 // FEATURE: LOD
  23 .int lodmodelindex0;
  24 .int lodmodelindex1;
  25 .int lodmodelindex2;
  26 void CSQCPlayer_LOD_Apply(entity this, bool isplayer)
  27 {
  28         int detailreduction = ((isplayer) ? autocvar_cl_playerdetailreduction : autocvar_cl_modeldetailreduction);
  29
  30         // LOD model loading
  31         if(this.lodmodelindex0 != this.modelindex)
  32         {
  33                 string modelname = this.model;
  34                 string s;
  35
  36                 vector mi = this.mins;
  37                 vector ma = this.maxs;
  38
  39                 // set modelindex
  40                 this.lodmodelindex0 = this.modelindex;
  41                 this.lodmodelindex1 = this.modelindex;
  42                 this.lodmodelindex2 = this.modelindex;
  43
  44                 // FIXME: this only supports 3-letter extensions
  45                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  46                 if(fexists(s))
  47                 {
  48                         precache_model(s);
  49                         _setmodel(this, s);
  50                         if(this.modelindex)
  51                                 this.lodmodelindex1 = this.modelindex;
  52                 }
  53
  54                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  55                 if(fexists(s))
  56                 {
  57                         precache_model(s);
  58                         _setmodel(this, s);
  59                         if(this.modelindex)
  60                                 this.lodmodelindex2 = this.modelindex;
  61                 }
  62
  63                 _setmodel(this, modelname); // make everything normal again
  64                 setsize(this, mi, ma);
  65         }
  66
  67         // apply LOD
  68         if(detailreduction <= 0)
  69         {
  70                 if(detailreduction <= -2)
  71                         this.modelindex = this.lodmodelindex2;
  72                 else if(detailreduction <= -1)
  73                         this.modelindex = this.lodmodelindex1;
  74                 else
  75                         this.modelindex = this.lodmodelindex0;
  76         }
  77         else
  78         {
  79                 float distance = vlen(((isplayer) ? this.origin : NearestPointOnBox(this, view_origin)) - view_origin); // TODO: perhaps it should just use NearestPointOnBox all the time, player hitbox can potentially be huge
  80                 float f = (distance * current_viewzoom + 100.0) * detailreduction;
  81                 f *= 1.0 / bound(0.01, view_quality, 1);
  82                 if(f > autocvar_cl_loddistance2)
  83                         this.modelindex = this.lodmodelindex2;
  84                 else if(f > autocvar_cl_loddistance1)
  85                         this.modelindex = this.lodmodelindex1;
  86                 else
  87                         this.modelindex = this.lodmodelindex0;
  88         }
  89 }
  90
  91 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  92 string forceplayermodels_model;
  93 bool forceplayermodels_modelisgoodmodel;
  94 int forceplayermodels_modelindex;
  95 int forceplayermodels_skin;
  96
  97 string forceplayermodels_mymodel;
  98 bool forceplayermodels_myisgoodmodel;
  99 int forceplayermodels_mymodelindex;
 100
 101 bool forceplayermodels_attempted;
 102
 103 .string forceplayermodels_savemodel;
 104 .int forceplayermodels_savemodelindex;
 105 .int forceplayermodels_saveskin;
 106 .int forceplayermodels_savecolormap;
 107
 108 .string forceplayermodels_isgoodmodel_mdl;
 109 .bool forceplayermodels_isgoodmodel;
 110
 111 string forceplayermodels_goodmodel;
 112 int forceplayermodels_goodmodelindex;
 113
 114 .vector glowmod;
 115
 116 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
 117 {
 118         this.model = this.forceplayermodels_savemodel;
 119         this.modelindex = this.forceplayermodels_savemodelindex;
 120         this.skin = this.forceplayermodels_saveskin;
 121         this.colormap = this.forceplayermodels_savecolormap;
 122 }
 123 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
 124 {
 125         this.forceplayermodels_savemodel = this.model;
 126         this.forceplayermodels_savemodelindex = this.modelindex;
 127         this.forceplayermodels_saveskin = this.skin;
 128         this.forceplayermodels_savecolormap = this.colormap;
 129
 130         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
 131         {
 132                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
 133                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
 134                 if(!this.forceplayermodels_isgoodmodel)
 135                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
 136         }
 137 }
 138 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
 139 {
 140         int cm = this.forceplayermodels_savecolormap;
 141         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
 142
 143         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
 144                 goto skipforcemodels;
 145
 146         // FORCEMODEL
 147         // which one is ALWAYS good?
 148         if (!forceplayermodels_goodmodel)
 149         {
 150                 entity e = spawn();
 151                 precache_model(cvar_defstring("_cl_playermodel"));
 152                 _setmodel(e, cvar_defstring("_cl_playermodel"));
 153                 forceplayermodels_goodmodel = e.model;
 154                 forceplayermodels_goodmodelindex = e.modelindex;
 155                 delete(e);
 156         }
 157
 158         // first, try finding it from the server
 159         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
 160         {
 161                 if(islocalplayer)
 162                 {
 163                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 164                         {
 165                                 // trust server's idea of "own player model"
 166                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
 167                                 forceplayermodels_model = this.forceplayermodels_savemodel;
 168                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
 169                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
 170                                 forceplayermodels_attempted = 1;
 171                         }
 172                 }
 173         }
 174
 175         // forcemodel finding
 176         if(!forceplayermodels_attempted)
 177         {
 178                 forceplayermodels_attempted = 1;
 179
 180                 // only if this failed, find it out on our own
 181                 entity e = spawn();
 182                 precache_model(autocvar__cl_playermodel);
 183                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 184                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 185                 forceplayermodels_model = e.model;
 186                 forceplayermodels_modelindex = e.modelindex;
 187                 forceplayermodels_skin = autocvar__cl_playerskin;
 188                 delete(e);
 189         }
 190
 191         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 192         {
 193                 entity e = spawn();
 194                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 195                 forceplayermodels_myisgoodmodel = fexists(e.model);
 196                 forceplayermodels_mymodel = e.model;
 197                 forceplayermodels_mymodelindex = e.modelindex;
 198                 delete(e);
 199         }
 200
 201         // apply it
 202         bool isfriend;
 203
 204         if(teamplay)
 205                 isfriend = (cm == 1024 + 17 * myteam);
 206         else
 207                 isfriend = islocalplayer;
 208
 209         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 210         {
 211                 this.model = forceplayermodels_mymodel;
 212                 this.modelindex = forceplayermodels_mymodelindex;
 213                 this.skin = autocvar_cl_forcemyplayerskin;
 214         }
 215         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 216         {
 217                 this.model = forceplayermodels_model;
 218                 this.modelindex = forceplayermodels_modelindex;
 219                 this.skin = forceplayermodels_skin;
 220         }
 221         else if(this.forceplayermodels_isgoodmodel)
 222         {
 223                 this.model = this.forceplayermodels_savemodel;
 224                 this.modelindex = this.forceplayermodels_savemodelindex;
 225                 this.skin = this.forceplayermodels_saveskin;
 226         }
 227         else
 228         {
 229                 this.model = forceplayermodels_goodmodel;
 230                 this.modelindex = forceplayermodels_goodmodelindex;
 231                 this.skin = this.forceplayermodels_saveskin;
 232         }
 233
 234         LABEL(skipforcemodels)
 235
 236         if(MUTATOR_CALLHOOK(ForcePlayercolors_Skip, this, islocalplayer))
 237                 goto skipforcecolors;
 238
 239         // forceplayercolors too
 240         if(teamplay)
 241         {
 242                 // own team's color is never forced
 243                 int forcecolor_friend = 0;
 244                 int forcecolor_enemy = 0;
 245                 entity tm;
 246
 247                 if(autocvar_cl_forcemyplayercolors)
 248                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 249                 if((autocvar_cl_forceplayercolors == 2 && team_count == 2)
 250                         || (autocvar_cl_forceplayercolors == 3 && IS_GAMETYPE(DUEL)))
 251                         forcecolor_enemy = 1024 + autocvar__cl_color;
 252
 253                 if(forcecolor_enemy && !forcecolor_friend)
 254                 {
 255                         // only enemy color is forced?
 256                         // verify it is not equal to the friend color
 257                         if(forcecolor_enemy == 1024 + 17 * myteam)
 258                                 forcecolor_enemy = 0;
 259                 }
 260
 261                 if(forcecolor_friend && !forcecolor_enemy)
 262                 {
 263                         // only friend color is forced?
 264                         // verify it is not equal to the enemy color
 265                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 266                                 // note: we even compare against our own team.
 267                                 // if we rejected because we matched our OWN team color,
 268                                 // this is not bad; we then simply keep our color as is
 269                                 // anyway.
 270                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 271                                         forcecolor_friend = 0;
 272                 }
 273
 274                 if(cm == 1024 + 17 * myteam)
 275                 {
 276                         if(forcecolor_friend)
 277                                 this.colormap = forcecolor_friend;
 278                 }
 279                 else
 280                 {
 281                         if(forcecolor_enemy)
 282                                 this.colormap = forcecolor_enemy;
 283                 }
 284         }
 285         else
 286         {
 287                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 288                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 289                 else if(autocvar_cl_forceplayercolors)
 290                         this.colormap = player_localnum + 1;
 291         }
 292
 293         LABEL(skipforcecolors)
 294
 295         if((this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST) && !autocvar_cl_respawn_ghosts_keepcolors)
 296         {
 297                 this.glowmod = '0 0 0';
 298                 this.colormap = 0;
 299                 return;
 300         }
 301
 302         // GLOWMOD AND DEATH FADING
 303         if(this.colormap > 0)
 304                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true) * 2;
 305         else
 306                 this.glowmod = '1 1 1';
 307
 308         if(autocvar_cl_deathglow > 0)
 309         {
 310                 if(this.csqcmodel_isdead)
 311                 {
 312                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
 313                         if(this.colormap > 0)
 314                                 min_factor /= 2;
 315                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
 316                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
 317                         if (this.glowmod == '0 0 0')
 318                                 this.glowmod.x = 0.000001;
 319                 }
 320         }
 321
 322         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
 323 }
 324
 325 // FEATURE: fallback frames
 326 .int csqcmodel_saveframe;
 327 .int csqcmodel_saveframe2;
 328 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 329 .int csqcmodel_saveframe3;
 330 .int csqcmodel_saveframe4;
 331 #endif
 332 .int csqcmodel_framecount;
 333
 334 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 335 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
 336 {
 337         this.frame = this.csqcmodel_saveframe;
 338         this.frame2 = this.csqcmodel_saveframe2;
 339 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 340         this.frame3 = this.csqcmodel_saveframe3;
 341         this.frame4 = this.csqcmodel_saveframe4;
 342 #endif
 343 }
 344 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
 345 {
 346         this.csqcmodel_saveframe = this.frame;
 347         this.csqcmodel_saveframe2 = this.frame2;
 348 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 349         this.csqcmodel_saveframe3 = this.frame3;
 350         this.csqcmodel_saveframe4 = this.frame4;
 351 #endif
 352
 353         // hack for death animations: set their frametime to zero in case a
 354         // player "pops in"
 355         if(isnew)
 356         {
 357 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
 358                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
 359                         this.ft = this.death_time; \
 360 MACRO_END
 361                 FIX_FRAMETIME(frame, frame1time);
 362                 FIX_FRAMETIME(frame2, frame2time);
 363 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 364                 FIX_FRAMETIME(frame3, frame3time);
 365                 FIX_FRAMETIME(frame4, frame4time);
 366 #endif
 367         }
 368         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
 369 }
 370 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
 371 {
 372         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 373 }
 374 int CSQCPlayer_FallbackFrame(entity this, int f)
 375 {
 376         TC(int, f);
 377         if(frameduration(this.modelindex, f) > 0)
 378                 return f; // goooooood
 379         if(frameduration(this.modelindex, 1) <= 0)
 380                 return f; // this is a static model. We can't fix it if we wanted to
 381         switch(f)
 382         {
 383                 case 23: return 11; // anim_melee -> anim_shoot
 384                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 385                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 386                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 387                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 388                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 389                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 390                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 391         }
 392         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
 393         return f;
 394 }
 395 void CSQCPlayer_FallbackFrame_Apply(entity this)
 396 {
 397         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
 398         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
 399 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 400         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
 401         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
 402 #endif
 403 }
 404
 405 // FEATURE: auto tag_index
 406 .entity tag_entity;
 407 .int tag_entity_lastmodelindex;
 408 .int tag_index;
 409 void CSQCModel_AutoTagIndex_Apply(entity this)
 410 {
 411         if(this.tag_entity && wasfreed(this.tag_entity))
 412                 this.tag_entity = NULL;
 413
 414         MUTATOR_CALLHOOK(TagIndex_Update, this);
 415
 416         if(this.tag_networkentity)
 417         {
 418                 // we are ATTACHED!
 419                 bool changed = 0;
 420                 if(this.tag_entity.entnum != this.tag_networkentity)
 421                 {
 422                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
 423                         changed = 1;
 424                 }
 425
 426                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 427                 if(this.tag_entity.classname == "ENT_CLIENT_MODEL")
 428                 {
 429                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
 430                 }
 431
 432                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
 433                 {
 434                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
 435                         changed = 1;
 436                 }
 437                 if(changed)
 438                 {
 439                         if(this.tag_entity)
 440                         {
 441                                 // the best part is: IT EXISTS
 442                                 if(substring(this.model, 0, 14) == "models/weapons")
 443                                 {
 444                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 445                                         {
 446                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
 447                                                 if(!this.tag_index)
 448                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
 449                                                 if(!this.tag_index)
 450                                                 {
 451                                                         // we need to prevent this from 'appening
 452                                                         this.tag_entity = NULL;
 453                                                         this.drawmask = 0;
 454                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
 455                                                 }
 456                                         }
 457                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
 458                                         {
 459                                                 skeleton_loadinfo(this.tag_entity);
 460                                                 this.tag_index = this.tag_entity.bone_weapon;
 461                                         }
 462                                 }
 463
 464                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 465                                 {
 466                                         this.tag_index = gettagindex(this.tag_entity, "shot");
 467                                         if(!this.tag_index)
 468                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
 469                                 }
 470
 471                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
 472                         }
 473                         else
 474                         {
 475                                 // damn, see you next frame
 476                                 this.drawmask = 0;
 477                         }
 478                 }
 479         }
 480 }
 481
 482 void CSQCModel_Effects_PreUpdate(entity this)
 483 {
 484         this.effects = this.csqcmodel_effects;
 485         this.modelflags = this.csqcmodel_modelflags;
 486         this.traileffect = this.csqcmodel_traileffect;
 487 }
 488 void Reset_ArcBeam();
 489 void CSQCModel_Effects_PostUpdate(entity this)
 490 {
 491         if (this == csqcplayer) {
 492                 if (this.csqcmodel_teleported) {
 493                         Reset_ArcBeam();
 494                 }
 495         }
 496         this.csqcmodel_effects = this.effects;
 497         this.csqcmodel_modelflags = this.modelflags;
 498         this.csqcmodel_traileffect = this.traileffect;
 499         this.effects = 0;
 500         this.modelflags = 0;
 501         if(this.csqcmodel_teleported)
 502                 Projectile_ResetTrail(this, this.origin);
 503 }
 504 .int snd_looping;
 505 void CSQCModel_Effects_Apply(entity this)
 506 {
 507         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
 508         int tref = this.csqcmodel_traileffect;
 509
 510         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 511         this.effects = 0;
 512         this.traileffect = 0;
 513
 514         if(eff & EF_BRIGHTFIELD)
 515                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
 516         // ignoring EF_MUZZLEFLASH
 517         if(eff & EF_BRIGHTLIGHT)
 518                 adddynamiclight(this.origin, 400, '3 3 3');
 519         if(eff & EF_DIMLIGHT)
 520                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
 521         if((eff & EF_NODRAW) || (this.alpha < 0))
 522                 this.drawmask = 0;
 523         if(eff & EF_ADDITIVE)
 524                 this.renderflags |= RF_ADDITIVE;
 525         if(eff & EF_BLUE)
 526                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
 527         if(eff & EF_RED)
 528                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
 529         // ignoring EF_NOGUNBOB
 530         if(eff & EF_FULLBRIGHT)
 531                 this.renderflags |= RF_FULLBRIGHT;
 532         if(eff & EF_FLAME)
 533         {
 534                 boxparticles(particleeffectnum(EFFECT_EF_FLAME), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 535                 //pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
 536         }
 537         if(eff & EF_STARDUST)
 538         {
 539                 boxparticles(particleeffectnum(EFFECT_EF_STARDUST), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 540                 //pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
 541         }
 542         if(eff & EF_NOSHADOW)
 543                 this.renderflags |= RF_NOSHADOW;
 544         if(eff & EF_NODEPTHTEST)
 545                 this.renderflags |= RF_DEPTHHACK;
 546         // ignoring EF_SELECTABLE
 547         if(eff & EF_DOUBLESIDED)
 548                 this.effects |= EF_DOUBLESIDED;
 549         if(eff & EF_NOSELFSHADOW)
 550                 this.effects |= EF_NOSELFSHADOW;
 551         if(eff & EF_DYNAMICMODELLIGHT)
 552                 this.renderflags |= RF_DYNAMICMODELLIGHT;
 553         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 554         if(this.csqcmodel_modelflags & MF_ROCKET)
 555                 tref = EFFECT_TR_ROCKET.m_id;
 556         if(this.csqcmodel_modelflags & MF_GRENADE)
 557                 tref = EFFECT_TR_GRENADE.m_id;
 558         if(this.csqcmodel_modelflags & MF_GIB)
 559                 tref = EFFECT_TR_BLOOD.m_id;
 560         if(this.csqcmodel_modelflags & MF_ROTATE)
 561         {
 562                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
 563                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
 564                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
 565                 this.renderflags |= RF_USEAXIS;
 566                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
 567         }
 568         if(this.csqcmodel_modelflags & MF_TRACER)
 569                 tref = EFFECT_TR_WIZSPIKE.m_id;
 570         if(this.csqcmodel_modelflags & MF_ZOMGIB)
 571                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
 572         if(this.csqcmodel_modelflags & MF_TRACER2)
 573                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
 574         if(this.csqcmodel_modelflags & MF_TRACER3)
 575                 tref = EFFECT_TR_VORESPIKE.m_id;
 576
 577         this.traileffect = tref;
 578
 579         if(this.drawmask)
 580                 Projectile_DrawTrail(this, this.origin);
 581         else
 582                 Projectile_ResetTrail(this, this.origin);
 583
 584         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 585                 this.renderflags |= RF_ADDITIVE;
 586                 // also special in CSQCPlayer_GlowMod_Apply
 587
 588         if(this.csqcmodel_modelflags & MF_ROCKET)
 589         {
 590                 if(!this.snd_looping)
 591                 {
 592                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
 593                         this.snd_looping = CH_TRIGGER_SINGLE;
 594                 }
 595         }
 596         else
 597         {
 598                 if(this.snd_looping)
 599                 {
 600                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 601                         this.snd_looping = 0;
 602                 }
 603         }
 604 }
 605
 606 // general functions
 607 .int csqcmodel_predraw_run;
 608 .int anim_frame;
 609 .int anim_frame1time;
 610 .int anim_frame2;
 611 .int anim_frame2time;
 612 .int anim_saveframe;
 613 .int anim_saveframe1time;
 614 .int anim_saveframe2;
 615 .int anim_saveframe2time;
 616 .int anim_prev_pmove_flags;
 617 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
 618 {
 619         if(this.csqcmodel_predraw_run == framecount)
 620                 return;
 621         this.csqcmodel_predraw_run = framecount;
 622
 623         if(!this.modelindex || this.model == "null")
 624         {
 625                 this.drawmask = 0;
 626                 if(this.snd_looping > 0)
 627                 {
 628                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 629                         this.snd_looping = 0;
 630                 }
 631                 return;
 632         }
 633         else
 634                 this.drawmask = MASK_NORMAL;
 635
 636         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
 637         {
 638                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
 639                 CSQCPlayer_LOD_Apply(this, true);
 640
 641                 if(!isplayer)
 642                 {
 643                         skeleton_loadinfo(this);
 644                         bool doblend = (this.bone_upperbody >= 0);
 645                         CSQCPlayer_FallbackFrame_Apply(this);
 646                         if(doblend)
 647                         {
 648                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 649                         }
 650                         else
 651                         {
 652                                 free_skeleton_from_frames(this);
 653                                 // just in case, clear these (we're animating in frame and frame3)
 654                                 this.lerpfrac = 0;
 655                                 this.lerpfrac4 = 0;
 656                         }
 657                 }
 658                 else
 659                 {
 660                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 661                         skeleton_loadinfo(this);
 662                         bool doblend = (this.bone_upperbody >= 0);
 663                         bool onground = 0;
 664                         if(this == csqcplayer)
 665                         {
 666                                 if(IS_ONGROUND(this))
 667                                         onground = 1;
 668                                 this.anim_prev_pmove_flags = this.flags;
 669                                 if(this.flags & FL_DUCKED)
 670                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
 671                                 else if(this.anim_state & ANIMSTATE_DUCK)
 672                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
 673                         }
 674                         else
 675                         {
 676                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
 677                                 if(trace_startsolid || trace_fraction < 1)
 678                                         onground = 1;
 679                                 // predicted clients handle smoothing in the prediction code
 680                                 this.origin = CSQCModel_ApplyStairSmoothing(this, onground, this.origin);
 681                         }
 682                         animdecide_load_if_needed(this);
 683                         animdecide_setimplicitstate(this, onground);
 684                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 685                         int sf = 0;
 686                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
 687                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 688                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
 689                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 690                         this.anim_saveframe = this.anim_frame;
 691                         this.anim_saveframe1time = this.anim_frame1time;
 692                         this.anim_saveframe2 = this.anim_frame2;
 693                         this.anim_saveframe2time = this.anim_frame2time;
 694                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
 695                         // This ensures that .frame etc. are always written.
 696                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
 697                         this.lerpfrac = (doblend ? 0.5 : 0);
 698                         this.frame = this.anim_frame;
 699                         this.frame1time = this.anim_frame1time;
 700                         this.frame2 = this.anim_frame2;
 701                         this.frame2time = this.anim_frame2time;
 702                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
 703                         CSQCModel_InterpolateAnimation_2To4_Do(this);
 704                         if(doblend)
 705                         {
 706                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 707                         }
 708                         else
 709                         {
 710                                 free_skeleton_from_frames(this);
 711                                 // just in case, clear these (we're animating in frame and frame3)
 712                                 this.lerpfrac = 0;
 713                                 this.lerpfrac4 = 0;
 714                         }
 715                 }
 716         }
 717         else
 718                 CSQCPlayer_LOD_Apply(this, false);
 719
 720         CSQCModel_AutoTagIndex_Apply(this);
 721
 722         CSQCModel_Effects_Apply(this);
 723 }
 724
 725 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 726 {
 727         // interpolate v_angle
 728         this.iflags |= IFLAG_V_ANGLE_X;
 729         // revert to values from server
 730         CSQCModel_Effects_PreUpdate(this);
 731         if((this.isplayermodel & ISPLAYER_MODEL))
 732         {
 733                 if(!isplayer)
 734                         CSQCPlayer_FallbackFrame_PreUpdate(this);
 735                 CSQCPlayer_ModelAppearance_PreUpdate(this);
 736         }
 737 }
 738
 739 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 740 {
 741         // is it a player model? (shared state)
 742         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" ||
 743                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
 744         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
 745
 746         // save values set by server
 747         if((this.isplayermodel & ISPLAYER_MODEL))
 748         {
 749                 CSQCPlayer_ModelAppearance_PostUpdate(this);
 750                 if(isplayer)
 751                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
 752                 else
 753                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
 754         }
 755         CSQCModel_Effects_PostUpdate(this);
 756 }