qcsrc/client/csqcmodel_hooks.qc

   1 #include "csqcmodel_hooks.qh"
   2
   3 #include <client/mutators/_mod.qh>
   4 #include <client/player_skeleton.qh>
   5 #include <client/weapons/projectile.qh>
   6 #include <common/animdecide.qh>
   7 #include <common/effects/all.inc>
   8 #include <common/effects/all.qh>
   9 #include <common/ent_cs.qh>
  10 #include <common/gamemodes/_mod.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/viewloc.qh>
  15 #include <lib/csqcmodel/cl_model.qh>
  16 #include <lib/csqcmodel/cl_player.qh>
  17 #include <lib/csqcmodel/interpolate.qh>
  18
  19 .float death_time;
  20 .int modelflags;
  21
  22 // FEATURE: LOD
  23 .int lodmodelindex0;
  24 .int lodmodelindex1;
  25 .int lodmodelindex2;
  26 void CSQCPlayer_LOD_Apply(entity this)
  27 {
  28         // LOD model loading
  29         if(this.lodmodelindex0 != this.modelindex)
  30         {
  31                 string modelname = this.model;
  32                 string s;
  33
  34                 vector mi = this.mins;
  35                 vector ma = this.maxs;
  36
  37                 // set modelindex
  38                 this.lodmodelindex0 = this.modelindex;
  39                 this.lodmodelindex1 = this.modelindex;
  40                 this.lodmodelindex2 = this.modelindex;
  41
  42                 // FIXME: this only supports 3-letter extensions
  43                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  44                 if(fexists(s))
  45                 {
  46                         precache_model(s);
  47                         _setmodel(this, s);
  48                         if(this.modelindex)
  49                                 this.lodmodelindex1 = this.modelindex;
  50                 }
  51
  52                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  53                 if(fexists(s))
  54                 {
  55                         precache_model(s);
  56                         _setmodel(this, s);
  57                         if(this.modelindex)
  58                                 this.lodmodelindex2 = this.modelindex;
  59                 }
  60
  61                 _setmodel(this, modelname); // make everything normal again
  62                 setsize(this, mi, ma);
  63         }
  64
  65         // apply LOD
  66         if(autocvar_cl_playerdetailreduction <= 0)
  67         {
  68                 if(autocvar_cl_playerdetailreduction <= -2)
  69                         this.modelindex = this.lodmodelindex2;
  70                 else if(autocvar_cl_playerdetailreduction <= -1)
  71                         this.modelindex = this.lodmodelindex1;
  72                 else
  73                         this.modelindex = this.lodmodelindex0;
  74         }
  75         else
  76         {
  77                 float distance = vlen(this.origin - view_origin);
  78                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  79                 f *= 1.0 / bound(0.01, view_quality, 1);
  80                 if(f > autocvar_cl_loddistance2)
  81                         this.modelindex = this.lodmodelindex2;
  82                 else if(f > autocvar_cl_loddistance1)
  83                         this.modelindex = this.lodmodelindex1;
  84                 else
  85                         this.modelindex = this.lodmodelindex0;
  86         }
  87 }
  88
  89 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  90 string forceplayermodels_model;
  91 bool forceplayermodels_modelisgoodmodel;
  92 int forceplayermodels_modelindex;
  93 int forceplayermodels_skin;
  94
  95 string forceplayermodels_mymodel;
  96 bool forceplayermodels_myisgoodmodel;
  97 int forceplayermodels_mymodelindex;
  98
  99 bool forceplayermodels_attempted;
 100
 101 .string forceplayermodels_savemodel;
 102 .int forceplayermodels_savemodelindex;
 103 .int forceplayermodels_saveskin;
 104 .int forceplayermodels_savecolormap;
 105
 106 .string forceplayermodels_isgoodmodel_mdl;
 107 .bool forceplayermodels_isgoodmodel;
 108
 109 string forceplayermodels_goodmodel;
 110 int forceplayermodels_goodmodelindex;
 111
 112 .vector glowmod;
 113
 114 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
 115 {
 116         this.model = this.forceplayermodels_savemodel;
 117         this.modelindex = this.forceplayermodels_savemodelindex;
 118         this.skin = this.forceplayermodels_saveskin;
 119         this.colormap = this.forceplayermodels_savecolormap;
 120 }
 121 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
 122 {
 123         this.forceplayermodels_savemodel = this.model;
 124         this.forceplayermodels_savemodelindex = this.modelindex;
 125         this.forceplayermodels_saveskin = this.skin;
 126         this.forceplayermodels_savecolormap = this.colormap;
 127
 128         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
 129         {
 130                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
 131                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
 132                 if(!this.forceplayermodels_isgoodmodel)
 133                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
 134         }
 135 }
 136 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
 137 {
 138         int cm = this.forceplayermodels_savecolormap;
 139         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
 140
 141         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
 142                 goto skipforcemodels;
 143
 144         // FORCEMODEL
 145         // which one is ALWAYS good?
 146         if (!forceplayermodels_goodmodel)
 147         {
 148                 entity e = spawn();
 149                 precache_model(cvar_defstring("_cl_playermodel"));
 150                 _setmodel(e, cvar_defstring("_cl_playermodel"));
 151                 forceplayermodels_goodmodel = e.model;
 152                 forceplayermodels_goodmodelindex = e.modelindex;
 153                 delete(e);
 154         }
 155
 156         // first, try finding it from the server
 157         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
 158         {
 159                 if(islocalplayer)
 160                 {
 161                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 162                         {
 163                                 // trust server's idea of "own player model"
 164                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
 165                                 forceplayermodels_model = this.forceplayermodels_savemodel;
 166                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
 167                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
 168                                 forceplayermodels_attempted = 1;
 169                         }
 170                 }
 171         }
 172
 173         // forcemodel finding
 174         if(!forceplayermodels_attempted)
 175         {
 176                 forceplayermodels_attempted = 1;
 177
 178                 // only if this failed, find it out on our own
 179                 entity e = spawn();
 180                 precache_model(autocvar__cl_playermodel);
 181                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 182                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 183                 forceplayermodels_model = e.model;
 184                 forceplayermodels_modelindex = e.modelindex;
 185                 forceplayermodels_skin = autocvar__cl_playerskin;
 186                 delete(e);
 187         }
 188
 189         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 190         {
 191                 entity e = spawn();
 192                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 193                 forceplayermodels_myisgoodmodel = fexists(e.model);
 194                 forceplayermodels_mymodel = e.model;
 195                 forceplayermodels_mymodelindex = e.modelindex;
 196                 delete(e);
 197         }
 198
 199         // apply it
 200         bool isfriend;
 201
 202         if(teamplay)
 203                 isfriend = (cm == 1024 + 17 * myteam);
 204         else
 205                 isfriend = islocalplayer;
 206
 207         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 208         {
 209                 this.model = forceplayermodels_mymodel;
 210                 this.modelindex = forceplayermodels_mymodelindex;
 211                 this.skin = autocvar_cl_forcemyplayerskin;
 212         }
 213         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 214         {
 215                 this.model = forceplayermodels_model;
 216                 this.modelindex = forceplayermodels_modelindex;
 217                 this.skin = forceplayermodels_skin;
 218         }
 219         else if(this.forceplayermodels_isgoodmodel)
 220         {
 221                 this.model = this.forceplayermodels_savemodel;
 222                 this.modelindex = this.forceplayermodels_savemodelindex;
 223                 this.skin = this.forceplayermodels_saveskin;
 224         }
 225         else
 226         {
 227                 this.model = forceplayermodels_goodmodel;
 228                 this.modelindex = forceplayermodels_goodmodelindex;
 229                 this.skin = this.forceplayermodels_saveskin;
 230         }
 231
 232         LABEL(skipforcemodels)
 233
 234         if(MUTATOR_CALLHOOK(ForcePlayercolors_Skip, this, islocalplayer))
 235                 goto skipforcecolors;
 236
 237         // forceplayercolors too
 238         if(teamplay)
 239         {
 240                 // own team's color is never forced
 241                 int forcecolor_friend = 0;
 242                 int forcecolor_enemy = 0;
 243                 entity tm;
 244
 245                 if(autocvar_cl_forcemyplayercolors)
 246                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 247                 if(autocvar_cl_forceplayercolors != 3 && autocvar_cl_forceplayercolors == 2 && team_count == 2)
 248                         forcecolor_enemy = 1024 + autocvar__cl_color;
 249
 250                 if(forcecolor_enemy && !forcecolor_friend)
 251                 {
 252                         // only enemy color is forced?
 253                         // verify it is not equal to the friend color
 254                         if(forcecolor_enemy == 1024 + 17 * myteam)
 255                                 forcecolor_enemy = 0;
 256                 }
 257
 258                 if(forcecolor_friend && !forcecolor_enemy)
 259                 {
 260                         // only friend color is forced?
 261                         // verify it is not equal to the enemy color
 262                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 263                                 // note: we even compare against our own team.
 264                                 // if we rejected because we matched our OWN team color,
 265                                 // this is not bad; we then simply keep our color as is
 266                                 // anyway.
 267                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 268                                         forcecolor_friend = 0;
 269                 }
 270
 271                 if(cm == 1024 + 17 * myteam)
 272                 {
 273                         if(forcecolor_friend)
 274                                 this.colormap = forcecolor_friend;
 275                 }
 276                 else
 277                 {
 278                         if(forcecolor_enemy)
 279                                 this.colormap = forcecolor_enemy;
 280                 }
 281         }
 282         else // if(!teamplay)
 283         {
 284                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 285                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 286                 else if (autocvar_cl_forceuniqueplayercolors && !islocalplayer && !ISGAMETYPE(DUEL))
 287                 {
 288                         // Assign each enemy unique colors
 289                         // pick colors from 0 to 14 since 15 is the rainbow color
 290                         // pl01 0 1, pl02 1 2, ..., pl14 13 14, pl15 14 0
 291                         // pl16 0 2, pl17 1 3, ..., pl29 13  0, pl30 14 1
 292                         int num = this.entnum - 1;
 293                         int c1 = num % 15;
 294                         int q = floor(num / 15);
 295                         int c2 = (c1 + 1 + q) % 15;
 296                         this.colormap = 1024 + (c1 << 4) + c2;
 297                 }
 298                 else if(autocvar_cl_forceplayercolors && (autocvar_cl_forceplayercolors != 3 || ISGAMETYPE(DUEL)))
 299                         this.colormap = player_localnum + 1;
 300         }
 301
 302         LABEL(skipforcecolors)
 303
 304         if((this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST) && !autocvar_cl_respawn_ghosts_keepcolors)
 305         {
 306                 this.glowmod = '0 0 0';
 307                 this.colormap = 0;
 308                 return;
 309         }
 310
 311         // GLOWMOD AND DEATH FADING
 312         if(this.colormap > 0)
 313                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true) * 2;
 314         else
 315                 this.glowmod = '1 1 1';
 316
 317         if(autocvar_cl_deathglow > 0)
 318         {
 319                 if(this.csqcmodel_isdead)
 320                 {
 321                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
 322                         if(this.colormap > 0)
 323                                 min_factor /= 2;
 324                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
 325                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
 326                         if (this.glowmod == '0 0 0')
 327                                 this.glowmod.x = 0.000001;
 328                 }
 329         }
 330
 331         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
 332 }
 333
 334 // FEATURE: fallback frames
 335 .int csqcmodel_saveframe;
 336 .int csqcmodel_saveframe2;
 337 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 338 .int csqcmodel_saveframe3;
 339 .int csqcmodel_saveframe4;
 340 #endif
 341 .int csqcmodel_framecount;
 342
 343 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 344 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
 345 {
 346         this.frame = this.csqcmodel_saveframe;
 347         this.frame2 = this.csqcmodel_saveframe2;
 348 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 349         this.frame3 = this.csqcmodel_saveframe3;
 350         this.frame4 = this.csqcmodel_saveframe4;
 351 #endif
 352 }
 353 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
 354 {
 355         this.csqcmodel_saveframe = this.frame;
 356         this.csqcmodel_saveframe2 = this.frame2;
 357 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 358         this.csqcmodel_saveframe3 = this.frame3;
 359         this.csqcmodel_saveframe4 = this.frame4;
 360 #endif
 361
 362         // hack for death animations: set their frametime to zero in case a
 363         // player "pops in"
 364         if(isnew)
 365         {
 366 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
 367                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
 368                         this.ft = this.death_time; \
 369 MACRO_END
 370                 FIX_FRAMETIME(frame, frame1time);
 371                 FIX_FRAMETIME(frame2, frame2time);
 372 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 373                 FIX_FRAMETIME(frame3, frame3time);
 374                 FIX_FRAMETIME(frame4, frame4time);
 375 #endif
 376         }
 377         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
 378 }
 379 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
 380 {
 381         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 382 }
 383 int CSQCPlayer_FallbackFrame(entity this, int f)
 384 {
 385         TC(int, f);
 386         if(frameduration(this.modelindex, f) > 0)
 387                 return f; // goooooood
 388         if(frameduration(this.modelindex, 1) <= 0)
 389                 return f; // this is a static model. We can't fix it if we wanted to
 390         switch(f)
 391         {
 392                 case 23: return 11; // anim_melee -> anim_shoot
 393                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 394                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 395                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 396                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 397                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 398                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 399                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 400         }
 401         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
 402         return f;
 403 }
 404 void CSQCPlayer_FallbackFrame_Apply(entity this)
 405 {
 406         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
 407         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
 408 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 409         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
 410         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
 411 #endif
 412 }
 413
 414 // FEATURE: auto tag_index
 415 .entity tag_entity;
 416 .int tag_entity_lastmodelindex;
 417 .int tag_index;
 418 void CSQCModel_AutoTagIndex_Apply(entity this)
 419 {
 420         if(this.tag_entity && wasfreed(this.tag_entity))
 421                 this.tag_entity = NULL;
 422
 423         MUTATOR_CALLHOOK(TagIndex_Update, this);
 424
 425         if(this.tag_networkentity)
 426         {
 427                 // we are ATTACHED!
 428                 bool changed = 0;
 429                 if(this.tag_entity.entnum != this.tag_networkentity)
 430                 {
 431                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
 432                         changed = 1;
 433                 }
 434
 435                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 436                 if(this.tag_entity.classname == "ENT_CLIENT_MODEL")
 437                 {
 438                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
 439                 }
 440
 441                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
 442                 {
 443                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
 444                         changed = 1;
 445                 }
 446                 if(changed)
 447                 {
 448                         if(this.tag_entity)
 449                         {
 450                                 // the best part is: IT EXISTS
 451                                 if(substring(this.model, 0, 14) == "models/weapons")
 452                                 {
 453                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 454                                         {
 455                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
 456                                                 if(!this.tag_index)
 457                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
 458                                                 if(!this.tag_index)
 459                                                 {
 460                                                         // we need to prevent this from 'appening
 461                                                         this.tag_entity = NULL;
 462                                                         this.drawmask = 0;
 463                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
 464                                                 }
 465                                         }
 466                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
 467                                         {
 468                                                 skeleton_loadinfo(this.tag_entity);
 469                                                 this.tag_index = this.tag_entity.bone_weapon;
 470                                         }
 471                                 }
 472
 473                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 474                                 {
 475                                         this.tag_index = gettagindex(this.tag_entity, "shot");
 476                                         if(!this.tag_index)
 477                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
 478                                 }
 479
 480                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
 481                         }
 482                         else
 483                         {
 484                                 // damn, see you next frame
 485                                 this.drawmask = 0;
 486                         }
 487                 }
 488         }
 489 }
 490
 491 void CSQCModel_Effects_PreUpdate(entity this)
 492 {
 493         this.effects = this.csqcmodel_effects;
 494         this.modelflags = this.csqcmodel_modelflags;
 495         this.traileffect = this.csqcmodel_traileffect;
 496 }
 497 void Reset_ArcBeam();
 498 void CSQCModel_Effects_PostUpdate(entity this)
 499 {
 500         if (this == csqcplayer) {
 501                 if (this.csqcmodel_teleported) {
 502                         Reset_ArcBeam();
 503                 }
 504         }
 505         this.csqcmodel_effects = this.effects;
 506         this.csqcmodel_modelflags = this.modelflags;
 507         this.csqcmodel_traileffect = this.traileffect;
 508         this.effects = 0;
 509         this.modelflags = 0;
 510         if(this.csqcmodel_teleported)
 511                 Projectile_ResetTrail(this, this.origin);
 512 }
 513 .int snd_looping;
 514 void CSQCModel_Effects_Apply(entity this)
 515 {
 516         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
 517         int tref = this.csqcmodel_traileffect;
 518
 519         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 520         this.effects = 0;
 521         this.traileffect = 0;
 522
 523         if(eff & EF_BRIGHTFIELD)
 524                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
 525         // ignoring EF_MUZZLEFLASH
 526         if(eff & EF_BRIGHTLIGHT)
 527                 adddynamiclight(this.origin, 400, '3 3 3');
 528         if(eff & EF_DIMLIGHT)
 529                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
 530         if((eff & EF_NODRAW) || (this.alpha < 0))
 531                 this.drawmask = 0;
 532         if(eff & EF_ADDITIVE)
 533                 this.renderflags |= RF_ADDITIVE;
 534         if(eff & EF_BLUE)
 535                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
 536         if(eff & EF_RED)
 537                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
 538         // ignoring EF_NOGUNBOB
 539         if(eff & EF_FULLBRIGHT)
 540                 this.renderflags |= RF_FULLBRIGHT;
 541         if(eff & EF_FLAME)
 542         {
 543                 boxparticles(particleeffectnum(EFFECT_EF_FLAME), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 544                 //pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
 545         }
 546         if(eff & EF_STARDUST)
 547         {
 548                 boxparticles(particleeffectnum(EFFECT_EF_STARDUST), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 549                 //pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
 550         }
 551         if(eff & EF_NOSHADOW)
 552                 this.renderflags |= RF_NOSHADOW;
 553         if(eff & EF_NODEPTHTEST)
 554                 this.renderflags |= RF_DEPTHHACK;
 555         // ignoring EF_SELECTABLE
 556         if(eff & EF_DOUBLESIDED)
 557                 this.effects |= EF_DOUBLESIDED;
 558         if(eff & EF_NOSELFSHADOW)
 559                 this.effects |= EF_NOSELFSHADOW;
 560         if(eff & EF_DYNAMICMODELLIGHT)
 561                 this.renderflags |= RF_DYNAMICMODELLIGHT;
 562         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 563         if(this.csqcmodel_modelflags & MF_ROCKET)
 564                 tref = EFFECT_TR_ROCKET.m_id;
 565         if(this.csqcmodel_modelflags & MF_GRENADE)
 566                 tref = EFFECT_TR_GRENADE.m_id;
 567         if(this.csqcmodel_modelflags & MF_GIB)
 568                 tref = EFFECT_TR_BLOOD.m_id;
 569         if(this.csqcmodel_modelflags & MF_ROTATE)
 570         {
 571                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
 572                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
 573                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
 574                 this.renderflags |= RF_USEAXIS;
 575                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
 576         }
 577         if(this.csqcmodel_modelflags & MF_TRACER)
 578                 tref = EFFECT_TR_WIZSPIKE.m_id;
 579         if(this.csqcmodel_modelflags & MF_ZOMGIB)
 580                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
 581         if(this.csqcmodel_modelflags & MF_TRACER2)
 582                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
 583         if(this.csqcmodel_modelflags & MF_TRACER3)
 584                 tref = EFFECT_TR_VORESPIKE.m_id;
 585
 586         this.traileffect = tref;
 587
 588         if(this.drawmask)
 589                 Projectile_DrawTrail(this, this.origin);
 590         else
 591                 Projectile_ResetTrail(this, this.origin);
 592
 593         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 594                 this.renderflags |= RF_ADDITIVE;
 595                 // also special in CSQCPlayer_GlowMod_Apply
 596
 597         if(this.csqcmodel_modelflags & MF_ROCKET)
 598         {
 599                 if(!this.snd_looping)
 600                 {
 601                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
 602                         this.snd_looping = CH_TRIGGER_SINGLE;
 603                 }
 604         }
 605         else
 606         {
 607                 if(this.snd_looping)
 608                 {
 609                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 610                         this.snd_looping = 0;
 611                 }
 612         }
 613 }
 614
 615 // general functions
 616 .int csqcmodel_predraw_run;
 617 .int anim_frame;
 618 .int anim_frame1time;
 619 .int anim_frame2;
 620 .int anim_frame2time;
 621 .int anim_saveframe;
 622 .int anim_saveframe1time;
 623 .int anim_saveframe2;
 624 .int anim_saveframe2time;
 625 .int anim_prev_pmove_flags;
 626 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
 627 {
 628         if(this.csqcmodel_predraw_run == framecount)
 629                 return;
 630         this.csqcmodel_predraw_run = framecount;
 631
 632         if(!this.modelindex || this.model == "null")
 633         {
 634                 this.drawmask = 0;
 635                 if(this.snd_looping > 0)
 636                 {
 637                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 638                         this.snd_looping = 0;
 639                 }
 640                 return;
 641         }
 642         else
 643                 this.drawmask = MASK_NORMAL;
 644
 645         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
 646         {
 647                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
 648                 CSQCPlayer_LOD_Apply(this);
 649
 650                 if(!isplayer)
 651                 {
 652                         skeleton_loadinfo(this);
 653                         bool doblend = (this.bone_upperbody >= 0);
 654                         CSQCPlayer_FallbackFrame_Apply(this);
 655                         if(doblend)
 656                         {
 657                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 658                         }
 659                         else
 660                         {
 661                                 free_skeleton_from_frames(this);
 662                                 // just in case, clear these (we're animating in frame and frame3)
 663                                 this.lerpfrac = 0;
 664                                 this.lerpfrac4 = 0;
 665                         }
 666                 }
 667                 else
 668                 {
 669                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 670                         skeleton_loadinfo(this);
 671                         bool doblend = (this.bone_upperbody >= 0);
 672                         bool onground = 0;
 673                         if(this == csqcplayer)
 674                         {
 675                                 if(IS_ONGROUND(this))
 676                                         onground = 1;
 677                                 this.anim_prev_pmove_flags = this.flags;
 678                                 if(this.flags & FL_DUCKED)
 679                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
 680                                 else if(this.anim_state & ANIMSTATE_DUCK)
 681                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
 682                         }
 683                         else
 684                         {
 685                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
 686                                 if(trace_startsolid || trace_fraction < 1)
 687                                         onground = 1;
 688                                 // predicted clients handle smoothing in the prediction code
 689                                 this.origin = CSQCModel_ApplyStairSmoothing(this, onground, this.origin);
 690                         }
 691                         animdecide_load_if_needed(this);
 692                         animdecide_setimplicitstate(this, onground);
 693                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 694                         int sf = 0;
 695                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
 696                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 697                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
 698                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 699                         this.anim_saveframe = this.anim_frame;
 700                         this.anim_saveframe1time = this.anim_frame1time;
 701                         this.anim_saveframe2 = this.anim_frame2;
 702                         this.anim_saveframe2time = this.anim_frame2time;
 703                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
 704                         // This ensures that .frame etc. are always written.
 705                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
 706                         this.lerpfrac = (doblend ? 0.5 : 0);
 707                         this.frame = this.anim_frame;
 708                         this.frame1time = this.anim_frame1time;
 709                         this.frame2 = this.anim_frame2;
 710                         this.frame2time = this.anim_frame2time;
 711                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
 712                         CSQCModel_InterpolateAnimation_2To4_Do(this);
 713                         if(doblend)
 714                         {
 715                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 716                         }
 717                         else
 718                         {
 719                                 free_skeleton_from_frames(this);
 720                                 // just in case, clear these (we're animating in frame and frame3)
 721                                 this.lerpfrac = 0;
 722                                 this.lerpfrac4 = 0;
 723                         }
 724                 }
 725         }
 726
 727         CSQCModel_AutoTagIndex_Apply(this);
 728
 729         CSQCModel_Effects_Apply(this);
 730 }
 731
 732 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 733 {
 734         // interpolate v_angle
 735         this.iflags |= IFLAG_V_ANGLE_X;
 736         // revert to values from server
 737         CSQCModel_Effects_PreUpdate(this);
 738         if((this.isplayermodel & ISPLAYER_MODEL))
 739         {
 740                 if(!isplayer)
 741                         CSQCPlayer_FallbackFrame_PreUpdate(this);
 742                 CSQCPlayer_ModelAppearance_PreUpdate(this);
 743         }
 744 }
 745
 746 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 747 {
 748         // is it a player model? (shared state)
 749         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" ||
 750                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
 751         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
 752         this.csqcmodel_isdead = false; // workaround for dead players who become a spectator
 753
 754         // save values set by server
 755         if((this.isplayermodel & ISPLAYER_MODEL))
 756         {
 757                 CSQCPlayer_ModelAppearance_PostUpdate(this);
 758                 if(isplayer)
 759                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
 760                 else
 761                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
 762         }
 763         CSQCModel_Effects_PostUpdate(this);
 764 }