Merge branch 'master' into develop
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / csqcmodel_hooks.qc
1 #include "csqcmodel_hooks.qh"
2
3 #include <client/mutators/_mod.qh>
4 #include <client/player_skeleton.qh>
5 #include <client/weapons/projectile.qh>
6 #include <common/animdecide.qh>
7 #include <common/effects/all.inc>
8 #include <common/effects/all.qh>
9 #include <common/ent_cs.qh>
10 #include <common/gamemodes/_mod.qh>
11 #include <common/mapinfo.qh>
12 #include <common/physics/movetypes/movetypes.qh>
13 #include <common/physics/player.qh>
14 #include <common/viewloc.qh>
15 #include <lib/csqcmodel/cl_model.qh>
16 #include <lib/csqcmodel/cl_player.qh>
17 #include <lib/csqcmodel/interpolate.qh>
18
19 .float death_time;
20 .int modelflags;
21
22 // FEATURE: LOD
23 .int lodmodelindex0;
24 .int lodmodelindex1;
25 .int lodmodelindex2;
26 void CSQCPlayer_LOD_Apply(entity this)
27 {
28         // LOD model loading
29         if(this.lodmodelindex0 != this.modelindex)
30         {
31                 string modelname = this.model;
32                 string s;
33
34                 vector mi = this.mins;
35                 vector ma = this.maxs;
36
37                 // set modelindex
38                 this.lodmodelindex0 = this.modelindex;
39                 this.lodmodelindex1 = this.modelindex;
40                 this.lodmodelindex2 = this.modelindex;
41
42                 // FIXME: this only supports 3-letter extensions
43                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
44                 if(fexists(s))
45                 {
46                         precache_model(s);
47                         _setmodel(this, s);
48                         if(this.modelindex)
49                                 this.lodmodelindex1 = this.modelindex;
50                 }
51
52                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
53                 if(fexists(s))
54                 {
55                         precache_model(s);
56                         _setmodel(this, s);
57                         if(this.modelindex)
58                                 this.lodmodelindex2 = this.modelindex;
59                 }
60
61                 _setmodel(this, modelname); // make everything normal again
62                 setsize(this, mi, ma);
63         }
64
65         // apply LOD
66         if(autocvar_cl_playerdetailreduction <= 0)
67         {
68                 if(autocvar_cl_playerdetailreduction <= -2)
69                         this.modelindex = this.lodmodelindex2;
70                 else if(autocvar_cl_playerdetailreduction <= -1)
71                         this.modelindex = this.lodmodelindex1;
72                 else
73                         this.modelindex = this.lodmodelindex0;
74         }
75         else
76         {
77                 float distance = vlen(this.origin - view_origin);
78                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
79                 f *= 1.0 / bound(0.01, view_quality, 1);
80                 if(f > autocvar_cl_loddistance2)
81                         this.modelindex = this.lodmodelindex2;
82                 else if(f > autocvar_cl_loddistance1)
83                         this.modelindex = this.lodmodelindex1;
84                 else
85                         this.modelindex = this.lodmodelindex0;
86         }
87 }
88
89 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
90 string forceplayermodels_model;
91 bool forceplayermodels_modelisgoodmodel;
92 int forceplayermodels_modelindex;
93 int forceplayermodels_skin;
94
95 string forceplayermodels_mymodel;
96 bool forceplayermodels_myisgoodmodel;
97 int forceplayermodels_mymodelindex;
98
99 bool forceplayermodels_attempted;
100
101 .string forceplayermodels_savemodel;
102 .int forceplayermodels_savemodelindex;
103 .int forceplayermodels_saveskin;
104 .int forceplayermodels_savecolormap;
105
106 .string forceplayermodels_isgoodmodel_mdl;
107 .bool forceplayermodels_isgoodmodel;
108
109 string forceplayermodels_goodmodel;
110 int forceplayermodels_goodmodelindex;
111
112 .vector glowmod;
113
114 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
115 {
116         this.model = this.forceplayermodels_savemodel;
117         this.modelindex = this.forceplayermodels_savemodelindex;
118         this.skin = this.forceplayermodels_saveskin;
119         this.colormap = this.forceplayermodels_savecolormap;
120 }
121 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
122 {
123         this.forceplayermodels_savemodel = this.model;
124         this.forceplayermodels_savemodelindex = this.modelindex;
125         this.forceplayermodels_saveskin = this.skin;
126         this.forceplayermodels_savecolormap = this.colormap;
127
128         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
129         {
130                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
131                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
132                 if(!this.forceplayermodels_isgoodmodel)
133                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
134         }
135 }
136 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
137 {
138         int cm = this.forceplayermodels_savecolormap;
139         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
140
141         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
142                 goto skipforcemodels;
143
144         // FORCEMODEL
145         // which one is ALWAYS good?
146         if (!forceplayermodels_goodmodel)
147         {
148                 entity e = spawn();
149                 precache_model(cvar_defstring("_cl_playermodel"));
150                 _setmodel(e, cvar_defstring("_cl_playermodel"));
151                 forceplayermodels_goodmodel = e.model;
152                 forceplayermodels_goodmodelindex = e.modelindex;
153                 delete(e);
154         }
155
156         // first, try finding it from the server
157         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
158         {
159                 if(islocalplayer)
160                 {
161                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
162                         {
163                                 // trust server's idea of "own player model"
164                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
165                                 forceplayermodels_model = this.forceplayermodels_savemodel;
166                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
167                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
168                                 forceplayermodels_attempted = 1;
169                         }
170                 }
171         }
172
173         // forcemodel finding
174         if(!forceplayermodels_attempted)
175         {
176                 forceplayermodels_attempted = 1;
177
178                 // only if this failed, find it out on our own
179                 entity e = spawn();
180                 precache_model(autocvar__cl_playermodel);
181                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
182                 forceplayermodels_modelisgoodmodel = fexists(e.model);
183                 forceplayermodels_model = e.model;
184                 forceplayermodels_modelindex = e.modelindex;
185                 forceplayermodels_skin = autocvar__cl_playerskin;
186                 delete(e);
187         }
188
189         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
190         {
191                 entity e = spawn();
192                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
193                 forceplayermodels_myisgoodmodel = fexists(e.model);
194                 forceplayermodels_mymodel = e.model;
195                 forceplayermodels_mymodelindex = e.modelindex;
196                 delete(e);
197         }
198
199         // apply it
200         bool isfriend;
201
202         if(teamplay)
203                 isfriend = (cm == 1024 + 17 * myteam);
204         else
205                 isfriend = islocalplayer;
206
207         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
208         {
209                 this.model = forceplayermodels_mymodel;
210                 this.modelindex = forceplayermodels_mymodelindex;
211                 this.skin = autocvar_cl_forcemyplayerskin;
212         }
213         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
214         {
215                 this.model = forceplayermodels_model;
216                 this.modelindex = forceplayermodels_modelindex;
217                 this.skin = forceplayermodels_skin;
218         }
219         else if(this.forceplayermodels_isgoodmodel)
220         {
221                 this.model = this.forceplayermodels_savemodel;
222                 this.modelindex = this.forceplayermodels_savemodelindex;
223                 this.skin = this.forceplayermodels_saveskin;
224         }
225         else
226         {
227                 this.model = forceplayermodels_goodmodel;
228                 this.modelindex = forceplayermodels_goodmodelindex;
229                 this.skin = this.forceplayermodels_saveskin;
230         }
231
232         LABEL(skipforcemodels)
233
234         if(MUTATOR_CALLHOOK(ForcePlayercolors_Skip, this, islocalplayer))
235                 goto skipforcecolors;
236
237         bool forceplayercolors_enabled = false;
238         #define fpc autocvar_cl_forceplayercolors
239         if (gametype.m_1v1)
240         {
241                 if ((myteam != NUM_SPECTATOR) && (fpc == 1 || fpc == 2 || fpc == 3 || fpc == 5))
242                         forceplayercolors_enabled = true;
243         }
244         else if (teamplay)
245         {
246                 if ((team_count == 2) && (myteam != NUM_SPECTATOR) && (fpc == 2 || fpc == 4 || fpc == 5))
247                         forceplayercolors_enabled = true;
248         }
249         else
250         {
251                 if (fpc == 1 || fpc == 2)
252                         forceplayercolors_enabled = true;
253         }
254
255         // forceplayercolors too
256         if(teamplay)
257         {
258                 // own team's color is never forced
259                 int forcecolor_friend = 0, forcecolor_enemy = 0;
260                 entity tm;
261
262                 if(autocvar_cl_forcemyplayercolors)
263                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
264
265                 if(forceplayercolors_enabled)
266                         forcecolor_enemy = 1024 + autocvar__cl_color;
267
268                 if(forcecolor_enemy && !forcecolor_friend)
269                 {
270                         // only enemy color is forced?
271                         // verify it is not equal to the friend color
272                         if(forcecolor_enemy == 1024 + 17 * myteam)
273                                 forcecolor_enemy = 0;
274                 }
275
276                 if(forcecolor_friend && !forcecolor_enemy)
277                 {
278                         // only friend color is forced?
279                         // verify it is not equal to the enemy color
280                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
281                                 // note: we even compare against our own team.
282                                 // if we rejected because we matched our OWN team color,
283                                 // this is not bad; we then simply keep our color as is
284                                 // anyway.
285                                 if(forcecolor_friend == 1024 + 17 * tm.team)
286                                         forcecolor_friend = 0;
287                 }
288
289                 if(cm == 1024 + 17 * myteam)
290                 {
291                         if(forcecolor_friend)
292                                 this.colormap = forcecolor_friend;
293                 }
294                 else
295                 {
296                         if(forcecolor_enemy)
297                                 this.colormap = forcecolor_enemy;
298                 }
299         }
300         else // if(!teamplay)
301         {
302                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
303                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
304                 else if (autocvar_cl_forceuniqueplayercolors && !islocalplayer && !gametype.m_1v1)
305                 {
306                         // Assign each enemy unique colors
307                         // pick colors from 0 to 14 since 15 is the rainbow color
308                         // pl01 0 1, pl02 1 2, ..., pl14 13 14, pl15 14 0
309                         // pl16 0 2, pl17 1 3, ..., pl29 13  0, pl30 14 1
310                         int num = this.entnum - 1;
311                         int c1 = num % 15;
312                         int q = floor(num / 15);
313                         int c2 = (c1 + 1 + q) % 15;
314                         this.colormap = 1024 + (c1 << 4) + c2;
315                 }
316                 else if(forceplayercolors_enabled)
317                         this.colormap = player_localnum + 1;
318         }
319
320         LABEL(skipforcecolors)
321
322         if((this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST) && !autocvar_cl_respawn_ghosts_keepcolors)
323         {
324                 this.glowmod = '0 0 0';
325                 this.colormap = 0;
326                 return;
327         }
328
329         // GLOWMOD AND DEATH FADING
330         if(this.colormap > 0)
331                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true);
332         else
333                 this.glowmod = '1 1 1';
334
335         if(autocvar_cl_deathglow > 0)
336         {
337                 if(this.csqcmodel_isdead)
338                 {
339                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
340                         if(this.colormap > 0)
341                                 min_factor /= 2;
342                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
343                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
344                         if (this.glowmod == '0 0 0')
345                                 this.glowmod.x = 0.000001;
346                 }
347         }
348
349         // don't let the engine increase player's glowmod
350         if (autocvar_r_hdr_glowintensity > 1)
351                 this.glowmod /= autocvar_r_hdr_glowintensity;
352
353         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
354 }
355
356 // FEATURE: fallback frames
357 .int csqcmodel_saveframe;
358 .int csqcmodel_saveframe2;
359 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
360 .int csqcmodel_saveframe3;
361 .int csqcmodel_saveframe4;
362 #endif
363 .int csqcmodel_framecount;
364
365 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
366 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
367 {
368         this.frame = this.csqcmodel_saveframe;
369         this.frame2 = this.csqcmodel_saveframe2;
370 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
371         this.frame3 = this.csqcmodel_saveframe3;
372         this.frame4 = this.csqcmodel_saveframe4;
373 #endif
374 }
375 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
376 {
377         this.csqcmodel_saveframe = this.frame;
378         this.csqcmodel_saveframe2 = this.frame2;
379 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
380         this.csqcmodel_saveframe3 = this.frame3;
381         this.csqcmodel_saveframe4 = this.frame4;
382 #endif
383
384         // hack for death animations: set their frametime to zero in case a
385         // player "pops in"
386         if(isnew)
387         {
388 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
389                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
390                         this.ft = this.death_time; \
391 MACRO_END
392                 FIX_FRAMETIME(frame, frame1time);
393                 FIX_FRAMETIME(frame2, frame2time);
394 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
395                 FIX_FRAMETIME(frame3, frame3time);
396                 FIX_FRAMETIME(frame4, frame4time);
397 #endif
398         }
399         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
400 }
401 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
402 {
403         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
404 }
405 int CSQCPlayer_FallbackFrame(entity this, int f)
406 {
407         TC(int, f);
408         if(frameduration(this.modelindex, f) > 0)
409                 return f; // goooooood
410         if(frameduration(this.modelindex, 1) <= 0)
411                 return f; // this is a static model. We can't fix it if we wanted to
412         switch(f)
413         {
414                 case 23: return 11; // anim_melee -> anim_shoot
415                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
416                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
417                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
418                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
419                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
420                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
421                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
422         }
423         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
424         return f;
425 }
426 void CSQCPlayer_FallbackFrame_Apply(entity this)
427 {
428         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
429         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
430 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
431         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
432         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
433 #endif
434 }
435
436 // FEATURE: auto tag_index
437 .entity tag_entity;
438 .int tag_entity_lastmodelindex;
439 .int tag_index;
440 void CSQCModel_AutoTagIndex_Apply(entity this)
441 {
442         if(this.tag_entity && wasfreed(this.tag_entity))
443                 this.tag_entity = NULL;
444
445         MUTATOR_CALLHOOK(TagIndex_Update, this);
446
447         if(this.tag_networkentity)
448         {
449                 // we are ATTACHED!
450                 bool changed = 0;
451                 if(this.tag_entity.entnum != this.tag_networkentity)
452                 {
453                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
454                         changed = 1;
455                 }
456
457                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
458                 if(this.tag_entity.classname == "ENT_CLIENT_MODEL")
459                 {
460                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
461                 }
462
463                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
464                 {
465                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
466                         changed = 1;
467                 }
468                 if(changed)
469                 {
470                         if(this.tag_entity)
471                         {
472                                 // the best part is: IT EXISTS
473                                 if(substring(this.model, 0, 14) == "models/weapons")
474                                 {
475                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
476                                         {
477                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
478                                                 if(!this.tag_index)
479                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
480                                                 if(!this.tag_index)
481                                                 {
482                                                         // we need to prevent this from 'appening
483                                                         this.tag_entity = NULL;
484                                                         this.drawmask = 0;
485                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
486                                                 }
487                                         }
488                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
489                                         {
490                                                 skeleton_loadinfo(this.tag_entity);
491                                                 this.tag_index = this.tag_entity.bone_weapon;
492                                         }
493                                 }
494
495                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
496                                 {
497                                         this.tag_index = gettagindex(this.tag_entity, "shot");
498                                         if(!this.tag_index)
499                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
500                                 }
501
502                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
503                         }
504                         else
505                         {
506                                 // damn, see you next frame
507                                 this.drawmask = 0;
508                         }
509                 }
510         }
511 }
512
513 void CSQCModel_Effects_PreUpdate(entity this)
514 {
515         this.effects = this.csqcmodel_effects;
516         this.modelflags = this.csqcmodel_modelflags;
517         this.traileffect = this.csqcmodel_traileffect;
518 }
519 void Reset_ArcBeam();
520 void CSQCModel_Effects_PostUpdate(entity this)
521 {
522         if (this == csqcplayer) {
523                 if (this.csqcmodel_teleported) {
524                         Reset_ArcBeam();
525                 }
526         }
527         this.csqcmodel_effects = this.effects;
528         this.csqcmodel_modelflags = this.modelflags;
529         this.csqcmodel_traileffect = this.traileffect;
530         this.effects = 0;
531         this.modelflags = 0;
532         if(this.csqcmodel_teleported)
533                 Projectile_ResetTrail(this, this.origin);
534 }
535 .int snd_looping;
536 void CSQCModel_Effects_Apply(entity this)
537 {
538         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
539         int tref = this.csqcmodel_traileffect;
540
541         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
542         this.effects = 0;
543         this.traileffect = 0;
544
545         if(eff & EF_BRIGHTFIELD)
546                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
547         // ignoring EF_MUZZLEFLASH
548         if(eff & EF_BRIGHTLIGHT)
549                 adddynamiclight(this.origin, 400, '3 3 3');
550         if(eff & EF_DIMLIGHT)
551                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
552         if((eff & EF_NODRAW) || (this.alpha < 0))
553                 this.drawmask = 0;
554         if(eff & EF_ADDITIVE)
555                 this.renderflags |= RF_ADDITIVE;
556         if(eff & EF_BLUE)
557                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
558         if(eff & EF_RED)
559                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
560         // ignoring EF_NOGUNBOB
561         if(eff & EF_FULLBRIGHT)
562                 this.renderflags |= RF_FULLBRIGHT;
563         if(eff & EF_FLAME)
564         {
565                 boxparticles(particleeffectnum(EFFECT_EF_FLAME), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
566                 //pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
567         }
568         if(eff & EF_STARDUST)
569         {
570                 boxparticles(particleeffectnum(EFFECT_EF_STARDUST), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
571                 //pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
572         }
573         if(eff & EF_NOSHADOW)
574                 this.renderflags |= RF_NOSHADOW;
575         if(eff & EF_NODEPTHTEST)
576                 this.renderflags |= RF_DEPTHHACK;
577         // ignoring EF_SELECTABLE
578         if(eff & EF_DOUBLESIDED)
579                 this.effects |= EF_DOUBLESIDED;
580         if(eff & EF_NOSELFSHADOW)
581                 this.effects |= EF_NOSELFSHADOW;
582         if(eff & EF_DYNAMICMODELLIGHT)
583                 this.renderflags |= RF_DYNAMICMODELLIGHT;
584         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
585         if(this.csqcmodel_modelflags & MF_ROCKET)
586                 tref = EFFECT_TR_ROCKET.m_id;
587         if(this.csqcmodel_modelflags & MF_GRENADE)
588                 tref = EFFECT_TR_GRENADE.m_id;
589         if(this.csqcmodel_modelflags & MF_GIB)
590                 tref = EFFECT_TR_BLOOD.m_id;
591         if(this.csqcmodel_modelflags & MF_ROTATE)
592         {
593                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
594                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
595                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
596                 this.renderflags |= RF_USEAXIS;
597                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
598         }
599         if(this.csqcmodel_modelflags & MF_TRACER)
600                 tref = EFFECT_TR_WIZSPIKE.m_id;
601         if(this.csqcmodel_modelflags & MF_ZOMGIB)
602                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
603         if(this.csqcmodel_modelflags & MF_TRACER2)
604                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
605         if(this.csqcmodel_modelflags & MF_TRACER3)
606                 tref = EFFECT_TR_VORESPIKE.m_id;
607
608         this.traileffect = tref;
609
610         if(this.drawmask)
611                 Projectile_DrawTrail(this, this.origin);
612         else
613                 Projectile_ResetTrail(this, this.origin);
614
615         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
616                 this.renderflags |= RF_ADDITIVE;
617                 // also special in CSQCPlayer_GlowMod_Apply
618
619         if(this.csqcmodel_modelflags & MF_ROCKET)
620         {
621                 if(!this.snd_looping)
622                 {
623                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
624                         this.snd_looping = CH_TRIGGER_SINGLE;
625                 }
626         }
627         else
628         {
629                 if(this.snd_looping)
630                 {
631                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
632                         this.snd_looping = 0;
633                 }
634         }
635 }
636
637 // general functions
638 .int csqcmodel_predraw_run;
639 .int anim_frame;
640 .int anim_frame1time;
641 .int anim_frame2;
642 .int anim_frame2time;
643 .int anim_saveframe;
644 .int anim_saveframe1time;
645 .int anim_saveframe2;
646 .int anim_saveframe2time;
647 .int anim_prev_pmove_flags;
648 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
649 {
650         if(this.csqcmodel_predraw_run == framecount)
651                 return;
652         this.csqcmodel_predraw_run = framecount;
653
654         if(!this.modelindex || this.model == "null")
655         {
656                 this.drawmask = 0;
657                 if(this.snd_looping > 0)
658                 {
659                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
660                         this.snd_looping = 0;
661                 }
662                 return;
663         }
664         else
665                 this.drawmask = MASK_NORMAL;
666
667         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
668         {
669                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
670                 CSQCPlayer_LOD_Apply(this);
671
672                 if(!isplayer)
673                 {
674                         skeleton_loadinfo(this);
675                         bool doblend = (this.bone_upperbody >= 0);
676                         CSQCPlayer_FallbackFrame_Apply(this);
677                         if(doblend)
678                         {
679                                 skeleton_from_frames(this, this.csqcmodel_isdead);
680                         }
681                         else
682                         {
683                                 free_skeleton_from_frames(this);
684                                 // just in case, clear these (we're animating in frame and frame3)
685                                 this.lerpfrac = 0;
686                                 this.lerpfrac4 = 0;
687                         }
688                 }
689                 else
690                 {
691                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
692                         skeleton_loadinfo(this);
693                         bool doblend = (this.bone_upperbody >= 0);
694                         bool onground = 0;
695                         if(this == csqcplayer)
696                         {
697                                 if(IS_ONGROUND(this))
698                                         onground = 1;
699                                 this.anim_prev_pmove_flags = this.flags;
700                                 if(this.flags & FL_DUCKED)
701                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
702                                 else if(this.anim_state & ANIMSTATE_DUCK)
703                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
704                         }
705                         else
706                         {
707                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
708                                 if(trace_startsolid || trace_fraction < 1)
709                                         onground = 1;
710                                 // predicted clients handle smoothing in the prediction code
711                                 this.origin = CSQCModel_ApplyStairSmoothing(this, onground, this.origin);
712                         }
713                         animdecide_load_if_needed(this);
714                         animdecide_setimplicitstate(this, onground);
715                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
716                         int sf = 0;
717                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
718                                 sf |= CSQCMODEL_PROPERTY_FRAME;
719                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
720                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
721                         this.anim_saveframe = this.anim_frame;
722                         this.anim_saveframe1time = this.anim_frame1time;
723                         this.anim_saveframe2 = this.anim_frame2;
724                         this.anim_saveframe2time = this.anim_frame2time;
725                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
726                         // This ensures that .frame etc. are always written.
727                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
728                         this.lerpfrac = (doblend ? 0.5 : 0);
729                         this.frame = this.anim_frame;
730                         this.frame1time = this.anim_frame1time;
731                         this.frame2 = this.anim_frame2;
732                         this.frame2time = this.anim_frame2time;
733                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
734                         CSQCModel_InterpolateAnimation_2To4_Do(this);
735                         if(doblend)
736                         {
737                                 skeleton_from_frames(this, this.csqcmodel_isdead);
738                         }
739                         else
740                         {
741                                 free_skeleton_from_frames(this);
742                                 // just in case, clear these (we're animating in frame and frame3)
743                                 this.lerpfrac = 0;
744                                 this.lerpfrac4 = 0;
745                         }
746                 }
747         }
748
749         CSQCModel_AutoTagIndex_Apply(this);
750
751         CSQCModel_Effects_Apply(this);
752 }
753
754 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
755 {
756         // interpolate v_angle
757         this.iflags |= IFLAG_V_ANGLE_X;
758         // revert to values from server
759         CSQCModel_Effects_PreUpdate(this);
760         if((this.isplayermodel & ISPLAYER_MODEL))
761         {
762                 if(!isplayer)
763                         CSQCPlayer_FallbackFrame_PreUpdate(this);
764                 CSQCPlayer_ModelAppearance_PreUpdate(this);
765         }
766 }
767
768 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
769 {
770         // is it a player model? (shared state)
771         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" || 
772                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
773         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
774         this.csqcmodel_isdead = false; // workaround for dead players who become a spectator
775
776         // save values set by server
777         if((this.isplayermodel & ISPLAYER_MODEL))
778         {
779                 CSQCPlayer_ModelAppearance_PostUpdate(this);
780                 if(isplayer)
781                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
782                 else
783                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
784         }
785         CSQCModel_Effects_PostUpdate(this);
786 }