qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 // set modelindex
  18                 self.lodmodelindex0 = self.modelindex;
  19                 self.lodmodelindex1 = self.modelindex;
  20                 self.lodmodelindex2 = self.modelindex;
  21
  22                 // FIXME: this only supports 3-letter extensions
  23                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  24                 if(fexists(s))
  25                 {
  26                         precache_model(s);
  27                         setmodel(self, s);
  28                         if(self.modelindex)
  29                                 self.lodmodelindex1 = self.modelindex;
  30                 }
  31
  32                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  33                 if(fexists(s))
  34                 {
  35                         precache_model(s);
  36                         setmodel(self, s);
  37                         if(self.modelindex)
  38                                 self.lodmodelindex2 = self.modelindex;
  39                 }
  40
  41                 setmodel(self, modelname); // make everything normal again
  42         }
  43
  44         // apply LOD
  45         if(autocvar_cl_playerdetailreduction <= 0)
  46         {
  47                 if(autocvar_cl_playerdetailreduction <= -2)
  48                         self.modelindex = self.lodmodelindex2;
  49                 else if(autocvar_cl_playerdetailreduction <= -1)
  50                         self.modelindex = self.lodmodelindex1;
  51                 else
  52                         self.modelindex = self.lodmodelindex0;
  53         }
  54         else
  55         {
  56                 float distance = vlen(self.origin - other.origin);
  57                 float f = (distance + 100.0) * autocvar_cl_playerdetailreduction;
  58                 f *= 1.0 / bound(0.01, view_quality, 1);
  59                 if(f > autocvar_cl_loddistance2)
  60                         self.modelindex = self.lodmodelindex2;
  61                 else if(f > autocvar_cl_loddistance1)
  62                         self.modelindex = self.lodmodelindex1;
  63                 else
  64                         self.modelindex = self.lodmodelindex0;
  65         }
  66 }
  67
  68 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  69 string forceplayermodels_model;
  70 float forceplayermodels_modelisgoodmodel;
  71 float forceplayermodels_modelindex;
  72 float forceplayermodels_skin;
  73
  74 string forceplayermodels_mymodel;
  75 float forceplayermodels_myisgoodmodel;
  76 float forceplayermodels_mymodelindex;
  77
  78 float forceplayermodels_attempted;
  79
  80 .string forceplayermodels_savemodel;
  81 .float forceplayermodels_savemodelindex;
  82 .float forceplayermodels_saveskin;
  83 .float forceplayermodels_savecolormap;
  84
  85 .string forceplayermodels_isgoodmodel_mdl;
  86 .float forceplayermodels_isgoodmodel;
  87
  88 string forceplayermodels_goodmodel;
  89 float forceplayermodels_goodmodelindex;
  90
  91 void CSQCPlayer_ForceModel_PreUpdate(void)
  92 {
  93         self.model = self.forceplayermodels_savemodel;
  94         self.modelindex = self.forceplayermodels_savemodelindex;
  95         self.skin = self.forceplayermodels_saveskin;
  96         self.colormap = self.forceplayermodels_savecolormap;
  97 }
  98 void CSQCPlayer_ForceModel_PostUpdate(void)
  99 {
 100         self.forceplayermodels_savemodel = self.model;
 101         self.forceplayermodels_savemodelindex = self.modelindex;
 102         self.forceplayermodels_saveskin = self.skin;
 103         self.forceplayermodels_savecolormap = self.colormap;
 104
 105         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 106         {
 107                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 108                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 109                 if(!self.forceplayermodels_isgoodmodel)
 110                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 111         }
 112 }
 113 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 114 {
 115         // which one is ALWAYS good?
 116         if not(forceplayermodels_goodmodel)
 117         {
 118                 entity e;
 119                 e = spawn();
 120                 setmodel(e, cvar_defstring("_cl_playermodel"));
 121                 forceplayermodels_goodmodel = e.model;
 122                 forceplayermodels_goodmodelindex = e.modelindex;
 123                 remove(e);
 124         }
 125
 126         // first, try finding it from the server
 127         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 128         {
 129                 if(islocalplayer)
 130                 {
 131                         // trust server's idea of "own player model"
 132                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 133                         forceplayermodels_model = self.forceplayermodels_savemodel;
 134                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 135                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 136                         forceplayermodels_attempted = 1;
 137                 }
 138         }
 139
 140         // forcemodel finding
 141         if(!forceplayermodels_attempted)
 142         {
 143                 forceplayermodels_attempted = 1;
 144
 145                 // only if this failed, find it out on our own
 146                 entity e;
 147                 e = spawn();
 148                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 149                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 150                 forceplayermodels_model = e.model;
 151                 forceplayermodels_modelindex = e.modelindex;
 152                 forceplayermodels_skin = autocvar__cl_playerskin;
 153                 remove(e);
 154         }
 155
 156         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 157         {
 158                 entity e;
 159                 e = spawn();
 160                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 161                 forceplayermodels_myisgoodmodel = fexists(e.model);
 162                 forceplayermodels_mymodel = e.model;
 163                 forceplayermodels_mymodelindex = e.modelindex;
 164                 remove(e);
 165         }
 166
 167         // apply it
 168         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && islocalplayer)
 169         {
 170                 self.model = forceplayermodels_mymodel;
 171                 self.modelindex = forceplayermodels_mymodelindex;
 172                 self.skin = autocvar_cl_forcemyplayerskin;
 173         }
 174         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 175         {
 176                 self.model = forceplayermodels_model;
 177                 self.modelindex = forceplayermodels_modelindex;
 178                 self.skin = forceplayermodels_skin;
 179         }
 180         else if(self.forceplayermodels_isgoodmodel)
 181         {
 182                 self.model = self.forceplayermodels_savemodel;
 183                 self.modelindex = self.forceplayermodels_savemodelindex;
 184                 self.skin = self.forceplayermodels_saveskin;
 185         }
 186         else
 187         {
 188                 self.model = forceplayermodels_goodmodel;
 189                 self.modelindex = forceplayermodels_goodmodelindex;
 190                 self.skin = self.forceplayermodels_saveskin;
 191         }
 192
 193         // forceplayercolors too
 194         if(!teamplay)
 195         {
 196                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 197                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 198                 else if(autocvar_cl_forceplayercolors)
 199                         self.colormap = player_localnum + 1;
 200         }
 201 }
 202
 203 // FEATURE: fallback frames
 204 .float csqcmodel_saveframe;
 205 .float csqcmodel_saveframe2;
 206 .float csqcmodel_saveframe3;
 207 .float csqcmodel_saveframe4;
 208 .float csqcmodel_framecount;
 209
 210 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 211 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 212 {
 213         self.frame = self.csqcmodel_saveframe;
 214         self.frame2 = self.csqcmodel_saveframe2;
 215         self.frame3 = self.csqcmodel_saveframe3;
 216         self.frame4 = self.csqcmodel_saveframe4;
 217 }
 218 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 219 {
 220         self.csqcmodel_saveframe = self.frame;
 221         self.csqcmodel_saveframe2 = self.frame2;
 222         self.csqcmodel_saveframe3 = self.frame3;
 223         self.csqcmodel_saveframe4 = self.frame4;
 224
 225         // hack for death animations: set their frametime to zero in case a
 226         // player "pops in"
 227         if(isnew)
 228         {
 229 #define FIX_FRAMETIME(f,ft) \
 230                 if(IS_DEAD_FRAME(self.f)) \
 231                 { \
 232                         self.ft = self.death_time; \
 233                 }
 234                 FIX_FRAMETIME(frame, frame1time)
 235                 FIX_FRAMETIME(frame2, frame2time)
 236                 FIX_FRAMETIME(frame3, frame3time)
 237                 FIX_FRAMETIME(frame4, frame4time)
 238         }
 239         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 240 }
 241 float CSQCPlayer_FallbackFrame(float f)
 242 {
 243         if(frameduration(self.modelindex, f) > 0)
 244                 return f; // goooooood
 245         switch(f)
 246         {
 247                 case 23: return 11; // anim_melee -> anim_shoot
 248                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 249                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 250                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 251                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 252                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 253                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 254                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 255         }
 256         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 257         return f;
 258 }
 259 void CSQCPlayer_FallbackFrame_Apply(void)
 260 {
 261         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 262         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 263         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 264         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 265 }
 266
 267 // FEATURE: auto tag_index
 268 .entity tag_entity;
 269 .float tag_entity_lastmodelindex;
 270 .float tag_index;
 271 void CSQCModel_AutoTagIndex_Apply(void)
 272 {
 273         if(self.tag_entity && wasfreed(self.tag_entity))
 274                 self.tag_entity = world;
 275
 276         if(self.tag_networkentity)
 277         {
 278                 // we are ATTACHED!
 279                 float changed = 0;
 280                 if(self.tag_entity.entnum != self.tag_networkentity)
 281                 {
 282                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 283                         changed = 1;
 284                 }
 285
 286                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 287                 {
 288                         entity oldself = self;
 289                         self = self.tag_entity;
 290                         CSQCModel_Hook_PreDraw();
 291                         self = oldself;
 292                 }
 293
 294                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 295                 {
 296                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 297                         changed = 1;
 298                 }
 299                 if(changed)
 300                 {
 301                         if(self.tag_entity)
 302                         {
 303                                 // the best part is: IT EXISTS
 304                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 305                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 306                                         {
 307                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 308                                                 if(!self.tag_index)
 309                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 310                                                 if(!self.tag_index)
 311                                                 {
 312                                                         // we need to prevent this from 'appening
 313                                                         self.tag_entity = world;
 314                                                         self.drawmask = 0;
 315                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 316                                                 }
 317                                         }
 318
 319                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 320                                         if(substring(self.tag_entity.model, 0, 14) == "models/player/")
 321                                         {
 322                                                 self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 323                                                 if(!self.tag_index)
 324                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 325                                         }
 326
 327                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 328                                 {
 329                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 330                                         if(!self.tag_index)
 331                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 332                                 }
 333                         }
 334                         else
 335                         {
 336                                 // damn, see you next frame
 337                                 self.drawmask = 0;
 338                         }
 339                 }
 340         }
 341 }
 342
 343 // FEATURE: EF_NODRAW workalike
 344 float EF_BRIGHTFIELD    = 1;
 345 float EF_BRIGHTLIGHT    = 4;
 346 float EF_DIMLIGHT       = 8;
 347 float EF_DOUBLESIDED = 32768;
 348 float EF_NOSELFSHADOW = 65536;
 349 float EF_DYNAMICMODELLIGHT = 131072;
 350 float MF_ROCKET  =   1; // leave a trail
 351 float MF_GRENADE =   2; // leave a trail
 352 float MF_GIB     =   4; // leave a trail
 353 float MF_ROTATE  =   8; // rotate (bonus items)
 354 float MF_TRACER  =  16; // green split trail
 355 float MF_ZOMGIB  =  32; // small blood trail
 356 float MF_TRACER2 =  64; // orange split trail
 357 float MF_TRACER3 = 128; // purple trail
 358 .float csqcmodel_effects;
 359 .float csqcmodel_modelflags;
 360 void CSQCModel_Effects_PreUpdate(void)
 361 {
 362         self.effects = self.csqcmodel_effects;
 363         self.modelflags = self.csqcmodel_modelflags;
 364 }
 365 void CSQCModel_Effects_PostUpdate(void)
 366 {
 367         self.csqcmodel_effects = self.effects;
 368         self.csqcmodel_modelflags = self.modelflags;
 369         self.effects = 0;
 370         self.modelflags = 0;
 371         if(self.csqcmodel_teleported)
 372                 Projectile_ResetTrail(self.origin);
 373 }
 374 void CSQCModel_Effects_Apply(void)
 375 {
 376         float eff = self.csqcmodel_effects;
 377         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 378
 379         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 380         self.effects = 0;
 381         self.traileffect = 0;
 382
 383         if(eff & EF_BRIGHTFIELD)
 384                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 385         // ignoring EF_MUZZLEFLASH
 386         if(eff & EF_BRIGHTLIGHT)
 387                 adddynamiclight(self.origin, 400, '3 3 3');
 388         if(eff & EF_DIMLIGHT)
 389                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 390         if((eff & EF_NODRAW) || (self.alpha < 0))
 391                 self.drawmask = 0;
 392         if(eff & EF_ADDITIVE)
 393                 self.renderflags |= RF_ADDITIVE;
 394         if(eff & EF_BLUE)
 395                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 396         if(eff & EF_RED)
 397                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 398         // ignoring EF_NOGUNBOB
 399         if(eff & EF_FULLBRIGHT)
 400                 self.renderflags |= RF_FULLBRIGHT;
 401         if(eff & EF_FLAME)
 402                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 403         if(eff & EF_STARDUST)
 404                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 405         if(eff & EF_NOSHADOW)
 406                 self.renderflags |= RF_NOSHADOW;
 407         if(eff & EF_NODEPTHTEST)
 408                 self.renderflags |= RF_DEPTHHACK;
 409         // ignoring EF_SELECTABLE
 410         if(eff & EF_DOUBLESIDED)
 411                 self.effects |= EF_DOUBLESIDED;
 412         if(eff & EF_NOSELFSHADOW)
 413                 self.effects |= EF_NOSELFSHADOW;
 414         if(eff & EF_DYNAMICMODELLIGHT)
 415                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 416         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 417         if(self.csqcmodel_modelflags & MF_ROCKET)
 418                 self.traileffect = particleeffectnum("TR_ROCKET");
 419         if(self.csqcmodel_modelflags & MF_GRENADE)
 420                 self.traileffect = particleeffectnum("TR_GRENADE");
 421         if(self.csqcmodel_modelflags & MF_GIB)
 422                 self.traileffect = particleeffectnum("TR_BLOOD");
 423         if(self.csqcmodel_modelflags & MF_ROTATE)
 424         {
 425                 self.renderflags |= RF_USEAXIS;
 426                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 427         }
 428         if(self.csqcmodel_modelflags & MF_TRACER)
 429                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 430         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 431                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 432         if(self.csqcmodel_modelflags & MF_TRACER2)
 433                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 434         if(self.csqcmodel_modelflags & MF_TRACER3)
 435                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 436
 437         if(self.drawmask)
 438                 Projectile_DrawTrail(self.origin);
 439         else
 440                 Projectile_ResetTrail(self.origin);
 441
 442         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 443                 self.renderflags |= RF_ADDITIVE;
 444                 // also special in CSQCPlayer_GlowMod_Apply
 445 }
 446
 447 // FEATURE: auto glowmod
 448 .vector glowmod;
 449 void CSQCPlayer_GlowMod_Apply(void)
 450 {
 451         float cm = self.colormap;
 452
 453         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 454                 cm = 1024;
 455
 456         if(self.colormap > 0)
 457                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 458         else
 459                 self.glowmod = '1 1 1';
 460
 461         if(autocvar_cl_deathglow > 0)
 462                 if(self.csqcmodel_isdead)
 463                 {
 464                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 465                         // prevent the zero vector
 466                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 467                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 468                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 469                 }
 470 }
 471
 472 // general functions
 473 .float csqcmodel_predraw_run;
 474 void CSQCModel_Hook_PreDraw()
 475 {
 476         if(self.csqcmodel_predraw_run == framecount)
 477                 return;
 478         self.csqcmodel_predraw_run = framecount;
 479
 480         if(!self.modelindex || self.model == "null")
 481         {
 482                 self.drawmask = 0;
 483                 return;
 484         }
 485         else
 486                 self.drawmask = MASK_NORMAL;
 487
 488         if(self.isplayermodel) // this checks if it's a player MODEL!
 489         {
 490                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 491                 CSQCPlayer_GlowMod_Apply();
 492                 CSQCPlayer_LOD_Apply();
 493                 CSQCPlayer_FallbackFrame_Apply();
 494         }
 495
 496         CSQCModel_AutoTagIndex_Apply();
 497
 498         CSQCModel_Effects_Apply();
 499 }
 500
 501 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 502 {
 503         // revert to values from server
 504         CSQCModel_Effects_PreUpdate();
 505         if(self.isplayermodel)
 506         {
 507                 CSQCPlayer_FallbackFrame_PreUpdate();
 508                 CSQCPlayer_ForceModel_PreUpdate();
 509         }
 510 }
 511
 512 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 513 {
 514         // is it a player model? (shared state)
 515         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
 516
 517         // save values set by server
 518         if(self.isplayermodel)
 519         {
 520                 CSQCPlayer_ForceModel_PostUpdate();
 521                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 522         }
 523         CSQCModel_Effects_PostUpdate();
 524 }